lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   7 ;;   2008, 2009, 2010 Free Software Foundation, Inc.
   8 ;; Based partially on earlier release by Lucid.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defcustom selection-coding-system nil
  30   "Coding system for communicating with other X clients.
  31
  32 When sending text via selection and clipboard, if the target
  33 data-type matches with the type of this coding system, it is used
  34 for encoding the text.  Otherwise (including the case that this
  35 variable is nil), a proper coding system is used as below:
  36
  37 data-type       coding system
  38 ---------       -------------
  39 UTF8_STRING     utf-8
  40 COMPOUND_TEXT   compound-text-with-extensions
  41 STRING          iso-latin-1
  42 C_STRING        no-conversion
  43
  44 When receiving text, if this coding system is non-nil, it is used
  45 for decoding regardless of the data-type.  If this is nil, a
  46 proper coding system is used according to the data-type as above.
  47
  48 See also the documentation of the variable `x-select-request-type' how
  49 to control which data-type to request for receiving text.
  50
  51 The default value is nil."
  52   :type 'coding-system
  53   :group 'mule
  54   ;; Default was compound-text-with-extensions in 22.x (pre-unicode).
  55   :version "23.1"
  56   :set (lambda (symbol value)
  57          (set-selection-coding-system value)
  58          (set symbol value)))
  59
  60 (defvar next-selection-coding-system nil
  61   "Coding system for the next communication with other X clients.
  62 Usually, `selection-coding-system' is used for communicating with
  63 other X clients.  But, if this variable is set, it is used for
  64 the next communication only.  After the communication, this
  65 variable is set to nil.")
  66
  67 (declare-function x-get-selection-internal "xselect.c"
  68                   (selection-symbol target-type &optional time-stamp))
  69
  70 ;; Only declared obsolete in 23.3.
  71 (define-obsolete-function-alias 'x-selection 'x-get-selection "at least 19.34")
  72
  73 (defun x-get-selection (&optional type data-type)
  74   "Return the value of an X Windows selection.
  75 The argument TYPE (default `PRIMARY') says which selection,
  76 and the argument DATA-TYPE (default `STRING') says
  77 how to convert the data.
  78
  79 TYPE may be any symbol \(but nil stands for `PRIMARY').  However,
  80 only a few symbols are commonly used.  They conventionally have
  81 all upper-case names.  The most often used ones, in addition to
  82 `PRIMARY', are `SECONDARY' and `CLIPBOARD'.
  83
  84 DATA-TYPE is usually `STRING', but can also be one of the symbols
  85 in `selection-converter-alist', which see."
  86   (let ((data (x-get-selection-internal (or type 'PRIMARY)
  87                                         (or data-type 'STRING)))
  88         coding)
  89     (when (and (stringp data)
  90                (setq data-type (get-text-property 0 'foreign-selection data)))
  91       (setq coding (or next-selection-coding-system
  92                        selection-coding-system
  93                        (cond ((eq data-type 'UTF8_STRING)
  94                               'utf-8)
  95                              ((eq data-type 'COMPOUND_TEXT)
  96                               'compound-text-with-extensions)
  97                              ((eq data-type 'C_STRING)
  98                               nil)
  99                              ((eq data-type 'STRING)
 100                               'iso-8859-1)
 101                              (t
 102                               (error "Unknow selection data type: %S" type))))
 103             data (if coding (decode-coding-string data coding)
 104                    (string-to-multibyte data)))
 105       (setq next-selection-coding-system nil)
 106       (put-text-property 0 (length data) 'foreign-selection data-type data))
 107     data))
 108
 109 (defun x-get-clipboard ()
 110   "Return text pasted to the clipboard."
 111   (x-get-selection-internal 'CLIPBOARD 'STRING))
 112
 113 (declare-function x-own-selection-internal "xselect.c"
 114                   (selection-name selection-value))
 115 (declare-function x-disown-selection-internal "xselect.c"
 116                   (selection &optional time))
 117
 118 (defun x-set-selection (type data)
 119   "Make an X selection of type TYPE and value DATA.
 120 The argument TYPE (nil means `PRIMARY') says which selection, and
 121 DATA specifies the contents.  TYPE must be a symbol.  \(It can also
 122 be a string, which stands for the symbol with that name, but this
 123 is considered obsolete.)  DATA may be a string, a symbol, an
 124 integer (or a cons of two integers or list of two integers).
 125
 126 The selection may also be a cons of two markers pointing to the same buffer,
 127 or an overlay.  In these cases, the selection is considered to be the text
 128 between the markers *at whatever time the selection is examined*.
 129 Thus, editing done in the buffer after you specify the selection
 130 can alter the effective value of the selection.
 131
 132 The data may also be a vector of valid non-vector selection values.
 133
 134 The return value is DATA.
 135
 136 Interactively, this command sets the primary selection.  Without
 137 prefix argument, it reads the selection in the minibuffer.  With
 138 prefix argument, it uses the text of the region as the selection value.
 139
 140 Note that on MS-Windows, primary and secondary selections set by Emacs
 141 are not available to other programs."
 142   (interactive (if (not current-prefix-arg)
 143                    (list 'PRIMARY (read-string "Set text for pasting: "))
 144                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
 145   (if (stringp type) (setq type (intern type)))
 146   (or (x-valid-simple-selection-p data)
 147       (and (vectorp data)
 148            (let ((valid t)
 149                  (i (1- (length data))))
 150              (while (>= i 0)
 151                (or (x-valid-simple-selection-p (aref data i))
 152                    (setq valid nil))
 153                (setq i (1- i)))
 154              valid))
 155       (signal 'error (list "invalid selection" data)))
 156   (or type (setq type 'PRIMARY))
 157   (if data
 158       (x-own-selection-internal type data)
 159     (x-disown-selection-internal type))
 160   data)
 161
 162 (defun x-valid-simple-selection-p (data)
 163   (or (bufferp data)
 164       (and (consp data)
 165            (markerp (car data))
 166            (markerp (cdr data))
 167            (marker-buffer (car data))
 168            (buffer-name (marker-buffer (car data)))
 169            (eq (marker-buffer (car data))
 170                (marker-buffer (cdr data))))
 171       (stringp data)
 172       (and (overlayp data)
 173            (overlay-buffer data)
 174            (buffer-name (overlay-buffer data)))
 175       (symbolp data)
 176       (integerp data)))
 177 \f
 178 ;;; Cut Buffer support
 179
 180 (declare-function x-get-cut-buffer-internal "xselect.c")
 181
 182 (defun x-get-cut-buffer (&optional which-one)
 183   "Return the value of one of the 8 X server cut-buffers.
 184 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 185 Cut buffers are considered obsolete; you should use selections instead."
 186   (x-get-cut-buffer-internal
 187    (if which-one
 188        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 189               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 190              which-one)
 191      'CUT_BUFFER0)))
 192
 193 (declare-function x-rotate-cut-buffers-internal "xselect.c")
 194 (declare-function x-store-cut-buffer-internal "xselect.c")
 195
 196 (defun x-set-cut-buffer (string &optional push)
 197   "Store STRING into the X server's primary cut buffer.
 198 If PUSH is non-nil, also rotate the cut buffers:
 199 this means the previous value of the primary cut buffer moves to the second
 200 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 201 Cut buffers are considered obsolete; you should use selections instead."
 202   (or (stringp string) (signal 'wrong-type-argument (list 'stringp string)))
 203   (if push
 204       (x-rotate-cut-buffers-internal 1))
 205   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 206
 207 \f
 208 ;; Functions to convert the selection into various other selection types.
 209 ;; Every selection type that Emacs handles is implemented this way, except
 210 ;; for TIMESTAMP, which is a special case.
 211
 212 (defun xselect--selection-bounds (value)
 213   "Return bounds of X selection value VALUE.
 214 The return value is a list (BEG END BUF) if VALUE is a cons of
 215 two markers or an overlay.  Otherwise, it is nil."
 216   (cond ((bufferp value)
 217          (with-current-buffer value
 218            (when (mark t)
 219              (list (mark t) (point) value))))
 220         ((and (consp value)
 221               (markerp (car value))
 222               (markerp (cdr value)))
 223          (when (and (marker-buffer (car value))
 224                     (buffer-name (marker-buffer (car value)))
 225                     (eq (marker-buffer (car value))
 226                         (marker-buffer (cdr value))))
 227            (list (marker-position (car value))
 228                  (marker-position (cdr value))
 229                  (marker-buffer (car value)))))
 230         ((overlayp value)
 231          (when (overlay-buffer value)
 232            (list (overlay-start value)
 233                  (overlay-end value)
 234                  (overlay-buffer value))))))
 235
 236 (defun xselect--int-to-cons (n)
 237   (cons (ash n -16) (logand n 65535)))
 238
 239 (defun xselect-convert-to-string (selection type value)
 240   (let (str coding)
 241     ;; Get the actual string from VALUE.
 242     (cond ((stringp value)
 243            (setq str value))
 244           ((setq value (xselect--selection-bounds value))
 245            (with-current-buffer (nth 2 value)
 246              (setq str (buffer-substring (nth 0 value)
 247                                          (nth 1 value))))))
 248     (when str
 249       ;; If TYPE is nil, this is a local request, thus return STR as
 250       ;; is.  Otherwise, encode STR.
 251       (if (not type)
 252           str
 253         (setq coding (or next-selection-coding-system selection-coding-system))
 254         (if coding
 255             (setq coding (coding-system-base coding)))
 256         (let ((inhibit-read-only t))
 257           ;; Suppress producing escape sequences for compositions.
 258           (remove-text-properties 0 (length str) '(composition nil) str)
 259           (if (eq type 'TEXT)
 260               ;; TEXT is a polymorphic target.  We must select the
 261               ;; actual type from `UTF8_STRING', `COMPOUND_TEXT',
 262               ;; `STRING', and `C_STRING'.
 263               (if (not (multibyte-string-p str))
 264                   (setq type 'C_STRING)
 265                 (let (non-latin-1 non-unicode eight-bit)
 266                   (mapc #'(lambda (x)
 267                             (if (>= x #x100)
 268                                 (if (< x #x110000)
 269                                     (setq non-latin-1 t)
 270                                   (if (< x #x3FFF80)
 271                                       (setq non-unicode t)
 272                                     (setq eight-bit t)))))
 273                         str)
 274                   (setq type (if non-unicode 'COMPOUND_TEXT
 275                                (if non-latin-1 'UTF8_STRING
 276                                  (if eight-bit 'C_STRING 'STRING)))))))
 277           (cond
 278            ((eq type 'UTF8_STRING)
 279             (if (or (not coding)
 280                     (not (eq (coding-system-type coding) 'utf-8)))
 281                 (setq coding 'utf-8))
 282             (setq str (encode-coding-string str coding)))
 283
 284            ((eq type 'STRING)
 285             (if (or (not coding)
 286                     (not (eq (coding-system-type coding) 'charset)))
 287                 (setq coding 'iso-8859-1))
 288             (setq str (encode-coding-string str coding)))
 289
 290            ((eq type 'COMPOUND_TEXT)
 291             (if (or (not coding)
 292                     (not (eq (coding-system-type coding) 'iso-2022)))
 293                 (setq coding 'compound-text-with-extensions))
 294             (setq str (encode-coding-string str coding)))
 295
 296            ((eq type 'C_STRING)
 297             (setq str (string-make-unibyte str)))
 298
 299            (t
 300             (error "Unknown selection type: %S" type)))))
 301
 302       (setq next-selection-coding-system nil)
 303       (cons type str))))
 304
 305 (defun xselect-convert-to-length (selection type value)
 306   (let ((len (cond ((stringp value)
 307                     (length value))
 308                    ((setq value (xselect--selection-bounds value))
 309                     (abs (- (nth 0 value) (nth 1 value)))))))
 310     (if len
 311         (xselect--int-to-cons len))))
 312
 313 (defun xselect-convert-to-targets (selection type value)
 314   ;; return a vector of atoms, but remove duplicates first.
 315   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 316          (rest all))
 317     (while rest
 318       (cond ((memq (car rest) (cdr rest))
 319              (setcdr rest (delq (car rest) (cdr rest))))
 320             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 321              (setcdr rest (cdr (cdr rest))))
 322             (t
 323              (setq rest (cdr rest)))))
 324     (apply 'vector all)))
 325
 326 (defun xselect-convert-to-delete (selection type value)
 327   (x-disown-selection-internal selection)
 328   ;; A return value of nil means that we do not know how to do this conversion,
 329   ;; and replies with an "error".  A return value of NULL means that we have
 330   ;; done the conversion (and any side-effects) but have no value to return.
 331   'NULL)
 332
 333 (defun xselect-convert-to-filename (selection type value)
 334   (when (setq value (xselect--selection-bounds value))
 335     (buffer-file-name (nth 2 value))))
 336
 337 (defun xselect-convert-to-charpos (selection type value)
 338   (when (setq value (xselect--selection-bounds value))
 339     (let ((beg (1- (nth 0 value))) ; zero-based
 340           (end (1- (nth 1 value))))
 341       (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 342                           (xselect--int-to-cons (max beg end)))))))
 343
 344 (defun xselect-convert-to-lineno (selection type value)
 345   (when (setq value (xselect--selection-bounds value))
 346     (with-current-buffer (nth 2 value)
 347       (let ((beg (line-number-at-pos (nth 0 value)))
 348             (end (line-number-at-pos (nth 1 value))))
 349         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 350                             (xselect--int-to-cons (max beg end))))))))
 351
 352 (defun xselect-convert-to-colno (selection type value)
 353   (when (setq value (xselect--selection-bounds value))
 354     (with-current-buffer (nth 2 value)
 355       (let ((beg (progn (goto-char (nth 0 value)) (current-column)))
 356             (end (progn (goto-char (nth 1 value)) (current-column))))
 357         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 358                             (xselect--int-to-cons (max beg end))))))))
 359
 360 (defun xselect-convert-to-os (selection type size)
 361   (symbol-name system-type))
 362
 363 (defun xselect-convert-to-host (selection type size)
 364   (system-name))
 365
 366 (defun xselect-convert-to-user (selection type size)
 367   (user-full-name))
 368
 369 (defun xselect-convert-to-class (selection type size)
 370   "Convert selection to class.
 371 This function returns the string \"Emacs\"."
 372   "Emacs")
 373
 374 ;; We do not try to determine the name Emacs was invoked with,
 375 ;; because it is not clean for a program's behavior to depend on that.
 376 (defun xselect-convert-to-name (selection type size)
 377   "Convert selection to name.
 378 This function returns the string \"emacs\"."
 379   "emacs")
 380
 381 (defun xselect-convert-to-integer (selection type value)
 382   (and (integerp value)
 383        (xselect--int-to-cons value)))
 384
 385 (defun xselect-convert-to-atom (selection type value)
 386   (and (symbolp value) value))
 387
 388 (defun xselect-convert-to-identity (selection type value) ; used internally
 389   (vector value))
 390
 391 (setq selection-converter-alist
 392       '((TEXT . xselect-convert-to-string)
 393         (COMPOUND_TEXT . xselect-convert-to-string)
 394         (STRING . xselect-convert-to-string)
 395         (UTF8_STRING . xselect-convert-to-string)
 396         (TARGETS . xselect-convert-to-targets)
 397         (LENGTH . xselect-convert-to-length)
 398         (DELETE . xselect-convert-to-delete)
 399         (FILE_NAME . xselect-convert-to-filename)
 400         (CHARACTER_POSITION . xselect-convert-to-charpos)
 401         (LINE_NUMBER . xselect-convert-to-lineno)
 402         (COLUMN_NUMBER . xselect-convert-to-colno)
 403         (OWNER_OS . xselect-convert-to-os)
 404         (HOST_NAME . xselect-convert-to-host)
 405         (USER . xselect-convert-to-user)
 406         (CLASS . xselect-convert-to-class)
 407         (NAME . xselect-convert-to-name)
 408         (ATOM . xselect-convert-to-atom)
 409         (INTEGER . xselect-convert-to-integer)
 410         (_EMACS_INTERNAL . xselect-convert-to-identity)))
 411
 412 (provide 'select)
 413
 414 ;;; select.el ends here