lisp/gnus/mm-url.el

   1 ;;; mm-url.el --- a wrapper of url functions/commands for Gnus
   2
   3 ;; Copyright (C) 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; Some codes are stolen from w3 and url packages. Some are moved from
  25 ;; nnweb.
  26
  27 ;; TODO: Support POST, cookie.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'mm-util)
  34 (require 'gnus)
  35
  36 (defvar url-current-object)
  37 (defvar url-package-name)
  38 (defvar url-package-version)
  39
  40 (defgroup mm-url nil
  41   "A wrapper of url package and external url command for Gnus."
  42   :group 'gnus)
  43
  44 (defcustom mm-url-use-external (not
  45                                 (condition-case nil
  46                                     (require 'url)
  47                                   (error nil)))
  48   "*If non-nil, use external grab program `mm-url-program'."
  49   :version "22.1"
  50   :type 'boolean
  51   :group 'mm-url)
  52
  53 (defvar mm-url-predefined-programs
  54   '((wget "wget" "--user-agent=mm-url" "-q" "-O" "-")
  55     (w3m  "w3m" "-dump_source")
  56     (lynx "lynx" "-source")
  57     (curl "curl" "--silent" "--user-agent" "mm-url" "--location")))
  58
  59 (defcustom mm-url-program
  60   (cond
  61    ((executable-find "wget") 'wget)
  62    ((executable-find "w3m") 'w3m)
  63    ((executable-find "lynx") 'lynx)
  64    ((executable-find "curl") 'curl)
  65    (t "GET"))
  66   "The url grab program.
  67 Likely values are `wget', `w3m', `lynx' and `curl'."
  68   :version "22.1"
  69   :type '(choice
  70           (symbol :tag "wget" wget)
  71           (symbol :tag "w3m" w3m)
  72           (symbol :tag "lynx" lynx)
  73           (symbol :tag "curl" curl)
  74           (string :tag "other"))
  75   :group 'mm-url)
  76
  77 (defcustom mm-url-arguments nil
  78   "The arguments for `mm-url-program'."
  79   :version "22.1"
  80   :type '(repeat string)
  81   :group 'mm-url)
  82
  83 \f
  84 ;;; Internal variables
  85
  86 ;; Stolen from w3.
  87 (defvar mm-url-html-entities
  88   '(
  89     ;;(excl        .  33)
  90     (quot        .  34)
  91     ;;(num         .  35)
  92     ;;(dollar      .  36)
  93     ;;(percent     .  37)
  94     (amp         .  38)
  95     (rsquo       .  39)                 ; should be U+8217
  96     ;;(apos        .  39)
  97     ;;(lpar        .  40)
  98     ;;(rpar        .  41)
  99     ;;(ast         .  42)
 100     ;;(plus        .  43)
 101     ;;(comma       .  44)
 102     ;;(period      .  46)
 103     ;;(colon       .  58)
 104     ;;(semi        .  59)
 105     (lt          .  60)
 106     ;;(equals      .  61)
 107     (gt          .  62)
 108     ;;(quest       .  63)
 109     ;;(commat      .  64)
 110     ;;(lsqb        .  91)
 111     ;;(rsqb        .  93)
 112     (uarr        .  94)                 ; should be U+8593
 113     ;;(lowbar      .  95)
 114     (lsquo       .  96)                 ; should be U+8216
 115     (lcub        . 123)
 116     ;;(verbar      . 124)
 117     (rcub        . 125)
 118     (tilde       . 126)
 119     (nbsp        . 160)
 120     (iexcl       . 161)
 121     (cent        . 162)
 122     (pound       . 163)
 123     (curren      . 164)
 124     (yen         . 165)
 125     (brvbar      . 166)
 126     (sect        . 167)
 127     (uml         . 168)
 128     (copy        . 169)
 129     (ordf        . 170)
 130     (laquo       . 171)
 131     (not         . 172)
 132     (shy         . 173)
 133     (reg         . 174)
 134     (macr        . 175)
 135     (deg         . 176)
 136     (plusmn      . 177)
 137     (sup2        . 178)
 138     (sup3        . 179)
 139     (acute       . 180)
 140     (micro       . 181)
 141     (para        . 182)
 142     (middot      . 183)
 143     (cedil       . 184)
 144     (sup1        . 185)
 145     (ordm        . 186)
 146     (raquo       . 187)
 147     (frac14      . 188)
 148     (frac12      . 189)
 149     (frac34      . 190)
 150     (iquest      . 191)
 151     (Agrave      . 192)
 152     (Aacute      . 193)
 153     (Acirc       . 194)
 154     (Atilde      . 195)
 155     (Auml        . 196)
 156     (Aring       . 197)
 157     (AElig       . 198)
 158     (Ccedil      . 199)
 159     (Egrave      . 200)
 160     (Eacute      . 201)
 161     (Ecirc       . 202)
 162     (Euml        . 203)
 163     (Igrave      . 204)
 164     (Iacute      . 205)
 165     (Icirc       . 206)
 166     (Iuml        . 207)
 167     (ETH         . 208)
 168     (Ntilde      . 209)
 169     (Ograve      . 210)
 170     (Oacute      . 211)
 171     (Ocirc       . 212)
 172     (Otilde      . 213)
 173     (Ouml        . 214)
 174     (times       . 215)
 175     (Oslash      . 216)
 176     (Ugrave      . 217)
 177     (Uacute      . 218)
 178     (Ucirc       . 219)
 179     (Uuml        . 220)
 180     (Yacute      . 221)
 181     (THORN       . 222)
 182     (szlig       . 223)
 183     (agrave      . 224)
 184     (aacute      . 225)
 185     (acirc       . 226)
 186     (atilde      . 227)
 187     (auml        . 228)
 188     (aring       . 229)
 189     (aelig       . 230)
 190     (ccedil      . 231)
 191     (egrave      . 232)
 192     (eacute      . 233)
 193     (ecirc       . 234)
 194     (euml        . 235)
 195     (igrave      . 236)
 196     (iacute      . 237)
 197     (icirc       . 238)
 198     (iuml        . 239)
 199     (eth         . 240)
 200     (ntilde      . 241)
 201     (ograve      . 242)
 202     (oacute      . 243)
 203     (ocirc       . 244)
 204     (otilde      . 245)
 205     (ouml        . 246)
 206     (divide      . 247)
 207     (oslash      . 248)
 208     (ugrave      . 249)
 209     (uacute      . 250)
 210     (ucirc       . 251)
 211     (uuml        . 252)
 212     (yacute      . 253)
 213     (thorn       . 254)
 214     (yuml        . 255)
 215
 216     ;; Special handling of these
 217     (frac56      . "5/6")
 218     (frac16      . "1/6")
 219     (frac45      . "4/5")
 220     (frac35      . "3/5")
 221     (frac25      . "2/5")
 222     (frac15      . "1/5")
 223     (frac23      . "2/3")
 224     (frac13      . "1/3")
 225     (frac78      . "7/8")
 226     (frac58      . "5/8")
 227     (frac38      . "3/8")
 228     (frac18      . "1/8")
 229
 230     ;; The following 5 entities are not mentioned in the HTML 2.0
 231     ;; standard, nor in any other HTML proposed standard of which I
 232     ;; am aware.  I am not even sure they are ISO entity names.  ***
 233     ;; Hence, some arrangement should be made to give a bad HTML
 234     ;; message when they are seen.
 235     (ndash       .  45)
 236     (mdash       .  45)
 237     (emsp        .  32)
 238     (ensp        .  32)
 239     (sim         . 126)
 240     (le          . "<=")
 241     (agr         . "alpha")
 242     (rdquo       . "''")
 243     (ldquo       . "``")
 244     (trade       . "(TM)")
 245     ;; To be done
 246     ;; (shy      . ????) ; soft hyphen
 247     )
 248   "*An assoc list of entity names and how to actually display them.")
 249
 250 (defconst mm-url-unreserved-chars
 251   '(
 252     ?a ?b ?c ?d ?e ?f ?g ?h ?i ?j ?k ?l ?m ?n ?o ?p ?q ?r ?s ?t ?u ?v ?w ?x ?y ?z
 253     ?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z
 254     ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9
 255     ?- ?_ ?. ?! ?~ ?* ?' ?\( ?\))
 256   "A list of characters that are _NOT_ reserved in the URL spec.
 257 This is taken from RFC 2396.")
 258
 259 (defun mm-url-load-url ()
 260   "Load `url-insert-file-contents'."
 261   (unless (condition-case ()
 262               (progn
 263                 (require 'url-handlers)
 264                 (require 'url-parse)
 265                 (require 'url-vars))
 266             (error nil))
 267     ;; w3-4.0pre0.46 or earlier version.
 268     (require 'w3-vars)
 269     (require 'url)))
 270
 271 ;;;###autoload
 272 (defun mm-url-insert-file-contents (url)
 273   "Insert file contents of URL.
 274 If `mm-url-use-external' is non-nil, use `mm-url-program'."
 275   (if mm-url-use-external
 276       (progn
 277         (if (string-match "^file:/+" url)
 278             (insert-file-contents (substring url (1- (match-end 0))))
 279           (mm-url-insert-file-contents-external url))
 280         (goto-char (point-min))
 281         (if (fboundp 'url-generic-parse-url)
 282             (setq url-current-object
 283                   (url-generic-parse-url url)))
 284         (list url (buffer-size)))
 285     (mm-url-load-url)
 286     (let ((name buffer-file-name)
 287           (url-request-extra-headers
 288            ;; ISTM setting a Connection header was a workaround for
 289            ;; older versions of url included with w3, but it does more
 290            ;; harm than good with the one shipped with Emacs. --ansel
 291            (if (not (and (boundp 'url-version)
 292                          (equal url-version "Emacs")))
 293                (list (cons "Connection" "Close"))))
 294           result)
 295       (setq result (url-insert-file-contents url))
 296       (save-excursion
 297         (goto-char (point-min))
 298         (while (re-search-forward "\r 1000\r ?" nil t)
 299           (replace-match "")))
 300       (setq buffer-file-name name)
 301       (if (and (fboundp 'url-generic-parse-url)
 302                (listp result))
 303           (setq url-current-object (url-generic-parse-url
 304                                     (car result))))
 305       result)))
 306
 307 ;;;###autoload
 308 (defun mm-url-insert-file-contents-external (url)
 309   "Insert file contents of URL using `mm-url-program'."
 310   (let (program args)
 311     (if (symbolp mm-url-program)
 312         (let ((item (cdr (assq mm-url-program mm-url-predefined-programs))))
 313           (setq program (car item)
 314                 args (append (cdr item) (list url))))
 315       (setq program mm-url-program
 316             args (append mm-url-arguments (list url))))
 317     (unless (eq 0 (apply 'call-process program nil t nil args))
 318       (error "Couldn't fetch %s" url))))
 319
 320 (defvar mm-url-timeout 30
 321   "The number of seconds before timing out an URL fetch.")
 322
 323 (defvar mm-url-retries 10
 324   "The number of retries after timing out when fetching an URL.")
 325
 326 (defun mm-url-insert (url &optional follow-refresh)
 327   "Insert the contents from an URL in the current buffer.
 328 If FOLLOW-REFRESH is non-nil, redirect refresh url in META."
 329   (let ((times mm-url-retries)
 330         (done nil)
 331         (first t)
 332         result)
 333     (while (and (not (zerop (decf times)))
 334                 (not done))
 335       (with-timeout (mm-url-timeout)
 336         (unless first
 337           (message "Trying again (%s)..." (- mm-url-retries times)))
 338         (setq first nil)
 339         (if follow-refresh
 340             (save-restriction
 341               (narrow-to-region (point) (point))
 342               (mm-url-insert-file-contents url)
 343               (goto-char (point-min))
 344               (when (re-search-forward
 345                      "<meta[ \t\r\n]*http-equiv=\"Refresh\"[^>]*URL=\\([^\"]+\\)\"" nil t)
 346                 (let ((url (match-string 1)))
 347                   (delete-region (point-min) (point-max))
 348                   (setq result (mm-url-insert url t)))))
 349           (setq result (mm-url-insert-file-contents url)))
 350         (setq done t)))
 351     result))
 352
 353 (defun mm-url-decode-entities ()
 354   "Decode all HTML entities."
 355   (goto-char (point-min))
 356   (while (re-search-forward "&\\(#[0-9]+\\|#x[0-9a-f]+\\|[a-z]+[0-9]*\\);"
 357                             nil t)
 358     (let* ((entity (match-string 1))
 359            (elem (if (eq (aref entity 0) ?\#)
 360                      (let ((c
 361                             ;; Hex number: &#x3212
 362                             (if (eq (aref entity 1) ?x)
 363                                 (string-to-number (substring entity 2)
 364                                                   16)
 365                               ;; Decimal number: &#23
 366                               (string-to-number (substring entity 1)))))
 367                        (setq c (or (cdr (assq c mm-extra-numeric-entities))
 368                                    (mm-ucs-to-char c)))
 369                        (if (mm-char-or-char-int-p c) c ?#))
 370                    (or (cdr (assq (intern entity)
 371                                   mm-url-html-entities))
 372                        ?#))))
 373       (unless (stringp elem)
 374         (setq elem (char-to-string elem)))
 375       (replace-match elem t t))))
 376
 377 (defun mm-url-decode-entities-nbsp ()
 378   "Decode all HTML entities and &nbsp; to a space."
 379   (let ((mm-url-html-entities (cons '(nbsp . 32) mm-url-html-entities)))
 380     (mm-url-decode-entities)))
 381
 382 (defun mm-url-decode-entities-string (string)
 383   (with-temp-buffer
 384     (insert string)
 385     (mm-url-decode-entities)
 386     (buffer-string)))
 387
 388 (defun mm-url-form-encode-xwfu (chunk)
 389   "Escape characters in a string for application/x-www-form-urlencoded.
 390 Blasphemous crap because someone didn't think %20 was good enough for encoding
 391 spaces.  Die Die Die."
 392   ;; This will get rid of the 'attributes' specified by the file type,
 393   ;; which are useless for an application/x-www-form-urlencoded form.
 394   (if (consp chunk)
 395       (setq chunk (cdr chunk)))
 396
 397   (mapconcat
 398    (lambda (char)
 399      (cond
 400       ((= char ?  ) "+")
 401       ((memq char mm-url-unreserved-chars) (char-to-string char))
 402       (t (upcase (format "%%%02x" char)))))
 403    (mm-encode-coding-string chunk
 404                             (if (fboundp 'find-coding-systems-string)
 405                                 (car (find-coding-systems-string chunk))
 406                               buffer-file-coding-system))
 407    ""))
 408
 409 (defun mm-url-encode-www-form-urlencoded (pairs)
 410   "Return PAIRS encoded for forms."
 411   (mapconcat
 412    (lambda (data)
 413      (concat (mm-url-form-encode-xwfu (car data)) "="
 414              (mm-url-form-encode-xwfu (cdr data))))
 415    pairs "&"))
 416
 417 (autoload 'mml-compute-boundary "mml")
 418
 419 (defun mm-url-remove-markup ()
 420   "Remove all HTML markup, leaving just plain text."
 421   (goto-char (point-min))
 422   (while (search-forward "<!--" nil t)
 423     (delete-region (match-beginning 0)
 424                    (or (search-forward "-->" nil t)
 425                        (point-max))))
 426   (goto-char (point-min))
 427   (while (re-search-forward "<[^>]+>" nil t)
 428     (replace-match "" t t)))
 429
 430 (provide 'mm-url)
 431
 432 ;;; mm-url.el ends here