lisp/calendar/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2
   3 ;; Copyright (C) 1998-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   7 ;; Keywords: mail news util
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Time values come in several formats.  The oldest format is a cons
  27 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  28 ;; supported.  The other formats are the lists (HIGH LOW), (HIGH LOW
  29 ;; USEC), and (HIGH LOW USEC PSEC).  These formats specify the time
  30 ;; value equal to HIGH * 2^16 + LOW + USEC * 10^-6 + PSEC * 10^-12
  31 ;; seconds, where missing components are treated as zero.  HIGH can be
  32 ;; negative, either because the value is a time difference, or because
  33 ;; the machine supports negative time stamps that fall before the epoch.
  34 ;; The macro `with-decoded-time-value' and the function
  35 ;; `encode-time-value' make it easier to deal with these formats.
  36 ;; See `time-subtract' for an example of how to use them.
  37
  38 ;;; Code:
  39
  40 (defmacro with-decoded-time-value (varlist &rest body)
  41   "Decode a time value and bind it according to VARLIST, then eval BODY.
  42
  43 The value of the last form in BODY is returned.
  44
  45 Each element of the list VARLIST is a list of the form
  46 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [PICO-SYMBOL [TYPE-SYMBOL]] TIME-VALUE).
  47 The time value TIME-VALUE is decoded and the result it bound to
  48 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  49 The optional PICO-SYMBOL is bound to the picoseconds part.
  50
  51 The optional TYPE-SYMBOL is bound to the type of the time value.
  52 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  53 LOW), type 2 is the list (HIGH LOW MICRO), and type 3 is the
  54 list (HIGH LOW MICRO PICO)."
  55   (declare (indent 1)
  56            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  57                    body)))
  58   (if varlist
  59       (let* ((elt (pop varlist))
  60              (high (pop elt))
  61              (low (pop elt))
  62              (micro (pop elt))
  63              (pico (unless (<= (length elt) 2)
  64                      (pop elt)))
  65              (type (unless (eq (length elt) 1)
  66                      (pop elt)))
  67              (time-value (car elt))
  68              (gensym (make-symbol "time")))
  69         `(let* ,(append `((,gensym ,time-value)
  70                           (,high (pop ,gensym))
  71                           ,low ,micro)
  72                         (when pico `(,pico))
  73                         (when type `(,type)))
  74            (if (consp ,gensym)
  75                (progn
  76                  (setq ,low (pop ,gensym))
  77                  (if ,gensym
  78                      (progn
  79                        (setq ,micro (car ,gensym))
  80                        ,(cond (pico
  81                                `(if (cdr ,gensym)
  82                                     ,(append `(setq ,pico (cadr ,gensym))
  83                                              (when type `(,type 3)))
  84                                   ,(append `(setq ,pico 0)
  85                                            (when type `(,type 2)))))
  86                               (type
  87                                `(setq type 2))))
  88                    ,(append `(setq ,micro 0)
  89                             (when pico `(,pico 0))
  90                             (when type `(,type 1)))))
  91              ,(append `(setq ,low ,gensym ,micro 0)
  92                       (when pico `(,pico 0))
  93                       (when type `(,type 0))))
  94            (with-decoded-time-value ,varlist ,@body)))
  95     `(progn ,@body)))
  96
  97 (defun encode-time-value (high low micro pico &optional type)
  98   "Encode HIGH, LOW, MICRO, and PICO into a time value of type TYPE.
  99 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
 100 type 2 is (HIGH LOW MICRO), and type 3 is (HIGH LOW MICRO PICO).
 101
 102 For backward compatibility, if only four arguments are given,
 103 it is assumed that PICO was omitted and should be treated as zero."
 104   (cond
 105    ((eq type 0) (cons high low))
 106    ((eq type 1) (list high low))
 107    ((eq type 2) (list high low micro))
 108    ((eq type 3) (list high low micro pico))
 109    ((null type) (encode-time-value high low micro 0 pico))))
 110
 111 (autoload 'parse-time-string "parse-time")
 112 (autoload 'timezone-make-date-arpa-standard "timezone")
 113
 114 ;;;###autoload
 115 ;; `parse-time-string' isn't sufficiently general or robust.  It fails
 116 ;; to grok some of the formats that timezone does (e.g. dodgy
 117 ;; post-2000 stuff from some Elms) and either fails or returns bogus
 118 ;; values.  timezone-make-date-arpa-standard should help.
 119 (defun date-to-time (date)
 120   "Parse a string DATE that represents a date-time and return a time value.
 121 If DATE lacks timezone information, GMT is assumed."
 122   (condition-case ()
 123       (apply 'encode-time (parse-time-string date))
 124     (error (condition-case ()
 125                (apply 'encode-time
 126                       (parse-time-string
 127                        (timezone-make-date-arpa-standard date)))
 128              (error (error "Invalid date: %s" date))))))
 129
 130 ;; Bit of a mess.  Emacs has float-time since at least 21.1.
 131 ;; This file is synced to Gnus, and XEmacs packages may have been written
 132 ;; using time-to-seconds from the Gnus library.
 133 ;;;###autoload(if (or (featurep 'emacs)
 134 ;;;###autoload        (and (fboundp 'float-time)
 135 ;;;###autoload             (subrp (symbol-function 'float-time))))
 136 ;;;###autoload    (defalias 'time-to-seconds 'float-time)
 137 ;;;###autoload  (autoload 'time-to-seconds "time-date"))
 138
 139 (eval-when-compile
 140   (or (featurep 'emacs)
 141       (and (fboundp 'float-time)
 142            (subrp (symbol-function 'float-time)))
 143       (defun time-to-seconds (time)
 144         "Convert time value TIME to a floating point number."
 145         (with-decoded-time-value ((high low micro pico type time))
 146           (+ (* 1.0 high 65536)
 147              low
 148              (/ (+ (* micro 1e6) pico) 1e12))))))
 149
 150 ;;;###autoload
 151 (defun seconds-to-time (seconds)
 152   "Convert SECONDS (a floating point number) to a time value."
 153   (let* ((usec (* 1000000 (mod seconds 1)))
 154          (ps (round (* 1000000 (mod usec 1))))
 155          (us (floor usec))
 156          (lo (floor (mod seconds 65536)))
 157          (hi (floor seconds 65536)))
 158     (if (eq ps 1000000)
 159         (progn
 160           (setq ps 0)
 161           (setq us (1+ us))
 162           (if (eq us 1000000)
 163               (progn
 164                 (setq us 0)
 165                 (setq lo (1+ lo))
 166                 (if (eq lo 65536)
 167                     (progn
 168                       (setq lo 0)
 169                       (setq hi (1+ hi))))))))
 170     (list hi lo us ps)))
 171
 172 ;;;###autoload
 173 (defun time-less-p (t1 t2)
 174   "Return non-nil if time value T1 is earlier than time value T2."
 175   (with-decoded-time-value ((high1 low1 micro1 pico1 type1 t1)
 176                             (high2 low2 micro2 pico2 type2 t2))
 177     (or (< high1 high2)
 178         (and (= high1 high2)
 179              (or (< low1 low2)
 180                  (and (= low1 low2)
 181                       (or (< micro1 micro2)
 182                           (and (= micro1 micro2)
 183                                (< pico1 pico2)))))))))
 184
 185 ;;;###autoload
 186 (defun days-to-time (days)
 187   "Convert DAYS into a time value."
 188   (let* ((seconds (* 1.0 days 60 60 24))
 189          (high (condition-case nil (floor (/ seconds 65536))
 190                  (range-error most-positive-fixnum))))
 191     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 192                  (range-error 65535)))))
 193
 194 ;;;###autoload
 195 (defun time-since (time)
 196   "Return the time elapsed since TIME.
 197 TIME should be either a time value or a date-time string."
 198   (when (stringp time)
 199     ;; Convert date strings to internal time.
 200     (setq time (date-to-time time)))
 201   (time-subtract (current-time) time))
 202
 203 ;;;###autoload
 204 (defalias 'subtract-time 'time-subtract)
 205
 206 ;;;###autoload
 207 (defun time-subtract (t1 t2)
 208   "Subtract two time values, T1 minus T2.
 209 Return the difference in the format of a time value."
 210   (with-decoded-time-value ((high low micro pico type t1)
 211                             (high2 low2 micro2 pico2 type2 t2))
 212     (setq high (- high high2)
 213           low (- low low2)
 214           micro (- micro micro2)
 215           pico (- pico pico2)
 216           type (max type type2))
 217     (when (< pico 0)
 218       (setq micro (1- micro)
 219             pico (+ pico 1000000)))
 220     (when (< micro 0)
 221       (setq low (1- low)
 222             micro (+ micro 1000000)))
 223     (when (< low 0)
 224       (setq high (1- high)
 225             low (+ low 65536)))
 226     (encode-time-value high low micro pico type)))
 227
 228 ;;;###autoload
 229 (defun time-add (t1 t2)
 230   "Add two time values T1 and T2.  One should represent a time difference."
 231   (with-decoded-time-value ((high low micro pico type t1)
 232                             (high2 low2 micro2 pico2 type2 t2))
 233     (setq high (+ high high2)
 234           low (+ low low2)
 235           micro (+ micro micro2)
 236           pico (+ pico pico2)
 237           type (max type type2))
 238     (when (>= pico 1000000)
 239       (setq micro (1+ micro)
 240             pico (- pico 1000000)))
 241     (when (>= micro 1000000)
 242       (setq low (1+ low)
 243             micro (- micro 1000000)))
 244     (when (>= low 65536)
 245       (setq high (1+ high)
 246             low (- low 65536)))
 247     (encode-time-value high low micro pico type)))
 248
 249 ;;;###autoload
 250 (defun date-to-day (date)
 251   "Return the number of days between year 1 and DATE.
 252 DATE should be a date-time string."
 253   (time-to-days (date-to-time date)))
 254
 255 ;;;###autoload
 256 (defun days-between (date1 date2)
 257   "Return the number of days between DATE1 and DATE2.
 258 DATE1 and DATE2 should be date-time strings."
 259   (- (date-to-day date1) (date-to-day date2)))
 260
 261 ;;;###autoload
 262 (defun date-leap-year-p (year)
 263   "Return t if YEAR is a leap year."
 264   (or (and (zerop (% year 4))
 265            (not (zerop (% year 100))))
 266       (zerop (% year 400))))
 267
 268 ;;;###autoload
 269 (defun time-to-day-in-year (time)
 270   "Return the day number within the year corresponding to TIME."
 271   (let* ((tim (decode-time time))
 272          (month (nth 4 tim))
 273          (day (nth 3 tim))
 274          (year (nth 5 tim))
 275          (day-of-year (+ day (* 31 (1- month)))))
 276     (when (> month 2)
 277       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 278       (when (date-leap-year-p year)
 279         (setq day-of-year (1+ day-of-year))))
 280     day-of-year))
 281
 282 ;;;###autoload
 283 (defun time-to-days (time)
 284   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 285 TIME should be a time value.
 286 The Gregorian date Sunday, December 31, 1bce is imaginary."
 287   (let* ((tim (decode-time time))
 288          (year (nth 5 tim)))
 289     (+ (time-to-day-in-year time)       ;       Days this year
 290        (* 365 (1- year))                ;       + Days in prior years
 291        (/ (1- year) 4)                  ;       + Julian leap years
 292        (- (/ (1- year) 100))            ;       - century years
 293        (/ (1- year) 400))))             ;       + Gregorian leap years
 294
 295 (defun time-to-number-of-days (time)
 296   "Return the number of days represented by TIME.
 297 Returns a floating point number."
 298   (/ (funcall (eval-when-compile
 299                 (if (or (featurep 'emacs)
 300                         (and (fboundp 'float-time)
 301                              (subrp (symbol-function 'float-time))))
 302                     'float-time
 303                   'time-to-seconds)) time) (* 60 60 24)))
 304
 305 ;;;###autoload
 306 (defun safe-date-to-time (date)
 307   "Parse a string DATE that represents a date-time and return a time value.
 308 If DATE is malformed, return a time value of zeros."
 309   (condition-case ()
 310       (date-to-time date)
 311     (error '(0 0))))
 312
 313 \f
 314 ;;;###autoload
 315 (defun format-seconds (string seconds)
 316   "Use format control STRING to format the number SECONDS.
 317 The valid format specifiers are:
 318 %y is the number of (365-day) years.
 319 %d is the number of days.
 320 %h is the number of hours.
 321 %m is the number of minutes.
 322 %s is the number of seconds.
 323 %z is a non-printing control flag (see below).
 324 %% is a literal \"%\".
 325
 326 Upper-case specifiers are followed by the unit-name (e.g. \"years\").
 327 Lower-case specifiers return only the unit.
 328
 329 \"%\" may be followed by a number specifying a width, with an
 330 optional leading \".\" for zero-padding.  For example, \"%.3Y\" will
 331 return something of the form \"001 year\".
 332
 333 The \"%z\" specifier does not print anything.  When it is used, specifiers
 334 must be given in order of decreasing size.  To the left of \"%z\", nothing
 335 is output until the first non-zero unit is encountered.
 336
 337 This function does not work for SECONDS greater than `most-positive-fixnum'."
 338   (let ((start 0)
 339         (units '(("y" "year"   31536000)
 340                  ("d" "day"       86400)
 341                  ("h" "hour"       3600)
 342                  ("m" "minute"       60)
 343                  ("s" "second"        1)
 344                  ("z")))
 345         (case-fold-search t)
 346         spec match usedunits zeroflag larger prev name unit num zeropos)
 347     (while (string-match "%\\.?[0-9]*\\(.\\)" string start)
 348       (setq start (match-end 0)
 349             spec (match-string 1 string))
 350       (unless (string-equal spec "%")
 351         (or (setq match (assoc (downcase spec) units))
 352             (error "Bad format specifier: `%s'" spec))
 353         (if (assoc (downcase spec) usedunits)
 354             (error "Multiple instances of specifier: `%s'" spec))
 355         (if (string-equal (car match) "z")
 356             (setq zeroflag t)
 357           (unless larger
 358             (setq unit (nth 2 match)
 359                   larger (and prev (> unit prev))
 360                   prev unit)))
 361         (push match usedunits)))
 362     (and zeroflag larger
 363          (error "Units are not in decreasing order of size"))
 364     (dolist (u units)
 365       (setq spec (car u)
 366             name (cadr u)
 367             unit (nth 2 u))
 368       (when (string-match (format "%%\\(\\.?[0-9]+\\)?\\(%s\\)" spec) string)
 369         (if (string-equal spec "z")     ; must be last in units
 370             (setq string
 371                   (replace-regexp-in-string
 372                    "%z" ""
 373                    (substring string (min (or zeropos (match-end 0))
 374                                           (match-beginning 0)))))
 375           ;; Cf article-make-date-line in gnus-art.
 376           (setq num (floor seconds unit)
 377                 seconds (- seconds (* num unit)))
 378           ;; Start position of the first non-zero unit.
 379           (or zeropos
 380               (setq zeropos (unless (zerop num) (match-beginning 0))))
 381           (setq string
 382                 (replace-match
 383                  (format (concat "%" (match-string 1 string) "d%s") num
 384                          (if (string-equal (match-string 2 string) spec)
 385                              ""       ; lower-case, no unit-name
 386                            (format " %s%s" name
 387                                    (if (= num 1) "" "s"))))
 388                  t t string))))))
 389   (replace-regexp-in-string "%%" "%" string))
 390
 391
 392 (provide 'time-date)
 393
 394 ;;; time-date.el ends here