lisp/gnus/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nnmail)
  34 (require 'gnus-start)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nnmh)
  39
  40 (defvoo nnmh-directory message-directory
  41   "Mail spool directory.")
  42
  43 (defvoo nnmh-get-new-mail t
  44   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  45
  46 (defvoo nnmh-prepare-save-mail-hook nil
  47   "Hook run narrowed to an article before saving.")
  48
  49 (defvoo nnmh-be-safe nil
  50   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  51 Go through the .nnmh-articles file and compare with the actual
  52 articles in this folder.  The articles that are \"new\" will be marked
  53 as unread by Gnus.")
  54
  55 \f
  56
  57 (defconst nnmh-version "nnmh 1.0"
  58   "nnmh version.")
  59
  60 (defvoo nnmh-current-directory nil
  61   "Current news group directory.")
  62
  63 (defvoo nnmh-status-string "")
  64 (defvoo nnmh-group-alist nil)
  65 ;; Don't even think about setting this variable.  It does not exist.
  66 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  67 ;; dynamically by certain functions in nndraft.
  68 (defvar nnmh-allow-delete-final nil)
  69
  70 \f
  71
  72 ;;; Interface functions.
  73
  74 (nnoo-define-basics nnmh)
  75
  76 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  77   (with-current-buffer nntp-server-buffer
  78     (erase-buffer)
  79     (let* ((file nil)
  80            (number (length articles))
  81            (large (and (numberp nnmail-large-newsgroup)
  82                        (> number nnmail-large-newsgroup)))
  83            (count 0)
  84            (file-name-coding-system nnmail-pathname-coding-system)
  85            beg article)
  86       (nnmh-possibly-change-directory newsgroup server)
  87       ;; We don't support fetching by Message-ID.
  88       (if (stringp (car articles))
  89           'headers
  90         (while articles
  91           (when (and (file-exists-p
  92                       (setq file (concat (file-name-as-directory
  93                                           nnmh-current-directory)
  94                                          (int-to-string
  95                                           (setq article (pop articles))))))
  96                      (not (file-directory-p file)))
  97             (insert (format "221 %d Article retrieved.\n" article))
  98             (setq beg (point))
  99             (nnheader-insert-head file)
 100             (goto-char beg)
 101             (if (search-forward "\n\n" nil t)
 102                 (forward-char -1)
 103               (goto-char (point-max))
 104               (insert "\n\n"))
 105             (insert ".\n")
 106             (delete-region (point) (point-max)))
 107           (setq count (1+ count))
 108
 109           (and large
 110                (zerop (% count 20))
 111                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 112                                  (/ (* count 100) number))))
 113
 114         (when large
 115           (nnheader-message 5 "nnmh: Receiving headers...done"))
 116
 117         (nnheader-fold-continuation-lines)
 118         'headers))))
 119
 120 (deffoo nnmh-open-server (server &optional defs)
 121   (nnoo-change-server 'nnmh server defs)
 122   (when (not (file-exists-p nnmh-directory))
 123     (condition-case ()
 124         (make-directory nnmh-directory t)
 125       (error t)))
 126   (cond
 127    ((not (file-exists-p nnmh-directory))
 128     (nnmh-close-server)
 129     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 130    ((not (file-directory-p (file-truename nnmh-directory)))
 131     (nnmh-close-server)
 132     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 133    (t
 134     (nnheader-report 'nnmh "Opened server %s using directory %s"
 135                      server nnmh-directory)
 136     t)))
 137
 138 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 139   (nnmh-possibly-change-directory newsgroup server)
 140   (let ((file (if (stringp id)
 141                   nil
 142                 (concat nnmh-current-directory (int-to-string id))))
 143         (file-name-coding-system nnmail-pathname-coding-system)
 144         (nntp-server-buffer (or buffer nntp-server-buffer)))
 145     (and (stringp file)
 146          (file-exists-p file)
 147          (not (file-directory-p file))
 148          (save-excursion (nnmail-find-file file))
 149          (string-to-number (file-name-nondirectory file)))))
 150
 151 (deffoo nnmh-request-group (group &optional server dont-check info)
 152   (nnheader-init-server-buffer)
 153   (nnmh-possibly-change-directory group server)
 154   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 155         (file-name-coding-system nnmail-pathname-coding-system)
 156         dir)
 157     (cond
 158      ((not (file-directory-p pathname))
 159       (nnheader-report
 160        'nnmh "Can't select group (no such directory): %s" group))
 161      (t
 162       (setq nnmh-current-directory pathname)
 163       (and nnmh-get-new-mail
 164            nnmh-be-safe
 165            (nnmh-update-gnus-unreads group))
 166       (cond
 167        (dont-check
 168         (nnheader-report 'nnmh "Selected group %s" group)
 169         t)
 170        (t
 171         ;; Re-scan the directory if it's on a foreign system.
 172         (nnheader-re-read-dir pathname)
 173         (setq dir
 174               (sort
 175                (mapcar 'string-to-number
 176                        (directory-files pathname nil "^[0-9]+$" t))
 177                '<))
 178         (cond
 179          (dir
 180           (setq nnmh-group-alist
 181                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 182           (push (list group (cons (car dir) (car (last dir))))
 183                 nnmh-group-alist)
 184           (nnheader-report 'nnmh "Selected group %s" group)
 185           (nnheader-insert
 186            "211 %d %d %d %s\n" (length dir) (car dir)
 187            (car (last dir)) group))
 188          (t
 189           (nnheader-report 'nnmh "Empty group %s" group)
 190           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 191
 192 (deffoo nnmh-request-scan (&optional group server)
 193   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 194
 195 (deffoo nnmh-request-list (&optional server dir)
 196   (nnheader-insert "")
 197   (nnmh-possibly-change-directory nil server)
 198   (let ((file-name-coding-system nnmail-pathname-coding-system)
 199         (nnmh-toplev
 200          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 201     (nnmh-request-list-1 nnmh-toplev))
 202   (setq nnmh-group-alist (nnmail-get-active))
 203   t)
 204
 205 (defvar nnmh-toplev)
 206 (defun nnmh-request-list-1 (dir)
 207   (setq dir (expand-file-name dir))
 208   ;; Recurse down all directories.
 209   (let ((files (nnheader-directory-files dir t nil t))
 210         (max 0)
 211         min rdir num subdirectoriesp file)
 212     ;; Recurse down directories.
 213     (setq subdirectoriesp
 214           ;; nth 1 of file-attributes always 1 on MS Windows :(
 215           (/= (nth 1 (file-attributes (file-truename dir))) 2))
 216     (dolist (rdir files)
 217       (if (or (not subdirectoriesp)
 218               (file-regular-p rdir))
 219           (progn
 220             (setq file (file-name-nondirectory rdir))
 221             (when (string-match "^[0-9]+$" file)
 222               (setq num (string-to-number file))
 223               (setq max (max max num))
 224               (when (or (null min)
 225                         (< num min))
 226                 (setq min num))))
 227         ;; This is a directory.
 228         (when (and (file-readable-p rdir)
 229                    (not (equal (file-truename rdir)
 230                                (file-truename dir))))
 231           (nnmh-request-list-1 rdir))))
 232     ;; For each directory, generate an active file line.
 233     (unless (string= (expand-file-name nnmh-toplev) dir)
 234       (with-current-buffer nntp-server-buffer
 235         (goto-char (point-max))
 236         (insert
 237          (format
 238           "%s %.0f %.0f y\n"
 239           (progn
 240             (string-match
 241              (regexp-quote
 242               (file-truename (file-name-as-directory
 243                               (expand-file-name nnmh-toplev))))
 244              dir)
 245             (mm-string-to-multibyte ;Why?  Isn't it multibyte already?
 246              (mm-encode-coding-string
 247               (nnheader-replace-chars-in-string
 248                (substring dir (match-end 0))
 249                ?/ ?.)
 250               nnmail-pathname-coding-system)))
 251           (or max 0)
 252           (or min 1))))))
 253   t)
 254
 255 (deffoo nnmh-request-newgroups (date &optional server)
 256   (nnmh-request-list server))
 257
 258 (deffoo nnmh-request-expire-articles (articles newsgroup
 259                                                &optional server force)
 260   (nnmh-possibly-change-directory newsgroup server)
 261   (let ((is-old t)
 262         article rest mod-time)
 263     (nnheader-init-server-buffer)
 264
 265     (while (and articles is-old)
 266       (setq article (concat nnmh-current-directory
 267                             (int-to-string (car articles))))
 268       (when (setq mod-time (nth 5 (file-attributes article)))
 269         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 270                  (setq is-old
 271                        (nnmail-expired-article-p newsgroup mod-time force)))
 272             (progn
 273               ;; Allow a special target group. -- jcn
 274               (unless (eq nnmail-expiry-target 'delete)
 275                 (with-temp-buffer
 276                   (nnmh-request-article (car articles)
 277                                         newsgroup server (current-buffer))
 278                   (nnmail-expiry-target-group
 279                    nnmail-expiry-target newsgroup)))
 280               (nnheader-message 5 "Deleting article %s in %s..."
 281                                 article newsgroup)
 282               (condition-case ()
 283                   (funcall nnmail-delete-file-function article)
 284                 (file-error
 285                  (nnheader-message 1 "Couldn't delete article %s in %s"
 286                                    article newsgroup)
 287                  (push (car articles) rest))))
 288           (push (car articles) rest)))
 289       (setq articles (cdr articles)))
 290     (nnheader-message 5 "")
 291     (nconc rest articles)))
 292
 293 (deffoo nnmh-close-group (group &optional server)
 294   t)
 295
 296 (deffoo nnmh-request-move-article (article group server accept-form
 297                                            &optional last move-is-internal)
 298   (let ((buf (get-buffer-create " *nnmh move*"))
 299         result)
 300     (and
 301      (nnmh-deletable-article-p group article)
 302      (nnmh-request-article article group server)
 303      (with-current-buffer buf
 304        (erase-buffer)
 305        (insert-buffer-substring nntp-server-buffer)
 306        (setq result (eval accept-form))
 307        (kill-buffer (current-buffer))
 308        result)
 309      (progn
 310        (nnmh-possibly-change-directory group server)
 311        (condition-case ()
 312            (funcall nnmail-delete-file-function
 313                     (concat nnmh-current-directory (int-to-string article)))
 314          (file-error nil))))
 315     result))
 316
 317 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 318   (nnmh-possibly-change-directory group server)
 319   (nnmail-check-syntax)
 320   (when nnmail-cache-accepted-message-ids
 321     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 322                          group
 323                          (nnmail-fetch-field "subject")
 324                          (nnmail-fetch-field "from")))
 325   (nnheader-init-server-buffer)
 326   (prog1
 327       (if (stringp group)
 328           (if noinsert
 329               (nnmh-active-number group)
 330             (car (nnmh-save-mail
 331                   (list (cons group (nnmh-active-number group)))
 332                   noinsert)))
 333         (let ((res (nnmail-article-group 'nnmh-active-number)))
 334           (if (and (null res)
 335                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 336               'junk
 337             (car (nnmh-save-mail res noinsert)))))
 338     (when (and last nnmail-cache-accepted-message-ids)
 339       (nnmail-cache-close))))
 340
 341 (deffoo nnmh-request-replace-article (article group buffer)
 342   (nnmh-possibly-change-directory group)
 343   (with-current-buffer buffer
 344     (nnmh-possibly-create-directory group)
 345     (ignore-errors
 346       (nnmail-write-region
 347        (point-min) (point-max)
 348        (concat nnmh-current-directory (int-to-string article))
 349        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 350       t)))
 351
 352 (deffoo nnmh-request-create-group (group &optional server args)
 353   (nnheader-init-server-buffer)
 354   (unless (assoc group nnmh-group-alist)
 355     (let (active)
 356       (push (list group (setq active (cons 1 0)))
 357             nnmh-group-alist)
 358       (nnmh-possibly-create-directory group)
 359       (nnmh-possibly-change-directory group server)
 360       (let ((articles (mapcar 'string-to-number
 361                               (directory-files
 362                                nnmh-current-directory nil "^[0-9]+$"))))
 363         (when articles
 364           (setcar active (apply 'min articles))
 365           (setcdr active (apply 'max articles))))))
 366   t)
 367
 368 (deffoo nnmh-request-delete-group (group &optional force server)
 369   (nnmh-possibly-change-directory group server)
 370   ;; Delete all articles in GROUP.
 371   (if (not force)
 372       ()                                ; Don't delete the articles.
 373     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 374       (while articles
 375         (when (file-writable-p (car articles))
 376           (nnheader-message 5 "Deleting article %s in %s..."
 377                             (car articles) group)
 378           (funcall nnmail-delete-file-function (car articles)))
 379         (setq articles (cdr articles))))
 380     ;; Try to delete the directory itself.
 381     (ignore-errors
 382       (delete-directory nnmh-current-directory)))
 383   ;; Remove the group from all structures.
 384   (setq nnmh-group-alist
 385         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 386         nnmh-current-directory nil)
 387   t)
 388
 389 (deffoo nnmh-request-rename-group (group new-name &optional server)
 390   (nnmh-possibly-change-directory group server)
 391   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 392         (old-dir (nnmail-group-pathname group nnmh-directory)))
 393     (when (ignore-errors
 394             (make-directory new-dir t)
 395             t)
 396       ;; We move the articles file by file instead of renaming
 397       ;; the directory -- there may be subgroups in this group.
 398       ;; One might be more clever, I guess.
 399       (let ((files (nnheader-article-to-file-alist old-dir)))
 400         (while files
 401           (rename-file
 402            (concat old-dir (cdar files))
 403            (concat new-dir (cdar files)))
 404           (pop files)))
 405       (when (<= (length (directory-files old-dir)) 2)
 406         (ignore-errors
 407           (delete-directory old-dir)))
 408       ;; That went ok, so we change the internal structures.
 409       (let ((entry (assoc group nnmh-group-alist)))
 410         (when entry
 411           (setcar entry new-name))
 412         (setq nnmh-current-directory nil)
 413         t))))
 414
 415 (nnoo-define-skeleton nnmh)
 416
 417 \f
 418 ;;; Internal functions.
 419
 420 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 421   (when (and server
 422              (not (nnmh-server-opened server)))
 423     (nnmh-open-server server))
 424   (when newsgroup
 425     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 426           (file-name-coding-system nnmail-pathname-coding-system))
 427       (if (file-directory-p pathname)
 428           (setq nnmh-current-directory pathname)
 429         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 430
 431 (defun nnmh-possibly-create-directory (group)
 432   (let (dir dirs)
 433     (setq dir (nnmail-group-pathname group nnmh-directory))
 434     (while (not (file-directory-p dir))
 435       (push dir dirs)
 436       (setq dir (file-name-directory (directory-file-name dir))))
 437     (while dirs
 438       (when (make-directory (directory-file-name (car dirs)))
 439         (error "Could not create directory %s" (car dirs)))
 440       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 441       (setq dirs (cdr dirs)))))
 442
 443 (defun nnmh-save-mail (group-art &optional noinsert)
 444   "Called narrowed to an article."
 445   (unless noinsert
 446     (nnmail-insert-lines)
 447     (nnmail-insert-xref group-art))
 448   (run-hooks 'nnmail-prepare-save-mail-hook)
 449   (run-hooks 'nnmh-prepare-save-mail-hook)
 450   (goto-char (point-min))
 451   (while (looking-at "From ")
 452     (replace-match "X-From-Line: ")
 453     (forward-line 1))
 454   ;; We save the article in all the newsgroups it belongs in.
 455   (let ((ga group-art)
 456         first)
 457     (while ga
 458       (nnmh-possibly-create-directory (caar ga))
 459       (let ((file (concat (nnmail-group-pathname
 460                            (caar ga) nnmh-directory)
 461                           (int-to-string (cdar ga)))))
 462         (if first
 463             ;; It was already saved, so we just make a hard link.
 464             (funcall nnmail-crosspost-link-function first file t)
 465           ;; Save the article.
 466           (nnmail-write-region (point-min) (point-max) file nil nil)
 467           (setq first file)))
 468       (setq ga (cdr ga))))
 469   group-art)
 470
 471 (defun nnmh-active-number (group)
 472   "Compute the next article number in GROUP."
 473   (let ((active (cadr (assoc group nnmh-group-alist)))
 474         (dir (nnmail-group-pathname group nnmh-directory))
 475         (file-name-coding-system nnmail-pathname-coding-system)
 476         file)
 477     (unless active
 478       ;; The group wasn't known to nnmh, so we just create an active
 479       ;; entry for it.
 480       (setq active (cons 1 0))
 481       (push (list group active) nnmh-group-alist)
 482       (unless (file-exists-p dir)
 483         (gnus-make-directory dir))
 484       ;; Find the highest number in the group.
 485       (let ((files (sort
 486                     (mapcar 'string-to-number
 487                             (directory-files dir nil "^[0-9]+$"))
 488                     '>)))
 489         (when files
 490           (setcdr active (car files)))))
 491     (setcdr active (1+ (cdr active)))
 492     (while (or
 493             ;; See whether the file exists...
 494             (file-exists-p
 495              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 496                                 (int-to-string (cdr active)))))
 497             ;; ... or there is a buffer that will make that file exist
 498             ;; in the future.
 499             (get-file-buffer file))
 500       ;; Skip past that file.
 501       (setcdr active (1+ (cdr active))))
 502     (cdr active)))
 503
 504 (defun nnmh-update-gnus-unreads (group)
 505   ;; Go through the .nnmh-articles file and compare with the actual
 506   ;; articles in this folder.  The articles that are "new" will be
 507   ;; marked as unread by Gnus.
 508   (let* ((dir nnmh-current-directory)
 509          (files (sort (mapcar 'string-to-number
 510                               (directory-files nnmh-current-directory
 511                                                nil "^[0-9]+$" t))
 512                       '<))
 513          (nnmh-file (concat dir ".nnmh-articles"))
 514          new articles)
 515     ;; Load the .nnmh-articles file.
 516     (when (file-exists-p nnmh-file)
 517       (setq articles
 518             (let (nnmh-newsgroup-articles)
 519               (ignore-errors (load nnmh-file nil t t))
 520               nnmh-newsgroup-articles)))
 521     ;; Add all new articles to the `new' list.
 522     (let ((art files))
 523       (while art
 524         (unless (assq (car art) articles)
 525           (push (car art) new))
 526         (setq art (cdr art))))
 527     ;; Remove all deleted articles.
 528     (let ((art articles))
 529       (while art
 530         (unless (memq (caar art) files)
 531           (setq articles (delq (car art) articles)))
 532         (setq art (cdr art))))
 533     ;; Check whether the articles really are the ones that Gnus thinks
 534     ;; they are by looking at the time-stamps.
 535     (let ((arts articles)
 536           art)
 537       (while (setq art (pop arts))
 538         (when (not (equal
 539                     (nth 5 (file-attributes
 540                             (concat dir (int-to-string (car art)))))
 541                     (cdr art)))
 542           (setq articles (delq art articles))
 543           (push (car art) new))))
 544     ;; Go through all the new articles and add them, and their
 545     ;; time-stamps, to the list.
 546     (setq articles
 547           (nconc articles
 548                  (mapcar
 549                   (lambda (art)
 550                     (cons art
 551                           (nth 5 (file-attributes
 552                                   (concat dir (int-to-string art))))))
 553                   new)))
 554     ;; Make Gnus mark all new articles as unread.
 555     (when new
 556       (gnus-make-articles-unread
 557        (gnus-group-prefixed-name group (list 'nnmh ""))
 558        (setq new (sort new '<))))
 559     ;; Sort the article list with highest numbers first.
 560     (setq articles (sort articles (lambda (art1 art2)
 561                                     (> (car art1) (car art2)))))
 562     ;; Finally write this list back to the .nnmh-articles file.
 563     (with-temp-file nnmh-file
 564       (insert ";; Gnus article active file for " group "\n\n")
 565       (insert "(setq nnmh-newsgroup-articles '")
 566       (gnus-prin1 articles)
 567       (insert ")\n"))))
 568
 569 (defun nnmh-deletable-article-p (group article)
 570   "Say whether ARTICLE in GROUP can be deleted."
 571   (let ((path (concat nnmh-current-directory (int-to-string article))))
 572     ;; Writable.
 573     (and (file-writable-p path)
 574          (or
 575           ;; We can never delete the last article in the group.
 576           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 577                    article))
 578           ;; Well, we can.
 579           nnmh-allow-delete-final))))
 580
 581 (provide 'nnmh)
 582
 583 ;;; nnmh.el ends here