lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer.
   2
   3 ;; Copyright (C) 1986, 1987 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 1, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  19 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 ;; Original version of most of this contributed by Howie Kaye
  22
  23 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  24   "General text sorting routine to divide buffer into records and sort them.
  25 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  26
  27 We consider this portion of the buffer to be divided into disjoint pieces
  28 called sort records.  A portion of each sort record (perhaps all of it)
  29 is designated as the sort key.  The records are rearranged in the buffer
  30 in order by their sort keys.  The records may or may not be contiguous.
  31
  32 Usually the records are rearranged in order of ascending sort key.
  33 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  34
  35 The next four arguments are functions to be called to move point
  36 across a sort record.  They will be called many times from within sort-subr.
  37
  38 NEXTRECFUN is called with point at the end of the previous record.
  39 It moves point to the start of the next record.
  40 It should move point to the end of the buffer if there are no more records.
  41 The first record is assumed to start at the position of point when sort-subr
  42 is called.
  43
  44 ENDRECFUN is is called with point within the record.
  45 It should move point to the end of the record.
  46
  47 STARTKEYFUN may moves from the start of the record to the start of the key.
  48 It may return either return a non-nil value to be used as the key, or
  49 else the key will be the substring between the values of point after
  50 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  51 starts at the beginning of the record.
  52
  53 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  54 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  55 same as ENDRECFUN."
  56   (save-excursion
  57     (message "Finding sort keys...")
  58     (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  59                                          startkeyfun endkeyfun))
  60            (old (reverse sort-lists)))
  61       (if (null sort-lists)
  62           ()
  63         (or reverse (setq sort-lists (nreverse sort-lists)))
  64         (message "Sorting records...")
  65         (setq sort-lists
  66               (if (fboundp 'sortcar)
  67                   (sortcar sort-lists
  68                            (cond ((numberp (car (car sort-lists)))
  69                                   ;; This handles both ints and floats.
  70                                   '<)
  71                                  ((consp (car (car sort-lists)))
  72                                   'buffer-substring-lessp)
  73                                  (t
  74                                   'string<)))
  75                   (sort sort-lists
  76                         (cond ((numberp (car (car sort-lists)))
  77                                (function
  78                                 (lambda (a b)
  79                                   (< (car a) (car b)))))
  80                               ((consp (car (car sort-lists)))
  81                                (function
  82                                 (lambda (a b)
  83                                   (buffer-substring-lessp (car a) (car b)))))
  84                               (t
  85                                (function
  86                                 (lambda (a b)
  87                                   (string< (car a) (car b)))))))))
  88         (if reverse (setq sort-lists (nreverse sort-lists)))
  89         (message "Reordering buffer...")
  90         (sort-reorder-buffer sort-lists old)))
  91     (message "Reordering buffer... Done"))
  92   nil)
  93
  94 ;; Parse buffer into records using the arguments as Lisp expressions;
  95 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
  96 ;; where KEY is the sort key (a number or string),
  97 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
  98
  99 ;; The records appear in the list lastmost first!
 100
 101 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 102   (let ((sort-lists ())
 103         (start-rec nil)
 104         done key)
 105     ;; Loop over sort records.
 106     ;(goto-char (point-min)) -- it is the caller's responsibility to
 107     ;arrange this if necessary
 108     (while (not (eobp))
 109       (setq start-rec (point))          ;save record start
 110       (setq done nil)
 111       ;; Get key value, or move to start of key.
 112       (setq key (catch 'key
 113                   (or (and startkeyfun (funcall startkeyfun))
 114                       ;; If key was not returned as value,
 115                       ;; move to end of key and get key from the buffer.
 116                       (let ((start (point)))
 117                         (funcall (or endkeyfun
 118                                      (prog1 endrecfun (setq done t))))
 119                         (if (fboundp 'buffer-substring-lessp)
 120                             (cons start (point))
 121                           (buffer-substring start (point)))))))
 122       ;; Move to end of this record (start of next one, or end of buffer).
 123       (cond ((prog1 done (setq done nil)))
 124             (endrecfun (funcall endrecfun))
 125             (nextrecfun (funcall nextrecfun) (setq done t)))
 126       (if key (setq sort-lists (cons
 127                                  ;; consing optimization in case in which key
 128                                  ;; is same as record.
 129                                  (if (and (consp key)
 130                                           (equal (car key) start-rec)
 131                                           (equal (cdr key) (point)))
 132                                      (cons key key)
 133                                    (cons key (cons start-rec (point))))
 134                                  sort-lists)))
 135       (and (not done) nextrecfun (funcall nextrecfun)))
 136     sort-lists))
 137
 138 (defun sort-reorder-buffer (sort-lists old)
 139   (let ((inhibit-quit t)
 140         (last (point-min))
 141         (min (point-min)) (max (point-max)))
 142     ;; Make sure insertions done for reordering
 143     ;; do not go after any markers at the end of the sorted region,
 144     ;; by inserting a space to separate them.
 145     (goto-char (point-max))
 146     (insert-before-markers " ")
 147     (narrow-to-region min (1- (point-max)))
 148     (while sort-lists
 149       (goto-char (point-max))
 150       (insert-buffer-substring (current-buffer)
 151                                last
 152                                (nth 1 (car old)))
 153       (goto-char (point-max))
 154       (insert-buffer-substring (current-buffer)
 155                                (nth 1 (car sort-lists))
 156                                (cdr (cdr (car sort-lists))))
 157       (setq last (cdr (cdr (car old)))
 158             sort-lists (cdr sort-lists)
 159             old (cdr old)))
 160     (goto-char (point-max))
 161     (insert-buffer-substring (current-buffer)
 162                              last
 163                              max)
 164     ;; Delete the original copy of the text.
 165     (delete-region min max)
 166     ;; Get rid of the separator " ".
 167     (goto-char (point-max))
 168     (narrow-to-region min (1+ (point)))
 169     (delete-region (point) (1+ (point)))))
 170
 171 ;;;###autoload
 172 (defun sort-lines (reverse beg end)
 173   "Sort lines in region alphabetically; argument means descending order.
 174 Called from a program, there are three arguments:
 175 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 176   (interactive "P\nr")
 177   (save-excursion
 178     (save-restriction
 179       (narrow-to-region beg end)
 180       (goto-char (point-min))
 181       (sort-subr reverse 'forward-line 'end-of-line))))
 182
 183 ;;;###autoload
 184 (defun sort-paragraphs (reverse beg end)
 185   "Sort paragraphs in region alphabetically; argument means descending order.
 186 Called from a program, there are three arguments:
 187 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 188   (interactive "P\nr")
 189   (save-excursion
 190     (save-restriction
 191       (narrow-to-region beg end)
 192       (goto-char (point-min))
 193       (sort-subr reverse
 194                  (function (lambda () (skip-chars-forward "\n \t\f")))
 195                  'forward-paragraph))))
 196
 197 ;;;###autoload
 198 (defun sort-pages (reverse beg end)
 199   "Sort pages in region alphabetically; argument means descending order.
 200 Called from a program, there are three arguments:
 201 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 202   (interactive "P\nr")
 203   (save-excursion
 204     (save-restriction
 205       (narrow-to-region beg end)
 206       (goto-char (point-min))
 207       (sort-subr reverse
 208                  (function (lambda () (skip-chars-forward "\n")))
 209                  'forward-page))))
 210 \f
 211 (defvar sort-fields-syntax-table nil)
 212 (if sort-fields-syntax-table nil
 213   (let ((table (make-syntax-table))
 214         (i 0))
 215     (while (< i 256)
 216       (modify-syntax-entry i "w" table)
 217       (setq i (1+ i)))
 218     (modify-syntax-entry ?\  " " table)
 219     (modify-syntax-entry ?\t " " table)
 220     (modify-syntax-entry ?\n " " table)
 221     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 222     (setq sort-fields-syntax-table table)))
 223
 224 ;;;###autoload
 225 (defun sort-numeric-fields (field beg end)
 226   "Sort lines in region numerically by the ARGth field of each line.
 227 Fields are separated by whitespace and numbered from 1 up.
 228 Specified field must contain a number in each line of the region.
 229 With a negative arg, sorts by the ARGth field counted from the right.
 230 Called from a program, there are three arguments:
 231 FIELD, BEG and END.  BEG and END specify region to sort."
 232   (interactive "p\nr")
 233   (sort-fields-1 field beg end
 234                  (function (lambda ()
 235                              (sort-skip-fields (1- field))
 236                              (string-to-int
 237                               (buffer-substring
 238                                 (point)
 239                                 (save-excursion
 240                                   ;; This is just wrong! Even without floats...
 241                                   ;; (skip-chars-forward "[0-9]")
 242                                   (forward-sexp 1)
 243                                   (point))))))
 244                  nil))
 245
 246 (defun sort-float-fields (field beg end)
 247   "Sort lines in region numerically by the ARGth field of each line.
 248 Fields are separated by whitespace and numbered from 1 up.  Specified field
 249 must contain a floating point number in each line of the region.  With a
 250 negative arg, sorts by the ARGth field counted from the right.  Called from a
 251 program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 252 region to sort."
 253   (interactive "p\nr")
 254   (sort-fields-1 field beg end
 255                  (function (lambda ()
 256                              (sort-skip-fields (1- field))
 257                              (string-to-float
 258                               (buffer-substring
 259                                (point)
 260                                (save-excursion
 261                                  (re-search-forward
 262                                   "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 263                                  (point))))))
 264                  nil))
 265
 266 ;;;###autoload
 267 (defun sort-fields (field beg end)
 268   "Sort lines in region lexicographically by the ARGth field of each line.
 269 Fields are separated by whitespace and numbered from 1 up.
 270 With a negative arg, sorts by the ARGth field counted from the right.
 271 Called from a program, there are three arguments:
 272 FIELD, BEG and END.  BEG and END specify region to sort."
 273   (interactive "p\nr")
 274   (sort-fields-1 field beg end
 275                  (function (lambda ()
 276                              (sort-skip-fields (1- field))
 277                              nil))
 278                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 279
 280 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 281   (let ((tbl (syntax-table)))
 282     (if (zerop field) (setq field 1))
 283     (unwind-protect
 284         (save-excursion
 285           (save-restriction
 286             (narrow-to-region beg end)
 287             (goto-char (point-min))
 288             (set-syntax-table sort-fields-syntax-table)
 289             (sort-subr nil
 290                        'forward-line 'end-of-line
 291                        startkeyfun endkeyfun)))
 292       (set-syntax-table tbl))))
 293
 294 (defun sort-skip-fields (n)
 295   (let ((bol (point))
 296         (eol (save-excursion (end-of-line 1) (point))))
 297     (if (> n 0) (forward-word n)
 298       (end-of-line)
 299       (forward-word (1+ n)))
 300     (if (or (and (>= (point) eol) (> n 0))
 301             ;; this is marginally wrong; if the first line of the sort
 302             ;; at bob has the wrong number of fields the error won't be
 303             ;; reported until the next short line.
 304             (and (< (point) bol) (< n 0)))
 305         (error "Line has too few fields: %s"
 306                (buffer-substring bol eol)))
 307     (skip-chars-forward " \t")))
 308
 309 \f
 310 ;;;###autoload
 311 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 312   "Sort the region lexicographically as specifed by RECORD-REGEXP and KEY.
 313 RECORD-REGEXP specifies the textual units which should be sorted.
 314   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 315 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 316   is to be used for sorting.
 317   If it is \"\\digit\" then the digit'th \"\\(...\\)\" match field from
 318   RECORD-REGEXP is used.
 319   If it is \"\\&\" then the whole record is used.
 320   Otherwise, it is a regular-expression for which to search within the record.
 321 If a match for KEY is not found within a record then that record is ignored.
 322
 323 With a negative prefix arg sorts in reverse order.
 324
 325 For example: to sort lines in the region by the first word on each line
 326  starting with the letter \"f\",
 327  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\=\\<f\\w*\\>\""
 328   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 329   ;; other sort-.*fields functions but then again this was before, since it
 330   ;; didn't use the magnitude of the arg to specify anything.
 331   (interactive "P\nsRegexp specifying records to sort:
 332 sRegexp specifying key within record: \nr")
 333   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 334          (setq key-regexp 0))
 335         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 336          (setq key-regexp (- (aref key-regexp 1) ?0))))
 337   (save-excursion
 338     (save-restriction
 339       (narrow-to-region beg end)
 340       (goto-char (point-min))
 341       (let (sort-regexp-record-end) ;isn't dynamic scoping wonderful?
 342         (re-search-forward record-regexp)
 343         (setq sort-regexp-record-end (point))
 344         (goto-char (match-beginning 0))
 345         (sort-subr reverse
 346                    (function (lambda ()
 347                                (and (re-search-forward record-regexp nil 'move)
 348                                     (setq sort-regexp-record-end (match-end 0))
 349                                     (goto-char (match-beginning 0)))))
 350                    (function (lambda ()
 351                                (goto-char sort-regexp-record-end)))
 352                    (function (lambda ()
 353                                (let ((n 0))
 354                                  (cond ((numberp key-regexp)
 355                                         (setq n key-regexp))
 356                                        ((re-search-forward
 357                                           key-regexp sort-regexp-record-end t)
 358                                         (setq n 0))
 359                                        (t (throw 'key nil)))
 360                                  (condition-case ()
 361                                      (if (fboundp 'buffer-substring-lessp)
 362                                          (cons (match-beginning n)
 363                                                (match-end n))
 364                                          (buffer-substring (match-beginning n)
 365                                                            (match-end n)))
 366                                    ;; if there was no such register
 367                                    (error (throw 'key nil)))))))))))
 368
 369 \f
 370 (defvar sort-columns-subprocess t)
 371
 372 ;;;###autoload
 373 (defun sort-columns (reverse &optional beg end)
 374   "Sort lines in region alphabetically by a certain range of columns.
 375 For the purpose of this command, the region includes
 376 the entire line that point is in and the entire line the mark is in.
 377 The column positions of point and mark bound the range of columns to sort on.
 378 A prefix argument means sort into reverse order.
 379
 380 Note that `sort-columns' rejects text that contains tabs,
 381 because tabs could be split across the specified columns
 382 and it doesn't know how to handle that.  Also, when possible,
 383 it uses the `sort' utility program, which doesn't understand tabs.
 384 Use \\[untabify] to convert tabs to spaces before sorting."
 385   (interactive "P\nr")
 386   (save-excursion
 387     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 388       (goto-char (min beg end))
 389       (setq col-beg1 (current-column))
 390       (beginning-of-line)
 391       (setq beg1 (point))
 392       (goto-char (max beg end))
 393       (setq col-end1 (current-column))
 394       (forward-line)
 395       (setq end1 (point))
 396       (setq col-start (min col-beg1 col-end1))
 397       (setq col-end (max col-beg1 col-end1))
 398       (if (search-backward "\t" beg1 t)
 399           (error "sort-columns does not work with tabs.  Use M-x untabify."))
 400       (if (not (eq system-type 'vax-vms))
 401           ;; Use the sort utility if we can; it is 4 times as fast.
 402           (call-process-region beg1 end1 "sort" t t nil
 403                                (if reverse "-rt\n" "-t\n")
 404                                (concat "+0." col-start)
 405                                (concat "-0." col-end))
 406         ;; On VMS, use Emacs's own facilities.
 407         (save-excursion
 408           (save-restriction
 409             (narrow-to-region beg1 end1)
 410             (goto-char beg1)
 411             (sort-subr reverse 'forward-line 'end-of-line
 412                        (function (lambda () (move-to-column col-start) nil))
 413                        (function (lambda () (move-to-column col-end) nil)))))))))
 414
 415 ;;;###autoload
 416 (defun reverse-region (beg end)
 417   "Reverse the order of lines in a region.
 418 From a program takes two point or marker arguments, BEG and END."
 419   (interactive "r")
 420   (if (> beg end)
 421       (let (mid) (setq mid end end beg beg mid)))
 422   (save-excursion
 423     ;; put beg at the start of a line and end and the end of one --
 424     ;; the largest possible region which fits this criteria
 425     (goto-char beg)
 426     (or (bolp) (forward-line 1))
 427     (setq beg (point))
 428     (goto-char end)
 429     ;; the test for bolp is for those times when end is on an empty line;
 430     ;; it is probably not the case that the line should be included in the
 431     ;; reversal; it isn't difficult to add it afterward.
 432     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 433     (setq end (point-marker))
 434     ;; the real work.  this thing cranks through memory on large regions.
 435     (let (ll (do t))
 436       (while do
 437         (goto-char beg)
 438         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 439                        ll))
 440         (setq do (/= (point) end))
 441         (delete-region beg (if do (1+ (point)) (point))))
 442       (while (cdr ll)
 443         (insert (car ll) "\n")
 444         (setq ll (cdr ll)))
 445       (insert (car ll)))))
 446
 447 (provide 'sort)
 448
 449 ;;; sort.el ends here