lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions.
   2
   3 ;; Copyright (C) 1985, 1986, 1987 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 1, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  19 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21
  22 ; Put buffer *Buffer List* into proper mode right away
  23 ; so that from now on even list-buffers is enough to get a buffer menu.
  24
  25 (defvar Buffer-menu-mode-map nil "")
  26
  27 (if Buffer-menu-mode-map
  28     ()
  29   (setq Buffer-menu-mode-map (make-keymap))
  30   (suppress-keymap Buffer-menu-mode-map t)
  31   (define-key Buffer-menu-mode-map "q" 'Buffer-menu-select)
  32   (define-key Buffer-menu-mode-map "2" 'Buffer-menu-2-window)
  33   (define-key Buffer-menu-mode-map "1" 'Buffer-menu-1-window)
  34   (define-key Buffer-menu-mode-map "f" 'Buffer-menu-this-window)
  35   (define-key Buffer-menu-mode-map "o" 'Buffer-menu-other-window)
  36   (define-key Buffer-menu-mode-map "s" 'Buffer-menu-save)
  37   (define-key Buffer-menu-mode-map "d" 'Buffer-menu-delete)
  38   (define-key Buffer-menu-mode-map "k" 'Buffer-menu-delete)
  39   (define-key Buffer-menu-mode-map "\C-d" 'Buffer-menu-delete-backwards)
  40   (define-key Buffer-menu-mode-map "\C-k" 'Buffer-menu-delete)
  41   (define-key Buffer-menu-mode-map "x" 'Buffer-menu-execute)
  42   (define-key Buffer-menu-mode-map " " 'next-line)
  43   (define-key Buffer-menu-mode-map "n" 'next-line)
  44   (define-key Buffer-menu-mode-map "p" 'previous-line)
  45   (define-key Buffer-menu-mode-map "\177" 'Buffer-menu-backup-unmark)
  46   (define-key Buffer-menu-mode-map "~" 'Buffer-menu-not-modified)
  47   (define-key Buffer-menu-mode-map "?" 'describe-mode)
  48   (define-key Buffer-menu-mode-map "u" 'Buffer-menu-unmark)
  49   (define-key Buffer-menu-mode-map "m" 'Buffer-menu-mark)
  50   (define-key Buffer-menu-mode-map "t" 'Buffer-menu-visit-tags-table))
  51
  52 ;; Buffer Menu mode is suitable only for specially formatted data.
  53 (put 'Buffer-menu-mode 'mode-class 'special)
  54
  55 (defun Buffer-menu-mode ()
  56   "Major mode for editing a list of buffers.
  57 Each line describes one of the buffers in Emacs.
  58 Letters do not insert themselves; instead, they are commands.
  59 \\<Buffer-menu-mode-map>
  60 \\[Buffer-menu-mark] -- mark buffer to be displayed.
  61 \\[Buffer-menu-select] -- select buffer of line point is on.
  62   Also show buffers marked with m in other windows.
  63 \\[Buffer-menu-1-window] -- select that buffer in full-screen window.
  64 \\[Buffer-menu-2-window] -- select that buffer in one window,
  65   together with buffer selected before this one in another window.
  66 \\[Buffer-menu-this-window] -- select that buffer in place of the buffer menu buffer.
  67 \\[Buffer-menu-other-window] -- select that buffer in another window,
  68   so the buffer menu buffer remains visible in its window.
  69 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
  70 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
  71 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
  72 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
  73 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
  74 \\[Buffer-menu-execute] -- delete or save marked buffers.
  75 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
  76 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks."
  77   (kill-all-local-variables)
  78   (use-local-map Buffer-menu-mode-map)
  79   (setq truncate-lines t)
  80   (setq buffer-read-only t)
  81   (setq major-mode 'Buffer-menu-mode)
  82   (setq mode-name "Buffer Menu")
  83   (run-hooks 'buffer-menu-mode-hook))
  84 \f
  85 (defvar Buffer-menu-buffer-column 4)
  86
  87 (defun Buffer-menu-buffer (error-if-non-existent-p)
  88   "Return buffer described by this line of buffer menu."
  89   (save-excursion
  90     (beginning-of-line)
  91     (forward-char Buffer-menu-buffer-column)
  92     (let ((start (point))
  93           string)
  94       ;; End of buffer name marked by tab or two spaces.
  95       (re-search-forward "\t\\|  ")
  96       (skip-chars-backward " \t")
  97       (setq string (buffer-substring start (point)))
  98       (or (get-buffer string)
  99           (if error-if-non-existent-p
 100               (error "No buffer named \"%s\"" string)
 101             nil)))))
 102 \f
 103 (defun buffer-menu (arg)
 104   "Make a menu of buffers so you can save, delete or select them.
 105 With argument, show only buffers that are visiting files.
 106 Type ? after invocation to get help on commands available.
 107 Type q immediately to make the buffer menu go away."
 108   (interactive "P")
 109   (list-buffers arg)
 110   (pop-to-buffer "*Buffer List*")
 111   (forward-line 2)
 112   (message
 113    "Commands: d, s, x; 1, 2, m, u, q; delete; ~;  ? for help."))
 114
 115 (defun Buffer-menu-mark ()
 116   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 117   (interactive)
 118   (beginning-of-line)
 119   (if (looking-at " [-M]")
 120       (ding)
 121     (let ((buffer-read-only nil))
 122       (delete-char 1)
 123       (insert ?>)
 124       (forward-line 1))))
 125
 126 (defun Buffer-menu-unmark ()
 127   "Cancel all requested operations on buffer on this line."
 128   (interactive)
 129   (beginning-of-line)
 130   (if (looking-at " [-M]")
 131       (ding)
 132     (let* ((buf (Buffer-menu-buffer t))
 133            (mod (buffer-modified-p buf))
 134            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 135            (buffer-read-only nil))
 136       (delete-char 3)
 137       (insert (if readonly (if mod " *%" "  %") (if mod " * " "   ")))))
 138   (forward-line 1))
 139
 140 (defun Buffer-menu-backup-unmark ()
 141   "Move up and cancel all requested operations on buffer on line above."
 142   (interactive)
 143   (forward-line -1)
 144   (Buffer-menu-unmark)
 145   (forward-line -1))
 146
 147 (defun Buffer-menu-delete ()
 148   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 149   (interactive)
 150   (beginning-of-line)
 151   (if (looking-at " [-M]")              ;header lines
 152       (ding)
 153     (let ((buffer-read-only nil))
 154       (delete-char 1)
 155       (insert ?D)
 156       (forward-line 1))))
 157
 158 (defun Buffer-menu-delete-backwards ()
 159   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 160 and then move up one line"
 161   (interactive)
 162   (Buffer-menu-delete)
 163   (forward-line -2)
 164   (if (looking-at " [-M]") (forward-line 1)))
 165
 166 (defun Buffer-menu-save ()
 167   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 168   (interactive)
 169   (beginning-of-line)
 170   (forward-char 1)
 171   (if (looking-at " [-M]")              ;header lines
 172       (ding)
 173     (let ((buffer-read-only nil))
 174       (delete-char 1)
 175       (insert ?S)
 176       (forward-line 1))))
 177
 178 (defun Buffer-menu-not-modified ()
 179   "Mark buffer on this line as unmodified (no changes to save)."
 180   (interactive)
 181   (save-excursion
 182     (set-buffer (Buffer-menu-buffer t))
 183     (set-buffer-modified-p nil))
 184   (save-excursion
 185    (beginning-of-line)
 186    (forward-char 1)
 187    (if (looking-at "\\*")
 188        (let ((buffer-read-only nil))
 189          (delete-char 1)
 190          (insert ? )))))
 191
 192 (defun Buffer-menu-execute ()
 193   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 194   (interactive)
 195   (save-excursion
 196     (goto-char (point-min))
 197     (forward-line 1)
 198     (while (re-search-forward "^.S" nil t)
 199       (let ((modp nil))
 200         (save-excursion
 201           (set-buffer (Buffer-menu-buffer t))
 202           (save-buffer)
 203           (setq modp (buffer-modified-p)))
 204         (let ((buffer-read-only nil))
 205           (delete-char -1)
 206           (insert (if modp ?* ? ))))))
 207   (save-excursion
 208     (goto-char (point-min))
 209     (forward-line 1)
 210     (let ((buff-menu-buffer (current-buffer))
 211           (buffer-read-only nil))
 212       (while (search-forward "\nD" nil t)
 213         (forward-char -1)
 214         (let ((buf (Buffer-menu-buffer nil)))
 215           (or (eq buf nil)
 216               (eq buf buff-menu-buffer)
 217               (save-excursion (kill-buffer buf))))
 218         (if (Buffer-menu-buffer nil)
 219             (progn (delete-char 1)
 220                    (insert ? ))
 221           (delete-region (point) (progn (forward-line 1) (point)))
 222           (forward-char -1))))))
 223
 224 (defun Buffer-menu-select ()
 225   "Select this line's buffer; also display buffers marked with `>'.
 226 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command."
 227   (interactive)
 228   (let ((buff (Buffer-menu-buffer t))
 229         (menu (current-buffer))
 230         (others ())
 231         tem)
 232     (goto-char (point-min))
 233     (while (search-forward "\n>" nil t)
 234       (setq tem (Buffer-menu-buffer t))
 235       (let ((buffer-read-only nil))
 236         (delete-char -1)
 237         (insert ?\ ))
 238       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 239     (setq others (nreverse others)
 240           tem (/ (1- (screen-height)) (1+ (length others))))
 241     (delete-other-windows)
 242     (switch-to-buffer buff)
 243     (or (eq menu buff)
 244         (bury-buffer menu))
 245     (while others
 246       (split-window nil tem)
 247       (other-window 1)
 248       (switch-to-buffer (car others))
 249       (setq others (cdr others)))
 250     (other-window 1)))                  ;back to the beginning!
 251 \f
 252 (defun Buffer-menu-visit-tags-table ()
 253   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 254   (interactive)
 255   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 256     (if file
 257         (visit-tags-table file)
 258       (error "Specified buffer has no file"))))
 259
 260 (defun Buffer-menu-1-window ()
 261   "Select this line's buffer, alone, in full screen."
 262   (interactive)
 263   (switch-to-buffer (Buffer-menu-buffer t))
 264   (bury-buffer (other-buffer))
 265   (delete-other-windows))
 266
 267 (defun Buffer-menu-this-window ()
 268   "Select this line's buffer in this window."
 269   (interactive)
 270   (switch-to-buffer (Buffer-menu-buffer t)))
 271
 272 (defun Buffer-menu-other-window ()
 273   "Select this line's buffer in other window, leaving buffer menu visible."
 274   (interactive)
 275   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 276
 277 (defun Buffer-menu-2-window ()
 278   "Select this line's buffer, with previous buffer in second window."
 279   (interactive)
 280   (let ((buff (Buffer-menu-buffer t))
 281         (menu (current-buffer))
 282         (pop-up-windows t))
 283     (switch-to-buffer (other-buffer))
 284     (pop-to-buffer buff)
 285     (bury-buffer menu)))
 286
 287 ;;; buff-menu.el ends here