lisp/vc-mtn.el

   1 ;;; vc-mtn.el --- VC backend for Monotone
   2
   3 ;; Copyright (C) 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords:
   7
   8 ;; This file is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 3, or (at your option)
  11 ;; any later version.
  12
  13 ;; This file is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 ;; Boston, MA 02110-1301, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl) (require 'vc))
  30
  31 ;; Clear up the cache to force vc-call to check again and discover
  32 ;; new functions when we reload this file.
  33 (put 'Mtn 'vc-functions nil)
  34
  35 (defvar vc-mtn-command "mtn")
  36 (unless (executable-find vc-mtn-command)
  37   ;; vc-mtn.el is 100% non-functional without the `mtn' executable.
  38   (setq vc-handled-backends (delq 'Mtn vc-handled-backends)))
  39
  40 ;;;###autoload
  41 (defconst vc-mtn-admin-dir "_MTN")
  42 ;;;###autoload
  43 (defconst vc-mtn-admin-format (concat vc-mtn-admin-dir "/format"))
  44
  45 ;;;###autoload (defun vc-mtn-registered (file)
  46 ;;;###autoload   (if (vc-find-root file vc-mtn-admin-format)
  47 ;;;###autoload       (progn
  48 ;;;###autoload         (load "vc-mtn")
  49 ;;;###autoload         (vc-mtn-registered file))))
  50
  51 (defun vc-mtn-revision-granularity () 'repository)
  52 (defun vc-mtn-checkout-model (file) 'implicit)
  53
  54 (defun vc-mtn-root (file)
  55   (setq file (if (file-directory-p file)
  56                  (file-name-as-directory file)
  57                (file-name-directory file)))
  58   (or (vc-file-getprop file 'vc-mtn-root)
  59       (vc-file-setprop file 'vc-mtn-root
  60                        (vc-find-root file vc-mtn-admin-format))))
  61
  62
  63 (defun vc-mtn-registered (file)
  64   (let ((root (vc-mtn-root file)))
  65     (when root
  66       (vc-mtn-state file))))
  67
  68 (defun vc-mtn-command (buffer okstatus files &rest flags)
  69   "A wrapper around `vc-do-command' for use in vc-mtn.el."
  70   (apply 'vc-do-command buffer okstatus vc-mtn-command files flags))
  71
  72 (defun vc-mtn-state (file)
  73   ;; If `mtn' fails or returns status>0, or if the search files, just
  74   ;; return nil.
  75   (ignore-errors
  76     (with-temp-buffer
  77       (vc-mtn-command t 0 file "status")
  78       (goto-char (point-min))
  79       (re-search-forward "^  \\(?:patched \\(.*\\)\\|no changes$\\)")
  80       (if (match-end 1)
  81           'edited
  82         'up-to-date))))
  83
  84 (defun vc-mtn-workfile-version (file)
  85   ;; If `mtn' fails or returns status>0, or if the search fails, just
  86   ;; return nil.
  87   (ignore-errors
  88     (with-temp-buffer
  89       (vc-mtn-command t 0 file "status")
  90       (goto-char (point-min))
  91       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
  92       (match-string 2))))
  93
  94 (defun vc-mtn-workfile-branch (file)
  95   ;; If `mtn' fails or returns status>0, or if the search files, just
  96   ;; return nil.
  97   (ignore-errors
  98     (with-temp-buffer
  99       (vc-mtn-command t 0 file "status")
 100       (goto-char (point-min))
 101       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
 102       (match-string 1))))
 103
 104 (defun vc-mtn-workfile-unchanged-p (file)
 105   (not (eq (vc-mtn-state file) 'edited)))
 106
 107 ;; Mode-line rewrite code copied from vc-arch.el.
 108
 109 (defcustom vc-mtn-mode-line-rewrite
 110   '(("\\`[^:/#]*[:/#]" . ""))           ;Drop the host part.
 111   "Rewrite rules to shorten Mtn's revision names on the mode-line."
 112   :type '(repeat (cons regexp string))
 113   :version "22.2"
 114   :group 'vc)
 115
 116 (defun vc-mtn-mode-line-string (file)
 117   "Return string for placement in modeline by `vc-mode-line' for FILE."
 118   (let ((branch (vc-mtn-workfile-branch file)))
 119     (dolist (rule vc-mtn-mode-line-rewrite)
 120       (if (string-match (car rule) branch)
 121           (setq branch (replace-match (cdr rule) t nil branch))))
 122     (format "Mtn%c%s"
 123             (case (vc-state file)
 124               ((up-to-date needs-patch) ?-)
 125               (added ?@)
 126               (t ?:))
 127             branch)))
 128
 129 (defun vc-mtn-register (files &optional rest)
 130   (vc-mtn-command nil 0 files "add"))
 131
 132 (defun vc-mtn-responsible-p (file) (vc-mtn-root file))
 133 (defun vc-mtn-could-register (file) (vc-mtn-root file))
 134
 135 (defun vc-mtn-checkin (files rev comment)
 136   (vc-mtn-command nil 0 files "commit" "-m" comment))
 137
 138 (defun vc-mtn-find-version (file rev buffer)
 139   (vc-mtn-command buffer 0 file "cat" "-r" rev))
 140
 141 ;; (defun vc-mtn-checkout (file &optional editable rev)
 142 ;;   )
 143
 144 (defun vc-mtn-revert (file &optional contents-done)
 145   (unless contents-done
 146     (vc-mtn-command nil 0 file "revert")))
 147
 148 ;; (defun vc-mtn-roolback (files)
 149 ;;   )
 150
 151 (defun vc-mtn-print-log (files &optional buffer)
 152   (vc-mtn-command buffer 0 files "log"))
 153
 154 (define-derived-mode vc-mtn-log-view-mode log-view-mode "Mtn-Log-View"
 155   ;; TODO: Not sure what to do about file markers for now.
 156   (set (make-local-variable 'log-view-file-re) "\\'\\`")
 157   ;; TODO: Use a more precise regexp than "[ |/]+" to avoid false positives
 158   ;; in the ChangeLog text.
 159   (set (make-local-variable 'log-view-message-re)
 160        "^[ |/]+Revision: \\([0-9a-f]+\\)")
 161   (require 'add-log)                    ;For change-log faces.
 162   (set (make-local-variable 'log-view-font-lock-keywords)
 163        (append log-view-font-lock-keywords
 164                '(("^[ |]+Author: \\(.*\\)" (1 'change-log-email))
 165                  ("^[ |]+Date: \\(.*\\)" (1 'change-log-date-face))))))
 166
 167 ;; (defun vc-mtn-show-log-entry (version)
 168 ;;   )
 169
 170 (defun vc-mtn-wash-log (file))
 171
 172 (defalias 'vc-mtn-diff-tree 'vc-mtn-diff)
 173 (defun vc-mtn-diff (files &optional rev1 rev2 buffer)
 174   (apply 'vc-mtn-command (or buffer "*vc-diff*") 1 files "diff"
 175          (append (if rev1 (list "-r" rev1)) (if rev2 (list "-r" rev2)))))
 176
 177 (defun vc-mtn-annotate-command (file buf &optional rev)
 178   (apply 'vc-mtn-command buf 0 file "annotate"
 179          (if rev (list "-r" rev))))
 180
 181 (defconst vc-mtn-annotate-full-re
 182   "^ *\\([0-9a-f]+\\)\\.* by [^ ]+ \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\): ")
 183 (defconst vc-mtn-annotate-any-re
 184   (concat "^\\(?: +: \\|" vc-mtn-annotate-full-re "\\)"))
 185
 186 (defun vc-mtn-annotate-time ()
 187   (when (looking-at vc-mtn-annotate-any-re)
 188     (goto-char (match-end 0))
 189     (let ((year (match-string 2)))
 190       (if (not year)
 191           ;; Look for the date on a previous line.
 192           (save-excursion
 193             (get-text-property (1- (previous-single-property-change
 194                                     (point) 'vc-mtn-time nil (point-min)))
 195                                'vc-mtn-time))
 196         (let ((time (vc-annotate-convert-time
 197                      (encode-time 0 0 0
 198                                   (string-to-number (match-string 4))
 199                                   (string-to-number (match-string 3))
 200                                   (string-to-number year)
 201                                   t))))
 202           (let ((inhibit-read-only t)
 203                 (inhibit-modification-hooks t))
 204             (put-text-property (match-beginning 0) (match-end 0)
 205                                'vc-mtn-time time))
 206           time)))))
 207
 208 (defun vc-mtn-annotate-extract-revision-at-line ()
 209   (save-excursion
 210     (when (or (looking-at vc-mtn-annotate-full-re)
 211               (re-search-backward vc-mtn-annotate-full-re nil t))
 212       (match-string 1))))
 213
 214 ;;; Revision completion.
 215
 216 (defun vc-mtn-list-tags ()
 217   (with-temp-buffer
 218     (vc-mtn-command t 0 nil "list" "tags")
 219     (goto-char (point-min))
 220     (let ((tags ()))
 221       (while (re-search-forward "^[^ ]+" nil t)
 222         (push (match-string 0) tags))
 223       tags)))
 224
 225 (defun vc-mtn-list-branches ()
 226   (with-temp-buffer
 227     (vc-mtn-command t 0 nil "list" "branches")
 228     (goto-char (point-min))
 229     (let ((branches ()))
 230       (while (re-search-forward "^.+" nil t)
 231         (push (match-string 0) branches))
 232       branches)))
 233
 234 (defun vc-mtn-list-revision-ids (prefix)
 235   (with-temp-buffer
 236     (vc-mtn-command t 0 nil "complete" "revision" prefix)
 237     (goto-char (point-min))
 238     (let ((ids ()))
 239       (while (re-search-forward "^.+" nil t)
 240         (push (match-string 0) ids))
 241       ids)))
 242
 243 (defun vc-mtn-revision-completion-table (file)
 244   ;; TODO: Implement completion for for selectors
 245   ;; TODO: Implement completion for composite selectors.
 246   (lexical-let ((file file))
 247     (lambda (string pred action)
 248       (cond
 249        ;; "Tag" selectors.
 250        ((string-match "\\`t:" string)
 251         (complete-with-action action
 252                               (mapcar (lambda (tag) (concat "t:" tag))
 253                                       (vc-mtn-list-tags))
 254                               string pred))
 255        ;; "Branch" selectors.
 256        ((string-match "\\`b:" string)
 257         (complete-with-action action
 258                               (mapcar (lambda (tag) (concat "b:" tag))
 259                                       (vc-mtn-list-branches))
 260                               string pred))
 261        ;; "Head" selectors.  Not sure how they differ from "branch" selectors.
 262        ((string-match "\\`h:" string)
 263         (complete-with-action action
 264                               (mapcar (lambda (tag) (concat "h:" tag))
 265                                       (vc-mtn-list-branches))
 266                               string pred))
 267        ;; "ID" selectors.
 268        ((string-match "\\`i:" string)
 269         (complete-with-action action
 270                               (mapcar (lambda (tag) (concat "i:" tag))
 271                                       (vc-mtn-list-revision-ids
 272                                        (substring string (match-end 0))))
 273                               string pred))
 274        (t
 275         (complete-with-action action
 276                               '("t:" "b:" "h:" "i:"
 277                                 ;; Completion not implemented for these.
 278                                 "a:" "c:" "d:" "e:" "l:")
 279                               string pred))))))
 280
 281
 282
 283 (provide 'vc-mtn)
 284
 285 ;; arch-tag: 2b89ffbc-cbb8-405a-9080-2eafd4becb70
 286 ;;; vc-mtn.el ends here