lisp/gnus/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :version "24.1"
  39   :group 'mail)
  40
  41 (defcustom shr-max-image-proportion 0.9
  42   "How big pictures displayed are in relation to the window they're in.
  43 A value of 0.7 means that they are allowed to take up 70% of the
  44 width and height of the window.  If they are larger than this,
  45 and Emacs supports it, then the images will be rescaled down to
  46 fit these criteria."
  47   :version "24.1"
  48   :group 'shr
  49   :type 'float)
  50
  51 (defcustom shr-blocked-images nil
  52   "Images that have URLs matching this regexp will be blocked."
  53   :version "24.1"
  54   :group 'shr
  55   :type 'regexp)
  56
  57 (defcustom shr-table-horizontal-line ?\s
  58   "Character used to draw horizontal table lines."
  59   :group 'shr
  60   :type 'character)
  61
  62 (defcustom shr-table-vertical-line ?\s
  63   "Character used to draw vertical table lines."
  64   :group 'shr
  65   :type 'character)
  66
  67 (defcustom shr-table-corner ?\s
  68   "Character used to draw table corners."
  69   :group 'shr
  70   :type 'character)
  71
  72 (defcustom shr-hr-line ?-
  73   "Character used to draw hr lines."
  74   :group 'shr
  75   :type 'character)
  76
  77 (defcustom shr-width fill-column
  78   "Frame width to use for rendering.
  79 May either be an integer specifying a fixed width in characters,
  80 or nil, meaning that the full width of the window should be
  81 used."
  82   :type '(choice (integer :tag "Fixed width in characters")
  83                  (const   :tag "Use the width of the window" nil))
  84   :group 'shr)
  85
  86 (defvar shr-content-function nil
  87   "If bound, this should be a function that will return the content.
  88 This is used for cid: URLs, and the function is called with the
  89 cid: URL as the argument.")
  90
  91 (defvar shr-put-image-function 'shr-put-image
  92   "Function called to put image and alt string.")
  93
  94 (defface shr-strike-through '((t (:strike-through t)))
  95   "Font for <s> elements."
  96   :group 'shr)
  97
  98 (defface shr-link
  99   '((t (:inherit link)))
 100   "Font for link elements."
 101   :group 'shr)
 102
 103 ;;; Internal variables.
 104
 105 (defvar shr-folding-mode nil)
 106 (defvar shr-state nil)
 107 (defvar shr-start nil)
 108 (defvar shr-indentation 0)
 109 (defvar shr-inhibit-images nil)
 110 (defvar shr-list-mode nil)
 111 (defvar shr-content-cache nil)
 112 (defvar shr-kinsoku-shorten nil)
 113 (defvar shr-table-depth 0)
 114 (defvar shr-stylesheet nil)
 115 (defvar shr-base nil)
 116 (defvar shr-ignore-cache nil)
 117
 118 (defvar shr-map
 119   (let ((map (make-sparse-keymap)))
 120     (define-key map "a" 'shr-show-alt-text)
 121     (define-key map "i" 'shr-browse-image)
 122     (define-key map "z" 'shr-zoom-image)
 123     (define-key map "I" 'shr-insert-image)
 124     (define-key map "u" 'shr-copy-url)
 125     (define-key map "v" 'shr-browse-url)
 126     (define-key map "o" 'shr-save-contents)
 127     (define-key map "\r" 'shr-browse-url)
 128     map))
 129
 130 ;; Public functions and commands.
 131
 132 (defun shr-render-buffer (buffer)
 133   "Display the HTML rendering of the current buffer."
 134   (interactive (list (current-buffer)))
 135   (pop-to-buffer "*html*")
 136   (erase-buffer)
 137   (shr-insert-document
 138    (with-current-buffer buffer
 139      (libxml-parse-html-region (point-min) (point-max))))
 140   (goto-char (point-min)))
 141
 142 (defun shr-visit-file (file)
 143   "Parse FILE as an HTML document, and render it in a new buffer."
 144   (interactive "fHTML file name: ")
 145   (with-temp-buffer
 146     (insert-file-contents file)
 147     (shr-render-buffer (current-buffer))))
 148
 149 ;;;###autoload
 150 (defun shr-insert-document (dom)
 151   "Render the parsed document DOM into the current buffer.
 152 DOM should be a parse tree as generated by
 153 `libxml-parse-html-region' or similar."
 154   (setq shr-content-cache nil)
 155   (let ((start (point))
 156         (shr-state nil)
 157         (shr-start nil)
 158         (shr-base nil)
 159         (shr-width (or shr-width (window-width))))
 160     (shr-descend (shr-transform-dom dom))
 161     (shr-remove-trailing-whitespace start (point))))
 162
 163 (defun shr-remove-trailing-whitespace (start end)
 164   (let ((width (window-width)))
 165     (save-restriction
 166       (narrow-to-region start end)
 167       (goto-char start)
 168       (while (not (eobp))
 169         (end-of-line)
 170         (when (> (shr-previous-newline-padding-width (current-column)) width)
 171           (dolist (overlay (overlays-at (point)))
 172             (when (overlay-get overlay 'before-string)
 173               (overlay-put overlay 'before-string nil))))
 174         (forward-line 1)))))
 175
 176 (defun shr-copy-url ()
 177   "Copy the URL under point to the kill ring.
 178 If called twice, then try to fetch the URL and see whether it
 179 redirects somewhere else."
 180   (interactive)
 181   (let ((url (get-text-property (point) 'shr-url)))
 182     (cond
 183      ((not url)
 184       (message "No URL under point"))
 185      ;; Resolve redirected URLs.
 186      ((equal url (car kill-ring))
 187       (url-retrieve
 188        url
 189        (lambda (a)
 190          (when (and (consp a)
 191                     (eq (car a) :redirect))
 192            (with-temp-buffer
 193              (insert (cadr a))
 194              (goto-char (point-min))
 195              ;; Remove common tracking junk from the URL.
 196              (when (re-search-forward ".utm_.*" nil t)
 197                (replace-match "" t t))
 198              (message "Copied %s" (buffer-string))
 199              (copy-region-as-kill (point-min) (point-max)))))
 200        nil t))
 201      ;; Copy the URL to the kill ring.
 202      (t
 203       (with-temp-buffer
 204         (insert url)
 205         (copy-region-as-kill (point-min) (point-max))
 206         (message "Copied %s" url))))))
 207
 208 (defun shr-show-alt-text ()
 209   "Show the ALT text of the image under point."
 210   (interactive)
 211   (let ((text (get-text-property (point) 'shr-alt)))
 212     (if (not text)
 213         (message "No image under point")
 214       (message "%s" text))))
 215
 216 (defun shr-browse-image (&optional copy-url)
 217   "Browse the image under point.
 218 If COPY-URL (the prefix if called interactively) is non-nil, copy
 219 the URL of the image to the kill buffer instead."
 220   (interactive "P")
 221   (let ((url (get-text-property (point) 'image-url)))
 222     (cond
 223      ((not url)
 224       (message "No image under point"))
 225      (copy-url
 226       (with-temp-buffer
 227         (insert url)
 228         (copy-region-as-kill (point-min) (point-max))
 229         (message "Copied %s" url)))
 230      (t
 231       (message "Browsing %s..." url)
 232       (browse-url url)))))
 233
 234 (defun shr-insert-image ()
 235   "Insert the image under point into the buffer."
 236   (interactive)
 237   (let ((url (get-text-property (point) 'image-url)))
 238     (if (not url)
 239         (message "No image under point")
 240       (message "Inserting %s..." url)
 241       (url-retrieve url 'shr-image-fetched
 242                     (list (current-buffer) (1- (point)) (point-marker))
 243                     t t))))
 244
 245 (defun shr-zoom-image ()
 246   "Toggle the image size.
 247 The size will be rotated between the default size, the original
 248 size, and full-buffer size."
 249   (interactive)
 250   (let ((url (get-text-property (point) 'image-url))
 251         (size (get-text-property (point) 'image-size))
 252         (buffer-read-only nil))
 253     (if (not url)
 254         (message "No image under point")
 255       ;; Delete the old picture.
 256       (while (get-text-property (point) 'image-url)
 257         (forward-char -1))
 258       (forward-char 1)
 259       (let ((start (point)))
 260         (while (get-text-property (point) 'image-url)
 261           (forward-char 1))
 262         (forward-char -1)
 263         (put-text-property start (point) 'display nil)
 264         (when (> (- (point) start) 2)
 265           (delete-region start (1- (point)))))
 266       (message "Inserting %s..." url)
 267       (url-retrieve url 'shr-image-fetched
 268                     (list (current-buffer) (1- (point)) (point-marker)
 269                           (list (cons 'size
 270                                       (cond ((or (eq size 'default)
 271                                                  (null size))
 272                                              'original)
 273                                             ((eq size 'original)
 274                                              'full)
 275                                             ((eq size 'full)
 276                                              'default)))))
 277                     t))))
 278
 279 ;;; Utility functions.
 280
 281 (defun shr-transform-dom (dom)
 282   (let ((result (list (pop dom))))
 283     (dolist (arg (pop dom))
 284       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 285                   (cdr arg))
 286             result))
 287     (dolist (sub dom)
 288       (if (stringp sub)
 289           (push (cons 'text sub) result)
 290         (push (shr-transform-dom sub) result)))
 291     (nreverse result)))
 292
 293 (defun shr-descend (dom)
 294   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 295         (style (cdr (assq :style (cdr dom))))
 296         (shr-stylesheet shr-stylesheet)
 297         (start (point)))
 298     (when style
 299       (if (string-match "color" style)
 300           (setq shr-stylesheet (nconc (shr-parse-style style)
 301                                       shr-stylesheet))
 302         (setq style nil)))
 303     (if (fboundp function)
 304         (funcall function (cdr dom))
 305       (shr-generic (cdr dom)))
 306     ;; If style is set, then this node has set the color.
 307     (when style
 308       (shr-colorize-region start (point)
 309                            (cdr (assq 'color shr-stylesheet))
 310                            (cdr (assq 'background-color shr-stylesheet))))))
 311
 312 (defun shr-generic (cont)
 313   (dolist (sub cont)
 314     (cond
 315      ((eq (car sub) 'text)
 316       (shr-insert (cdr sub)))
 317      ((listp (cdr sub))
 318       (shr-descend sub)))))
 319
 320 (defmacro shr-char-breakable-p (char)
 321   "Return non-nil if a line can be broken before and after CHAR."
 322   `(aref fill-find-break-point-function-table ,char))
 323 (defmacro shr-char-nospace-p (char)
 324   "Return non-nil if no space is required before and after CHAR."
 325   `(aref fill-nospace-between-words-table ,char))
 326
 327 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 328 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 329 ;; parentheses, and so on, that should not be placed in the beginning
 330 ;; of a line or the end of a line.
 331 (defmacro shr-char-kinsoku-bol-p (char)
 332   "Return non-nil if a line ought not to begin with CHAR."
 333   `(aref (char-category-set ,char) ?>))
 334 (defmacro shr-char-kinsoku-eol-p (char)
 335   "Return non-nil if a line ought not to end with CHAR."
 336   `(aref (char-category-set ,char) ?<))
 337 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 338   (load "kinsoku" nil t))
 339
 340 (defun shr-insert (text)
 341   (when (and (eq shr-state 'image)
 342              (not (bolp))
 343              (not (string-match "\\`[ \t\n]+\\'" text)))
 344     (insert "\n")
 345     (setq shr-state nil))
 346   (cond
 347    ((eq shr-folding-mode 'none)
 348     (insert text))
 349    (t
 350     (when (and (string-match "\\`[ \t\n ]" text)
 351                (not (bolp))
 352                (not (eq (char-after (1- (point))) ? )))
 353       (insert " "))
 354     (dolist (elem (split-string text "[ \f\t\n\r\v ]+" t))
 355       (when (and (bolp)
 356                  (> shr-indentation 0))
 357         (shr-indent))
 358       ;; No space is needed behind a wide character categorized as
 359       ;; kinsoku-bol, between characters both categorized as nospace,
 360       ;; or at the beginning of a line.
 361       (let (prev)
 362         (when (and (> (current-column) shr-indentation)
 363                    (eq (preceding-char) ? )
 364                    (or (= (line-beginning-position) (1- (point)))
 365                        (and (shr-char-breakable-p
 366                              (setq prev (char-after (- (point) 2))))
 367                             (shr-char-kinsoku-bol-p prev))
 368                        (and (shr-char-nospace-p prev)
 369                             (shr-char-nospace-p (aref elem 0)))))
 370           (delete-char -1)))
 371       ;; The shr-start is a special variable that is used to pass
 372       ;; upwards the first point in the buffer where the text really
 373       ;; starts.
 374       (unless shr-start
 375         (setq shr-start (point)))
 376       (insert elem)
 377       (setq shr-state nil)
 378       (let (found)
 379         (while (and (> (current-column) shr-width)
 380                     (progn
 381                       (setq found (shr-find-fill-point))
 382                       (not (eolp))))
 383           (when (eq (preceding-char) ? )
 384             (delete-char -1))
 385           (insert "\n")
 386           (unless found
 387             ;; No space is needed at the beginning of a line.
 388             (when (eq (following-char) ? )
 389               (delete-char 1)))
 390           (when (> shr-indentation 0)
 391             (shr-indent))
 392           (end-of-line))
 393         (insert " ")))
 394     (unless (string-match "[ \t\r\n ]\\'" text)
 395       (delete-char -1)))))
 396
 397 (defun shr-find-fill-point ()
 398   (when (> (move-to-column shr-width) shr-width)
 399     (backward-char 1))
 400   (let ((bp (point))
 401         failed)
 402     (while (not (or (setq failed (= (current-column) shr-indentation))
 403                     (eq (preceding-char) ? )
 404                     (eq (following-char) ? )
 405                     (shr-char-breakable-p (preceding-char))
 406                     (shr-char-breakable-p (following-char))
 407                     (if (eq (preceding-char) ?')
 408                         (not (memq (char-after (- (point) 2))
 409                                    (list nil ?\n ? )))
 410                       (and (shr-char-kinsoku-bol-p (preceding-char))
 411                            (shr-char-breakable-p (following-char))
 412                            (not (shr-char-kinsoku-bol-p (following-char)))))
 413                     (shr-char-kinsoku-eol-p (following-char))))
 414       (backward-char 1))
 415     (if (and (not (or failed (eolp)))
 416              (eq (preceding-char) ?'))
 417         (while (not (or (setq failed (eolp))
 418                         (eq (following-char) ? )
 419                         (shr-char-breakable-p (following-char))
 420                         (shr-char-kinsoku-eol-p (following-char))))
 421           (forward-char 1)))
 422     (if failed
 423         ;; There's no breakable point, so we give it up.
 424         (let (found)
 425           (goto-char bp)
 426           (unless shr-kinsoku-shorten
 427             (while (and (setq found (re-search-forward
 428                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 429                                      (line-end-position) 'move))
 430                         (eq (preceding-char) ?')))
 431             (if (and found (not (match-beginning 1)))
 432                 (goto-char (match-beginning 0)))))
 433       (or
 434        (eolp)
 435        ;; Don't put kinsoku-bol characters at the beginning of a line,
 436        ;; or kinsoku-eol characters at the end of a line.
 437        (cond
 438         (shr-kinsoku-shorten
 439          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 440                      (shr-char-kinsoku-eol-p (preceding-char)))
 441            (backward-char 1))
 442          (when (setq failed (= (current-column) shr-indentation))
 443            ;; There's no breakable point that doesn't violate kinsoku,
 444            ;; so we look for the second best position.
 445            (while (and (progn
 446                          (forward-char 1)
 447                          (<= (current-column) shr-width))
 448                        (progn
 449                          (setq bp (point))
 450                          (shr-char-kinsoku-eol-p (following-char)))))
 451            (goto-char bp)))
 452         ((shr-char-kinsoku-eol-p (preceding-char))
 453          ;; Find backward the point where kinsoku-eol characters begin.
 454          (let ((count 4))
 455            (while
 456                (progn
 457                  (backward-char 1)
 458                  (and (> (setq count (1- count)) 0)
 459                       (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 460                       (or (shr-char-kinsoku-eol-p (preceding-char))
 461                           (shr-char-kinsoku-bol-p (following-char)))))))
 462          (if (setq failed (= (current-column) shr-indentation))
 463              ;; There's no breakable point that doesn't violate kinsoku,
 464              ;; so we go to the second best position.
 465              (if (looking-at "\\(\\c<+\\)\\c<")
 466                  (goto-char (match-end 1))
 467                (forward-char 1))))
 468         ((shr-char-kinsoku-bol-p (following-char))
 469          ;; Find forward the point where kinsoku-bol characters end.
 470          (let ((count 4))
 471            (while (progn
 472                     (forward-char 1)
 473                     (and (>= (setq count (1- count)) 0)
 474                          (shr-char-kinsoku-bol-p (following-char))
 475                          (shr-char-breakable-p (following-char))))))))
 476        (when (eq (following-char) ? )
 477          (forward-char 1))))
 478     (not failed)))
 479
 480 (defun shr-expand-url (url)
 481   (cond
 482    ;; Absolute URL.
 483    ((or (not url)
 484         (string-match "\\`[a-z]*:" url)
 485         (not shr-base))
 486     url)
 487    ((and (string-match "\\`//" url)
 488          (string-match "\\`[a-z]*:" shr-base))
 489     (concat (match-string 0 shr-base) url))
 490    ((and (not (string-match "/\\'" shr-base))
 491          (not (string-match "\\`/" url)))
 492     (concat shr-base "/" url))
 493    (t
 494     (concat shr-base url))))
 495
 496 (defun shr-ensure-newline ()
 497   (unless (zerop (current-column))
 498     (insert "\n")))
 499
 500 (defun shr-ensure-paragraph ()
 501   (unless (bobp)
 502     (if (<= (current-column) shr-indentation)
 503         (unless (save-excursion
 504                   (forward-line -1)
 505                   (looking-at " *$"))
 506           (insert "\n"))
 507       (if (save-excursion
 508             (beginning-of-line)
 509             (looking-at " *$"))
 510           (delete-region (match-beginning 0) (match-end 0))
 511         (insert "\n\n")))))
 512
 513 (defun shr-indent ()
 514   (when (> shr-indentation 0)
 515     (insert (make-string shr-indentation ? ))))
 516
 517 (defun shr-fontize-cont (cont &rest types)
 518   (let (shr-start)
 519     (shr-generic cont)
 520     (dolist (type types)
 521       (shr-add-font (or shr-start (point)) (point) type))))
 522
 523 ;; Add an overlay in the region, but avoid putting the font properties
 524 ;; on blank text at the start of the line, and the newline at the end,
 525 ;; to avoid ugliness.
 526 (defun shr-add-font (start end type)
 527   (save-excursion
 528     (goto-char start)
 529     (while (< (point) end)
 530       (when (bolp)
 531         (skip-chars-forward " "))
 532       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 533         (overlay-put overlay 'face type))
 534       (if (< (line-end-position) end)
 535           (forward-line 1)
 536         (goto-char end)))))
 537
 538 (defun shr-browse-url ()
 539   "Browse the URL under point."
 540   (interactive)
 541   (let ((url (get-text-property (point) 'shr-url)))
 542     (cond
 543      ((not url)
 544       (message "No link under point"))
 545      ((string-match "^mailto:" url)
 546       (browse-url-mail url))
 547      (t
 548       (browse-url url)))))
 549
 550 (defun shr-save-contents (directory)
 551   "Save the contents from URL in a file."
 552   (interactive "DSave contents of URL to directory: ")
 553   (let ((url (get-text-property (point) 'shr-url)))
 554     (if (not url)
 555         (message "No link under point")
 556       (url-retrieve (shr-encode-url url)
 557                     'shr-store-contents (list url directory)
 558                     nil t))))
 559
 560 (defun shr-store-contents (status url directory)
 561   (unless (plist-get status :error)
 562     (when (or (search-forward "\n\n" nil t)
 563               (search-forward "\r\n\r\n" nil t))
 564       (write-region (point) (point-max)
 565                     (expand-file-name (file-name-nondirectory url)
 566                                       directory)))))
 567
 568 (defun shr-image-fetched (status buffer start end &optional flags)
 569   (let ((image-buffer (current-buffer)))
 570     (when (and (buffer-name buffer)
 571                (not (plist-get status :error)))
 572       (url-store-in-cache image-buffer)
 573       (when (or (search-forward "\n\n" nil t)
 574                 (search-forward "\r\n\r\n" nil t))
 575         (let ((data (buffer-substring (point) (point-max))))
 576           (with-current-buffer buffer
 577             (save-excursion
 578               (let ((alt (buffer-substring start end))
 579                     (properties (text-properties-at start))
 580                     (inhibit-read-only t))
 581                 (delete-region start end)
 582                 (goto-char start)
 583                 (funcall shr-put-image-function data alt flags)
 584                 (while properties
 585                   (let ((type (pop properties))
 586                         (value (pop properties)))
 587                     (unless (memq type '(display image-size))
 588                       (put-text-property start (point) type value))))))))))
 589     (kill-buffer image-buffer)))
 590
 591 (defun shr-put-image (data alt &optional flags)
 592   "Put image DATA with a string ALT.  Return image."
 593   (if (display-graphic-p)
 594       (let* ((size (cdr (assq 'size flags)))
 595              (start (point))
 596              (image (cond
 597                      ((eq size 'original)
 598                       (create-image data nil t :ascent 100))
 599                      ((eq size 'full)
 600                       (ignore-errors
 601                         (shr-rescale-image data t)))
 602                      (t
 603                       (ignore-errors
 604                         (shr-rescale-image data))))))
 605         (when image
 606           ;; When inserting big-ish pictures, put them at the
 607           ;; beginning of the line.
 608           (when (and (> (current-column) 0)
 609                      (> (car (image-size image t)) 400))
 610             (insert "\n"))
 611           (if (eq size 'original)
 612               (let ((overlays (overlays-at (point))))
 613                 (insert-sliced-image image (or alt "*") nil 20 1)
 614                 (dolist (overlay overlays)
 615                   (overlay-put overlay 'face 'default)))
 616             (insert-image image (or alt "*")))
 617           (put-text-property start (point) 'image-size size)
 618           (when (if (fboundp 'image-multi-frame-p)
 619                     ;; Only animate multi-frame things that specify a
 620                     ;; delay; eg animated gifs as opposed to
 621                     ;; multi-page tiffs.  FIXME?
 622                     (cdr (image-multi-frame-p image))
 623                   (image-animated-p image))
 624             (image-animate image nil 60)))
 625         image)
 626     (insert alt)))
 627
 628 (defun shr-rescale-image (data &optional force)
 629   "Rescale DATA, if too big, to fit the current buffer.
 630 If FORCE, rescale the image anyway."
 631   (let ((image (create-image data nil t :ascent 100)))
 632     (if (or (not (fboundp 'imagemagick-types))
 633             (not (get-buffer-window (current-buffer))))
 634         image
 635       (let* ((size (image-size image t))
 636              (width (car size))
 637              (height (cdr size))
 638              (edges (window-inside-pixel-edges
 639                      (get-buffer-window (current-buffer))))
 640              (window-width (truncate (* shr-max-image-proportion
 641                                         (- (nth 2 edges) (nth 0 edges)))))
 642              (window-height (truncate (* shr-max-image-proportion
 643                                          (- (nth 3 edges) (nth 1 edges)))))
 644              scaled-image)
 645         (when (or force
 646                   (> height window-height))
 647           (setq image (or (create-image data 'imagemagick t
 648                                         :height window-height
 649                                         :ascent 100)
 650                           image))
 651           (setq size (image-size image t)))
 652         (when (> (car size) window-width)
 653           (setq image (or
 654                        (create-image data 'imagemagick t
 655                                      :width window-width
 656                                      :ascent 100)
 657                        image)))
 658         image))))
 659
 660 ;; url-cache-extract autoloads url-cache.
 661 (declare-function url-cache-create-filename "url-cache" (url))
 662 (autoload 'mm-disable-multibyte "mm-util")
 663 (autoload 'browse-url-mail "browse-url")
 664
 665 (defun shr-get-image-data (url)
 666   "Get image data for URL.
 667 Return a string with image data."
 668   (with-temp-buffer
 669     (mm-disable-multibyte)
 670     (when (ignore-errors
 671             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 672             t)
 673       (when (or (search-forward "\n\n" nil t)
 674                 (search-forward "\r\n\r\n" nil t))
 675         (buffer-substring (point) (point-max))))))
 676
 677 (defun shr-image-displayer (content-function)
 678   "Return a function to display an image.
 679 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 680 is an argument.  The function to be returned takes three arguments URL,
 681 START, and END.  Note that START and END should be markers."
 682   `(lambda (url start end)
 683      (when url
 684        (if (string-match "\\`cid:" url)
 685            ,(when content-function
 686               `(let ((image (funcall ,content-function
 687                                      (substring url (match-end 0)))))
 688                  (when image
 689                    (goto-char start)
 690                    (funcall shr-put-image-function
 691                             image (buffer-substring start end))
 692                    (delete-region (point) end))))
 693          (url-retrieve url 'shr-image-fetched
 694                        (list (current-buffer) start end)
 695                        t t)))))
 696
 697 (defun shr-heading (cont &rest types)
 698   (shr-ensure-paragraph)
 699   (apply #'shr-fontize-cont cont types)
 700   (shr-ensure-paragraph))
 701
 702 (autoload 'widget-convert-button "wid-edit")
 703
 704 (defun shr-urlify (start url &optional title)
 705   (widget-convert-button
 706    'url-link start (point)
 707    :help-echo (if title (format "%s (%s)" url title) url)
 708    :keymap shr-map
 709    url)
 710   (shr-add-font start (point) 'shr-link)
 711   (put-text-property start (point) 'shr-url url))
 712
 713 (defun shr-encode-url (url)
 714   "Encode URL."
 715   (browse-url-url-encode-chars url "[)$ ]"))
 716
 717 (autoload 'shr-color-visible "shr-color")
 718 (autoload 'shr-color->hexadecimal "shr-color")
 719
 720 (defun shr-color-check (fg bg)
 721   "Check that FG is visible on BG.
 722 Returns (fg bg) with corrected values.
 723 Returns nil if the colors that would be used are the default
 724 ones, in case fg and bg are nil."
 725   (when (or fg bg)
 726     (let ((fixed (cond ((null fg) 'fg)
 727                        ((null bg) 'bg))))
 728       ;; Convert colors to hexadecimal, or set them to default.
 729       (let ((fg (or (shr-color->hexadecimal fg)
 730                     (frame-parameter nil 'foreground-color)))
 731             (bg (or (shr-color->hexadecimal bg)
 732                     (frame-parameter nil 'background-color))))
 733         (cond ((eq fixed 'bg)
 734                ;; Only return the new fg
 735                (list nil (cadr (shr-color-visible bg fg t))))
 736               ((eq fixed 'fg)
 737                ;; Invert args and results and return only the new bg
 738                (list (cadr (shr-color-visible fg bg t)) nil))
 739               (t
 740                (shr-color-visible bg fg)))))))
 741
 742 (defun shr-colorize-region (start end fg &optional bg)
 743   (when (or fg bg)
 744     (let ((new-colors (shr-color-check fg bg)))
 745       (when new-colors
 746         (when fg
 747           (shr-put-color start end :foreground (cadr new-colors)))
 748         (when bg
 749           (shr-put-color start end :background (car new-colors))))
 750       new-colors)))
 751
 752 ;; Put a color in the region, but avoid putting colors on blank
 753 ;; text at the start of the line, and the newline at the end, to avoid
 754 ;; ugliness.  Also, don't overwrite any existing color information,
 755 ;; since this can be called recursively, and we want the "inner" color
 756 ;; to win.
 757 (defun shr-put-color (start end type color)
 758   (save-excursion
 759     (goto-char start)
 760     (while (< (point) end)
 761       (when (and (bolp)
 762                  (not (eq type :background)))
 763         (skip-chars-forward " "))
 764       (when (> (line-end-position) (point))
 765         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 766       (if (< (line-end-position) end)
 767           (forward-line 1)
 768         (goto-char end)))
 769     (when (and (eq type :background)
 770                (= shr-table-depth 0))
 771       (shr-expand-newlines start end color))))
 772
 773 (defun shr-expand-newlines (start end color)
 774   (save-restriction
 775     ;; Skip past all white space at the start and ends.
 776     (goto-char start)
 777     (skip-chars-forward " \t\n")
 778     (beginning-of-line)
 779     (setq start (point))
 780     (goto-char end)
 781     (skip-chars-backward " \t\n")
 782     (forward-line 1)
 783     (setq end (point))
 784     (narrow-to-region start end)
 785     (let ((width (shr-buffer-width))
 786           column)
 787       (goto-char (point-min))
 788       (while (not (eobp))
 789         (end-of-line)
 790         (when (and (< (setq column (current-column)) width)
 791                    (< (setq column (shr-previous-newline-padding-width column))
 792                       width))
 793           (let ((overlay (make-overlay (point) (1+ (point)))))
 794             (overlay-put overlay 'before-string
 795                          (concat
 796                           (mapconcat
 797                            (lambda (overlay)
 798                              (let ((string (plist-get
 799                                             (overlay-properties overlay)
 800                                             'before-string)))
 801                                (if (not string)
 802                                    ""
 803                                  (overlay-put overlay 'before-string "")
 804                                  string)))
 805                            (overlays-at (point))
 806                            "")
 807                           (propertize (make-string (- width column) ? )
 808                                       'face (list :background color))))))
 809         (forward-line 1)))))
 810
 811 (defun shr-previous-newline-padding-width (width)
 812   (let ((overlays (overlays-at (point)))
 813         (previous-width 0))
 814     (if (null overlays)
 815         width
 816       (dolist (overlay overlays)
 817         (setq previous-width
 818               (+ previous-width
 819                  (length (plist-get (overlay-properties overlay)
 820                                     'before-string)))))
 821       (+ width previous-width))))
 822
 823 (defun shr-put-color-1 (start end type color)
 824   (let* ((old-props (get-text-property start 'face))
 825          (do-put (and (listp old-props)
 826                       (not (memq type old-props))))
 827          change)
 828     (while (< start end)
 829       (setq change (next-single-property-change start 'face nil end))
 830       (when do-put
 831         (put-text-property start change 'face
 832                            (nconc (list type color) old-props)))
 833       (setq old-props (get-text-property change 'face))
 834       (setq do-put (and (listp old-props)
 835                         (not (memq type old-props))))
 836       (setq start change))
 837     (when (and do-put
 838                (> end start))
 839       (put-text-property start end 'face
 840                          (nconc (list type color old-props))))))
 841
 842 ;;; Tag-specific rendering rules.
 843
 844 (defun shr-tag-body (cont)
 845   (let* ((start (point))
 846          (fgcolor (cdr (or (assq :fgcolor cont)
 847                            (assq :text cont))))
 848          (bgcolor (cdr (assq :bgcolor cont)))
 849          (shr-stylesheet (list (cons 'color fgcolor)
 850                                (cons 'background-color bgcolor))))
 851     (shr-generic cont)
 852     (shr-colorize-region start (point) fgcolor bgcolor)))
 853
 854 (defun shr-tag-style (cont)
 855   )
 856
 857 (defun shr-tag-script (cont)
 858   )
 859
 860 (defun shr-tag-comment (cont)
 861   )
 862
 863 (defun shr-tag-sup (cont)
 864   (let ((start (point)))
 865     (shr-generic cont)
 866     (put-text-property start (point) 'display '(raise 0.5))))
 867
 868 (defun shr-tag-sub (cont)
 869   (let ((start (point)))
 870     (shr-generic cont)
 871     (put-text-property start (point) 'display '(raise -0.5))))
 872
 873 (defun shr-tag-label (cont)
 874   (shr-generic cont)
 875   (shr-ensure-paragraph))
 876
 877 (defun shr-tag-p (cont)
 878   (shr-ensure-paragraph)
 879   (shr-indent)
 880   (shr-generic cont)
 881   (shr-ensure-paragraph))
 882
 883 (defun shr-tag-div (cont)
 884   (shr-ensure-newline)
 885   (shr-indent)
 886   (shr-generic cont)
 887   (shr-ensure-newline))
 888
 889 (defun shr-tag-s (cont)
 890   (shr-fontize-cont cont 'shr-strike-through))
 891
 892 (defun shr-tag-del (cont)
 893   (shr-fontize-cont cont 'shr-strike-through))
 894
 895 (defun shr-tag-b (cont)
 896   (shr-fontize-cont cont 'bold))
 897
 898 (defun shr-tag-i (cont)
 899   (shr-fontize-cont cont 'italic))
 900
 901 (defun shr-tag-em (cont)
 902   (shr-fontize-cont cont 'italic))
 903
 904 (defun shr-tag-strong (cont)
 905   (shr-fontize-cont cont 'bold))
 906
 907 (defun shr-tag-u (cont)
 908   (shr-fontize-cont cont 'underline))
 909
 910 (defun shr-parse-style (style)
 911   (when style
 912     (save-match-data
 913       (when (string-match "\n" style)
 914         (setq style (replace-match " " t t style))))
 915     (let ((plist nil))
 916       (dolist (elem (split-string style ";"))
 917         (when elem
 918           (setq elem (split-string elem ":"))
 919           (when (and (car elem)
 920                      (cadr elem))
 921             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 922                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 923               (when (string-match " *!important\\'" value)
 924                 (setq value (substring value 0 (match-beginning 0))))
 925               (push (cons (intern name obarray)
 926                           value)
 927                     plist)))))
 928       plist)))
 929
 930 (defun shr-tag-base (cont)
 931   (setq shr-base (cdr (assq :href cont))))
 932
 933 (defun shr-tag-a (cont)
 934   (let ((url (cdr (assq :href cont)))
 935         (title (cdr (assq :title cont)))
 936         (start (point))
 937         shr-start)
 938     (shr-generic cont)
 939     (when url
 940       (shr-urlify (or shr-start start) (shr-expand-url url) title))))
 941
 942 (defun shr-tag-object (cont)
 943   (let ((start (point))
 944         url)
 945     (dolist (elem cont)
 946       (when (eq (car elem) 'embed)
 947         (setq url (or url (cdr (assq :src (cdr elem))))))
 948       (when (and (eq (car elem) 'param)
 949                  (equal (cdr (assq :name (cdr elem))) "movie"))
 950         (setq url (or url (cdr (assq :value (cdr elem)))))))
 951     (when url
 952       (shr-insert " [multimedia] ")
 953       (shr-urlify start (shr-expand-url url)))
 954     (shr-generic cont)))
 955
 956 (defun shr-tag-video (cont)
 957   (let ((image (cdr (assq :poster cont)))
 958         (url (cdr (assq :src cont)))
 959         (start (point)))
 960     (shr-tag-img nil image)
 961     (shr-urlify start (shr-expand-url url))))
 962
 963 (defun shr-tag-img (cont &optional url)
 964   (when (or url
 965             (and cont
 966                  (cdr (assq :src cont))))
 967     (when (and (> (current-column) 0)
 968                (not (eq shr-state 'image)))
 969       (insert "\n"))
 970     (let ((alt (cdr (assq :alt cont)))
 971           (url (shr-expand-url (or url (cdr (assq :src cont))))))
 972       (let ((start (point-marker)))
 973         (when (zerop (length alt))
 974           (setq alt "*"))
 975         (cond
 976          ((or (member (cdr (assq :height cont)) '("0" "1"))
 977               (member (cdr (assq :width cont)) '("0" "1")))
 978           ;; Ignore zero-sized or single-pixel images.
 979           )
 980          ((and (not shr-inhibit-images)
 981                (string-match "\\`cid:" url))
 982           (let ((url (substring url (match-end 0)))
 983                 image)
 984             (if (or (not shr-content-function)
 985                     (not (setq image (funcall shr-content-function url))))
 986                 (insert alt)
 987               (funcall shr-put-image-function image alt))))
 988          ((or shr-inhibit-images
 989               (and shr-blocked-images
 990                    (string-match shr-blocked-images url)))
 991           (setq shr-start (point))
 992           (let ((shr-state 'space))
 993             (if (> (string-width alt) 8)
 994                 (shr-insert (truncate-string-to-width alt 8))
 995               (shr-insert alt))))
 996          ((and (not shr-ignore-cache)
 997                (url-is-cached (shr-encode-url url)))
 998           (funcall shr-put-image-function (shr-get-image-data url) alt))
 999          (t
1000           (insert alt " ")
1001           (when (and shr-ignore-cache
1002                      (url-is-cached (shr-encode-url url)))
1003             (let ((file (url-cache-create-filename (shr-encode-url url))))
1004               (when (file-exists-p file)
1005                 (delete-file file))))
1006           (url-queue-retrieve
1007            (shr-encode-url url) 'shr-image-fetched
1008            (list (current-buffer) start (set-marker (make-marker) (1- (point))))
1009            t t)))
1010         (when (zerop shr-table-depth) ;; We are not in a table.
1011           (put-text-property start (point) 'keymap shr-map)
1012           (put-text-property start (point) 'shr-alt alt)
1013           (put-text-property start (point) 'image-url url)
1014           (put-text-property start (point) 'image-displayer
1015                              (shr-image-displayer shr-content-function))
1016           (put-text-property start (point) 'help-echo alt))
1017         (setq shr-state 'image)))))
1018
1019 (defun shr-tag-pre (cont)
1020   (let ((shr-folding-mode 'none))
1021     (shr-ensure-newline)
1022     (shr-indent)
1023     (shr-generic cont)
1024     (shr-ensure-newline)))
1025
1026 (defun shr-tag-blockquote (cont)
1027   (shr-ensure-paragraph)
1028   (shr-indent)
1029   (let ((shr-indentation (+ shr-indentation 4)))
1030     (shr-generic cont))
1031   (shr-ensure-paragraph))
1032
1033 (defun shr-tag-ul (cont)
1034   (shr-ensure-paragraph)
1035   (let ((shr-list-mode 'ul))
1036     (shr-generic cont))
1037   (shr-ensure-paragraph))
1038
1039 (defun shr-tag-ol (cont)
1040   (shr-ensure-paragraph)
1041   (let ((shr-list-mode 1))
1042     (shr-generic cont))
1043   (shr-ensure-paragraph))
1044
1045 (defun shr-tag-li (cont)
1046   (shr-ensure-paragraph)
1047   (shr-indent)
1048   (let* ((bullet
1049           (if (numberp shr-list-mode)
1050               (prog1
1051                   (format "%d " shr-list-mode)
1052                 (setq shr-list-mode (1+ shr-list-mode)))
1053             "* "))
1054          (shr-indentation (+ shr-indentation (length bullet))))
1055     (insert bullet)
1056     (shr-generic cont)))
1057
1058 (defun shr-tag-br (cont)
1059   (when (and (not (bobp))
1060              ;; Only add a newline if we break the current line, or
1061              ;; the previous line isn't a blank line.
1062              (or (not (bolp))
1063                  (and (> (- (point) 2) (point-min))
1064                       (not (= (char-after (- (point) 2)) ?\n)))))
1065     (insert "\n")
1066     (shr-indent))
1067   (shr-generic cont))
1068
1069 (defun shr-tag-h1 (cont)
1070   (shr-heading cont 'bold 'underline))
1071
1072 (defun shr-tag-h2 (cont)
1073   (shr-heading cont 'bold))
1074
1075 (defun shr-tag-h3 (cont)
1076   (shr-heading cont 'italic))
1077
1078 (defun shr-tag-h4 (cont)
1079   (shr-heading cont))
1080
1081 (defun shr-tag-h5 (cont)
1082   (shr-heading cont))
1083
1084 (defun shr-tag-h6 (cont)
1085   (shr-heading cont))
1086
1087 (defun shr-tag-hr (cont)
1088   (shr-ensure-newline)
1089   (insert (make-string shr-width shr-hr-line) "\n"))
1090
1091 (defun shr-tag-title (cont)
1092   (shr-heading cont 'bold 'underline))
1093
1094 (defun shr-tag-font (cont)
1095   (let* ((start (point))
1096          (color (cdr (assq :color cont)))
1097          (shr-stylesheet (nconc (list (cons 'color color))
1098                                 shr-stylesheet)))
1099     (shr-generic cont)
1100     (when color
1101       (shr-colorize-region start (point) color
1102                            (cdr (assq 'background-color shr-stylesheet))))))
1103
1104 ;;; Table rendering algorithm.
1105
1106 ;; Table rendering is the only complicated thing here.  We do this by
1107 ;; first counting how many TDs there are in each TR, and registering
1108 ;; how wide they think they should be ("width=45%", etc).  Then we
1109 ;; render each TD separately (this is done in temporary buffers, so
1110 ;; that we can use all the rendering machinery as if we were in the
1111 ;; main buffer).  Now we know how much space each TD really takes, so
1112 ;; we then render everything again with the new widths, and finally
1113 ;; insert all these boxes into the main buffer.
1114 (defun shr-tag-table-1 (cont)
1115   (setq cont (or (cdr (assq 'tbody cont))
1116                  cont))
1117   (let* ((shr-inhibit-images t)
1118          (shr-table-depth (1+ shr-table-depth))
1119          (shr-kinsoku-shorten t)
1120          ;; Find all suggested widths.
1121          (columns (shr-column-specs cont))
1122          ;; Compute how many characters wide each TD should be.
1123          (suggested-widths (shr-pro-rate-columns columns))
1124          ;; Do a "test rendering" to see how big each TD is (this can
1125          ;; be smaller (if there's little text) or bigger (if there's
1126          ;; unbreakable text).
1127          (sketch (shr-make-table cont suggested-widths))
1128          ;; Compute the "natural" width by setting each column to 500
1129          ;; characters and see how wide they really render.
1130          (natural (shr-make-table cont (make-vector (length columns) 500)))
1131          (sketch-widths (shr-table-widths sketch natural suggested-widths)))
1132     ;; This probably won't work very well.
1133     (when (> (+ (loop for width across sketch-widths
1134                       summing (1+ width))
1135                 shr-indentation 1)
1136              (frame-width))
1137       (setq truncate-lines t))
1138     ;; Then render the table again with these new "hard" widths.
1139     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
1140   ;; Finally, insert all the images after the table.  The Emacs buffer
1141   ;; model isn't strong enough to allow us to put the images actually
1142   ;; into the tables.
1143   (when (zerop shr-table-depth)
1144     (dolist (elem (shr-find-elements cont 'img))
1145       (shr-tag-img (cdr elem)))))
1146
1147 (defun shr-tag-table (cont)
1148   (shr-ensure-paragraph)
1149   (let* ((caption (cdr (assq 'caption cont)))
1150          (header (cdr (assq 'thead cont)))
1151          (body (or (cdr (assq 'tbody cont)) cont))
1152          (footer (cdr (assq 'tfoot cont)))
1153          (bgcolor (cdr (assq :bgcolor cont)))
1154          (start (point))
1155          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
1156                                 shr-stylesheet))
1157          (nheader (if header (shr-max-columns header)))
1158          (nbody (if body (shr-max-columns body)))
1159          (nfooter (if footer (shr-max-columns footer))))
1160     (if (and (not caption)
1161              (not header)
1162              (not (cdr (assq 'tbody cont)))
1163              (not (cdr (assq 'tr cont)))
1164              (not footer))
1165         ;; The table is totally invalid and just contains random junk.
1166         ;; Try to output it anyway.
1167         (shr-generic cont)
1168       ;; It's a real table, so render it.
1169       (shr-tag-table-1
1170        (nconc
1171         (if caption `((tr (td ,@caption))))
1172         (if header
1173             (if footer
1174                 ;; hader + body + footer
1175                 (if (= nheader nbody)
1176                     (if (= nbody nfooter)
1177                         `((tr (td (table (tbody ,@header ,@body ,@footer)))))
1178                       (nconc `((tr (td (table (tbody ,@header ,@body)))))
1179                              (if (= nfooter 1)
1180                                  footer
1181                                `((tr (td (table (tbody ,@footer))))))))
1182                   (nconc `((tr (td (table (tbody ,@header)))))
1183                          (if (= nbody nfooter)
1184                              `((tr (td (table (tbody ,@body ,@footer)))))
1185                            (nconc `((tr (td (table (tbody ,@body)))))
1186                                   (if (= nfooter 1)
1187                                       footer
1188                                     `((tr (td (table (tbody ,@footer))))))))))
1189               ;; header + body
1190               (if (= nheader nbody)
1191                   `((tr (td (table (tbody ,@header ,@body)))))
1192                 (if (= nheader 1)
1193                     `(,@header (tr (td (table (tbody ,@body)))))
1194                   `((tr (td (table (tbody ,@header))))
1195                     (tr (td (table (tbody ,@body))))))))
1196           (if footer
1197               ;; body + footer
1198               (if (= nbody nfooter)
1199                   `((tr (td (table (tbody ,@body ,@footer)))))
1200                 (nconc `((tr (td (table (tbody ,@body)))))
1201                        (if (= nfooter 1)
1202                            footer
1203                          `((tr (td (table (tbody ,@footer))))))))
1204             (if caption
1205                 `((tr (td (table (tbody ,@body)))))
1206               body))))))
1207     (when bgcolor
1208       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
1209                            bgcolor))))
1210
1211 (defun shr-find-elements (cont type)
1212   (let (result)
1213     (dolist (elem cont)
1214       (cond ((eq (car elem) type)
1215              (push elem result))
1216             ((consp (cdr elem))
1217              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
1218     (nreverse result)))
1219
1220 (defun shr-insert-table (table widths)
1221   (shr-insert-table-ruler widths)
1222   (dolist (row table)
1223     (let ((start (point))
1224           (height (let ((max 0))
1225                     (dolist (column row)
1226                       (setq max (max max (cadr column))))
1227                     max)))
1228       (dotimes (i height)
1229         (shr-indent)
1230         (insert shr-table-vertical-line "\n"))
1231       (dolist (column row)
1232         (goto-char start)
1233         (let ((lines (nth 2 column))
1234               (overlay-lines (nth 3 column))
1235               overlay overlay-line)
1236           (dolist (line lines)
1237             (setq overlay-line (pop overlay-lines))
1238             (end-of-line)
1239             (insert line shr-table-vertical-line)
1240             (dolist (overlay overlay-line)
1241               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
1242                                      (- (point) (nth 1 overlay) 1)))
1243                     (properties (nth 2 overlay)))
1244                 (while properties
1245                   (overlay-put o (pop properties) (pop properties)))))
1246             (forward-line 1))
1247           ;; Add blank lines at padding at the bottom of the TD,
1248           ;; possibly.
1249           (dotimes (i (- height (length lines)))
1250             (end-of-line)
1251             (let ((start (point)))
1252               (insert (make-string (string-width (car lines)) ? )
1253                       shr-table-vertical-line)
1254               (when (nth 4 column)
1255                 (shr-put-color start (1- (point)) :background (nth 4 column))))
1256             (forward-line 1)))))
1257     (shr-insert-table-ruler widths)))
1258
1259 (defun shr-insert-table-ruler (widths)
1260   (when (and (bolp)
1261              (> shr-indentation 0))
1262     (shr-indent))
1263   (insert shr-table-corner)
1264   (dotimes (i (length widths))
1265     (insert (make-string (aref widths i) shr-table-horizontal-line)
1266             shr-table-corner))
1267   (insert "\n"))
1268
1269 (defun shr-table-widths (table natural-table suggested-widths)
1270   (let* ((length (length suggested-widths))
1271          (widths (make-vector length 0))
1272          (natural-widths (make-vector length 0)))
1273     (dolist (row table)
1274       (let ((i 0))
1275         (dolist (column row)
1276           (aset widths i (max (aref widths i) column))
1277           (setq i (1+ i)))))
1278     (dolist (row natural-table)
1279       (let ((i 0))
1280         (dolist (column row)
1281           (aset natural-widths i (max (aref natural-widths i) column))
1282           (setq i (1+ i)))))
1283     (let ((extra (- (apply '+ (append suggested-widths nil))
1284                     (apply '+ (append widths nil))))
1285           (expanded-columns 0))
1286       ;; We have extra, unused space, so divide this space amongst the
1287       ;; columns.
1288       (when (> extra 0)
1289         ;; If the natural width is wider than the rendered width, we
1290         ;; want to allow the column to expand.
1291         (dotimes (i length)
1292           (when (> (aref natural-widths i) (aref widths i))
1293             (setq expanded-columns (1+ expanded-columns))))
1294         (dotimes (i length)
1295           (when (> (aref natural-widths i) (aref widths i))
1296             (aset widths i (min
1297                             (aref natural-widths i)
1298                             (+ (/ extra expanded-columns)
1299                                (aref widths i))))))))
1300     widths))
1301
1302 (defun shr-make-table (cont widths &optional fill)
1303   (let ((trs nil))
1304     (dolist (row cont)
1305       (when (eq (car row) 'tr)
1306         (let ((tds nil)
1307               (columns (cdr row))
1308               (i 0)
1309               column)
1310           (while (< i (length widths))
1311             (setq column (pop columns))
1312             (when (or (memq (car column) '(td th))
1313                       (null column))
1314               (push (shr-render-td (cdr column) (aref widths i) fill)
1315                     tds)
1316               (setq i (1+ i))))
1317           (push (nreverse tds) trs))))
1318     (nreverse trs)))
1319
1320 (defun shr-render-td (cont width fill)
1321   (with-temp-buffer
1322     (let ((bgcolor (cdr (assq :bgcolor cont)))
1323           (fgcolor (cdr (assq :fgcolor cont)))
1324           (style (cdr (assq :style cont)))
1325           (shr-stylesheet shr-stylesheet)
1326           overlays actual-colors)
1327       (when style
1328         (setq style (and (string-match "color" style)
1329                          (shr-parse-style style))))
1330       (when bgcolor
1331         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1332       (when fgcolor
1333         (setq style (nconc (list (cons 'color fgcolor)) style)))
1334       (when style
1335         (setq shr-stylesheet (append style shr-stylesheet)))
1336       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1337         (if cache
1338             (progn
1339               (insert (car cache))
1340               (let ((end (length (car cache))))
1341                 (dolist (overlay (cadr cache))
1342                   (let ((new-overlay
1343                          (make-overlay (1+ (- end (nth 0 overlay)))
1344                                        (1+ (- end (nth 1 overlay)))))
1345                         (properties (nth 2 overlay)))
1346                     (while properties
1347                       (overlay-put new-overlay
1348                                    (pop properties) (pop properties)))))))
1349           (let ((shr-width width)
1350                 (shr-indentation 0))
1351             (shr-descend (cons 'td cont)))
1352           ;; Delete padding at the bottom of the TDs.
1353           (delete-region
1354            (point)
1355            (progn
1356              (skip-chars-backward " \t\n")
1357              (end-of-line)
1358              (point)))
1359           (push (list (cons width cont) (buffer-string)
1360                       (shr-overlays-in-region (point-min) (point-max)))
1361                 shr-content-cache)))
1362       (goto-char (point-min))
1363       (let ((max 0))
1364         (while (not (eobp))
1365           (end-of-line)
1366           (setq max (max max (current-column)))
1367           (forward-line 1))
1368         (when fill
1369           (goto-char (point-min))
1370           ;; If the buffer is totally empty, then put a single blank
1371           ;; line here.
1372           (if (zerop (buffer-size))
1373               (insert (make-string width ? ))
1374             ;; Otherwise, fill the buffer.
1375             (while (not (eobp))
1376               (end-of-line)
1377               (when (> (- width (current-column)) 0)
1378                 (insert (make-string (- width (current-column)) ? )))
1379               (forward-line 1)))
1380           (when style
1381             (setq actual-colors
1382                   (shr-colorize-region
1383                    (point-min) (point-max)
1384                    (cdr (assq 'color shr-stylesheet))
1385                    (cdr (assq 'background-color shr-stylesheet))))))
1386         (if fill
1387             (list max
1388                   (count-lines (point-min) (point-max))
1389                   (split-string (buffer-string) "\n")
1390                   (shr-collect-overlays)
1391                   (car actual-colors))
1392           max)))))
1393
1394 (defun shr-buffer-width ()
1395   (goto-char (point-min))
1396   (let ((max 0))
1397     (while (not (eobp))
1398       (end-of-line)
1399       (setq max (max max (current-column)))
1400       (forward-line 1))
1401     max))
1402
1403 (defun shr-collect-overlays ()
1404   (save-excursion
1405     (goto-char (point-min))
1406     (let ((overlays nil))
1407       (while (not (eobp))
1408         (push (shr-overlays-in-region (point) (line-end-position))
1409               overlays)
1410         (forward-line 1))
1411       (nreverse overlays))))
1412
1413 (defun shr-overlays-in-region (start end)
1414   (let (result)
1415     (dolist (overlay (overlays-in start end))
1416       (push (list (if (> start (overlay-start overlay))
1417                       (- end start)
1418                     (- end (overlay-start overlay)))
1419                   (if (< end (overlay-end overlay))
1420                       0
1421                     (- end (overlay-end overlay)))
1422                   (overlay-properties overlay))
1423             result))
1424     (nreverse result)))
1425
1426 (defun shr-pro-rate-columns (columns)
1427   (let ((total-percentage 0)
1428         (widths (make-vector (length columns) 0)))
1429     (dotimes (i (length columns))
1430       (setq total-percentage (+ total-percentage (aref columns i))))
1431     (setq total-percentage (/ 1.0 total-percentage))
1432     (dotimes (i (length columns))
1433       (aset widths i (max (truncate (* (aref columns i)
1434                                        total-percentage
1435                                        (- shr-width (1+ (length columns)))))
1436                           10)))
1437     widths))
1438
1439 ;; Return a summary of the number and shape of the TDs in the table.
1440 (defun shr-column-specs (cont)
1441   (let ((columns (make-vector (shr-max-columns cont) 1)))
1442     (dolist (row cont)
1443       (when (eq (car row) 'tr)
1444         (let ((i 0))
1445           (dolist (column (cdr row))
1446             (when (memq (car column) '(td th))
1447               (let ((width (cdr (assq :width (cdr column)))))
1448                 (when (and width
1449                            (string-match "\\([0-9]+\\)%" width)
1450                            (not (zerop (setq width (string-to-number
1451                                                     (match-string 1 width))))))
1452                   (aset columns i (/ width 100.0))))
1453               (setq i (1+ i)))))))
1454     columns))
1455
1456 (defun shr-count (cont elem)
1457   (let ((i 0))
1458     (dolist (sub cont)
1459       (when (eq (car sub) elem)
1460         (setq i (1+ i))))
1461     i))
1462
1463 (defun shr-max-columns (cont)
1464   (let ((max 0))
1465     (dolist (row cont)
1466       (when (eq (car row) 'tr)
1467         (setq max (max max (+ (shr-count (cdr row) 'td)
1468                               (shr-count (cdr row) 'th))))))
1469     max))
1470
1471 (provide 'shr)
1472
1473 ;; Local Variables:
1474 ;; coding: iso-8859-1
1475 ;; End:
1476
1477 ;;; shr.el ends here