lisp/custom.el

   1 ;;; custom.el --- tools for declaring and initializing options
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2001, 2002, 2004
   4 ;;  Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This file only contains the code needed to declare and initialize
  30 ;; user options.  The code to customize options is autoloaded from
  31 ;; `cus-edit.el' and is documented in the Emacs Lisp Reference manual.
  32
  33 ;; The code implementing face declarations is in `cus-face.el'.
  34
  35 ;;; Code:
  36
  37 (require 'widget)
  38
  39 (defvar custom-define-hook nil
  40   ;; Customize information for this option is in `cus-edit.el'.
  41   "Hook called after defining each customize option.")
  42
  43 (defvar custom-dont-initialize nil
  44   "Non-nil means `defcustom' should not initialize the variable.
  45 That is used for the sake of `custom-make-dependencies'.
  46 Users should not set it.")
  47
  48 (defvar custom-current-group-alist nil
  49   "Alist of (FILE . GROUP) indicating the current group to use for FILE.")
  50
  51 ;;; The `defcustom' Macro.
  52
  53 (defun custom-initialize-default (symbol value)
  54   "Initialize SYMBOL with VALUE.
  55 This will do nothing if symbol already has a default binding.
  56 Otherwise, if symbol has a `saved-value' property, it will evaluate
  57 the car of that and use it as the default binding for symbol.
  58 Otherwise, VALUE will be evaluated and used as the default binding for
  59 symbol."
  60   (unless (default-boundp symbol)
  61     ;; Use the saved value if it exists, otherwise the standard setting.
  62     (set-default symbol (if (get symbol 'saved-value)
  63                             (eval (car (get symbol 'saved-value)))
  64                           (eval value)))))
  65
  66 (defun custom-initialize-set (symbol value)
  67   "Initialize SYMBOL based on VALUE.
  68 If the symbol doesn't have a default binding already,
  69 then set it using its `:set' function (or `set-default' if it has none).
  70 The value is either the value in the symbol's `saved-value' property,
  71 if any, or VALUE."
  72   (unless (default-boundp symbol)
  73     (funcall (or (get symbol 'custom-set) 'set-default)
  74              symbol
  75              (if (get symbol 'saved-value)
  76                  (eval (car (get symbol 'saved-value)))
  77                (eval value)))))
  78
  79 (defun custom-initialize-reset (symbol value)
  80   "Initialize SYMBOL based on VALUE.
  81 Set the symbol, using its `:set' function (or `set-default' if it has none).
  82 The value is either the symbol's current value
  83  \(as obtained using the `:get' function), if any,
  84 or the value in the symbol's `saved-value' property if any,
  85 or (last of all) VALUE."
  86     (funcall (or (get symbol 'custom-set) 'set-default)
  87              symbol
  88              (cond ((default-boundp symbol)
  89                     (funcall (or (get symbol 'custom-get) 'default-value)
  90                              symbol))
  91                    ((get symbol 'saved-value)
  92                     (eval (car (get symbol 'saved-value))))
  93                    (t
  94                     (eval value)))))
  95
  96 (defun custom-initialize-changed (symbol value)
  97   "Initialize SYMBOL with VALUE.
  98 Like `custom-initialize-reset', but only use the `:set' function if
  99 not using the standard setting.
 100 For the standard setting, use `set-default'."
 101   (cond ((default-boundp symbol)
 102          (funcall (or (get symbol 'custom-set) 'set-default)
 103                   symbol
 104                   (funcall (or (get symbol 'custom-get) 'default-value)
 105                            symbol)))
 106         ((get symbol 'saved-value)
 107          (funcall (or (get symbol 'custom-set) 'set-default)
 108                   symbol
 109                   (eval (car (get symbol 'saved-value)))))
 110         (t
 111          (set-default symbol (eval value)))))
 112
 113 (defun custom-declare-variable (symbol default doc &rest args)
 114   "Like `defcustom', but SYMBOL and DEFAULT are evaluated as normal arguments.
 115 DEFAULT should be an expression to evaluate to compute the default value,
 116 not the default value itself.
 117
 118 DEFAULT is stored as SYMBOL's value in the standard theme.  See
 119 `custom-known-themes' for a list of known themes.  For backwards
 120 compatibility, DEFAULT is also stored in SYMBOL's property
 121 `standard-value'.  At the same time, SYMBOL's property `force-value' is
 122 set to nil, as the value is no longer rogue."
 123   ;; Remember the standard setting.  The value should be in the standard
 124   ;; theme, not in this property.  However, his would require changeing
 125   ;; the C source of defvar and others as well...
 126   (put symbol 'standard-value (list default))
 127   ;; Maybe this option was rogue in an earlier version.  It no longer is.
 128   (when (get symbol 'force-value)
 129     (put symbol 'force-value nil))
 130   (when doc
 131     (put symbol 'variable-documentation doc))
 132   (let ((initialize 'custom-initialize-reset)
 133         (requests nil))
 134     (unless (memq :group args)
 135       (custom-add-to-group (custom-current-group) symbol 'custom-variable))
 136     (while args
 137       (let ((arg (car args)))
 138         (setq args (cdr args))
 139         (unless (symbolp arg)
 140           (error "Junk in args %S" args))
 141         (let ((keyword arg)
 142               (value (car args)))
 143           (unless args
 144             (error "Keyword %s is missing an argument" keyword))
 145           (setq args (cdr args))
 146           (cond ((eq keyword :initialize)
 147                  (setq initialize value))
 148                 ((eq keyword :set)
 149                  (put symbol 'custom-set value))
 150                 ((eq keyword :get)
 151                  (put symbol 'custom-get value))
 152                 ((eq keyword :require)
 153                  (push value requests))
 154                 ((eq keyword :type)
 155                  (put symbol 'custom-type (purecopy value)))
 156                 ((eq keyword :options)
 157                  (if (get symbol 'custom-options)
 158                      ;; Slow safe code to avoid duplicates.
 159                      (mapc (lambda (option)
 160                              (custom-add-option symbol option))
 161                            value)
 162                    ;; Fast code for the common case.
 163                    (put symbol 'custom-options (copy-sequence value))))
 164                 (t
 165                  (custom-handle-keyword symbol keyword value
 166                                         'custom-variable))))))
 167     (put symbol 'custom-requests requests)
 168     ;; Do the actual initialization.
 169     (unless custom-dont-initialize
 170       (funcall initialize symbol default)))
 171   (push symbol current-load-list)
 172   (run-hooks 'custom-define-hook)
 173   symbol)
 174
 175 (defmacro defcustom (symbol value doc &rest args)
 176   "Declare SYMBOL as a customizable variable that defaults to VALUE.
 177 DOC is the variable documentation.
 178
 179 Neither SYMBOL nor VALUE need to be quoted.
 180 If SYMBOL is not already bound, initialize it to VALUE.
 181 The remaining arguments should have the form
 182
 183    [KEYWORD VALUE]...
 184
 185 The following keywords are meaningful:
 186
 187 :type   VALUE should be a widget type for editing the symbol's value.
 188 :options VALUE should be a list of valid members of the widget type.
 189 :group  VALUE should be a customization group.
 190         Add SYMBOL to that group.
 191 :link LINK-DATA
 192         Include an external link after the documentation string for this
 193         item.  This is a sentence containing an active field which
 194         references some other documentation.
 195
 196         There are three alternatives you can use for LINK-DATA:
 197
 198         (custom-manual INFO-NODE)
 199              Link to an Info node; INFO-NODE is a string which specifies
 200              the node name, as in \"(emacs)Top\".  The link appears as
 201              `[manual]' in the customization buffer.
 202
 203         (info-link INFO-NODE)
 204              Like `custom-manual' except that the link appears in the
 205              customization buffer with the Info node name.
 206
 207         (url-link URL)
 208              Link to a web page; URL is a string which specifies the URL.
 209              The link appears in the customization buffer as URL.
 210
 211         You can specify the text to use in the customization buffer by
 212         adding `:tag NAME' after the first element of the LINK-DATA; for
 213         example, (info-link :tag \"foo\" \"(emacs)Top\") makes a link to the
 214         Emacs manual which appears in the buffer as `foo'.
 215
 216         An item can have more than one external link; however, most items
 217         have none at all.
 218 :initialize
 219         VALUE should be a function used to initialize the
 220         variable.  It takes two arguments, the symbol and value
 221         given in the `defcustom' call.  The default is
 222         `custom-initialize-reset'.
 223 :set    VALUE should be a function to set the value of the symbol.
 224         It takes two arguments, the symbol to set and the value to
 225         give it.  The default choice of function is `custom-set-default'.
 226 :get    VALUE should be a function to extract the value of symbol.
 227         The function takes one argument, a symbol, and should return
 228         the current value for that symbol.  The default choice of function
 229         is `custom-default-value'.
 230 :require
 231         VALUE should be a feature symbol.  If you save a value
 232         for this option, then when your `.emacs' file loads the value,
 233         it does (require VALUE) first.
 234 :version
 235         VALUE should be a string specifying that the variable was
 236         first introduced, or its default value was changed, in Emacs
 237         version VERSION.
 238 :tag LABEL
 239         Use LABEL, a string, instead of the item's name, to label the item
 240         in customization menus and buffers.
 241 :load FILE
 242         Load file FILE (a string) before displaying this customization
 243         item.  Loading is done with `load', and only if the file is
 244         not already loaded.
 245 :set-after VARIABLES
 246         Specifies that SYMBOL should be set after the list of variables
 247         VARIABLES when both have been customized.
 248
 249 If SYMBOL has a local binding, then this form affects the local
 250 binding.  This is normally not what you want.  Thus, if you need
 251 to load a file defining variables with this form, or with
 252 `defvar' or `defconst', you should always load that file
 253 _outside_ any bindings for these variables.  \(`defvar' and
 254 `defconst' behave similarly in this respect.)
 255
 256 Read the section about customization in the Emacs Lisp manual for more
 257 information."
 258   ;; It is better not to use backquote in this file,
 259   ;; because that makes a bootstrapping problem
 260   ;; if you need to recompile all the Lisp files using interpreted code.
 261   (nconc (list 'custom-declare-variable
 262                (list 'quote symbol)
 263                (list 'quote value)
 264                doc)
 265          args))
 266
 267 ;;; The `defface' Macro.
 268
 269 (defmacro defface (face spec doc &rest args)
 270   "Declare FACE as a customizable face that defaults to SPEC.
 271 FACE does not need to be quoted.
 272
 273 Third argument DOC is the face documentation.
 274
 275 If FACE has been set with `custom-set-faces', set the face attributes
 276 as specified by that function, otherwise set the face attributes
 277 according to SPEC.
 278
 279 The remaining arguments should have the form
 280
 281    [KEYWORD VALUE]...
 282
 283 The following KEYWORDs are defined:
 284
 285 :group  VALUE should be a customization group.
 286         Add FACE to that group.
 287
 288 SPEC should be an alist of the form ((DISPLAY ATTS)...).
 289
 290 The first element of SPEC where the DISPLAY matches the frame
 291 is the one that takes effect in that frame.  The ATTRs in this
 292 element take effect; the other elements are ignored, on that frame.
 293
 294 ATTS is a list of face attributes followed by their values:
 295   (ATTR VALUE ATTR VALUE...)
 296
 297 The possible attributes are `:family', `:width', `:height', `:weight',
 298 `:slant', `:underline', `:overline', `:strike-through', `:box',
 299 `:foreground', `:background', `:stipple', `:inverse-video', and `:inherit'.
 300
 301 DISPLAY can either be the symbol t, which will match all frames, or an
 302 alist of the form \((REQ ITEM...)...).  For the DISPLAY to match a
 303 FRAME, the REQ property of the frame must match one of the ITEM.  The
 304 following REQ are defined:
 305
 306 `type' (the value of `window-system')
 307   Under X, in addition to the values `window-system' can take,
 308   `motif', `lucid', `gtk' and `x-toolkit' are allowed, and match when
 309   the Motif toolkit, Lucid toolkit, GTK toolkit or any X toolkit is in use.
 310
 311 `class' (the frame's color support)
 312   Should be one of `color', `grayscale', or `mono'.
 313
 314 `background' (what color is used for the background text)
 315   Should be one of `light' or `dark'.
 316
 317 `min-colors' (the minimum number of colors the frame should support)
 318   Should be an integer, it is compared with the result of
 319   `display-color-cells'.
 320
 321 `supports' (only match frames that support the specified face attributes)
 322   Should be a list of face attributes.  See the documentation for
 323   the function `display-supports-face-attributes-p' for more
 324   information on exactly how testing is done.
 325
 326 Read the section about customization in the Emacs Lisp manual for more
 327 information."
 328   ;; It is better not to use backquote in this file,
 329   ;; because that makes a bootstrapping problem
 330   ;; if you need to recompile all the Lisp files using interpreted code.
 331   (nconc (list 'custom-declare-face (list 'quote face) spec doc) args))
 332
 333 ;;; The `defgroup' Macro.
 334
 335 (defun custom-current-group ()
 336   (cdr (assoc load-file-name custom-current-group-alist)))
 337
 338 (defun custom-declare-group (symbol members doc &rest args)
 339   "Like `defgroup', but SYMBOL is evaluated as a normal argument."
 340   (while members
 341     (apply 'custom-add-to-group symbol (car members))
 342     (setq members (cdr members)))
 343   (when doc
 344     ;; This text doesn't get into DOC.
 345     (put symbol 'group-documentation (purecopy doc)))
 346   (while args
 347     (let ((arg (car args)))
 348       (setq args (cdr args))
 349       (unless (symbolp arg)
 350         (error "Junk in args %S" args))
 351       (let ((keyword arg)
 352             (value (car args)))
 353         (unless args
 354           (error "Keyword %s is missing an argument" keyword))
 355         (setq args (cdr args))
 356         (cond ((eq keyword :prefix)
 357                (put symbol 'custom-prefix value))
 358               (t
 359                (custom-handle-keyword symbol keyword value
 360                                       'custom-group))))))
 361   ;; Record the group on the `current' list.
 362   (let ((elt (assoc load-file-name custom-current-group-alist)))
 363     (if elt (setcdr elt symbol)
 364       (push (cons load-file-name symbol) custom-current-group-alist)))
 365   (run-hooks 'custom-define-hook)
 366   symbol)
 367
 368 (defmacro defgroup (symbol members doc &rest args)
 369   "Declare SYMBOL as a customization group containing MEMBERS.
 370 SYMBOL does not need to be quoted.
 371
 372 Third arg DOC is the group documentation.
 373
 374 MEMBERS should be an alist of the form ((NAME WIDGET)...) where
 375 NAME is a symbol and WIDGET is a widget for editing that symbol.
 376 Useful widgets are `custom-variable' for editing variables,
 377 `custom-face' for edit faces, and `custom-group' for editing groups.
 378
 379 The remaining arguments should have the form
 380
 381    [KEYWORD VALUE]...
 382
 383 The following KEYWORDs are defined:
 384
 385 :group   VALUE should be a customization group.
 386          Add SYMBOL to that group.
 387
 388 :version VALUE should be a string specifying that the group was introduced
 389          in Emacs version VERSION.
 390
 391 Read the section about customization in the Emacs Lisp manual for more
 392 information."
 393   ;; It is better not to use backquote in this file,
 394   ;; because that makes a bootstrapping problem
 395   ;; if you need to recompile all the Lisp files using interpreted code.
 396   (nconc (list 'custom-declare-group (list 'quote symbol) members doc) args))
 397
 398 (defun custom-add-to-group (group option widget)
 399   "To existing GROUP add a new OPTION of type WIDGET.
 400 If there already is an entry for OPTION and WIDGET, nothing is done."
 401   (let ((members (get group 'custom-group))
 402         (entry (list option widget)))
 403     (unless (member entry members)
 404       (put group 'custom-group (nconc members (list entry))))))
 405
 406 (defun custom-group-of-mode (mode)
 407   "Return the custom group corresponding to the major or minor MODE.
 408 If no such group is found, return nil."
 409   (or (get mode 'custom-mode-group)
 410       (if (or (get mode 'custom-group)
 411               (and (string-match "-mode\\'" (symbol-name mode))
 412                    (get (setq mode (intern (substring (symbol-name mode)
 413                                                       0 (match-beginning 0))))
 414                         'custom-group)))
 415           mode)))
 416
 417 ;;; Properties.
 418
 419 (defun custom-handle-all-keywords (symbol args type)
 420   "For customization option SYMBOL, handle keyword arguments ARGS.
 421 Third argument TYPE is the custom option type."
 422   (unless (memq :group args)
 423     (custom-add-to-group (custom-current-group) symbol type))
 424   (while args
 425     (let ((arg (car args)))
 426       (setq args (cdr args))
 427       (unless (symbolp arg)
 428         (error "Junk in args %S" args))
 429       (let ((keyword arg)
 430             (value (car args)))
 431         (unless args
 432           (error "Keyword %s is missing an argument" keyword))
 433         (setq args (cdr args))
 434         (custom-handle-keyword symbol keyword value type)))))
 435
 436 (defun custom-handle-keyword (symbol keyword value type)
 437   "For customization option SYMBOL, handle KEYWORD with VALUE.
 438 Fourth argument TYPE is the custom option type."
 439   (if purify-flag
 440       (setq value (purecopy value)))
 441   (cond ((eq keyword :group)
 442          (custom-add-to-group value symbol type))
 443         ((eq keyword :version)
 444          (custom-add-version symbol value))
 445         ((eq keyword :link)
 446          (custom-add-link symbol value))
 447         ((eq keyword :load)
 448          (custom-add-load symbol value))
 449         ((eq keyword :tag)
 450          (put symbol 'custom-tag value))
 451         ((eq keyword :set-after)
 452          (custom-add-dependencies symbol value))
 453         (t
 454          (error "Unknown keyword %s" keyword))))
 455
 456 (defun custom-add-dependencies (symbol value)
 457   "To the custom option SYMBOL, add dependencies specified by VALUE.
 458 VALUE should be a list of symbols.  For each symbol in that list,
 459 this specifies that SYMBOL should be set after the specified symbol, if
 460 both appear in constructs like `custom-set-variables'."
 461   (unless (listp value)
 462     (error "Invalid custom dependency `%s'" value))
 463   (let* ((deps (get symbol 'custom-dependencies))
 464          (new-deps deps))
 465     (while value
 466       (let ((dep (car value)))
 467         (unless (symbolp dep)
 468           (error "Invalid custom dependency `%s'" dep))
 469         (unless (memq dep new-deps)
 470           (setq new-deps (cons dep new-deps)))
 471         (setq value (cdr value))))
 472     (unless (eq deps new-deps)
 473       (put symbol 'custom-dependencies new-deps))))
 474
 475 (defun custom-add-option (symbol option)
 476   "To the variable SYMBOL add OPTION.
 477
 478 If SYMBOL is a hook variable, OPTION should be a hook member.
 479 For other types variables, the effect is undefined."
 480   (let ((options (get symbol 'custom-options)))
 481     (unless (member option options)
 482       (put symbol 'custom-options (cons option options)))))
 483
 484 (defun custom-add-link (symbol widget)
 485   "To the custom option SYMBOL add the link WIDGET."
 486   (let ((links (get symbol 'custom-links)))
 487     (unless (member widget links)
 488       (put symbol 'custom-links (cons (purecopy widget) links)))))
 489
 490 (defun custom-add-version (symbol version)
 491   "To the custom option SYMBOL add the version VERSION."
 492   (put symbol 'custom-version (purecopy version)))
 493
 494 (defun custom-add-load (symbol load)
 495   "To the custom option SYMBOL add the dependency LOAD.
 496 LOAD should be either a library file name, or a feature name."
 497   (let ((loads (get symbol 'custom-loads)))
 498     (unless (member load loads)
 499       (put symbol 'custom-loads (cons (purecopy load) loads)))))
 500
 501 (defun custom-autoload (symbol load)
 502   "Mark SYMBOL as autoloaded custom variable and add dependency LOAD."
 503   (put symbol 'custom-autoload t)
 504   (custom-add-load symbol load))
 505
 506 ;; This test is also in the C code of `user-variable-p'.
 507 (defun custom-variable-p (variable)
 508   "Return non-nil if VARIABLE is a custom variable."
 509   (or (get variable 'standard-value)
 510       (get variable 'custom-autoload)))
 511
 512 ;;; Loading files needed to customize a symbol.
 513 ;;; This is in custom.el because menu-bar.el needs it for toggle cmds.
 514
 515 (defvar custom-load-recursion nil
 516   "Hack to avoid recursive dependencies.")
 517
 518 (defun custom-load-symbol (symbol)
 519   "Load all dependencies for SYMBOL."
 520   (unless custom-load-recursion
 521     (let ((custom-load-recursion t))
 522       ;; Load these files if not already done,
 523       ;; to make sure we know all the dependencies of SYMBOL.
 524       (condition-case nil
 525           (require 'cus-load)
 526         (error nil))
 527       (condition-case nil
 528           (require 'cus-start)
 529         (error nil))
 530       (dolist (load (get symbol 'custom-loads))
 531         (cond ((symbolp load) (condition-case nil (require load) (error nil)))
 532               ;; This is subsumed by the test below, but it's much faster.
 533               ((assoc load load-history))
 534               ;; This was just (assoc (locate-library load) load-history)
 535               ;; but has been optimized not to load locate-library
 536               ;; if not necessary.
 537               ((let ((regexp (concat "\\(\\`\\|/\\)" (regexp-quote load)
 538                                      "\\(\\'\\|\\.\\)"))
 539                      (found nil))
 540                  (dolist (loaded load-history)
 541                    (and (stringp (car loaded))
 542                         (string-match regexp (car loaded))
 543                         (setq found t)))
 544                  found))
 545               ;; Without this, we would load cus-edit recursively.
 546               ;; We are still loading it when we call this,
 547               ;; and it is not in load-history yet.
 548               ((equal load "cus-edit"))
 549               (t (condition-case nil (load load) (error nil))))))))
 550
 551 (defvar custom-known-themes '(user standard)
 552    "Themes that have been define with `deftheme'.
 553 The default value is the list (user standard).  The theme `standard'
 554 contains the Emacs standard settings from the original Lisp files.  The
 555 theme `user' contains all the the settings the user customized and saved.
 556 Additional themes declared with the `deftheme' macro will be added to
 557 the front of this list.")
 558
 559 (defun custom-declare-theme (theme feature &optional doc &rest args)
 560   "Like `deftheme', but THEME is evaluated as a normal argument.
 561 FEATURE is the feature this theme provides.  This symbol is created
 562 from THEME by `custom-make-theme-feature'."
 563   (add-to-list 'custom-known-themes theme)
 564   (put theme 'theme-feature feature)
 565   (when doc
 566     (put theme 'theme-documentation doc))
 567   (while args
 568     (let ((arg (car args)))
 569       (setq args (cdr args))
 570       (unless (symbolp arg)
 571         (error "Junk in args %S" args))
 572       (let ((keyword arg)
 573             (value (car args)))
 574         (unless args
 575           (error "Keyword %s is missing an argument" keyword))
 576         (setq args (cdr args))
 577         (cond ((eq keyword :short-description)
 578                (put theme 'theme-short-description value))
 579               ((eq keyword :immediate)
 580                (put theme 'theme-immediate value))
 581               ((eq keyword :variable-set-string)
 582                (put theme 'theme-variable-set-string value))
 583               ((eq keyword :variable-reset-string)
 584                (put theme 'theme-variable-reset-string value))
 585               ((eq keyword :face-set-string)
 586                (put theme 'theme-face-set-string value))
 587               ((eq keyword :face-reset-string)
 588                (put theme 'theme-face-reset-string value)))))))
 589
 590 (defmacro deftheme (theme &optional doc &rest args)
 591   "Declare custom theme THEME.
 592 The optional argument DOC is a doc string describing the theme.
 593 The remaining arguments should have the form
 594
 595    [KEYWORD VALUE]...
 596
 597 The following KEYWORD's are defined:
 598
 599 :short-description
 600         VALUE is a short (one line) description of the theme.  If not
 601         given, DOC is used.
 602 :immediate
 603         If VALUE is non-nil, variables specified in this theme are set
 604         immediately when loading the theme.
 605 :variable-set-string
 606         VALUE is a string used to indicate that a variable takes its
 607         setting from this theme.  It is passed to FORMAT with the name
 608         of the theme as an additional argument.  If not given, a
 609         generic description is used.
 610 :variable-reset-string
 611         VALUE is a string used in the case a variable has been forced
 612         to its value in this theme.  It is passed to FORMAT with the
 613         name of the theme as an additional argument.  If not given, a
 614         generic description is used.
 615 :face-set-string
 616         VALUE is a string used to indicate that a face takes its
 617         setting from this theme.  It is passed to FORMAT with the name
 618         of the theme as an additional argument.  If not given, a
 619         generic description is used.
 620 :face-reset-string
 621         VALUE is a string used in the case a face has been forced to
 622         its value in this theme.  It is passed to FORMAT with the name
 623         of the theme as an additional argument.  If not given, a
 624         generic description is used.
 625
 626 Any theme `foo' should be defined in a file called `foo-theme.el';
 627 see `custom-make-theme-feature' for more information."
 628   (let ((feature (custom-make-theme-feature theme)))
 629     ;; It is better not to use backquote in this file,
 630     ;; because that makes a bootstrapping problem
 631     ;; if you need to recompile all the Lisp files using interpreted code.
 632     (nconc (list 'custom-declare-theme
 633                  (list 'quote theme)
 634                  (list 'quote feature)
 635                  doc) args)))
 636
 637 (defun custom-make-theme-feature (theme)
 638   "Given a symbol THEME, create a new symbol by appending \"-theme\".
 639 Store this symbol in the `theme-feature' property of THEME.
 640 Calling `provide-theme' to provide THEME actually puts `THEME-theme'
 641 into `features'.
 642
 643 This allows for a file-name convention for autoloading themes:
 644 Every theme X has a property `provide-theme' whose value is \"X-theme\".
 645 \(require-theme X) then attempts to load the file `X-theme.el'."
 646   (intern (concat (symbol-name theme) "-theme")))
 647
 648 (defsubst custom-theme-p (theme)
 649   "Non-nil when THEME has been defined."
 650   (memq theme custom-known-themes))
 651
 652 (defsubst custom-check-theme (theme)
 653   "Check whether THEME is valid, and signal an error if it is not."
 654   (unless (custom-theme-p theme)
 655     (error "Unknown theme `%s'" theme)))
 656
 657 ;;; Initializing.
 658
 659 (defun custom-push-theme (prop symbol theme mode value)
 660   "Add (THEME MODE VALUE) to the list in property PROP of SYMBOL.
 661 If the first element in that list is already (THEME ...),
 662 discard it first.
 663
 664 MODE can be either the symbol `set' or the symbol `reset'.  If it is the
 665 symbol `set', then VALUE is the value to use.  If it is the symbol
 666 `reset', then VALUE is the mode to query instead.
 667
 668 In the following example for the variable `goto-address-url-face', the
 669 theme `subtle-hacker' uses the same value for the variable as the theme
 670 `gnome2':
 671
 672   \((standard set bold)
 673    \(gnome2 set info-xref)
 674    \(jonadab set underline)
 675    \(subtle-hacker reset gnome2))
 676
 677
 678 If a value has been stored for themes A B and C, and a new value
 679 is to be stored for theme C, then the old value of C is discarded.
 680 If a new value is to be stored for theme B, however, the old value
 681 of B is not discarded because B is not the car of the list.
 682
 683 For variables, list property PROP is `theme-value'.
 684 For faces, list property PROP is `theme-face'.
 685 This is used in `custom-do-theme-reset', for example.
 686
 687 The list looks the same in any case; the examples shows a possible
 688 value of the `theme-face' property for the face `region':
 689
 690   \((gnome2 set ((t (:foreground \"cyan\" :background \"dark cyan\"))))
 691    \(standard set ((((class color) (background dark))
 692                    \(:background \"blue\"))
 693                   \(t (:background \"gray\")))))
 694
 695 This records values for the `standard' and the `gnome2' themes.
 696 The user has not customized the face; had he done that,
 697 the list would contain an entry for the `user' theme, too.
 698 See `custom-known-themes' for a list of known themes."
 699   (let ((old (get symbol prop)))
 700     (if (eq (car-safe (car-safe old)) theme)
 701         (setq old (cdr old)))
 702     (put symbol prop (cons (list theme mode value) old))))
 703
 704 (defvar custom-local-buffer nil
 705   "Non-nil, in a Customization buffer, means customize a specific buffer.
 706 If this variable is non-nil, it should be a buffer,
 707 and it means customize the local bindings of that buffer.
 708 This variable is a permanent local, and it normally has a local binding
 709 in every Customization buffer.")
 710 (put 'custom-local-buffer 'permanent-local t)
 711
 712 (defun custom-set-variables (&rest args)
 713   "Install user customizations of variable values specified in ARGS.
 714 These settings are registered as theme `user'.
 715 The arguments should each be a list of the form:
 716
 717   (SYMBOL EXP [NOW [REQUEST [COMMENT]]])
 718
 719 This stores EXP (without evaluating it) as the saved value for SYMBOL.
 720 If NOW is present and non-nil, then also evaluate EXP and set
 721 the default value for the SYMBOL to the value of EXP.
 722
 723 REQUEST is a list of features we must require in order to
 724 handle SYMBOL properly.
 725 COMMENT is a comment string about SYMBOL."
 726   (apply 'custom-theme-set-variables 'user args))
 727
 728 (defun custom-theme-set-variables (theme &rest args)
 729   "Initialize variables for theme THEME according to settings in ARGS.
 730 Each of the arguments in ARGS should be a list of this form:
 731
 732   (SYMBOL EXP [NOW [REQUEST [COMMENT]]])
 733
 734 This stores EXP (without evaluating it) as the saved value for SYMBOL.
 735 If NOW is present and non-nil, then also evaluate EXP and set
 736 the default value for the SYMBOL to the value of EXP.
 737
 738 REQUEST is a list of features we must require in order to
 739 handle SYMBOL properly.
 740 COMMENT is a comment string about SYMBOL.
 741
 742 Several properties of THEME and SYMBOL are used in the process:
 743
 744 If THEME's property `theme-immediate' is non-nil, this is equivalent of
 745 providing the NOW argument to all symbols in the argument list:
 746 evaluate each EXP and set the corresponding SYMBOL.  However,
 747 there's a difference in the handling of SYMBOL's property
 748 `force-value': if NOW is non-nil, SYMBOL's property `force-value' is set to
 749 the symbol `rogue', else if THEME's property `theme-immediate' is non-nil,
 750 SYMBOL's property `force-value' is set to the symbol `immediate'.
 751
 752 EXP itself is saved unevaluated as SYMBOL property `saved-value' and
 753 in SYMBOL's list property `theme-value' \(using `custom-push-theme')."
 754   (custom-check-theme theme)
 755   (let ((immediate (get theme 'theme-immediate)))
 756     (setq args
 757           (sort args
 758                 (lambda (a1 a2)
 759                   (let* ((sym1 (car a1))
 760                          (sym2 (car a2))
 761                          (1-then-2 (memq sym1 (get sym2 'custom-dependencies)))
 762                          (2-then-1 (memq sym2 (get sym1 'custom-dependencies))))
 763                     (cond ((and 1-then-2 2-then-1)
 764                            (error "Circular custom dependency between `%s' and `%s'"
 765                                   sym1 sym2))
 766                           (2-then-1 nil)
 767                           ;; Put symbols with :require last.  The macro
 768                           ;; define-minor-mode generates a defcustom
 769                           ;; with a :require and a :set, where the
 770                           ;; setter function calls the mode function.
 771                           ;; Putting symbols with :require last ensures
 772                           ;; that the mode function will see other
 773                           ;; customized values rather than default
 774                           ;; values.
 775                           (t (nth 3 a2)))))))
 776     (while args
 777       (let ((entry (car args)))
 778         (if (listp entry)
 779             (let* ((symbol (nth 0 entry))
 780                    (value (nth 1 entry))
 781                    (now (nth 2 entry))
 782                    (requests (nth 3 entry))
 783                    (comment (nth 4 entry))
 784                    set)
 785               (when requests
 786                 (put symbol 'custom-requests requests)
 787                 (mapc 'require requests))
 788               (setq set (or (get symbol 'custom-set) 'custom-set-default))
 789               (put symbol 'saved-value (list value))
 790               (put symbol 'saved-variable-comment comment)
 791               (custom-push-theme 'theme-value symbol theme 'set value)
 792               ;; Allow for errors in the case where the setter has
 793             ;; changed between versions, say, but let the user know.
 794             (condition-case data
 795                 (cond (now
 796                        ;; Rogue variable, set it now.
 797                        (put symbol 'force-value t)
 798                        (funcall set symbol (eval value)))
 799                       ((default-boundp symbol)
 800                        ;; Something already set this, overwrite it.
 801                        (funcall set symbol (eval value))))
 802               (error
 803                (message "Error setting %s: %s" symbol data)))
 804               (setq args (cdr args))
 805               (and (or now (default-boundp symbol))
 806                    (put symbol 'variable-comment comment)))
 807           ;; Old format, a plist of SYMBOL VALUE pairs.
 808           (message "Warning: old format `custom-set-variables'")
 809           (ding)
 810           (sit-for 2)
 811           (let ((symbol (nth 0 args))
 812                 (value (nth 1 args)))
 813             (put symbol 'saved-value (list value))
 814             (custom-push-theme 'theme-value symbol theme 'set value))
 815           (setq args (cdr (cdr args))))))))
 816
 817 (defun custom-set-default (variable value)
 818   "Default :set function for a customizable variable.
 819 Normally, this sets the default value of VARIABLE to VALUE,
 820 but if `custom-local-buffer' is non-nil,
 821 this sets the local binding in that buffer instead."
 822   (if custom-local-buffer
 823       (with-current-buffer custom-local-buffer
 824         (set variable value))
 825     (set-default variable value)))
 826
 827 (defun custom-set-minor-mode (variable value)
 828   ":set function for minor mode variables.
 829 Normally, this sets the default value of VARIABLE to nil if VALUE
 830 is nil and to t otherwise,
 831 but if `custom-local-buffer' is non-nil,
 832 this sets the local binding in that buffer instead."
 833   (if custom-local-buffer
 834       (with-current-buffer custom-local-buffer
 835         (funcall variable (or value 0)))
 836     (funcall variable (or value 0))))
 837
 838 (defun custom-quote (sexp)
 839   "Quote SEXP iff it is not self quoting."
 840   (if (or (memq sexp '(t nil))
 841           (keywordp sexp)
 842           (and (listp sexp)
 843                (memq (car sexp) '(lambda)))
 844           (stringp sexp)
 845           (numberp sexp)
 846           (vectorp sexp)
 847 ;;;       (and (fboundp 'characterp)
 848 ;;;            (characterp sexp))
 849           )
 850       sexp
 851     (list 'quote sexp)))
 852
 853 (defun customize-mark-to-save (symbol)
 854   "Mark SYMBOL for later saving.
 855
 856 If the default value of SYMBOL is different from the standard value,
 857 set the `saved-value' property to a list whose car evaluates to the
 858 default value.  Otherwise, set it to nil.
 859
 860 To actually save the value, call `custom-save-all'.
 861
 862 Return non-nil iff the `saved-value' property actually changed."
 863   (let* ((get (or (get symbol 'custom-get) 'default-value))
 864          (value (funcall get symbol))
 865          (saved (get symbol 'saved-value))
 866          (standard (get symbol 'standard-value))
 867          (comment (get symbol 'customized-variable-comment)))
 868     ;; Save default value iff different from standard value.
 869     (if (or (null standard)
 870             (not (equal value (condition-case nil
 871                                   (eval (car standard))
 872                                 (error nil)))))
 873         (put symbol 'saved-value (list (custom-quote value)))
 874       (put symbol 'saved-value nil))
 875     ;; Clear customized information (set, but not saved).
 876     (put symbol 'customized-value nil)
 877     ;; Save any comment that might have been set.
 878     (when comment
 879       (put symbol 'saved-variable-comment comment))
 880     (not (equal saved (get symbol 'saved-value)))))
 881
 882 (defun customize-mark-as-set (symbol)
 883   "Mark current value of SYMBOL as being set from customize.
 884
 885 If the default value of SYMBOL is different from the saved value if any,
 886 or else if it is different from the standard value, set the
 887 `customized-value' property to a list whose car evaluates to the
 888 default value.  Otherwise, set it to nil.
 889
 890 Return non-nil iff the `customized-value' property actually changed."
 891   (let* ((get (or (get symbol 'custom-get) 'default-value))
 892          (value (funcall get symbol))
 893          (customized (get symbol 'customized-value))
 894          (old (or (get symbol 'saved-value) (get symbol 'standard-value))))
 895     ;; Mark default value as set iff different from old value.
 896     (if (or (null old)
 897             (not (equal value (condition-case nil
 898                                   (eval (car old))
 899                                 (error nil)))))
 900         (put symbol 'customized-value (list (custom-quote value)))
 901       (put symbol 'customized-value nil))
 902     ;; Changed?
 903     (not (equal customized (get symbol 'customized-value)))))
 904
 905 ;;; Theme Manipulation
 906
 907 (defvar custom-loaded-themes nil
 908   "Themes in the order they are loaded.")
 909
 910 (defun custom-theme-loaded-p (theme)
 911   "Return non-nil when THEME has been loaded."
 912   (memq theme custom-loaded-themes))
 913
 914 (defun provide-theme (theme)
 915   "Indicate that this file provides THEME.
 916 Add THEME to `custom-loaded-themes' and `provide' whatever
 917 is stored in THEME's property `theme-feature'.
 918
 919 Usually the theme-feature property contains a symbol created
 920 by `custom-make-theme-feature'."
 921   (custom-check-theme theme)
 922   (provide (get theme 'theme-feature))
 923   (setq custom-loaded-themes (nconc (list theme) custom-loaded-themes)))
 924
 925 (defun require-theme (theme)
 926   "Try to load a theme by requiring its feature.
 927 THEME's feature is stored in THEME's `theme-feature' property.
 928
 929 Usually the `theme-feature' property contains a symbol created
 930 by `custom-make-theme-feature'."
 931   ;; Note we do no check for validity of the theme here.
 932   ;; This allows to pull in themes by a file-name convention
 933   (require (or (get theme 'theme-feature)
 934                (custom-make-theme-feature theme))))
 935
 936 (defun custom-remove-theme (spec-alist theme)
 937   "Delete all elements from SPEC-ALIST whose car is THEME."
 938   (let ((elt (assoc theme spec-alist)))
 939     (while elt
 940         (setq spec-alist (delete elt spec-alist)
 941               elt (assoc theme spec-alist))))
 942   spec-alist)
 943
 944 (defun custom-do-theme-reset (theme)
 945   "Undo all settings defined by THEME.
 946
 947 A variable remains unchanged if its property `theme-value' does not
 948 contain a value for THEME.  A face remains unchanged if its property
 949 `theme-face' does not contain a value for THEME.  In either case, all
 950 settings for THEME are removed from the property and the variable or
 951 face is set to the `user' theme.
 952
 953 See `custom-known-themes' for a list of known themes."
 954   (let (spec-list)
 955     (mapatoms (lambda (symbol)
 956                 ;; This works even if symbol is both a variable and a
 957                 ;; face.
 958                 (setq spec-list (get symbol 'theme-value))
 959                 (when spec-list
 960                   (put symbol 'theme-value (custom-remove-theme spec-list theme))
 961                   (custom-theme-reset-internal symbol 'user))
 962                 (setq spec-list (get symbol 'theme-face))
 963                 (when spec-list
 964                   (put symbol 'theme-face (custom-remove-theme spec-list theme))
 965                   (custom-theme-reset-internal-face symbol 'user))))))
 966
 967 (defun custom-theme-load-themes (by-theme &rest body)
 968   "Load the themes specified by BODY.
 969 Record them as required by theme BY-THEME.  BODY is a sequence of either
 970
 971 THEME
 972         BY-THEME requires THEME
 973 \(reset THEME)
 974         Undo all the settings made by THEME
 975 \(hidden THEME)
 976         Require THEME but hide it from the user
 977
 978 All the themes loaded for BY-THEME are recorded in BY-THEME's property
 979 `theme-loads-themes'.  Any theme loaded with the hidden predicate will
 980 be given the property `theme-hidden' unless it has been loaded before.
 981 Whether a theme has been loaded before is determined by the function
 982 `custom-theme-loaded-p'."
 983   (custom-check-theme by-theme)
 984   (let ((theme)
 985         (themes-loaded (get by-theme 'theme-loads-themes)))
 986     (while theme
 987       (setq theme (car body)
 988             body (cdr body))
 989       (cond ((and (consp theme) (eq (car theme) 'reset))
 990              (custom-do-theme-reset (cadr theme)))
 991             ((and (consp theme) (eq (car theme) 'hidden))
 992              (require-theme (cadr theme))
 993              (unless (custom-theme-loaded-p (cadr theme))
 994                (put (cadr theme) 'theme-hidden t)))
 995             (t
 996              (require-theme theme)
 997              (put theme 'theme-hidden nil)))
 998       (setq themes-loaded (nconc (list theme) themes-loaded)))
 999     (put by-theme 'theme-loads-themes themes-loaded)))
1000
1001 (defun custom-load-themes (&rest body)
1002   "Load themes for the USER theme as specified by BODY.
1003
1004 See `custom-theme-load-themes' for more information on BODY."
1005   (apply 'custom-theme-load-themes 'user body))
1006
1007 ; (defsubst copy-upto-last (elt list)
1008 ;   "Copy all the elements of the list upto the last occurence of elt"
1009 ;   ;; Is it faster to do more work in C than to do less in elisp?
1010 ;   (nreverse (cdr (member elt (reverse list)))))
1011
1012 (defun custom-theme-value (theme theme-spec-list)
1013   "Determine the value for THEME defined by THEME-SPEC-LIST.
1014 Returns a list with the original value if found; nil otherwise.
1015
1016 THEME-SPEC-LIST is an alist with themes as its key.  As new themes are
1017 installed, these are added to the front of THEME-SPEC-LIST.
1018 Each element has the form
1019
1020   \(THEME MODE VALUE)
1021
1022 MODE is either the symbol `set' or the symbol `reset'.  See
1023 `custom-push-theme' for more information on the format of
1024 THEME-SPEC-LIST."
1025   ;; Note we do _NOT_ signal an error if the theme is unknown
1026   ;; it might have gone away without the user knowing.
1027   (let ((value (cdr (assoc theme theme-spec-list))))
1028     (if value
1029         (if (eq (car value) 'set)
1030             (cdr value)
1031           (custom-theme-value (cadr value) theme-spec-list)))))
1032
1033 (defun custom-theme-variable-value (variable theme)
1034   "Return (list value) indicating value of VARIABLE in THEME.
1035 If THEME does not define a value for VARIABLE, return nil.  The value
1036 definitions per theme are stored in VARIABLE's property `theme-value'.
1037 The actual work is done by function `custom-theme-value', which see.
1038 See `custom-push-theme' for more information on how these definitions
1039 are stored."
1040   (custom-theme-value theme (get variable 'theme-value)))
1041
1042 (defun custom-theme-reset-internal (symbol to-theme)
1043   "Reset SYMBOL to the value defined by TO-THEME.
1044 If SYMBOL is not defined in TO-THEME, reset SYMBOL to the standard
1045 value.  See `custom-theme-variable-value'.  The standard value is
1046 stored in SYMBOL's property `standard-value'."
1047   (let ((value (custom-theme-variable-value symbol to-theme))
1048         was-in-theme)
1049     (setq was-in-theme value)
1050     (setq value (or value (get symbol 'standard-value)))
1051     (when value
1052       (put symbol 'saved-value was-in-theme)
1053       (if (or (get 'force-value symbol) (default-boundp symbol))
1054           (funcall (or (get symbol 'custom-set) 'set-default) symbol
1055                    (eval (car value)))))
1056     value))
1057
1058 (defun custom-theme-reset-variables (theme &rest args)
1059   "Reset the value of the variables to values previously defined.
1060 Associate this setting with THEME.
1061
1062 ARGS is a list of lists of the form
1063
1064     (VARIABLE TO-THEME)
1065
1066 This means reset VARIABLE to its value in TO-THEME."
1067   (custom-check-theme theme)
1068   (mapcar '(lambda (arg)
1069              (apply 'custom-theme-reset-internal arg)
1070              (custom-push-theme 'theme-value (car arg) theme 'reset (cadr arg)))
1071           args))
1072
1073 (defun custom-reset-variables (&rest args)
1074     "Reset the value of the variables to values previously saved.
1075 This is the setting associated the `user' theme.
1076
1077 ARGS is a list of lists of the form
1078
1079     (VARIABLE TO-THEME)
1080
1081 This means reset VARIABLE to its value in TO-THEME."
1082     (apply 'custom-theme-reset-variables 'user args))
1083
1084 ;;; The End.
1085
1086 ;; Process the defcustoms for variables loaded before this file.
1087 (while custom-declare-variable-list
1088   (apply 'custom-declare-variable (car custom-declare-variable-list))
1089   (setq custom-declare-variable-list (cdr custom-declare-variable-list)))
1090
1091 (provide 'custom)
1092
1093 ;;; arch-tag: 041b6116-aabe-4f9a-902d-74092bc3dab2
1094 ;;; custom.el ends here