configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.62)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" != no; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" != no; then
  88   if test "${with_kerberos}" = no; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 dnl FIXME hesiod support may not be present, so it seems like an error
  97 dnl to define, or at least use, this unconditionally.
  98 if test "$with_hesiod" != no; then
  99   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 100 fi
 101
 102 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 103 if test "$with_mmdf" != no; then
 104    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 105 fi
 106
 107 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 108 if test "$with_mail_unlink" != no; then
 109    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 110 fi
 111
 112 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 113     [string giving default POP mail host])],
 114     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 115
 116 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 117
 118 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 119 if test "$with_sync_input" = yes; then
 120    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 121 fi
 122
 123 dnl FIXME currently it is not the last.
 124 dnl This should be the last --with option, because --with-x is
 125 dnl added later on when we find the path of X, and it's best to
 126 dnl keep them together visually.
 127 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 128  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 129 [         case "${withval}" in
 130             y | ye | yes )      val=gtk ;;
 131             n | no )            val=no  ;;
 132             l | lu | luc | luci | lucid )       val=lucid ;;
 133             a | at | ath | athe | athen | athena )      val=athena ;;
 134             m | mo | mot | moti | motif )       val=motif ;;
 135             g | gt | gtk  )     val=gtk ;;
 136             * )
 137 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 138 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 139 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 140             ;;
 141           esac
 142           with_x_toolkit=$val
 143 ])
 144
 145 dnl _ON results in a '--without' option in the --help output, so
 146 dnl the help text should refer to "don't compile", etc.
 147 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 148 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 149 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 150 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 151 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 152 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 153
 154 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 155 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 156 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 157
 158 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 159 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 160 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 161 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 162
 163 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 164 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 165 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 166 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 167
 168 ## For the times when you want to build Emacs but don't have
 169 ## a suitable makeinfo, and can live without the manuals.
 170 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 171 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 172
 173 AC_ARG_WITH([pkg-config-prog],dnl
 174 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 175                   [path to pkg-config for finding GTK and librsvg])])
 176 if test "X${with_pkg_config_prog}" != X; then
 177    if test "${with_pkg_config_prog}" != yes; then
 178       PKG_CONFIG="${with_pkg_config_prog}"
 179    fi
 180 fi
 181
 182 CRT_DIR=
 183 AC_ARG_WITH([crt-dir],dnl
 184 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 185 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 186 CRT_DIR="${with_crt_dir}"
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     case "${canonical}" in
 425       alpha*-*-netbsd*) machine=alpha ;;
 426       i[3456]86-*-netbsd*) machine=intel386 ;;
 427       mips-*-netbsd*)   machine=mips ;;
 428       mipsel-*-netbsd*) machine=mips ;;
 429       mipseb-*-netbsd*) machine=mips ;;
 430       powerpc-*-netbsd*) machine=macppc ;;
 431       sparc*-*-netbsd*) machine=sparc ;;
 432       vax-*-netbsd*)    machine=vax ;;
 433       arm-*-netbsd*)    machine=arm ;;
 434       x86_64-*-netbsd*) machine=amdx86-64 ;;
 435       hppa-*-netbsd*)   machine=hp800 ;;
 436       m68k-*-netbsd*)   machine=m68k ;;
 437     esac
 438   ;;
 439
 440   ## OpenBSD ports
 441   *-*-openbsd* )
 442     opsys=openbsd
 443     case "${canonical}" in
 444       alpha*-*-openbsd*)        machine=alpha ;;
 445       arm-*-openbsd*)          machine=arm ;;
 446       i386-*-openbsd*)         machine=intel386 ;;
 447       powerpc-*-openbsd*)      machine=macppc ;;
 448       sparc*-*-openbsd*)       machine=sparc ;;
 449       vax-*-openbsd*)          machine=vax ;;
 450       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 451       hppa-*-openbsd*)         machine=hp800 ;;
 452     esac
 453   ;;
 454
 455   alpha*-*-linux-gnu* )
 456     machine=alpha opsys=gnu-linux
 457   ;;
 458
 459   arm*-*-linux-gnu* )
 460     machine=arm opsys=gnu-linux
 461   ;;
 462
 463   ## Apple Darwin / Mac OS X
 464   *-apple-darwin* )
 465     case "${canonical}" in
 466       i[3456]86-* )  machine=intel386 ;;
 467       powerpc-* )    machine=macppc ;;
 468       x86_64-* )     machine=amdx86-64 ;;
 469       * )            unported=yes ;;
 470     esac
 471     opsys=darwin
 472     # Define CPP as follows to make autoconf work correctly.
 473     CPP="${CC-cc} -E -no-cpp-precomp"
 474     # Use fink packages if available.
 475     if test -d /sw/include && test -d /sw/lib; then
 476       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 477       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 478       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 479     fi
 480   ;;
 481
 482   ## HP 9000 series 700 and 800, running HP/UX
 483   hppa*-hp-hpux10.2* )
 484     machine=hp800 opsys=hpux10-20
 485   ;;
 486   hppa*-hp-hpux1[1-9]* )
 487     machine=hp800 opsys=hpux11
 488     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 489   ;;
 490
 491   hppa*-*-linux-gnu* )
 492     machine=hp800 opsys=gnu-linux
 493   ;;
 494
 495   ## IBM machines
 496   s390-*-linux-gnu* )
 497     machine=ibms390 opsys=gnu-linux
 498   ;;
 499   s390x-*-linux-gnu* )
 500     machine=ibms390x opsys=gnu-linux
 501   ;;
 502   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 503     machine=ibmrs6000 opsys=aix4-2
 504   ;;
 505   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 506     machine=ibmrs6000 opsys=aix4-2
 507   ;;
 508   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514
 515   ## Macintosh PowerPC
 516   powerpc*-*-linux-gnu* )
 517     machine=macppc opsys=gnu-linux
 518   ;;
 519
 520   ## Silicon Graphics machines
 521   ## Iris 4D
 522   mips-sgi-irix6.5 )
 523     machine=iris4d opsys=irix6-5
 524     # Without defining _LANGUAGE_C, things get masked out in the headers
 525     # so that, for instance, grepping for `free' in stdlib.h fails and
 526     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 527     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 528     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 529   ;;
 530
 531   ## Suns
 532   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 533     machine=sparc opsys=gnu-linux
 534   ;;
 535
 536   *-sun-solaris* \
 537     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 538     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       sparc* )          machine=sparc ;;
 543       * )               unported=yes ;;
 544     esac
 545     case "${canonical}" in
 546       *-sunos5.6* | *-solaris2.6* )
 547                 opsys=sol2-6
 548                 NON_GNU_CPP=/usr/ccs/lib/cpp
 549                 RANLIB="ar -ts"
 550                 ;;
 551       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 552                 opsys=sol2-6
 553                 emacs_check_sunpro_c=yes
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 ;;
 556       *-sunos5* | *-solaris* )
 557                 opsys=sol2-10
 558                 emacs_check_sunpro_c=yes
 559                 NON_GNU_CPP=/usr/ccs/lib/cpp
 560                 ;;
 561     esac
 562     ## Watch out for a compiler that we know will not work.
 563     case "${canonical}" in
 564      *-solaris* | *-sunos5* )
 565                 if [ "x$CC" = x/usr/ucb/cc ]; then
 566                   ## /usr/ucb/cc doesn't work;
 567                   ## we should find some other compiler that does work.
 568                   unset CC
 569                 fi
 570                 ;;
 571       *) ;;
 572     esac
 573   ;;
 574
 575   ## IA-64
 576   ia64*-*-linux* )
 577     machine=ia64 opsys=gnu-linux
 578   ;;
 579
 580   ## Intel 386 machines where we don't care about the manufacturer
 581   i[3456]86-*-* )
 582     machine=intel386
 583     case "${canonical}" in
 584       *-cygwin )                opsys=cygwin ;;
 585       *-darwin* )               opsys=darwin
 586                                 CPP="${CC-cc} -E -no-cpp-precomp"
 587                                 ;;
 588       *-linux-gnu* )            opsys=gnu-linux ;;
 589       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 593     esac
 594   ;;
 595
 596   ## m68k Linux-based GNU system
 597   m68k-*-linux-gnu* )
 598     machine=m68k opsys=gnu-linux
 599   ;;
 600
 601   ## Mips Linux-based GNU system
 602   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 603     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 604     machine=mips opsys=gnu-linux
 605   ;;
 606
 607   ## AMD x86-64 Linux-based GNU system
 608   x86_64-*-linux-gnu* )
 609     machine=amdx86-64 opsys=gnu-linux
 610   ;;
 611
 612   ## Tensilica Xtensa Linux-based GNU system
 613   xtensa*-*-linux-gnu* )
 614     machine=xtensa opsys=gnu-linux
 615     ;;
 616
 617   ## SuperH Linux-based GNU system
 618   sh[34]*-*-linux-gnu* )
 619     machine=sh3 opsys=gnu-linux
 620   ;;
 621
 622   * )
 623     unported=yes
 624   ;;
 625 esac
 626
 627 ### If the code above didn't choose an operating system, just choose
 628 ### an operating system based on the configuration name.  You really
 629 ### only want to use this when you have no idea what the right
 630 ### operating system is; if you know what operating systems a machine
 631 ### runs, it's cleaner to make it explicit in the case statement
 632 ### above.
 633 if test x"${opsys}" = x; then
 634   case "${canonical}" in
 635     *-gnu* )                            opsys=gnu ;;
 636     * )
 637       unported=yes
 638     ;;
 639   esac
 640 fi
 641
 642 ]
 643 dnl quotation ends
 644
 645 if test $unported = yes; then
 646   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 647 Check `etc/MACHINES' for recognized configuration names.])
 648 fi
 649
 650 machfile="m/${machine}.h"
 651 opsysfile="s/${opsys}.h"
 652
 653
 654 #### Choose a compiler.
 655 test -n "$CC" && cc_specified=yes
 656
 657 # Save the value of CFLAGS that the user specified.
 658 SPECIFIED_CFLAGS="$CFLAGS"
 659
 660 dnl Sets GCC=yes if using gcc.
 661 AC_PROG_CC
 662
 663 # On Suns, sometimes $CPP names a directory.
 664 if test -n "$CPP" && test -d "$CPP"; then
 665   CPP=
 666 fi
 667
 668 ## If not using gcc, and on Solaris, and no CPP specified, see if
 669 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 670 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 671  test x"$CPP" = x; then
 672   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 673   AC_CACHE_VAL(emacs_cv_sunpro_c,
 674   [AC_TRY_LINK([],
 675 [#ifndef __SUNPRO_C
 676 fail;
 677 #endif
 678 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 679   AC_MSG_RESULT($emacs_cv_sunpro_c)
 680
 681   if test x"$emacs_cv_sunpro_c" = xyes; then
 682     NON_GNU_CPP="$CC -E -Xs"
 683   fi
 684 fi
 685
 686 #### Some systems specify a CPP to use unless we are using GCC.
 687 #### Now that we know whether we are using GCC, we can decide whether
 688 #### to use that one.
 689 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 690 then
 691   CPP="$NON_GNU_CPP"
 692 fi
 693
 694 #### Some systems specify a CC to use unless we are using GCC.
 695 #### Now that we know whether we are using GCC, we can decide whether
 696 #### to use that one.
 697 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 698   test x$cc_specified != xyes
 699 then
 700   CC="$NON_GNU_CC"
 701 fi
 702
 703 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 704 then
 705   CC="$CC $GCC_TEST_OPTIONS"
 706 fi
 707
 708 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 709 then
 710   CC="$CC $NON_GCC_TEST_OPTIONS"
 711 fi
 712
 713 dnl checks for Unix variants
 714 AC_USE_SYSTEM_EXTENSIONS
 715
 716 ### Use -Wno-pointer-sign if the compiler supports it
 717 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wno-pointer-sign"
 720 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wdeclaration-after-statement if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 #### Some other nice autoconf tests.
 743
 744 dnl checks for programs
 745 AC_PROG_CPP
 746 AC_PROG_INSTALL
 747 if test "x$RANLIB" = x; then
 748   AC_PROG_RANLIB
 749 fi
 750
 751 ## Although we're running on an amd64 kernel, we're actually compiling for
 752 ## the x86 architecture.  The user should probably have provided an
 753 ## explicit --build to `configure', but if everything else than the kernel
 754 ## is running in i386 mode, we can help them out.
 755 if test "$machine" = "amdx86-64"; then
 756   AC_CHECK_DECL([i386])
 757   if test "$ac_cv_have_decl_i386" = "yes"; then
 758     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 759     machine=intel386
 760     machfile="m/${machine}.h"
 761   fi
 762 fi
 763
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 if test "$MAKEINFO" = "no"; then
 790   if test "x${with_makeinfo}" = "xno"; then
 791     MAKEINFO=off
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799
 800 dnl Add our options to ac_link now, after it is set up.
 801
 802 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 803 then
 804   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test "$GCC" = yes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([main(){return 0;}],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831 #### Extract some information from the operating system and machine files.
 832
 833 AC_CHECKING([the machine- and system-dependent files to find out
 834  - which libraries the lib-src programs will want, and
 835  - whether the GNU malloc routines are usable])
 836
 837 ### First figure out CFLAGS (which we use for running the compiler here)
 838 ### and REAL_CFLAGS (which we use for real compilation).
 839 ### The two are the same except on a few systems, where they are made
 840 ### different to work around various lossages.  For example,
 841 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 842 ### as implying static linking.
 843
 844 ### If the CFLAGS env var is specified, we use that value
 845 ### instead of the default.
 846
 847 ### It's not important that this name contain the PID; you can't run
 848 ### two configures in the same directory and have anything work
 849 ### anyway.
 850 tempcname="conftest.c"
 851
 852 echo '
 853 #include "'${srcdir}'/src/'${opsysfile}'"
 854 #include "'${srcdir}'/src/'${machfile}'"
 855
 856 configure___ LIBX=-lX11
 857
 858 configure___ unexec=UNEXEC
 859
 860 #ifdef CANNOT_DUMP
 861 configure___ cannot_dump=yes
 862 #else
 863 configure___ cannot_dump=no
 864 #endif
 865
 866 #ifdef SYSTEM_MALLOC
 867 configure___ system_malloc=yes
 868 #else
 869 configure___ system_malloc=no
 870 #endif
 871
 872 #ifdef USE_MMAP_FOR_BUFFERS
 873 configure___ use_mmap_for_buffers=yes
 874 #else
 875 configure___ use_mmap_for_buffers=no
 876 #endif
 877
 878 #ifndef C_OPTIMIZE_SWITCH
 879 #ifdef __GNUC__
 880 #define C_OPTIMIZE_SWITCH -O2
 881 #else
 882 #define C_OPTIMIZE_SWITCH -O
 883 #endif
 884 #endif
 885
 886 #ifndef C_WARNINGS_SWITCH
 887 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 888 #endif
 889
 890 #ifdef THIS_IS_CONFIGURE
 891
 892 /* Get the CFLAGS for tests in configure.  */
 893 #ifdef __GNUC__
 894 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 895 #else
 896 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 897 #endif
 898
 899 #else /* not THIS_IS_CONFIGURE */
 900
 901 /* Get the CFLAGS for real compilation.  */
 902 #ifdef __GNUC__
 903 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 904 #else
 905 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 906 #endif
 907
 908 #endif /* not THIS_IS_CONFIGURE */
 909 ' > ${tempcname}
 910
 911 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 912
 913 # The value of CPP is a quoted variable reference, so we need to do this
 914 # to get its actual value...
 915 CPP=`eval "echo $CPP"`
 916 [eval `${CPP} -Isrc ${tempcname} \
 917        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 918 if test "x$SPECIFIED_CFLAGS" = x; then
 919   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 920          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 921 else
 922   REAL_CFLAGS="$CFLAGS"
 923 fi]
 924 rm ${tempcname}
 925
 926
 927 AC_SUBST(cannot_dump)
 928
 929
 930 LD_SWITCH_SYSTEM=
 931 case "$opsys" in
 932   freebsd)
 933    ## Let `ld' find image libs and similar things in /usr/local/lib.
 934    ## The system compiler, GCC, has apparently been modified to not
 935    ## look there, contrary to what a stock GCC would do.
 936    LD_SWITCH_SYSTEM=-L/usr/local/lib
 937    ;;
 938
 939   gnu-linux)
 940    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 941    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 942    ;;
 943
 944   netbsd)
 945    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 946    ;;
 947
 948   openbsd)
 949    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 950    ## otherwise Emacs dumps core on elf systems.
 951    LD_SWITCH_SYSTEM="-Z"
 952    ;;
 953 esac
 954 AC_SUBST(LD_SWITCH_SYSTEM)
 955
 956 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 957
 958 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 959 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 960 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 961 ## values in configure and the Makefiles.  How helpful.
 962 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 963 case "$opsys" in
 964   gnu-linux)
 965    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 966    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 967
 968   netbsd|openbsd)
 969    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 970    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 971 esac
 972
 973
 974 C_SWITCH_MACHINE=
 975 if test "$machine" = "alpha"; then
 976   AC_CHECK_DECL([__ELF__])
 977   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 978     ## With ELF, make sure that all common symbols get allocated to in the
 979     ## data section.  Otherwise, the dump of temacs may miss variables in
 980     ## the shared library that have been initialized.  For example, with
 981     ## GNU libc, __malloc_initialized would normally be resolved to the
 982     ## shared library's .bss section, which is fatal.
 983     if test "x$GCC" = "xyes"; then
 984       C_SWITCH_MACHINE="-fno-common"
 985     else
 986       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 987     fi
 988   fi
 989 fi
 990 AC_SUBST(C_SWITCH_MACHINE)
 991
 992
 993 C_SWITCH_SYSTEM=
 994 ## Some programs in src produce warnings saying certain subprograms
 995 ## are too complex and need a MAXMEM value greater than 2000 for
 996 ## additional optimization.  --nils@exp-math.uni-essen.de
 997 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 998   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 999 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1000 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1001 AC_SUBST(C_SWITCH_SYSTEM)
1002
1003
1004 LIBS_SYSTEM=
1005 case "$opsys" in
1006   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1007   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1008
1009   freebsd) LIBS_SYSTEM="-lutil" ;;
1010
1011   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1012
1013   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1014
1015   ## Motif needs -lgen.
1016   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1017 esac
1018 AC_SUBST(LIBS_SYSTEM)
1019
1020
1021 ### Make sure subsequent tests use flags consistent with the build flags.
1022
1023 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1024   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1025 else
1026   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1027 fi
1028
1029 dnl For AC_FUNC_GETLOADAVG, at least:
1030 AC_CONFIG_LIBOBJ_DIR(src)
1031
1032 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1033 AC_SYS_LARGEFILE
1034
1035
1036 ## If user specified a crt-dir, use that unconditionally.
1037 if test "X$CRT_DIR" = "X"; then
1038
1039   case "$canonical" in
1040     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1041     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1042     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1043     ## For anything else (eg /usr/lib32), it is up the user to specify
1044     ## the location (bug#5655).
1045     ## Test for crtn.o, not just the directory, because sometimes the
1046     ## directory exists but does not have the relevant files (bug#1287).
1047     ## FIXME better to test for binary compatibility somehow.
1048     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1049     ;;
1050
1051     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1052   esac
1053
1054   case "$opsys" in
1055     hpux10-20) CRT_DIR=/lib ;;
1056   esac
1057
1058   ## Default is /usr/lib.
1059   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1060
1061 else
1062
1063   ## Some platforms don't use any of these files, so it is not
1064   ## appropriate to put this test outside the if block.
1065   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1066     AC_MSG_ERROR([crt*.o not found in specified location.])
1067
1068 fi
1069
1070 AC_SUBST(CRT_DIR)
1071
1072 LIB_MATH=-lm
1073 LIB_STANDARD=
1074 START_FILES=
1075
1076 case $opsys in
1077   cygwin )
1078     LIB_MATH=
1079     START_FILES='ecrt0.o'
1080     ;;
1081   darwin )
1082     ## Adding -lm confuses the dynamic linker, so omit it.
1083     LIB_MATH=
1084     START_FILES='pre-crt0.o'
1085     ;;
1086   freebsd )
1087     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1088     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1089     ;;
1090   gnu-linux | gnu-kfreebsd )
1091     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1092     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1093     ;;
1094   hpux10-20 | hpux11 )
1095     LIB_STANDARD=-lc
1096     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1097     ;;
1098   netbsd | openbsd )
1099     if test -f $CRT_DIR/crti.o; then
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     else
1103         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1104         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1105     fi
1106     ;;
1107 esac
1108
1109 AC_SUBST(LIB_MATH)
1110 AC_SUBST(START_FILES)
1111
1112 dnl This function definition taken from Gnome 2.0
1113 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1114 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1115 dnl also defines GSTUFF_PKG_ERRORS on error
1116 AC_DEFUN([PKG_CHECK_MODULES], [
1117   succeeded=no
1118
1119   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1120
1121   if test "$PKG_CONFIG" = "no" ; then
1122      ifelse([$4], , [AC_MSG_ERROR([
1123       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1124   else
1125      PKG_CONFIG_MIN_VERSION=0.9.0
1126      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1127         AC_MSG_CHECKING(for $2)
1128
1129         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1130             AC_MSG_RESULT(yes)
1131             succeeded=yes
1132
1133             AC_MSG_CHECKING($1_CFLAGS)
1134             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1135             AC_MSG_RESULT($$1_CFLAGS)
1136
1137             AC_MSG_CHECKING($1_LIBS)
1138             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1139             AC_MSG_RESULT($$1_LIBS)
1140         else
1141             AC_MSG_RESULT(no)
1142             $1_CFLAGS=""
1143             $1_LIBS=""
1144             ## If we have a custom action on failure, don't print errors, but
1145             ## do set a variable so people can do so.
1146             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1147             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1148         fi
1149
1150         AC_SUBST($1_CFLAGS)
1151         AC_SUBST($1_LIBS)
1152      else
1153         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1154         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1155      fi
1156   fi
1157
1158   if test $succeeded = yes; then
1159      ifelse([$3], , :, [$3])
1160   else
1161      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1162   fi
1163 ])
1164
1165
1166 if test "${with_sound}" != "no"; then
1167   # Sound support for GNU/Linux and the free BSDs.
1168   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1169   # Emulation library used on NetBSD.
1170   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1171   AC_SUBST(LIBSOUND)
1172
1173   ALSA_REQUIRED=1.0.0
1174   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1175   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1176   if test $HAVE_ALSA = yes; then
1177     SAVE_CFLAGS="$CFLAGS"
1178     SAVE_LDFLAGS="$LDFLAGS"
1179     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1180     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1181     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1182                     emacs_alsa_normal=yes,
1183                     emacs_alsa_normal=no)
1184     if test "$emacs_alsa_normal" != yes; then
1185       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1186                      [snd_lib_error_set_handler (0);],
1187                      emacs_alsa_subdir=yes,
1188                      emacs_alsa_subdir=no)
1189       if test "$emacs_alsa_subdir" != yes; then
1190         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1191       fi
1192       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1193     fi
1194
1195     CFLAGS="$SAVE_CFLAGS"
1196     LDFLAGS="$SAVE_LDFLAGS"
1197     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1198     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1199     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1200   fi
1201   AC_SUBST(CFLAGS_SOUND)
1202 fi
1203
1204 dnl checks for header files
1205 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1206   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1207   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1208   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1209   sys/utsname.h pwd.h utmp.h)
1210
1211 AC_MSG_CHECKING(if personality LINUX32 can be set)
1212 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1213                emacs_cv_personality_linux32=yes,
1214                emacs_cv_personality_linux32=no)
1215 AC_MSG_RESULT($emacs_cv_personality_linux32)
1216
1217 if test $emacs_cv_personality_linux32 = yes; then
1218   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1219             [Define to 1 if personality LINUX32 can be set.])
1220 fi
1221
1222 dnl On Solaris 8 there's a compilation warning for term.h because
1223 dnl it doesn't define `bool'.
1224 AC_CHECK_HEADERS(term.h, , , -)
1225 AC_HEADER_STDC
1226 AC_HEADER_TIME
1227 AC_CHECK_DECLS([sys_siglist])
1228 if test $ac_cv_have_decl_sys_siglist != yes; then
1229   # For Tru64, at least:
1230   AC_CHECK_DECLS([__sys_siglist])
1231   if test $ac_cv_have_decl___sys_siglist = yes; then
1232     AC_DEFINE(sys_siglist, __sys_siglist,
1233               [Define to any substitute for sys_siglist.])
1234   fi
1235 fi
1236 AC_HEADER_SYS_WAIT
1237
1238 dnl Some systems have utime.h but don't declare the struct anyplace.
1239 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1240 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1241 #include <sys/time.h>
1242 #include <time.h>
1243 #else
1244 #ifdef HAVE_SYS_TIME_H
1245 #include <sys/time.h>
1246 #else
1247 #include <time.h>
1248 #endif
1249 #endif
1250 #ifdef HAVE_UTIME_H
1251 #include <utime.h>
1252 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1253   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1254 if test $emacs_cv_struct_utimbuf = yes; then
1255   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1256 fi
1257
1258 dnl checks for typedefs
1259 AC_TYPE_SIGNAL
1260
1261 dnl Check for speed_t typedef.
1262 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1263   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1264     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1265 if test $emacs_cv_speed_t = yes; then
1266   AC_DEFINE(HAVE_SPEED_T, 1,
1267            [Define to 1 if `speed_t' is declared by <termios.h>.])
1268 fi
1269
1270 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1271 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1272 #include <sys/time.h>
1273 #include <time.h>
1274 #else
1275 #ifdef HAVE_SYS_TIME_H
1276 #include <sys/time.h>
1277 #else
1278 #include <time.h>
1279 #endif
1280 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1281   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1282 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1283 if test $emacs_cv_struct_timeval = yes; then
1284   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1285 fi
1286
1287 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1288 AC_TRY_COMPILE([#include <math.h>],
1289 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1290   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1291 HAVE_EXCEPTION=$emacs_cv_struct_exception
1292 if test $emacs_cv_struct_exception != yes; then
1293   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1294 fi
1295
1296 AC_CHECK_HEADERS(sys/socket.h)
1297 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1298 #if HAVE_SYS_SOCKET_H
1299 #include <sys/socket.h>
1300 #endif])
1301
1302 dnl checks for structure members
1303 AC_STRUCT_TM
1304 AC_STRUCT_TIMEZONE
1305 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1306                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1307                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1308                 [#include <time.h>])
1309 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1310                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1311                   struct ifreq.ifr_addr], , ,
1312                  [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif
1316 #if HAVE_NET_IF_H
1317 #include <net/if.h>
1318 #endif])
1319
1320 dnl checks for compiler characteristics
1321
1322 dnl Testing __STDC__ to determine prototype support isn't good enough.
1323 dnl DEC C, for instance, doesn't define it with default options, and
1324 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1325 dnl and void *.
1326 AC_C_PROTOTYPES
1327 AC_C_VOLATILE
1328 AC_C_CONST
1329 dnl This isn't useful because we can't turn on use of `inline' unless
1330 dnl the compiler groks `extern inline'.
1331 dnl AC_C_INLINE
1332 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1333   [AC_TRY_COMPILE(, [void * foo;],
1334                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1335 if test $emacs_cv_void_star = yes; then
1336   AC_DEFINE(POINTER_TYPE, void)
1337 else
1338   AC_DEFINE(POINTER_TYPE, char)
1339 fi
1340 AH_TEMPLATE(POINTER_TYPE,
1341             [Define as `void' if your compiler accepts `void *'; otherwise
1342              define as `char'.])dnl
1343
1344
1345
1346 dnl This could be used for targets which can have both byte sexes.
1347 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1348 dnl AC_C_BIGENDIAN
1349
1350 dnl check for Make feature
1351 AC_PROG_MAKE_SET
1352
1353 DEPFLAGS=
1354 MKDEPDIR=":"
1355 deps_frag=deps.mk
1356 dnl check for GNU Make if we have GCC and autodepend is on.
1357 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1358    AC_MSG_CHECKING([whether we are using GNU Make])
1359    HAVE_GNU_MAKE=no
1360    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1361    if test "x$testval" != x; then
1362       HAVE_GNU_MAKE=yes
1363    else
1364       ac_enable_autodepend=no
1365    fi
1366    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1367    if test $HAVE_GNU_MAKE = yes; then
1368       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1369       SAVE_CFLAGS="$CFLAGS"
1370       CFLAGS="$CFLAGS -MMD -MF deps.d"
1371       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1372       CFLAGS="$SAVE_CFLAGS"
1373       test -f deps.d || ac_enable_autodepend=no
1374       rm -rf deps.d
1375       AC_MSG_RESULT([$ac_enable_autodepend])
1376    fi
1377    if test $ac_enable_autodepend = yes; then
1378       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1379       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR}'
1380       deps_frag=autodeps.mk
1381    fi
1382 fi
1383 deps_frag=$srcdir/src/$deps_frag
1384 AC_SUBST(MKDEPDIR)
1385 AC_SUBST(DEPFLAGS)
1386 AC_SUBST_FILE(deps_frag)
1387
1388
1389 dnl checks for operating system services
1390 AC_SYS_LONG_FILE_NAMES
1391
1392 #### Choose a window system.
1393
1394 AC_PATH_X
1395 if test "$no_x" = yes; then
1396   window_system=none
1397 else
1398   window_system=x11
1399 fi
1400
1401 ## Workaround for bug in autoconf <= 2.62.
1402 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1403 ## No need to do anything special for these standard directories.
1404 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1405
1406    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1407
1408 fi
1409
1410 LD_SWITCH_X_SITE_AUX=
1411 LD_SWITCH_X_SITE_AUX_RPATH=
1412 if test "${x_libraries}" != NONE; then
1413   if test -n "${x_libraries}"; then
1414     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1415     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1416     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1417   fi
1418   x_default_search_path=""
1419   x_search_path=${x_libraries}
1420   if test -z "${x_search_path}"; then
1421     x_search_path=/usr/lib
1422   fi
1423   for x_library in `echo ${x_search_path}: | \
1424                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1425     x_search_path="\
1426 ${x_library}/X11/%L/%T/%N%C%S:\
1427 ${x_library}/X11/%l/%T/%N%C%S:\
1428 ${x_library}/X11/%T/%N%C%S:\
1429 ${x_library}/X11/%L/%T/%N%S:\
1430 ${x_library}/X11/%l/%T/%N%S:\
1431 ${x_library}/X11/%T/%N%S"
1432     if test x"${x_default_search_path}" = x; then
1433       x_default_search_path=${x_search_path}
1434     else
1435       x_default_search_path="${x_search_path}:${x_default_search_path}"
1436     fi
1437   done
1438 fi
1439 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1441
1442 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1443   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1444 fi
1445
1446 if test x"${x_includes}" = x; then
1447   bitmapdir=/usr/include/X11/bitmaps
1448 else
1449   # accumulate include directories that have X11 bitmap subdirectories
1450   bmd_acc="dummyval"
1451   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1452     if test -d "${bmd}/X11/bitmaps"; then
1453       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1454     fi
1455     if test -d "${bmd}/bitmaps"; then
1456       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1457     fi
1458   done
1459   if test ${bmd_acc} != "dummyval"; then
1460     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1461   fi
1462 fi
1463
1464 HAVE_NS=no
1465 NS_IMPL_COCOA=no
1466 NS_IMPL_GNUSTEP=no
1467 NS_IMPL_GNUSTEP_INC=
1468 NS_IMPL_GNUSTEP_TEMACS_LDFLAGS=
1469 tmp_CPPFLAGS="$CPPFLAGS"
1470 tmp_CFLAGS="$CFLAGS"
1471 CPPFLAGS="$CPPFLAGS -x objective-c"
1472 CFLAGS="$CFLAGS -x objective-c"
1473 TEMACS_LDFLAGS2="\${LDFLAGS}"
1474 dnl I don't think it's especially important, but src/Makefile.in
1475 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1476 dnl trailing "/" to it, so now we do it here.
1477 if test "${with_ns}" != no; then
1478   if test "${opsys}" = darwin; then
1479      NS_IMPL_COCOA=yes
1480      ns_appdir=`pwd`/nextstep/Emacs.app/
1481      ns_appbindir=${ns_appdir}Contents/MacOS/
1482      ns_appresdir=${ns_appdir}Contents/Resources
1483      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1484   elif test -f $GNUSTEP_CONFIG_FILE; then
1485      NS_IMPL_GNUSTEP=yes
1486      ns_appdir=`pwd`/nextstep/Emacs.app/
1487      ns_appbindir=${ns_appdir}
1488      ns_appresdir=${ns_appdir}Resources
1489      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1490      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1491      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1492      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1493      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1494      ## Pull in stuff from GNUstep-make.
1495      ## FIXME? Cleaner to use AC_SUBST_FILE for this?
1496      NS_IMPL_GNUSTEP_INC="FOUNDATION_LIB=gnu
1497 GUI_LIB=gnu
1498 include $GNUSTEP_MAKEFILES/Additional/base.make
1499 include $GNUSTEP_MAKEFILES/Additional/gui.make
1500 shared=no
1501 "
1502      dnl Presumably ${CONFIG_SYSTEM_LIBS} is defined by above includes.
1503      NS_IMPL_GNUSTEP_TEMACS_LDFLAGS="-L${GNUSTEP_SYSTEM_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc \${CONFIG_SYSTEM_LIBS} -lpthread"
1504      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1505      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1506      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1507      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1508      LIB_STANDARD=
1509      START_FILES=
1510      TEMACS_LDFLAGS2=
1511   fi
1512   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1513                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1514   files are missing or cannot be compiled.])])
1515   NS_HAVE_NSINTEGER=yes
1516   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1517                                      [NSInteger i;])],
1518                     ns_have_nsinteger=yes,
1519                     ns_have_nsinteger=no)
1520   if test $ns_have_nsinteger = no; then
1521     NS_HAVE_NSINTEGER=no
1522   fi
1523 fi
1524 AC_SUBST(NS_IMPL_GNUSTEP_INC)
1525 AC_SUBST(NS_IMPL_GNUSTEP_TEMACS_LDFLAGS)
1526 AC_SUBST(TEMACS_LDFLAGS2)
1527
1528 ns_frag=/dev/null
1529 NS_OBJ=
1530 NS_SUPPORT=
1531 if test "${HAVE_NS}" = yes; then
1532   window_system=nextstep
1533   with_xft=no
1534   # set up packaging dirs
1535   exec_prefix=${ns_appbindir}
1536   libexecdir=${ns_appbindir}/libexec
1537   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1538      prefix=${ns_appresdir}
1539   fi
1540   ns_frag=$srcdir/src/ns.mk
1541   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1542   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1543 fi
1544 CFLAGS="$tmp_CFLAGS"
1545 CPPFLAGS="$tmp_CPPFLAGS"
1546 AC_SUBST(NS_OBJ)
1547 AC_SUBST(NS_SUPPORT)
1548 AC_SUBST(LIB_STANDARD)
1549 AC_SUBST_FILE(ns_frag)
1550
1551 case "${window_system}" in
1552   x11 )
1553     HAVE_X_WINDOWS=yes
1554     HAVE_X11=yes
1555     case "${with_x_toolkit}" in
1556       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1557       motif ) USE_X_TOOLKIT=MOTIF ;;
1558       gtk ) with_gtk=yes
1559 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1560 dnl USE_X_TOOLKIT is set.
1561             USE_X_TOOLKIT=none ;;
1562       no ) USE_X_TOOLKIT=none ;;
1563 dnl If user did not say whether to use a toolkit, make this decision later:
1564 dnl use the toolkit if we have gtk, or X11R5 or newer.
1565       * ) USE_X_TOOLKIT=maybe ;;
1566     esac
1567   ;;
1568   nextstep | none )
1569     HAVE_X_WINDOWS=no
1570     HAVE_X11=no
1571     USE_X_TOOLKIT=none
1572   ;;
1573 esac
1574
1575 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1576    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1577    if test "$HAVE_XSERVER" = true ||
1578       test -n "$DISPLAY" ||
1579       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1580         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1581 were found.  You should install the relevant development files for X
1582 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1583 sure you have development files for image handling, i.e.
1584 tiff, gif, jpeg, png and xpm.
1585 If you are sure you want Emacs compiled without X window support, pass
1586   --without-x
1587 to configure.])
1588    fi
1589 fi
1590
1591 ### If we're using X11, we should use the X menu package.
1592 HAVE_MENUS=no
1593 case ${HAVE_X11} in
1594   yes ) HAVE_MENUS=yes ;;
1595 esac
1596
1597 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1598 # Assume not, until told otherwise.
1599 GNU_MALLOC=yes
1600 doug_lea_malloc=yes
1601 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1602 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1603 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1604                emacs_cv_var___after_morecore_hook,
1605 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1606   emacs_cv_var___after_morecore_hook=yes,
1607   emacs_cv_var___after_morecore_hook=no)])
1608 if test $emacs_cv_var___after_morecore_hook = no; then
1609   doug_lea_malloc=no
1610 fi
1611
1612 if test "${system_malloc}" = "yes"; then
1613   GNU_MALLOC=no
1614   GNU_MALLOC_reason="
1615     (The GNU allocators don't work with this system configuration.)"
1616   GMALLOC_OBJ=
1617   VMLIMIT_OBJ=
1618 else
1619   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1620   VMLIMIT_OBJ=vm-limit.o
1621 fi
1622 AC_SUBST(GMALLOC_OBJ)
1623 AC_SUBST(VMLIMIT_OBJ)
1624
1625 if test "$doug_lea_malloc" = "yes" ; then
1626   if test "$GNU_MALLOC" = yes ; then
1627     GNU_MALLOC_reason="
1628       (Using Doug Lea's new malloc from the GNU C Library.)"
1629   fi
1630   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1631             [Define to 1 if you are using the GNU C Library.])
1632
1633   ## Use mmap directly for allocating larger buffers.
1634   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1635   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1636   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1637   case "$opsys" in
1638     gnu*) REL_ALLOC=no ;;
1639   esac
1640 fi
1641
1642 if test x"${REL_ALLOC}" = x; then
1643   REL_ALLOC=${GNU_MALLOC}
1644 fi
1645
1646 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1647 dnl the system configuration file (s/*.h) to turn the use of mmap
1648 dnl in the relocating allocator on.
1649
1650 AC_FUNC_MMAP
1651 if test $use_mmap_for_buffers = yes; then
1652   REL_ALLOC=no
1653 fi
1654
1655 LIBS="$LIBS_SYSTEM $LIBS"
1656
1657 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1658 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1659 AC_CHECK_LIB(dnet, dnet_ntoa)
1660 dnl This causes -lresolv to get used in subsequent tests,
1661 dnl which causes failures on some systems such as HPUX 9.
1662 dnl AC_CHECK_LIB(resolv, gethostbyname)
1663
1664 dnl FIXME replace main with a function we actually want from this library.
1665 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1666
1667 AC_CHECK_LIB(pthreads, cma_open)
1668
1669 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1670 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1671 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1672 ## added to LIBS in configure would never contain the pthreads part,
1673 ## but the value used in Makefiles might.  FIXME?
1674 ##
1675 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1676 ## be harmless on older versions of X where it happens to exist.
1677 test "$opsys" = "aix4-2" && \
1678   test $ac_cv_lib_pthreads_cma_open = yes && \
1679   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1680
1681 dnl Check for need for bigtoc support on IBM AIX
1682
1683 case ${host_os} in
1684 aix*)
1685   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1686     case $GCC in
1687     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1688     *) gdb_cv_bigtoc=-bbigtoc ;;
1689     esac
1690
1691     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1692     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1693   ])
1694   ;;
1695 esac
1696
1697 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1698 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1699 # REAL_CPPFLAGS later on.
1700
1701 REAL_CPPFLAGS="$CPPFLAGS"
1702
1703 if test "${HAVE_X11}" = "yes"; then
1704   DEFS="$C_SWITCH_X_SITE $DEFS"
1705   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1706   LIBS="$LIBX $LIBS"
1707   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1708   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1709
1710   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1711   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1712   # but it's more convenient here to set LD_RUN_PATH
1713   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1714   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1715     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1716     export LD_RUN_PATH
1717   fi
1718
1719   if test "${opsys}" = "gnu-linux"; then
1720     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1721     AC_TRY_LINK([],
1722      [XOpenDisplay ("foo");],
1723      [xlinux_first_failure=no],
1724      [xlinux_first_failure=yes])
1725     if test "${xlinux_first_failure}" = "yes"; then
1726       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1727       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1728       OLD_CPPFLAGS="$CPPFLAGS"
1729       OLD_LIBS="$LIBS"
1730       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1731       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1732       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1733       LIBS="$LIBS -b i486-linuxaout"
1734       AC_TRY_LINK([],
1735        [XOpenDisplay ("foo");],
1736        [xlinux_second_failure=no],
1737        [xlinux_second_failure=yes])
1738       if test "${xlinux_second_failure}" = "yes"; then
1739         # If we get the same failure with -b, there is no use adding -b.
1740         # So take it out.  This plays safe.
1741         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1742         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1743         CPPFLAGS="$OLD_CPPFLAGS"
1744         LIBS="$OLD_LIBS"
1745         AC_MSG_RESULT(no)
1746       else
1747         AC_MSG_RESULT(yes)
1748       fi
1749     else
1750       AC_MSG_RESULT(no)
1751     fi
1752   fi
1753
1754   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1755   # header files included from there.
1756   AC_MSG_CHECKING(for Xkb)
1757   AC_TRY_LINK([#include <X11/Xlib.h>
1758 #include <X11/XKBlib.h>],
1759         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1760         emacs_xkb=yes, emacs_xkb=no)
1761   AC_MSG_RESULT($emacs_xkb)
1762   if test $emacs_xkb = yes; then
1763     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1764   fi
1765
1766   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1767 XScreenNumberOfScreen XSetWMProtocols)
1768 fi
1769
1770 if test "${window_system}" = "x11"; then
1771   AC_MSG_CHECKING(X11 version 6)
1772   AC_CACHE_VAL(emacs_cv_x11_version_6,
1773   [AC_TRY_LINK([#include <X11/Xlib.h>],
1774 [#if XlibSpecificationRelease < 6
1775 fail;
1776 #endif
1777 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1778   if test $emacs_cv_x11_version_6 = yes; then
1779     AC_MSG_RESULT(6 or newer)
1780     AC_DEFINE(HAVE_X11R6, 1,
1781               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1782   else
1783     AC_MSG_RESULT(before 6)
1784   fi
1785 fi
1786
1787
1788 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1789 HAVE_RSVG=no
1790 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1791   if test "${with_rsvg}" != "no"; then
1792     RSVG_REQUIRED=2.11.0
1793     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1794
1795     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1796     AC_SUBST(RSVG_CFLAGS)
1797     AC_SUBST(RSVG_LIBS)
1798
1799     if test ".${RSVG_CFLAGS}" != "."; then
1800       HAVE_RSVG=yes
1801       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1802       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1803       LIBS="$RSVG_LIBS $LIBS"
1804     fi
1805   fi
1806 fi
1807
1808
1809 HAVE_GTK=no
1810 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1811   GLIB_REQUIRED=2.6
1812   GTK_REQUIRED=2.6
1813   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1814
1815   dnl Checks for libraries.
1816   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1817   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1818      AC_MSG_ERROR($GTK_PKG_ERRORS)
1819   fi
1820 fi
1821
1822
1823 GTK_OBJ=
1824 if test x"$pkg_check_gtk" = xyes; then
1825
1826   AC_SUBST(GTK_CFLAGS)
1827   AC_SUBST(GTK_LIBS)
1828   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1829   CFLAGS="$CFLAGS $GTK_CFLAGS"
1830   LIBS="$GTK_LIBS $LIBS"
1831   dnl Try to compile a simple GTK program.
1832   GTK_COMPILES=no
1833   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1834   if test "${GTK_COMPILES}" != "yes"; then
1835     if test "$USE_X_TOOLKIT" != "maybe"; then
1836       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1837     fi
1838   else
1839     HAVE_GTK=yes
1840     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1841     GTK_OBJ=gtkutil.o
1842     USE_X_TOOLKIT=none
1843     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1844       :
1845     else
1846       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1847        closing open displays.  This is no problem if you just use
1848        one display, but if you use more than one and close one of them
1849        Emacs may crash.]])
1850       sleep 3
1851     fi
1852   fi
1853
1854 fi
1855 AC_SUBST(GTK_OBJ)
1856
1857
1858 if test "${HAVE_GTK}" = "yes"; then
1859
1860   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1861   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1862   if test "$with_toolkit_scroll_bars" != no; then
1863     with_toolkit_scroll_bars=yes
1864   fi
1865
1866   dnl  Check if we can use multiple displays with this GTK version.
1867   dnl  If gdk_display_open exists, assume all others are there also.
1868   HAVE_GTK_MULTIDISPLAY=no
1869   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1870   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1871     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1872               [Define to 1 if GTK can handle more than one display.])
1873   fi
1874
1875   dnl  Check if we have the old file selection dialog declared and
1876   dnl  in the link library.  In 2.x it may be in the library,
1877   dnl  but not declared if deprecated featured has been selected out.
1878   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1879   HAVE_GTK_FILE_SELECTION=no
1880   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1881                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1882 #include <gtk/gtk.h>])
1883   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1884     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1885                    HAVE_GTK_FILE_SELECTION=no)
1886   fi
1887
1888   dnl  Check if we have the new file chooser dialog
1889   HAVE_GTK_FILE_CHOOSER=no
1890   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1891                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1892 #include <gtk/gtk.h>])
1893   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1894     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1895                    HAVE_GTK_FILE_CHOOSER=no)
1896   fi
1897
1898   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1899      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1900     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1901               [Define to 1 if GTK has both file selection and chooser dialog.])
1902   fi
1903
1904   dnl Check if pthreads are available.  Emacs only needs this when using
1905   dnl gtk_file_chooser under Gnome.
1906   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1907     HAVE_GTK_AND_PTHREAD=no
1908     AC_CHECK_HEADERS(pthread.h)
1909     if test "$ac_cv_header_pthread_h"; then
1910       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1911     fi
1912     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1913       case "${canonical}" in
1914         *-hpux*) ;;
1915         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1916       esac
1917       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1918                [Define to 1 if you have GTK and pthread (-lpthread).])
1919     fi
1920   fi
1921 fi
1922
1923 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1924 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1925 dnl also not configured.
1926 HAVE_DBUS=no
1927 DBUS_OBJ=
1928 if test "${with_dbus}" = "yes"; then
1929    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1930    if test "$HAVE_DBUS" = yes; then
1931      LIBS="$LIBS $DBUS_LIBS"
1932      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1933      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1934      DBUS_OBJ=dbusbind.o
1935    fi
1936 fi
1937 AC_SUBST(DBUS_OBJ)
1938
1939 dnl GConf has been tested under GNU/Linux only.
1940 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1941 HAVE_GCONF=no
1942 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1943    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1944    if test "$HAVE_GCONF" = yes; then
1945       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1946    fi
1947 fi
1948
1949 dnl SELinux is available for GNU/Linux only.
1950 HAVE_LIBSELINUX=no
1951 LIBSELINUX_LIBS=
1952 if test "${with_selinux}" = "yes"; then
1953    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1954    if test "$HAVE_LIBSELINUX" = yes; then
1955       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1956       LIBSELINUX_LIBS=-lselinux
1957    fi
1958 fi
1959 AC_SUBST(LIBSELINUX_LIBS)
1960
1961 dnl Do not put whitespace before the #include statements below.
1962 dnl Older compilers (eg sunos4 cc) choke on it.
1963 HAVE_XAW3D=no
1964 LUCID_LIBW=
1965 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1966   if test "$with_xaw3d" != no; then
1967     AC_MSG_CHECKING(for xaw3d)
1968     AC_CACHE_VAL(emacs_cv_xaw3d,
1969     [AC_TRY_LINK([
1970 #include <X11/Intrinsic.h>
1971 #include <X11/Xaw3d/Simple.h>],
1972       [],
1973       emacs_cv_xaw3d=yes,
1974       emacs_cv_xaw3d=no)])
1975   else
1976     emacs_cv_xaw3d=no
1977   fi
1978   if test $emacs_cv_xaw3d = yes; then
1979     AC_MSG_RESULT([yes; using Lucid toolkit])
1980     USE_X_TOOLKIT=LUCID
1981     HAVE_XAW3D=yes
1982     LUCID_LIBW=-lXaw3d
1983     AC_DEFINE(HAVE_XAW3D, 1,
1984               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1985   else
1986     AC_MSG_RESULT(no)
1987     AC_MSG_CHECKING(for libXaw)
1988     AC_CACHE_VAL(emacs_cv_xaw,
1989     [AC_TRY_LINK([
1990 #include <X11/Intrinsic.h>
1991 #include <X11/Xaw/Simple.h>],
1992       [],
1993       emacs_cv_xaw=yes,
1994       emacs_cv_xaw=no)])
1995     if test $emacs_cv_xaw = yes; then
1996       AC_MSG_RESULT([yes; using Lucid toolkit])
1997       USE_X_TOOLKIT=LUCID
1998       LUCID_LIBW=-lXaw
1999     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2000       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2001     else
2002       AC_MSG_RESULT([no; do not use toolkit by default])
2003       USE_X_TOOLKIT=none
2004     fi
2005   fi
2006 fi
2007
2008 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2009
2010 LIBXTR6=
2011 if test "${USE_X_TOOLKIT}" != "none"; then
2012   AC_MSG_CHECKING(X11 toolkit version)
2013   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2014   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2015 [#if XtSpecificationRelease < 6
2016 fail;
2017 #endif
2018 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2019   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2020   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2021     AC_MSG_RESULT(6 or newer)
2022     AC_DEFINE(HAVE_X11XTR6, 1,
2023               [Define to 1 if you have the X11R6 or newer version of Xt.])
2024     LIBXTR6="-lSM -lICE"
2025     case "$opsys" in
2026       ## Use libw.a along with X11R6 Xt.
2027       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2028     esac
2029   else
2030     AC_MSG_RESULT(before 6)
2031   fi
2032
2033 dnl If using toolkit, check whether libXmu.a exists.
2034 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2035   OLDLIBS="$LIBS"
2036   if test x$HAVE_X11XTR6 = xyes; then
2037     LIBS="-lXt -lSM -lICE $LIBS"
2038   else
2039     LIBS="-lXt $LIBS"
2040   fi
2041   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2042   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2043 fi
2044 AC_SUBST(LIBXTR6)
2045
2046 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2047 dnl Why not just test for libxmu in the normal way?
2048 LIBXMU=-lXmu
2049 case "$machine" in
2050   ## These machines don't supply Xmu.
2051   hpux* | aix4-2 )
2052     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2053     ;;
2054 esac
2055 AC_SUBST(LIBXMU)
2056
2057 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2058 if test "${HAVE_X11}" = "yes"; then
2059   if test "${USE_X_TOOLKIT}" != "none"; then
2060     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2061   fi
2062 fi
2063
2064 LIBXP=
2065 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2066   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2067   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2068     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2069 int x = 5;
2070 #else
2071 Motif version prior to 2.1.
2072 #endif],
2073     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2074   if test $emacs_cv_motif_version_2_1 = yes; then
2075     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2076   else
2077     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2078     # We put this in CFLAGS temporarily to precede other -I options
2079     # that might be in CFLAGS temporarily.
2080     # We put this in CPPFLAGS where it precedes the other -I options.
2081     OLD_CPPFLAGS=$CPPFLAGS
2082     OLD_CFLAGS=$CFLAGS
2083     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2084     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2085     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2086       [int x = 5;],
2087       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2088     if test $emacs_cv_lesstif = yes; then
2089       # Make sure this -I option remains in CPPFLAGS after it is set
2090       # back to REAL_CPPFLAGS.
2091       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2092       # have those other -I options anyway.  Ultimately, having this
2093       # directory ultimately in CPPFLAGS will be enough.
2094       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2095       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2096     else
2097       CFLAGS=$OLD_CFLAGS
2098       CPPFLAGS=$OLD_CPPFLAGS
2099     fi
2100   fi
2101 fi
2102
2103 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2104 dnl using Motif or Xaw3d is available, and unless
2105 dnl --with-toolkit-scroll-bars=no was specified.
2106
2107 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2108             [Define to 1 if we should use toolkit scroll bars.])dnl
2109 USE_TOOLKIT_SCROLL_BARS=no
2110 if test "${with_toolkit_scroll_bars}" != "no"; then
2111   if test "${USE_X_TOOLKIT}" != "none"; then
2112     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2113       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2114       HAVE_XAW3D=no
2115       USE_TOOLKIT_SCROLL_BARS=yes
2116     elif test "${HAVE_XAW3D}" = "yes"; then
2117       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2118       USE_TOOLKIT_SCROLL_BARS=yes
2119     fi
2120   elif test "${HAVE_GTK}" = "yes"; then
2121     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2122     USE_TOOLKIT_SCROLL_BARS=yes
2123   elif test "${HAVE_NS}" = "yes"; then
2124     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2125     USE_TOOLKIT_SCROLL_BARS=yes
2126   fi
2127 fi
2128
2129 dnl See if XIM is available.
2130 AC_TRY_COMPILE([
2131           #include <X11/Xlib.h>
2132           #include <X11/Xresource.h>],
2133          [XIMProc  callback;],
2134          [HAVE_XIM=yes
2135          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2136          HAVE_XIM=no)
2137
2138 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2139
2140 if test "${with_xim}" != "no"; then
2141   AC_DEFINE(USE_XIM, 1,
2142             [Define to 1 if we should use XIM, if it is available.])
2143 fi
2144
2145
2146 if test "${HAVE_XIM}" != "no"; then
2147   late_CFLAGS=$CFLAGS
2148   if test "$GCC" = yes; then
2149     CFLAGS="$CFLAGS --pedantic-errors"
2150   fi
2151   AC_TRY_COMPILE([
2152 #include <X11/Xlib.h>
2153 #include <X11/Xresource.h>],
2154 [Display *display;
2155 XrmDatabase db;
2156 char *res_name;
2157 char *res_class;
2158 XIMProc  callback;
2159 XPointer *client_data;
2160 #ifndef __GNUC__
2161 /* If we're not using GCC, it's probably not XFree86, and this is
2162    probably right, but we can't use something like --pedantic-errors.  */
2163 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2164                                            char*, XIMProc, XPointer*);
2165 #endif
2166 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2167    client_data);],
2168     [emacs_cv_arg6_star=yes])
2169   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2170          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2171 either XPointer or XPointer*.])dnl
2172   if test "$emacs_cv_arg6_star" = yes; then
2173     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2174   else
2175     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2176   fi
2177   CFLAGS=$late_CFLAGS
2178 fi
2179
2180 ### Start of font-backend (under any platform) section.
2181 # (nothing here yet -- this is a placeholder)
2182 ### End of font-backend (under any platform) section.
2183
2184 ### Start of font-backend (under X11) section.
2185 if test "${HAVE_X11}" = "yes"; then
2186    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2187
2188    ## Use -lXft if available, unless `--with-xft=no'.
2189    HAVE_XFT=maybe
2190     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2191       with_xft="no";
2192     fi
2193     if test "x${with_xft}" != "xno"; then
2194
2195       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2196       ## Because xftfont.c uses XRenderQueryExtension, we also
2197       ## need to link to -lXrender.
2198       HAVE_XRENDER=no
2199       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2200       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2201         OLD_CPPFLAGS="$CPPFLAGS"
2202         OLD_CFLAGS="$CFLAGS"
2203         OLD_LIBS="$LIBS"
2204         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2205         CFLAGS="$CFLAGS $XFT_CFLAGS"
2206         XFT_LIBS="-lXrender $XFT_LIBS"
2207         LIBS="$XFT_LIBS $LIBS"
2208         AC_CHECK_HEADER(X11/Xft/Xft.h,
2209           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2210
2211         if test "${HAVE_XFT}" = "yes"; then
2212           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2213             AC_SUBST(XFT_LIBS)
2214           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2215         else
2216           CPPFLAGS="$OLD_CPPFLAGS"
2217           CFLAGS="$OLD_CFLAGS"
2218           LIBS="$OLD_LIBS"
2219         fi                        # "${HAVE_XFT}" = "yes"
2220       fi                          # "$HAVE_XFT" != no
2221     fi                            # "x${with_xft}" != "xno"
2222
2223     dnl For the "Does Emacs use" message at the end.
2224     if test "$HAVE_XFT" != "yes"; then
2225        HAVE_XFT=no
2226     fi
2227
2228
2229     HAVE_FREETYPE=no
2230     ## We used to allow building with FreeType and without Xft.
2231     ## However, the ftx font backend driver is not in good shape.
2232     if test "${HAVE_XFT}" = "yes"; then
2233       dnl As we use Xft, we anyway use freetype.
2234       dnl There's no need for additional CFLAGS and LIBS.
2235       HAVE_FREETYPE=yes
2236       FONTCONFIG_CFLAGS=
2237       FONTCONFIG_LIBS=
2238     fi
2239
2240     HAVE_LIBOTF=no
2241     if test "${HAVE_FREETYPE}" = "yes"; then
2242       AC_DEFINE(HAVE_FREETYPE, 1,
2243                 [Define to 1 if using the freetype and fontconfig libraries.])
2244       if test "${with_libotf}" != "no"; then
2245         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2246                           HAVE_LIBOTF=no)
2247         if test "$HAVE_LIBOTF" = "yes"; then
2248           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2249           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2250                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2251                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2252           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2253             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2254                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2255           fi
2256         fi
2257       fi
2258     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2259     dnl Does the new font backend require it, or can it work without it?
2260     fi
2261
2262     HAVE_M17N_FLT=no
2263     if test "${HAVE_LIBOTF}" = yes; then
2264       if test "${with_m17n_flt}" != "no"; then
2265         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2266         if test "$HAVE_M17N_FLT" = "yes"; then
2267           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2268         fi
2269       fi
2270     fi
2271 else
2272     HAVE_XFT=no
2273     HAVE_FREETYPE=no
2274     HAVE_LIBOTF=no
2275     HAVE_M17N_FLT=no
2276 fi
2277
2278 ### End of font-backend (under X11) section.
2279
2280 AC_SUBST(FREETYPE_CFLAGS)
2281 AC_SUBST(FREETYPE_LIBS)
2282 AC_SUBST(FONTCONFIG_CFLAGS)
2283 AC_SUBST(FONTCONFIG_LIBS)
2284 AC_SUBST(LIBOTF_CFLAGS)
2285 AC_SUBST(LIBOTF_LIBS)
2286 AC_SUBST(M17N_FLT_CFLAGS)
2287 AC_SUBST(M17N_FLT_LIBS)
2288
2289 ### Use -lXpm if available, unless `--with-xpm=no'.
2290 HAVE_XPM=no
2291 LIBXPM=
2292 if test "${HAVE_X11}" = "yes"; then
2293   if test "${with_xpm}" != "no"; then
2294     AC_CHECK_HEADER(X11/xpm.h,
2295       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2296     if test "${HAVE_XPM}" = "yes"; then
2297       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2298       AC_EGREP_CPP(no_return_alloc_pixels,
2299       [#include "X11/xpm.h"
2300 #ifndef XpmReturnAllocPixels
2301 no_return_alloc_pixels
2302 #endif
2303       ], HAVE_XPM=no, HAVE_XPM=yes)
2304
2305       if test "${HAVE_XPM}" = "yes"; then
2306         AC_MSG_RESULT(yes)
2307       else
2308         AC_MSG_RESULT(no)
2309       fi
2310     fi
2311   fi
2312
2313   if test "${HAVE_XPM}" = "yes"; then
2314     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2315     LIBXPM=-lXpm
2316   fi
2317 fi
2318 AC_SUBST(LIBXPM)
2319
2320 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2321 HAVE_JPEG=no
2322 LIBJPEG=
2323 if test "${HAVE_X11}" = "yes"; then
2324   if test "${with_jpeg}" != "no"; then
2325     dnl Checking for jpeglib.h can lose because of a redefinition of
2326     dnl  HAVE_STDLIB_H.
2327     AC_CHECK_HEADER(jerror.h,
2328       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2329   fi
2330
2331   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2332   if test "${HAVE_JPEG}" = "yes"; then
2333     AC_DEFINE(HAVE_JPEG)
2334     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2335         [#include <jpeglib.h>
2336          version=JPEG_LIB_VERSION
2337 ],
2338         [AC_DEFINE(HAVE_JPEG)],
2339         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2340         HAVE_JPEG=no])
2341   fi
2342   if test "${HAVE_JPEG}" = "yes"; then
2343     LIBJPEG=-ljpeg
2344   fi
2345 fi
2346 AC_SUBST(LIBJPEG)
2347
2348 ### Use -lpng if available, unless `--with-png=no'.
2349 HAVE_PNG=no
2350 LIBPNG=
2351 if test "${HAVE_X11}" = "yes"; then
2352   if test "${with_png}" != "no"; then
2353     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2354     # in /usr/include/libpng.
2355     AC_CHECK_HEADERS(png.h libpng/png.h)
2356     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2357       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2358     fi
2359   fi
2360
2361   if test "${HAVE_PNG}" = "yes"; then
2362     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2363     LIBPNG="-lpng -lz -lm"
2364   fi
2365 fi
2366 AC_SUBST(LIBPNG)
2367
2368 ### Use -ltiff if available, unless `--with-tiff=no'.
2369 HAVE_TIFF=no
2370 LIBTIFF=
2371 if test "${HAVE_X11}" = "yes"; then
2372   if test "${with_tiff}" != "no"; then
2373     AC_CHECK_HEADER(tiffio.h,
2374       [tifflibs="-lz -lm"
2375       # At least one tiff package requires the jpeg library.
2376       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2377       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2378   fi
2379
2380   if test "${HAVE_TIFF}" = "yes"; then
2381     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2382     dnl FIXME -lz -lm, as per libpng?
2383     LIBTIFF=-ltiff
2384   fi
2385 fi
2386 AC_SUBST(LIBTIFF)
2387
2388 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2389 HAVE_GIF=no
2390 LIBGIF=
2391 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2392   AC_CHECK_HEADER(gif_lib.h,
2393 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2394 # Earlier versions can crash Emacs.
2395     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2396
2397   if test "$HAVE_GIF" = yes; then
2398     LIBGIF=-lgif
2399   elif test "$HAVE_GIF" = maybe; then
2400 # If gif_lib.h but no libgif, try libungif.
2401     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2402     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2403   fi
2404
2405   if test "${HAVE_GIF}" = "yes"; then
2406     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2407   fi
2408 fi
2409 AC_SUBST(LIBGIF)
2410
2411 dnl Check for required libraries.
2412 if test "${HAVE_X11}" = "yes"; then
2413   MISSING=""
2414   WITH_NO=""
2415   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2416     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2417   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2418     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2419   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2420     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2421   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2422     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2423   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2424     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2425
2426   if test "X${MISSING}" != X; then
2427     AC_MSG_ERROR([The following required libraries were not found:
2428     $MISSING
2429 Maybe some development libraries/packages are missing?
2430 If you don't want to link with them give
2431     $WITH_NO
2432 as options to configure])
2433   fi
2434 fi
2435
2436 ### Use -lgpm if available, unless `--with-gpm=no'.
2437 HAVE_GPM=no
2438 LIBGPM=
2439 MOUSE_SUPPORT=
2440 if test "${with_gpm}" != "no"; then
2441   AC_CHECK_HEADER(gpm.h,
2442     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2443
2444   if test "${HAVE_GPM}" = "yes"; then
2445     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2446     LIBGPM=-lgpm
2447     ## May be reset below.
2448     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2449   fi
2450 fi
2451 AC_SUBST(LIBGPM)
2452
2453 dnl Check for malloc/malloc.h on darwin
2454 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2455
2456 C_SWITCH_X_SYSTEM=
2457 ### Use NeXTstep API to implement GUI.
2458 if test "${HAVE_NS}" = "yes"; then
2459   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2460   if test "${NS_IMPL_COCOA}" = "yes"; then
2461     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2462     GNU_OBJC_CFLAGS=
2463   fi
2464   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2465     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2466     # See also .m.o rule in Makefile.in */
2467     # FIXME: are all these flags really needed?  Document here why.  */
2468     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2469     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2470   fi
2471   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2472     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2473   fi
2474   # We also have mouse menus.
2475   HAVE_MENUS=yes
2476   OTHER_FILES=ns-app
2477 fi
2478
2479
2480 ### Use session management (-lSM -lICE) if available
2481 HAVE_X_SM=no
2482 LIBXSM=
2483 if test "${HAVE_X11}" = "yes"; then
2484   AC_CHECK_HEADER(X11/SM/SMlib.h,
2485     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2486
2487   if test "${HAVE_X_SM}" = "yes"; then
2488     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2489     LIBXSM="-lSM -lICE"
2490     case "$LIBS" in
2491       *-lSM*) ;;
2492       *)      LIBS="$LIBXSM $LIBS" ;;
2493     esac
2494   fi
2495 fi
2496 AC_SUBST(LIBXSM)
2497
2498 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2499 AC_CACHE_CHECK(whether netdb declares h_errno,
2500                emacs_cv_netdb_declares_h_errno,
2501 [AC_TRY_LINK([#include <netdb.h>],
2502   [return h_errno;],
2503   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2504 if test $emacs_cv_netdb_declares_h_errno = yes; then
2505   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2506 fi
2507
2508 AC_FUNC_ALLOCA
2509
2510 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2511 dnl FIXME is there an autoconf test that does the right thing, without
2512 dnl needing to call A_M_E afterwards?
2513 if test x"$ac_cv_func_alloca_works" != xyes; then
2514    AC_MSG_ERROR( [a system implementation of alloca is required] )
2515 fi
2516
2517 # fmod, logb, and frexp are found in -lm on most systems.
2518 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2519 AC_CHECK_LIB(m, sqrt)
2520
2521 # Check for mail-locking functions in a "mail" library.  Probably this should
2522 # have the same check as for liblockfile below.
2523 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2524 if test $have_mail = yes; then
2525   LIBS_MAIL=-lmail
2526   LIBS="$LIBS_MAIL $LIBS"
2527   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2528 else
2529   LIBS_MAIL=
2530 fi
2531 dnl Debian, at least:
2532 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2533 if test $have_lockfile = yes; then
2534    LIBS_MAIL=-llockfile
2535    LIBS="$LIBS_MAIL $LIBS"
2536    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2537 else
2538 # If we have the shared liblockfile, assume we must use it for mail
2539 # locking (e.g. Debian).  If we couldn't link against liblockfile
2540 # (no liblockfile.a installed), ensure that we don't need to.
2541   dnl This works for files generally, not just executables.
2542   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2543   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2544                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2545   if test $ac_cv_prog_liblockfile = yes; then
2546     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2547 This probably means that movemail could lose mail.
2548 There may be a `development' package to install containing liblockfile.])
2549   fi
2550 fi
2551 AC_CHECK_FUNCS(touchlock)
2552 AC_CHECK_HEADERS(maillock.h)
2553 AC_SUBST(LIBS_MAIL)
2554
2555 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2556 ## interlock access to the mail spool.  The alternative is a lock file named
2557 ## /usr/spool/mail/$USER.lock.
2558 mail_lock=no
2559 case "$opsys" in
2560   aix4-2) mail_lock="lockf" ;;
2561
2562   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2563
2564   ## On GNU/Linux systems, both methods are used by various mail programs.
2565   ## I assume most people are using newer mailers that have heard of flock.
2566   ## Change this if you need to.
2567   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2568   ## configure gets the right answers, and that means *NOT* using flock.
2569   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2570   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2571   ## Debian maintainer hasn't provided a clean fix for Emacs.
2572   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2573   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2574   ## correct logic.  -- fx
2575   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2576   ## liblockfile is a Free Software replacement for libmail, used on
2577   ## Debian systems and elsewhere. -rfr.
2578   gnu-*)
2579     mail_lock="flock"
2580     if test $have_mail = yes || test $have_lockfile = yes; then
2581       test $ac_cv_header_maillock_h = yes && mail_lock=no
2582     fi
2583     ;;
2584 esac
2585
2586 BLESSMAIL_TARGET=
2587 case "$mail_lock" in
2588   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2589
2590   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2591
2592   *) BLESSMAIL_TARGET="need-blessmail" ;;
2593 esac
2594 AC_SUBST(BLESSMAIL_TARGET)
2595
2596
2597 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2598 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2599 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2600 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2601 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2602 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2603 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2604 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2605 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2606 cfmakeraw cfsetspeed isnan copysign)
2607
2608 AC_CHECK_HEADERS(sys/un.h)
2609
2610 AC_FUNC_MKTIME
2611 if test "$ac_cv_func_working_mktime" = no; then
2612   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2613 fi
2614
2615 AC_FUNC_GETLOADAVG
2616
2617 AC_FUNC_FSEEKO
2618
2619 # Configure getopt.
2620 m4_include([m4/getopt.m4])
2621 gl_GETOPT_IFELSE([
2622   gl_GETOPT_SUBSTITUTE_HEADER
2623   gl_PREREQ_GETOPT
2624   GETOPTOBJS='getopt.o getopt1.o'
2625 ])
2626 AC_SUBST(GETOPTOBJS)
2627
2628 AC_FUNC_GETPGRP
2629
2630 AC_FUNC_STRFTIME
2631
2632 # UNIX98 PTYs.
2633 AC_CHECK_FUNCS(grantpt)
2634
2635 # PTY-related GNU extensions.
2636 AC_CHECK_FUNCS(getpt)
2637
2638 # Check this now, so that we will NOT find the above functions in ncurses.
2639 # That is because we have not set up to link ncurses in lib-src.
2640 # It's better to believe a function is not available
2641 # than to expect to find it in ncurses.
2642 # Also we need tputs and friends to be able to build at all.
2643 have_tputs_et_al=true
2644 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2645 if test "$have_tputs_et_al" != true; then
2646   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2647 Maybe some development libraries/packages are missing?  Try installing
2648 libncurses-dev(el), libterminfo-dev(el) or similar.])
2649 fi
2650 # Must define this when any termcap library is found.
2651 AC_DEFINE(HAVE_LIBNCURSES, 1,
2652           [Define to 1 if you have the `ncurses' library (-lncurses).])
2653 ## FIXME This was the cpp logic, but I am not sure it is right.
2654 ## The above test has not necessarily found libncurses.
2655 HAVE_LIBNCURSES=yes
2656
2657 ## Use terminfo instead of termcap?
2658 ## Note only system files NOT using terminfo are:
2659 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2660 ## darwin|gnu without ncurses.
2661 TERMINFO=no
2662 LIBS_TERMCAP=
2663 case "$opsys" in
2664   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2665   ## hpux10-20: Use the system provided termcap(3) library.
2666   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2667   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2668   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2669
2670   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2671   ##  The ncurses library has been moved out of the System framework in
2672   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2673   ##  option to use it.
2674   darwin|gnu*)
2675     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2676     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2677       TERMINFO=yes
2678       LIBS_TERMCAP="-lncurses"
2679     fi
2680     ;;
2681
2682   freebsd)
2683     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2684     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2685     [AC_TRY_LINK([#include <osreldate.h>],
2686 [#if __FreeBSD_version < 400000
2687 fail;
2688 #endif
2689 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2690
2691     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2692
2693     if test $emacs_cv_freebsd_terminfo = yes; then
2694       TERMINFO=yes
2695       LIBS_TERMCAP="-lncurses"
2696     else
2697       LIBS_TERMCAP="-ltermcap"
2698     fi
2699     ;;
2700
2701   netbsd)
2702     if test $ac_cv_search_tputs = -lterminfo; then
2703       TERMINFO=yes
2704       LIBS_TERMCAP="-lterminfo"
2705     else
2706       LIBS_TERMCAP="-ltermcap"
2707     fi
2708     ;;
2709
2710 esac
2711
2712 case "$opsys" in
2713   ## hpux: Make sure we get select from libc rather than from libcurses
2714   ##  because libcurses on HPUX 10.10 has a broken version of select.
2715   ##  We used to use -lc -lcurses, but this may be cleaner.
2716   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2717
2718   openbsd) LIBS_TERMCAP="-lncurses" ;;
2719
2720   ## Must use system termcap, if we use any termcap.  It does special things.
2721   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2722 esac
2723
2724 TERMCAP_OBJ=tparam.o
2725 if test $TERMINFO = yes; then
2726   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2727
2728   ## Default used to be -ltermcap.  Add a case above if need something else.
2729   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2730
2731   TERMCAP_OBJ=terminfo.o
2732 fi
2733 AC_SUBST(LIBS_TERMCAP)
2734 AC_SUBST(TERMCAP_OBJ)
2735
2736
2737 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2738 resolv=no
2739 AC_TRY_LINK([#include <netinet/in.h>
2740 #include <arpa/nameser.h>
2741 #include <resolv.h>],
2742     [return res_init();],
2743     have_res_init=yes, have_res_init=no)
2744 if test "$have_res_init" = no; then
2745   OLIBS="$LIBS"
2746   LIBS="$LIBS -lresolv"
2747   AC_MSG_CHECKING(for res_init with -lresolv)
2748   AC_TRY_LINK([#include <netinet/in.h>
2749 #include <arpa/nameser.h>
2750 #include <resolv.h>],
2751     [return res_init();],
2752     have_res_init=yes, have_res_init=no)
2753   AC_MSG_RESULT($have_res_init)
2754   if test "$have_res_init" = yes ; then
2755     resolv=yes
2756   fi
2757   LIBS="$OLIBS"
2758 fi
2759
2760 if test "$have_res_init" = yes; then
2761   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2762 fi
2763
2764 # Do we need the Hesiod library to provide the support routines?
2765 LIBHESIOD=
2766 if test "$with_hesiod" != no ; then
2767   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2768   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2769      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2770                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2771   if test "$resolv" = yes ; then
2772     RESOLVLIB=-lresolv
2773   else
2774     RESOLVLIB=
2775   fi
2776   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2777         hesiod=yes, :, $RESOLVLIB)])
2778
2779   if test x"$hesiod" = xyes; then
2780     AC_DEFINE(HAVE_LIBHESIOD, 1,
2781               [Define to 1 if you have the hesiod library (-lhesiod).])
2782     LIBHESIOD=-lhesiod
2783   fi
2784 fi
2785 AC_SUBST(LIBHESIOD)
2786
2787 # Do we need libresolv (due to res_init or Hesiod)?
2788 if test "$resolv" = yes ; then
2789   AC_DEFINE(HAVE_LIBRESOLV, 1,
2790             [Define to 1 if you have the resolv library (-lresolv).])
2791   LIBRESOLV=-lresolv
2792 else
2793   LIBRESOLV=
2794 fi
2795 AC_SUBST(LIBRESOLV)
2796
2797 # These tell us which Kerberos-related libraries to use.
2798 COM_ERRLIB=
2799 CRYPTOLIB=
2800 KRB5LIB=
2801 DESLIB=
2802 KRB4LIB=
2803
2804 if test "${with_kerberos}" != no; then
2805   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2806   if test $have_com_err = yes; then
2807     COM_ERRLIB=-lcom_err
2808     LIBS="$COM_ERRLIB $LIBS"
2809     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2810   fi
2811   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2812   if test $have_crypto = yes; then
2813     CRYPTOLIB=-lcrypto
2814     LIBS="$CRYPTOLIB $LIBS"
2815     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2816   fi
2817   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2818   if test $have_k5crypto = yes; then
2819     CRYPTOLIB=-lk5crypto
2820     LIBS="$CRYPTOLIB $LIBS"
2821     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2822   fi
2823   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2824   if test $have_krb5=yes; then
2825     KRB5LIB=-lkrb5
2826     LIBS="$KRB5LIB $LIBS"
2827     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2828   fi
2829   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2830   if test "${with_kerberos5}" = no; then
2831     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2832     if test $have_des425 = yes; then
2833       DESLIB=-ldes425
2834       LIBS="$DESLIB $LIBS"
2835       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2836     else
2837       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2838       if test $have_des = yes; then
2839         DESLIB=-ldes
2840         LIBS="$DESLIB $LIBS"
2841         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2842       fi
2843     fi
2844     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2845     if test $have_krb4 = yes; then
2846       KRB4LIB=-lkrb4
2847       LIBS="$KRB4LIB $LIBS"
2848       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2849     else
2850       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2851       if test $have_krb = yes; then
2852         KRB4LIB=-lkrb
2853         LIBS="$KRB4LIB $LIBS"
2854         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2855       fi
2856     fi
2857   fi
2858
2859   if test "${with_kerberos5}" != no; then
2860     AC_CHECK_HEADERS(krb5.h,
2861       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2862                         [#include <krb5.h>])])
2863   else
2864     AC_CHECK_HEADERS(des.h,,
2865                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2866                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2867     AC_CHECK_HEADERS(krb.h,,
2868                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2869                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2870   fi
2871   AC_CHECK_HEADERS(com_err.h)
2872 fi
2873
2874 AC_SUBST(COM_ERRLIB)
2875 AC_SUBST(CRYPTOLIB)
2876 AC_SUBST(KRB5LIB)
2877 AC_SUBST(DESLIB)
2878 AC_SUBST(KRB4LIB)
2879
2880 # Solaris requires -lintl if you want strerror (which calls dgettext)
2881 # to return localized messages.
2882 AC_CHECK_LIB(intl, dgettext)
2883
2884 AC_MSG_CHECKING(whether localtime caches TZ)
2885 AC_CACHE_VAL(emacs_cv_localtime_cache,
2886 [if test x$ac_cv_func_tzset = xyes; then
2887 AC_TRY_RUN([#include <time.h>
2888 extern char **environ;
2889 unset_TZ ()
2890 {
2891   char **from, **to;
2892   for (to = from = environ; (*to = *from); from++)
2893     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2894       to++;
2895 }
2896 char TZ_GMT0[] = "TZ=GMT0";
2897 char TZ_PST8[] = "TZ=PST8";
2898 main()
2899 {
2900   time_t now = time ((time_t *) 0);
2901   int hour_GMT0, hour_unset;
2902   if (putenv (TZ_GMT0) != 0)
2903     exit (1);
2904   hour_GMT0 = localtime (&now)->tm_hour;
2905   unset_TZ ();
2906   hour_unset = localtime (&now)->tm_hour;
2907   if (putenv (TZ_PST8) != 0)
2908     exit (1);
2909   if (localtime (&now)->tm_hour == hour_GMT0)
2910     exit (1);
2911   unset_TZ ();
2912   if (localtime (&now)->tm_hour != hour_unset)
2913     exit (1);
2914   exit (0);
2915 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2916 [# If we have tzset, assume the worst when cross-compiling.
2917 emacs_cv_localtime_cache=yes])
2918 else
2919         # If we lack tzset, report that localtime does not cache TZ,
2920         # since we can't invalidate the cache if we don't have tzset.
2921         emacs_cv_localtime_cache=no
2922 fi])dnl
2923 AC_MSG_RESULT($emacs_cv_localtime_cache)
2924 if test $emacs_cv_localtime_cache = yes; then
2925   AC_DEFINE(LOCALTIME_CACHE, 1,
2926             [Define to 1 if localtime caches TZ.])
2927 fi
2928
2929 if test "x$HAVE_TIMEVAL" = xyes; then
2930   AC_CHECK_FUNCS(gettimeofday)
2931   if test $ac_cv_func_gettimeofday = yes; then
2932     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2933                    emacs_cv_gettimeofday_two_arguments,
2934     [AC_TRY_COMPILE([
2935 #ifdef TIME_WITH_SYS_TIME
2936 #include <sys/time.h>
2937 #include <time.h>
2938 #else
2939 #ifdef HAVE_SYS_TIME_H
2940 #include <sys/time.h>
2941 #else
2942 #include <time.h>
2943 #endif
2944 #endif],
2945       [struct timeval time;
2946        gettimeofday (&time, 0);],
2947       emacs_cv_gettimeofday_two_arguments=yes,
2948       emacs_cv_gettimeofday_two_arguments=no)])
2949     if test $emacs_cv_gettimeofday_two_arguments = no; then
2950       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2951                 [Define to 1 if gettimeofday accepts only one argument.])
2952     fi
2953   fi
2954 fi
2955
2956 ok_so_far=yes
2957 AC_CHECK_FUNC(socket, , ok_so_far=no)
2958 if test $ok_so_far = yes; then
2959   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2960 fi
2961 if test $ok_so_far = yes; then
2962   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2963 fi
2964 if test $ok_so_far = yes; then
2965 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2966   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2967             [Define to 1 if you have inet sockets.])
2968 fi
2969
2970 AC_CHECK_HEADERS(sys/ioctl.h)
2971
2972 if test -f /usr/lpp/X11/bin/smt.exp; then
2973   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2974             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2975 fi
2976
2977 AC_MSG_CHECKING(whether system supports dynamic ptys)
2978 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2979   AC_MSG_RESULT(yes)
2980   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2981 else
2982   AC_MSG_RESULT(no)
2983 fi
2984
2985 AC_FUNC_FORK
2986
2987 dnl Adapted from Haible's version.
2988 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2989   [AC_TRY_LINK([#include <langinfo.h>],
2990     [char* cs = nl_langinfo(CODESET);],
2991     emacs_cv_langinfo_codeset=yes,
2992     emacs_cv_langinfo_codeset=no)
2993   ])
2994 if test $emacs_cv_langinfo_codeset = yes; then
2995   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2996     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2997 fi
2998
2999 AC_CHECK_TYPES(size_t)
3000
3001 AC_TYPE_MBSTATE_T
3002
3003 dnl Restrict could probably be used effectively other than in regex.c.
3004 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3005   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3006                   emacs_cv_c_restrict=yes,
3007                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3008                                   emacs_cv_c_restrict=__restrict,
3009                                   emacs_cv_c_restrict=no)])])
3010 case "$emacs_cv_c_restrict" in
3011   yes) emacs_restrict=restrict;;
3012   no) emacs_restrict="";;
3013   *) emacs_restrict="$emacs_cv_c_restrict";;
3014 esac
3015 if test "$emacs_restrict" != __restrict; then
3016   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3017     [Define to compiler's equivalent of C99 restrict keyword.
3018      Don't define if equivalent is `__restrict'.])
3019 fi
3020
3021 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3022   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3023                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3024 if test "$emacs_cv_c_restrict_arr" = yes; then
3025   AC_DEFINE(__restrict_arr, __restrict,
3026     [Define to compiler's equivalent of C99 restrict keyword in array
3027      declarations.  Define as empty for no equivalent.])
3028 fi
3029
3030 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3031 dnl how the tty code is related to POSIX and/or other versions of termios.
3032 dnl The following looks like a useful start.
3033 dnl
3034 dnl AC_SYS_POSIX_TERMIOS
3035 dnl if test $ac_cv_sys_posix_termios = yes; then
3036 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3037 dnl                                and macros for terminal control.])
3038 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3039 dnl fi
3040
3041 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3042
3043 # Set up the CFLAGS for real compilation, so we can substitute it.
3044 CFLAGS="$REAL_CFLAGS"
3045 CPPFLAGS="$REAL_CPPFLAGS"
3046
3047 ## Hack to detect a buggy GCC version.
3048 if test "x$GCC" = xyes \
3049    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3050    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3051    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3052    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3053 fi
3054
3055 #### Find out which version of Emacs this is.
3056 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3057          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3058 if test x"${version}" = x; then
3059   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3060 fi
3061 if test x"${version}" != x"$PACKAGE_VERSION"; then
3062   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3063 fi
3064
3065 ### Specify what sort of things we'll be editing into Makefile and config.h.
3066 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3067 AC_SUBST(version)
3068 AC_SUBST(configuration)
3069 ## Unused?
3070 AC_SUBST(canonical)
3071 AC_SUBST(srcdir)
3072 AC_SUBST(prefix)
3073 AC_SUBST(exec_prefix)
3074 AC_SUBST(bindir)
3075 AC_SUBST(datadir)
3076 AC_SUBST(sharedstatedir)
3077 AC_SUBST(libexecdir)
3078 AC_SUBST(mandir)
3079 AC_SUBST(infodir)
3080 AC_SUBST(lispdir)
3081 AC_SUBST(locallisppath)
3082 AC_SUBST(lisppath)
3083 AC_SUBST(x_default_search_path)
3084 AC_SUBST(etcdir)
3085 AC_SUBST(archlibdir)
3086 AC_SUBST(docdir)
3087 AC_SUBST(bitmapdir)
3088 AC_SUBST(gamedir)
3089 AC_SUBST(gameuser)
3090 AC_SUBST(unexec)
3091 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3092 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3093 ## end of LIBX_BASE, but nothing ever set it.
3094 AC_SUBST(LD_SWITCH_X_SITE)
3095 AC_SUBST(C_SWITCH_X_SITE)
3096 AC_SUBST(C_SWITCH_X_SYSTEM)
3097 AC_SUBST(CFLAGS)
3098 ## Used in lwlib/Makefile.in.
3099 AC_SUBST(X_TOOLKIT_TYPE)
3100 AC_SUBST(machfile)
3101 AC_SUBST(opsysfile)
3102 AC_SUBST(GETLOADAVG_LIBS)
3103 AC_SUBST(ns_appdir)
3104 AC_SUBST(ns_appbindir)
3105 AC_SUBST(ns_appresdir)
3106 AC_SUBST(ns_appsrc)
3107 AC_SUBST(GNU_OBJC_CFLAGS)
3108 AC_SUBST(OTHER_FILES)
3109
3110 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3111                    [Define to the canonical Emacs configuration name.])
3112 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3113                    [Define to the options passed to configure.])
3114 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3115                    [Define to the used machine dependent file.])
3116 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3117                    [Define to the used os dependent file.])
3118
3119 XMENU_OBJ=
3120 XOBJ=
3121 FONT_OBJ=
3122 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3123   AC_DEFINE(HAVE_X_WINDOWS, 1,
3124             [Define to 1 if you want to use the X window system.])
3125   XMENU_OBJ=xmenu.o
3126   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3127   FONT_OBJ=xfont.o
3128   if test "$HAVE_XFT" = "yes"; then
3129     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3130   elif test "$HAVE_FREETYPE" = "yes"; then
3131     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3132   fi
3133   AC_SUBST(FONT_OBJ)
3134 fi
3135 AC_SUBST(XMENU_OBJ)
3136 AC_SUBST(XOBJ)
3137 AC_SUBST(FONT_OBJ)
3138
3139 WIDGET_OBJ=
3140 MOTIF_LIBW=
3141 if test "${USE_X_TOOLKIT}" != "none" ; then
3142   WIDGET_OBJ=widget.o
3143   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3144   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3145     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3146   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3147     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3148     MOTIF_LIBW=-lXm
3149     case "$opsys" in
3150       gnu-linux)
3151         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3152         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3153         ;;
3154
3155       unixware)
3156         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3157         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3158         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3159         ;;
3160
3161       aix4-2)
3162         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3163         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3164         ;;
3165     esac
3166     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3167   fi
3168 fi
3169 AC_SUBST(WIDGET_OBJ)
3170
3171 TOOLKIT_LIBW=
3172 case "$USE_X_TOOLKIT" in
3173   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3174   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3175   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3176 esac
3177 AC_SUBST(TOOLKIT_LIBW)
3178
3179 if test "$USE_X_TOOLKIT" = "none"; then
3180   LIBXT_OTHER="\$(LIBXSM)"
3181   OLDXMENU_TARGET="really-oldXMenu"
3182 else
3183   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3184   OLDXMENU_TARGET="really-lwlib"
3185 fi
3186 AC_SUBST(LIBXT_OTHER)
3187
3188 ## The X Menu stuff is present in the X10 distribution, but missing
3189 ## from X11.  If we have X10, just use the installed library;
3190 ## otherwise, use our own copy.
3191 if test "${HAVE_X11}" = "yes" ; then
3192   AC_DEFINE(HAVE_X11, 1,
3193             [Define to 1 if you want to use version 11 of X windows.
3194              Otherwise, Emacs expects to use version 10.])
3195
3196   if test "$USE_X_TOOLKIT" = "none"; then
3197     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3198   else
3199     OLDXMENU="\${lwlibdir}liblw.a"
3200   fi
3201   LIBXMENU="\$(OLDXMENU)"
3202   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3203   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3204 else
3205   ## For a syntactically valid Makefile; not actually used for anything.
3206   ## See comments in src/Makefile.in.
3207   OLDXMENU=nothing
3208   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3209   if test "${HAVE_X_WINDOWS}" = "yes"; then
3210     LIBXMENU="-lXMenu"
3211   else
3212     LIBXMENU=
3213   fi
3214   LIBX_OTHER=
3215   OLDXMENU_DEPS=
3216 fi
3217
3218 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3219   OLDXMENU_TARGET=
3220   OLDXMENU=nothing
3221   LIBXMENU=
3222   OLDXMENU_DEPS=
3223 fi
3224
3225 AC_SUBST(OLDXMENU_TARGET)
3226 AC_SUBST(OLDXMENU)
3227 AC_SUBST(LIBXMENU)
3228 AC_SUBST(LIBX_OTHER)
3229 AC_SUBST(OLDXMENU_DEPS)
3230
3231 if test "${HAVE_MENUS}" = "yes" ; then
3232   AC_DEFINE(HAVE_MENUS, 1,
3233             [Define to 1 if you have mouse menus.
3234              (This is automatic if you use X, but the option to specify it remains.)
3235              It is also defined with other window systems that support xmenu.c.])
3236 fi
3237
3238 if test "${GNU_MALLOC}" = "yes" ; then
3239   AC_DEFINE(GNU_MALLOC, 1,
3240             [Define to 1 if you want to use the GNU memory allocator.])
3241 fi
3242
3243 RALLOC_OBJ=
3244 if test "${REL_ALLOC}" = "yes" ; then
3245   AC_DEFINE(REL_ALLOC, 1,
3246             [Define REL_ALLOC if you want to use the relocating allocator for
3247              buffer space.])
3248
3249   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3250 fi
3251 AC_SUBST(RALLOC_OBJ)
3252
3253 if test "$opsys" = "cygwin"; then
3254   CYGWIN_OBJ="sheap.o"
3255   ## Cygwin differs because of its unexec().
3256   PRE_ALLOC_OBJ=
3257   POST_ALLOC_OBJ=lastfile.o
3258 else
3259   CYGWIN_OBJ=
3260   PRE_ALLOC_OBJ=lastfile.o
3261   POST_ALLOC_OBJ=
3262 fi
3263 AC_SUBST(CYGWIN_OBJ)
3264 AC_SUBST(PRE_ALLOC_OBJ)
3265 AC_SUBST(POST_ALLOC_OBJ)
3266
3267
3268 case "$opsys" in
3269   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3270
3271   darwin)
3272   ## The -headerpad option tells ld (see man page) to leave room at the
3273   ## end of the header for adding load commands.  Needed for dumping.
3274   ## 0x690 is the total size of 30 segment load commands (at 56
3275   ## each); under Cocoa 31 commands are required.
3276   if test "$HAVE_NS" = "yes"; then
3277     libs_nsgui="-framework AppKit"
3278     headerpad_extra=6C8
3279   else
3280     libs_nsgui=
3281     headerpad_extra=690
3282   fi
3283   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3284   ;;
3285
3286   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3287 esac
3288 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3289
3290
3291 ## This exists because src/Makefile.in did some extra fiddling around
3292 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3293 ##   #ifndef LD_SWITCH_SYSTEM
3294 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3295 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3296 ## not using gcc, darwin system not on an alpha (ie darwin, since
3297 ## darwin + alpha does not occur).
3298 ## Note that unlike L_S_S, this is not used in ac_link.
3299 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3300    test "$opsys" = "darwin"; then
3301   LD_SWITCH_SYSTEM_EXTRA="-X"
3302 else
3303   LD_SWITCH_SYSTEM_EXTRA=
3304 fi
3305 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3306
3307
3308 LINKER=
3309 ORDINARY_LINK=
3310 case "$opsys" in
3311   ## gnu: GNU needs its own crt0.
3312   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3313
3314   cygwin) LINKER="\$(CC)" ;;
3315
3316   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3317   ## library search parth, i.e. it won't search /usr/lib for libc and
3318   ## friends.  Using -nostartfiles instead avoids this problem, and
3319   ## will also work on earlier NetBSD releases.
3320   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3321
3322   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3323   ##   MkLinux/LinuxPPC needs this.
3324   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3325   gnu-*)
3326     case "$machine" in
3327       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3328     esac
3329     ;;
3330 esac
3331
3332 ## A macro which other sections of Makefile can redefine to munge the
3333 ## flags before they are passed to LD.  This is helpful if you have
3334 ## redefined LD to something odd, like "gcc".
3335 ## (The YMF prefix is a holdover from the old name "ymakefile".)
3336 YMF_PASS_LDFLAGS=flags
3337 if test "x$ORDINARY_LINK" = "xyes"; then
3338
3339   LINKER="\$(CC)"
3340   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3341
3342 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3343 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3344 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3345
3346   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3347   ## places that are difficult to figure out at make time.  Fortunately,
3348   ## these same versions allow you to pass arbitrary flags on to the
3349   ## linker, so there is no reason not to use it as a linker.
3350   ##
3351   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3352   ## searching for libraries in its internal directories, so we have to
3353   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3354   LINKER="\$(CC) -nostdlib"
3355   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3356   ## See prefix-args.c for an explanation of why we do not do this with the
3357   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3358   ## their paths, so we must use ./prefix-args.
3359   ## TODO either make prefix-args check ORDINARY_LINK internally,
3360   ## or remove it altogether (bug#6184), removing the need for this macro.
3361   YMF_PASS_LDFLAGS='`./prefix-args -Xlinker flags`'
3362 fi
3363 AC_SUBST(YMF_PASS_LDFLAGS)
3364
3365 test "x$LINKER" = "x" && LINKER=ld
3366 ## FIXME? What setting of YMF_PASS_LDFLAGS should this have?
3367 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3368
3369 AC_SUBST(LINKER)
3370
3371
3372 ## FIXME? The logic here is not precisely the same as that above
3373 ## setting YMF_PASS_LDFLAGS.  There is no check here for a pre-defined
3374 ## LINKER.  Should we only be setting LIB_GCC if LD ~ -nostdlib?
3375 LIB_GCC=
3376 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3377
3378   case "$opsys" in
3379     ## cygwin: don't link against static libgcc.
3380     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3381
3382     gnu-*)
3383       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3384       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3385       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3386       if test "$machine" = "arm"; then
3387         LIB_GCC="-lgcc_s"
3388       else
3389         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3390         ## immediately undefine it again and redefine it to empty.
3391         ## Was the C_SWITCH_X_SITE part really necessary?
3392 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3393         LIB_GCC=
3394       fi
3395       ;;
3396
3397     ## Ask GCC where to find libgcc.a.
3398     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3399   esac
3400 fi                              dnl if $GCC
3401 AC_SUBST(LIB_GCC)
3402
3403
3404 TOOLTIP_SUPPORT=
3405 WINDOW_SUPPORT=
3406 ## If we're using X11/GNUstep, define some consequences.
3407 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3408   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3409   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3410   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3411   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3412
3413   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3414   test "$HAVE_X_WINDOWS" = "yes" && \
3415     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3416
3417 fi
3418 AC_SUBST(MOUSE_SUPPORT)
3419 AC_SUBST(TOOLTIP_SUPPORT)
3420 AC_SUBST(WINDOW_SUPPORT)
3421
3422
3423 AH_TOP([/* GNU Emacs site configuration template file.
3424    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3425      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3426
3427 This file is part of GNU Emacs.
3428
3429 GNU Emacs is free software: you can redistribute it and/or modify
3430 it under the terms of the GNU General Public License as published by
3431 the Free Software Foundation, either version 3 of the License, or
3432 (at your option) any later version.
3433
3434 GNU Emacs is distributed in the hope that it will be useful,
3435 but WITHOUT ANY WARRANTY; without even the implied warranty of
3436 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3437 GNU General Public License for more details.
3438
3439 You should have received a copy of the GNU General Public License
3440 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3441
3442
3443 /* No code in Emacs #includes config.h twice, but some bits of code
3444    intended to work with other packages as well (like gmalloc.c)
3445    think they can include it as many times as they like.  */
3446 #ifndef EMACS_CONFIG_H
3447 #define EMACS_CONFIG_H
3448 ])dnl
3449
3450 AH_BOTTOM([
3451 /* Define AMPERSAND_FULL_NAME if you use the convention
3452    that & in the full name stands for the login id.  */
3453 /* Turned on June 1996 supposing nobody will mind it.  */
3454 #define AMPERSAND_FULL_NAME
3455
3456 /* Define HAVE_SOUND if we have sound support.  We know it works
3457    and compiles only on the specified platforms.   For others,
3458    it probably doesn't make sense to try.  */
3459
3460 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3461 #ifdef HAVE_MACHINE_SOUNDCARD_H
3462 #define HAVE_SOUND 1
3463 #endif
3464 #ifdef HAVE_SYS_SOUNDCARD_H
3465 #define HAVE_SOUND 1
3466 #endif
3467 #ifdef HAVE_SOUNDCARD_H
3468 #define HAVE_SOUND 1
3469 #endif
3470 #ifdef HAVE_ALSA
3471 #define HAVE_SOUND 1
3472 #endif
3473 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3474
3475 /* If using GNU, then support inline function declarations.  */
3476 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3477    generally, because even if non-gcc compilers accept `inline', they
3478    may reject `extern inline'.  */
3479 #if defined (__GNUC__) && defined (OPTIMIZE)
3480 #define INLINE __inline__
3481 #else
3482 #define INLINE
3483 #endif
3484
3485 /* `subprocesses' should be defined if you want to
3486    have code for asynchronous subprocesses
3487    (as used in M-x compile and M-x shell).
3488    Only MSDOS does not support this (it overrides
3489    this in its config_opsysfile below).  */
3490
3491 #define subprocesses
3492
3493 /* Include the os and machine dependent files.  */
3494 #include config_opsysfile
3495 #include config_machfile
3496
3497 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3498   (There is probably a better place to do this, but right now the Cocoa
3499    side does this in s/darwin.h and we cannot
3500    parallel this exactly since GNUstep is multi-OS.  */
3501 #ifdef HAVE_NS
3502 # ifdef NS_IMPL_GNUSTEP
3503 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3504 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3505 #  define SYSTEM_PURESIZE_EXTRA 30000
3506 # endif /* NS_IMPL_GNUSTEP */
3507 #endif /* HAVE_NS */
3508
3509 /* SIGTYPE is the macro we actually use.  */
3510 #ifndef SIGTYPE
3511 #define SIGTYPE RETSIGTYPE
3512 #endif
3513
3514 #ifdef emacs /* Don't do this for lib-src.  */
3515 /* Tell regex.c to use a type compatible with Emacs.  */
3516 #define RE_TRANSLATE_TYPE Lisp_Object
3517 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3518 #ifdef make_number
3519 /* If make_number is a macro, use it.  */
3520 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3521 #else
3522 /* If make_number is a function, avoid it.  */
3523 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3524 #endif
3525 #endif
3526
3527 /* Avoid link-time collision with system mktime if we will use our own.  */
3528 #if ! HAVE_MKTIME || BROKEN_MKTIME
3529 #define mktime emacs_mktime
3530 #endif
3531
3532 #define my_strftime nstrftime   /* for strftime.c */
3533
3534 /* The rest of the code currently tests the CPP symbol BSTRING.
3535    Override any claims made by the system-description files.
3536    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3537 #undef BSTRING
3538 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3539 #define BSTRING
3540 #endif
3541
3542 /* Some of the files of Emacs which are intended for use with other
3543    programs assume that if you have a config.h file, you must declare
3544    the type of getenv.
3545
3546    This declaration shouldn't appear when alloca.s or Makefile.in
3547    includes config.h.  */
3548 #ifndef NOT_C_CODE
3549 extern char *getenv ();
3550 #endif
3551
3552 /* These default definitions are good for almost all machines.
3553    The exceptions override them in m/MACHINE.h.  */
3554
3555 #ifndef BITS_PER_CHAR
3556 #define BITS_PER_CHAR 8
3557 #endif
3558
3559 #ifndef BITS_PER_SHORT
3560 #define BITS_PER_SHORT 16
3561 #endif
3562
3563 /* Note that lisp.h uses this in a preprocessor conditional, so it
3564    would not work to use sizeof.  That being so, we do all of them
3565    without sizeof, for uniformity's sake.  */
3566 #ifndef BITS_PER_INT
3567 #define BITS_PER_INT 32
3568 #endif
3569
3570 #ifndef BITS_PER_LONG
3571 #ifdef _LP64
3572 #define BITS_PER_LONG 64
3573 #else
3574 #define BITS_PER_LONG 32
3575 #endif
3576 #endif
3577
3578 /* Define if the compiler supports function prototypes.  It may do so
3579    but not define __STDC__ (e.g. DEC C by default) or may define it as
3580    zero.  */
3581 #undef PROTOTYPES
3582 /* For mktime.c:  */
3583 #ifndef __P
3584 # if defined PROTOTYPES
3585 #  define __P(args) args
3586 # else
3587 #  define __P(args) ()
3588 # endif  /* GCC.  */
3589 #endif /* __P */
3590
3591 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3592 #ifndef NOT_C_CODE
3593 #ifdef HAVE_STRING_H
3594 #include "string.h"
3595 #endif
3596 #ifdef HAVE_STRINGS_H
3597 #include "strings.h"  /* May be needed for bcopy & al.  */
3598 #endif
3599 #ifdef HAVE_STDLIB_H
3600 #include <stdlib.h>
3601 #endif
3602 #ifndef __GNUC__
3603 # ifdef HAVE_ALLOCA_H
3604 #  include <alloca.h>
3605 # else /* AIX files deal with #pragma.  */
3606 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3607 char *alloca ();
3608 #  endif
3609 # endif /* HAVE_ALLOCA_H */
3610 #endif /* __GNUC__ */
3611 #ifndef HAVE_SIZE_T
3612 typedef unsigned size_t;
3613 #endif
3614 #endif /* NOT_C_CODE */
3615
3616 /* Define HAVE_X_I18N if we have usable i18n support.  */
3617
3618 #ifdef HAVE_X11R6
3619 #define HAVE_X_I18N
3620 #endif
3621
3622 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3623
3624 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3625 #define HAVE_X11R6_XIM
3626 #endif
3627
3628 #if defined __GNUC__ && (__GNUC__ > 2 \
3629                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3630 #define NO_RETURN       __attribute__ ((__noreturn__))
3631 #else
3632 #define NO_RETURN       /* nothing */
3633 #endif
3634
3635 /* These won't be used automatically yet.  We also need to know, at least,
3636    that the stack is continuous.  */
3637 #ifdef __GNUC__
3638 #  ifndef GC_SETJMP_WORKS
3639   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3640 #    define GC_SETJMP_WORKS 1
3641 #  endif
3642 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3643 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3644 #  endif
3645 #endif
3646
3647 #ifndef HAVE_BCOPY
3648 #define bcopy(a,b,s) memcpy (b,a,s)
3649 #endif
3650 #ifndef HAVE_BZERO
3651 #define bzero(a,s) memset (a,0,s)
3652 #endif
3653 #ifndef HAVE_BCMP
3654 #define BCMP memcmp
3655 #endif
3656
3657 #endif /* EMACS_CONFIG_H */
3658
3659 /*
3660 Local Variables:
3661 mode: c
3662 End:
3663 */
3664 ])dnl
3665
3666 #### Report on what we decided to do.
3667 #### Report GTK as a toolkit, even if it doesn't use Xt.
3668 #### It makes printing result more understandable as using GTK sets
3669 #### toolkit_scroll_bars to yes by default.
3670 if test "${HAVE_GTK}" = "yes"; then
3671   USE_X_TOOLKIT=GTK
3672 fi
3673
3674 echo "
3675 Configured for \`${canonical}'.
3676
3677   Where should the build process find the source code?    ${srcdir}
3678   What operating system and machine description files should Emacs use?
3679         \`${opsysfile}' and \`${machfile}'
3680   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3681   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3682   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3683   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3684   What window system should Emacs use?                    ${window_system}
3685   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3686
3687 if test -n "${x_includes}"; then
3688 echo "  Where do we find X Windows header files?                ${x_includes}"
3689 else
3690 echo "  Where do we find X Windows header files?                Standard dirs"
3691 fi
3692 if test -n "${x_libraries}"; then
3693 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3694 else
3695 echo "  Where do we find X Windows libraries?                   Standard dirs"
3696 fi
3697
3698 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3699 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3700 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3701 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3702 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3703 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3704 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3705 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3706 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3707 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3708 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3709
3710 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3711 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3712 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3713 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3714
3715 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3716 echo
3717
3718 if test $USE_XASSERTS = yes; then
3719    echo "  Compiling with asserts turned on."
3720    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3721 fi
3722
3723 echo
3724
3725 if test "$HAVE_NS" = "yes"; then
3726    echo
3727    echo "You must run \"make install\" in order to test the built application.
3728 The installed application will go to nextstep/Emacs.app and can be
3729 run or moved from there."
3730    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3731       echo "The application will be fully self-contained."
3732     else
3733       echo "The lisp resources for the application will be installed under ${prefix}.
3734 You may need to run \"make install\" with sudo.  The application will fail
3735 to run if these resources are not installed."
3736    fi
3737    echo
3738 fi
3739
3740 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3741   echo "D-Bus integration has been tested for GNU/Linux only."
3742   echo
3743 fi
3744
3745
3746 # Remove any trailing slashes in these variables.
3747 [test "${prefix}" != NONE &&
3748   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3749 test "${exec_prefix}" != NONE &&
3750   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3751
3752 # Now get this: Some word that is part of the ${srcdir} directory name
3753 # or the ${configuration} value might, just might, happen to be an
3754 # identifier like `sun4' or `i386' or something, and be predefined by
3755 # the C preprocessor to some helpful value like 1, or maybe the empty
3756 # string.  Needless to say consequent macro substitutions are less
3757 # than conducive to the makefile finding the correct directory.
3758 # src/Makefile.in used to treat X11 as equivalent to HAVE_X11.
3759 # But nothing in Emacs defines X11, and everywhere else uses HAVE_X11,
3760 # so that cannot have been doing anything.
3761 [cpp_undefs="`echo $srcdir $configuration $canonical unix mktime register X11 |
3762   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3763   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3764
3765 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3766 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3767 ## from Makefile.c can correctly provide the arg `-traditional' to the
3768 ## C preprocessor.
3769
3770 AC_EGREP_CPP(yes..yes,
3771         [yes..yes],
3772         CPP_NEED_TRADITIONAL=no,
3773         CPP_NEED_TRADITIONAL=yes)
3774
3775 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3776         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3777         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3778         lwlib/Makefile lisp/Makefile leim/Makefile, [
3779
3780 ### Make the necessary directories, if they don't exist.
3781 for dir in etc lisp ; do
3782   test -d ${dir} || mkdir ${dir}
3783 done
3784
3785 # Build src/Makefile from ${srcdir}/src/Makefile.c
3786 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3787 # This must be done after src/config.h is built, since we rely on that file.
3788
3789 echo creating src/epaths.h
3790 ${MAKE-make} epaths-force
3791
3792 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3793 # `..' to `. .'  unless invoked with -traditional
3794
3795 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3796   CPPFLAGS="$CPPFLAGS -traditional"
3797 fi
3798
3799 echo creating src/Makefile
3800 ( cd src
3801   rm -f junk.c junk1.c junk2.c
3802   sed -e '/start of cpp stuff/q' \
3803       < Makefile.c > junk1.c
3804   sed -e '1,/start of cpp stuff/d'\
3805       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3806       < Makefile.c > junk.c
3807   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3808       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3809   cat junk1.c junk2.c > Makefile.new
3810   rm -f junk.c junk1.c junk2.c
3811   chmod 444 Makefile.new
3812   mv -f Makefile.new Makefile
3813 )
3814
3815 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3816   echo creating src/.gdbinit
3817   echo source $srcdir/src/.gdbinit > src/.gdbinit
3818 fi
3819
3820 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3821
3822 m4_if(dnl       Do not change this comment
3823    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3824 )dnl