lisp/reposition.el

   1 ;;; reposition.el --- center a Lisp function or comment on the screen
   2
   3 ;; Copyright (C) 1991, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael D. Ernst <mernst@theory.lcs.mit.edu>
   7 ;; Created: Jan 1991
   8 ;; Maintainer: FSF
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Reposition-window makes an entire function definition or comment visible,
  30 ;; or, if it is already visible, places it at the top of the window;
  31 ;; additional invocations toggle the visibility of comments preceding the
  32 ;; code.  For the gory details, see the documentation for reposition-window;
  33 ;; rather than reading that, you may just want to play with it.
  34
  35 ;; This tries pretty hard to do the recentering correctly; the precise
  36 ;; action depends on what the buffer looks like.  If you find a situation
  37 ;; where it doesn't behave well, let me know.  This function is modeled
  38 ;; after one of the same name in ZMACS, but the code is all-new and the
  39 ;; behavior in some situations differs.
  40
  41 ;;; Code:
  42
  43 ;;;###autoload
  44 (defun reposition-window (&optional arg)
  45   "Make the current definition and/or comment visible.
  46 Further invocations move it to the top of the window or toggle the
  47 visibility of comments that precede it.
  48   Point is left unchanged unless prefix ARG is supplied.
  49   If the definition is fully onscreen, it is moved to the top of the
  50 window.  If it is partly offscreen, the window is scrolled to get the
  51 definition (or as much as will fit) onscreen, unless point is in a comment
  52 which is also partly offscreen, in which case the scrolling attempts to get
  53 as much of the comment onscreen as possible.
  54   Initially `reposition-window' attempts to make both the definition and
  55 preceding comments visible.  Further invocations toggle the visibility of
  56 the comment lines.
  57   If ARG is non-nil, point may move in order to make the whole defun
  58 visible (if only part could otherwise be made so), to make the defun line
  59 visible (if point is in code and it could not be made so, or if only
  60 comments, including the first comment line, are visible), or to make the
  61 first comment line visible (if point is in a comment)."
  62   (interactive "P")
  63   (let* (;; (here (save-excursion (beginning-of-line) (point)))
  64          (here (point))
  65          ;; change this name once I've gotten rid of references to ht.
  66          ;; this is actually the number of the last screen line
  67          (ht (- (window-height (selected-window)) 2))
  68          (line (repos-count-screen-lines (window-start) (point)))
  69          (comment-height
  70           ;; The call to max deals with the case of cursor between defuns.
  71           (max 0
  72                (repos-count-screen-lines-signed
  73                 ;; the beginning of the preceding comment
  74                 (save-excursion
  75                   (if (not (eobp)) (forward-char 1))
  76                   (end-of-defun -1)
  77                   ;; Skip whitespace, newlines, and form feeds.
  78                   (if (re-search-forward "[^ \t\n\f]" nil t)
  79                       (backward-char 1))
  80                   (point))
  81                 here)))
  82          (defun-height
  83            (repos-count-screen-lines-signed
  84             (save-excursion
  85               (end-of-defun 1) ; so comments associate with following defuns
  86               (beginning-of-defun 1)
  87               (point))
  88             here))
  89          ;; This must be positive, so don't use the signed version.
  90          (defun-depth (repos-count-screen-lines here
  91                                                 (save-excursion
  92                                                   (end-of-defun 1)
  93                                                   (point))))
  94          (defun-line-onscreen-p
  95            (and (<= defun-height line)
  96                 (<= (- line defun-height) ht))))
  97     (cond ((or (= comment-height line)
  98                (and (= line ht)
  99                     (> comment-height line)
 100                     ;; if defun line offscreen, we should be in case 4
 101                     defun-line-onscreen-p))
 102            ;; Either first comment line is at top of screen or (point at
 103            ;; bottom of screen, defun line onscreen, and first comment line
 104            ;; off top of screen).  That is, it looks like we just did
 105            ;; recenter-definition, trying to fit as much of the comment
 106            ;; onscreen as possible.  Put defun line at top of screen; that
 107            ;; is, show as much code, and as few comments, as possible.
 108
 109            (if (and arg (> defun-depth (1+ ht)))
 110                ;; Can't fit whole defun onscreen without moving point.
 111                (progn (end-of-defun) (beginning-of-defun) (recenter 0))
 112              (recenter (max defun-height 0)))
 113            ;;(repos-debug-macro "1")
 114            )
 115
 116           ((or (= defun-height line)
 117                (= line 0)
 118                (and (< line comment-height)
 119                     (< defun-height 0)))
 120            ;; Defun line or cursor at top of screen, OR cursor in comment
 121            ;; whose first line is offscreen.
 122            ;; Avoid moving definition up even if defun runs offscreen;
 123            ;; we care more about getting the comment onscreen.
 124
 125            (cond ((= line ht)
 126                   ;; cursor on last screen line (and so in a comment)
 127                   (if arg (progn (end-of-defun) (beginning-of-defun)))
 128                   (recenter 0)
 129                   ;;(repos-debug-macro "2a")
 130                   )
 131
 132                  ;; This condition, copied from case 4, may not be quite right
 133
 134                  ((and arg (< ht comment-height))
 135                   ;; Can't get first comment line onscreen.
 136                   ;; Go there and try again.
 137                   (forward-line (- comment-height))
 138                   (beginning-of-line)
 139                   ;; was (reposition-window)
 140                   (recenter 0)
 141                   ;;(repos-debug-macro "2b")
 142                   )
 143                  (t
 144                   (recenter (min ht comment-height))
 145                   ;;(repos-debug-macro "2c")
 146                   ))
 147            ;; (recenter (min ht comment-height))
 148            )
 149
 150           ((and (> (+ line defun-depth -1) ht)
 151                 defun-line-onscreen-p)
 152            ;; Defun runs off the bottom of the screen and the defun line
 153            ;; is onscreen.
 154            ;; Move the defun up.
 155            (recenter (max 0 (1+ (- ht defun-depth)) defun-height))
 156            ;;(repos-debug-macro "3")
 157            )
 158
 159           (t
 160            ;; If on the bottom line and comment start is offscreen
 161            ;; then just move all comments offscreen, or at least as
 162            ;; far as they'll go.
 163
 164            ;; Try to get as much of the comments onscreen as possible.
 165            (if (and arg (< ht comment-height))
 166                ;; Can't get defun line onscreen; go there and try again.
 167                (progn (forward-line (- defun-height))
 168                       (beginning-of-line)
 169                       (reposition-window))
 170              (recenter (min ht comment-height)))
 171            ;;(repos-debug-macro "4")
 172            ))))
 173
 174 ;;;###autoload (define-key esc-map "\C-l" 'reposition-window)
 175
 176 ;;; Auxiliary functions
 177
 178 ;; Return number of screen lines between START and END.
 179 (defun repos-count-screen-lines (start end)
 180   (save-excursion
 181     (save-restriction
 182       (narrow-to-region start end)
 183       (goto-char (point-min))
 184       (vertical-motion (- (point-max) (point-min))))))
 185
 186 ;; Return number of screen lines between START and END; returns a negative
 187 ;; number if END precedes START.
 188 (defun repos-count-screen-lines-signed (start end)
 189   (let ((lines (repos-count-screen-lines start end)))
 190     (if (< start end)
 191         lines
 192       (- lines))))
 193
 194 ;; (defmacro repos-debug-macro (case-no)
 195 ;;   `(message (concat "Case " ,case-no ": %s %s %s %s %s")
 196 ;;             ht line comment-height defun-height defun-depth))
 197
 198 (provide 'reposition)
 199
 200 ;;; arch-tag: 79487039-3bd7-4ab5-a3e8-ecf3b4919010
 201 ;;; reposition.el ends here