(truncate-string-to-width):
[emacs.git] / lisp / gnus / nnvirtual.el
blob05db759111209f28ae69fb6047d8ecfc2d4a5e85
1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
2 ;; Copyright (C) 1994,95,96,97 Free Software Foundation, Inc.
4 ;; Author: David Moore <dmoore@ucsd.edu>
5 ;; Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
6 ;; Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
7 ;; Keywords: news
9 ;; This file is part of GNU Emacs.
11 ;; GNU Emacs is free software; you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation; either version 2, or (at your option)
14 ;; any later version.
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 ;; GNU General Public License for more details.
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs; see the file COPYING. If not, write to the
23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 ;; Boston, MA 02111-1307, USA.
26 ;;; Commentary:
28 ;; The other access methods (nntp, nnspool, etc) are general news
29 ;; access methods. This module relies on Gnus and can not be used
30 ;; separately.
32 ;;; Code:
34 (require 'nntp)
35 (require 'nnheader)
36 (require 'gnus)
37 (require 'nnoo)
38 (require 'gnus-util)
39 (require 'gnus-start)
40 (require 'gnus-sum)
41 (eval-when-compile (require 'cl))
43 (nnoo-declare nnvirtual)
45 (defvoo nnvirtual-always-rescan nil
46 "*If non-nil, always scan groups for unread articles when entering a group.
47 If this variable is nil (which is the default) and you read articles
48 in a component group after the virtual group has been activated, the
49 read articles from the component group will show up when you enter the
50 virtual group.")
52 (defvoo nnvirtual-component-regexp nil
53 "*Regexp to match component groups.")
55 (defvoo nnvirtual-component-groups nil
56 "Component group in this nnvirtual group.")
60 (defconst nnvirtual-version "nnvirtual 1.1")
62 (defvoo nnvirtual-current-group nil)
64 (defvoo nnvirtual-mapping-table nil
65 "Table of rules on how to map between component group and article number
66 to virtual article number.")
68 (defvoo nnvirtual-mapping-offsets nil
69 "Table indexed by component group to an offset to be applied to article numbers in that group.")
71 (defvoo nnvirtual-mapping-len 0
72 "Number of articles in this virtual group.")
74 (defvoo nnvirtual-mapping-reads nil
75 "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
77 (defvoo nnvirtual-mapping-marks nil
78 "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
80 (defvoo nnvirtual-info-installed nil
81 "T if we have already installed the group info for this group, and shouldn't blast over it again.")
83 (defvoo nnvirtual-status-string "")
85 (eval-and-compile
86 (autoload 'gnus-cache-articles-in-group "gnus-cache"))
90 ;;; Interface functions.
92 (nnoo-define-basics nnvirtual)
95 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
96 server fetch-old)
97 (when (nnvirtual-possibly-change-server server)
98 (save-excursion
99 (set-buffer nntp-server-buffer)
100 (erase-buffer)
101 (if (stringp (car articles))
102 'headers
103 (let ((vbuf (nnheader-set-temp-buffer
104 (get-buffer-create " *virtual headers*")))
105 (carticles (nnvirtual-partition-sequence articles))
106 (system-name (system-name))
107 cgroup carticle article result prefix)
108 (while carticles
109 (setq cgroup (caar carticles))
110 (setq articles (cdar carticles))
111 (pop carticles)
112 (when (and articles
113 (gnus-check-server
114 (gnus-find-method-for-group cgroup) t)
115 (gnus-request-group cgroup t)
116 (setq prefix (gnus-group-real-prefix cgroup))
117 ;; FIX FIX FIX we want to check the cache!
118 ;; This is probably evil if people have set
119 ;; gnus-use-cache to nil themselves, but I
120 ;; have no way of finding the true value of it.
121 (let ((gnus-use-cache t))
122 (setq result (gnus-retrieve-headers
123 articles cgroup nil))))
124 (set-buffer nntp-server-buffer)
125 ;; If we got HEAD headers, we convert them into NOV
126 ;; headers. This is slow, inefficient and, come to think
127 ;; of it, downright evil. So sue me. I couldn't be
128 ;; bothered to write a header parse routine that could
129 ;; parse a mixed HEAD/NOV buffer.
130 (when (eq result 'headers)
131 (nnvirtual-convert-headers))
132 (goto-char (point-min))
133 (while (not (eobp))
134 (delete-region (point)
135 (progn
136 (setq carticle (read nntp-server-buffer))
137 (point)))
139 ;; We remove this article from the articles list, if
140 ;; anything is left in the articles list after going through
141 ;; the entire buffer, then those articles have been
142 ;; expired or canceled, so we appropriately update the
143 ;; component group below. They should be coming up
144 ;; generally in order, so this shouldn't be slow.
145 (setq articles (delq carticle articles))
147 (setq article (nnvirtual-reverse-map-article cgroup carticle))
148 (if (null article)
149 ;; This line has no reverse mapping, that means it
150 ;; was an extra article reference returned by nntp.
151 (progn
152 (beginning-of-line)
153 (delete-region (point) (progn (forward-line 1) (point))))
154 ;; Otherwise insert the virtual article number,
155 ;; and clean up the xrefs.
156 (princ article nntp-server-buffer)
157 (nnvirtual-update-xref-header cgroup carticle
158 prefix system-name)
159 (forward-line 1))
162 (set-buffer vbuf)
163 (goto-char (point-max))
164 (insert-buffer-substring nntp-server-buffer))
165 ;; Anything left in articles is expired or canceled.
166 ;; Could be smart and not tell it about articles already known?
167 (when articles
168 (gnus-group-make-articles-read cgroup articles))
171 ;; The headers are ready for reading, so they are inserted into
172 ;; the nntp-server-buffer, which is where Gnus expects to find
173 ;; them.
174 (prog1
175 (save-excursion
176 (set-buffer nntp-server-buffer)
177 (erase-buffer)
178 (insert-buffer-substring vbuf)
179 ;; FIX FIX FIX, we should be able to sort faster than
180 ;; this if needed, since each cgroup is sorted, we just
181 ;; need to merge
182 (sort-numeric-fields 1 (point-min) (point-max))
183 'nov)
184 (kill-buffer vbuf)))))))
187 (defvoo nnvirtual-last-accessed-component-group nil)
189 (deffoo nnvirtual-request-article (article &optional group server buffer)
190 (when (nnvirtual-possibly-change-server server)
191 (if (stringp article)
192 ;; This is a fetch by Message-ID.
193 (cond
194 ((not nnvirtual-last-accessed-component-group)
195 (nnheader-report
196 'nnvirtual "Don't know what server to request from"))
198 (save-excursion
199 (when buffer
200 (set-buffer buffer))
201 (let ((method (gnus-find-method-for-group
202 nnvirtual-last-accessed-component-group)))
203 (funcall (gnus-get-function method 'request-article)
204 article nil (nth 1 method) buffer)))))
205 ;; This is a fetch by number.
206 (let* ((amap (nnvirtual-map-article article))
207 (cgroup (car amap)))
208 (cond
209 ((not amap)
210 (nnheader-report 'nnvirtual "No such article: %s" article))
211 ((not (gnus-check-group cgroup))
212 (nnheader-report
213 'nnvirtual "Can't open server where %s exists" cgroup))
214 ((not (gnus-request-group cgroup t))
215 (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
217 (setq nnvirtual-last-accessed-component-group cgroup)
218 (if buffer
219 (save-excursion
220 (set-buffer buffer)
221 (gnus-request-article-this-buffer (cdr amap) cgroup))
222 (gnus-request-article (cdr amap) cgroup))))))))
225 (deffoo nnvirtual-open-server (server &optional defs)
226 (unless (assq 'nnvirtual-component-regexp defs)
227 (push `(nnvirtual-component-regexp ,server)
228 defs))
229 (nnoo-change-server 'nnvirtual server defs)
230 (if nnvirtual-component-groups
232 (setq nnvirtual-mapping-table nil
233 nnvirtual-mapping-offsets nil
234 nnvirtual-mapping-len 0
235 nnvirtual-mapping-reads nil
236 nnvirtual-mapping-marks nil
237 nnvirtual-info-installed nil)
238 (when nnvirtual-component-regexp
239 ;; Go through the newsrc alist and find all component groups.
240 (let ((newsrc (cdr gnus-newsrc-alist))
241 group)
242 (while (setq group (car (pop newsrc)))
243 (when (string-match nnvirtual-component-regexp group) ; Match
244 ;; Add this group to the list of component groups.
245 (setq nnvirtual-component-groups
246 (cons group (delete group nnvirtual-component-groups)))))))
247 (if (not nnvirtual-component-groups)
248 (nnheader-report 'nnvirtual "No component groups: %s" server)
249 t)))
252 (deffoo nnvirtual-request-group (group &optional server dont-check)
253 (nnvirtual-possibly-change-server server)
254 (setq nnvirtual-component-groups
255 (delete (nnvirtual-current-group) nnvirtual-component-groups))
256 (cond
257 ((null nnvirtual-component-groups)
258 (setq nnvirtual-current-group nil)
259 (nnheader-report 'nnvirtual "No component groups in %s" group))
261 (when (or (not dont-check)
262 nnvirtual-always-rescan)
263 (nnvirtual-create-mapping))
264 (setq nnvirtual-current-group group)
265 (nnheader-insert "211 %d 1 %d %s\n"
266 nnvirtual-mapping-len nnvirtual-mapping-len group))))
269 (deffoo nnvirtual-request-type (group &optional article)
270 (if (not article)
271 'unknown
272 (let ((mart (nnvirtual-map-article article)))
273 (when mart
274 (gnus-request-type (car mart) (cdr mart))))))
276 (deffoo nnvirtual-request-update-mark (group article mark)
277 (let* ((nart (nnvirtual-map-article article))
278 (cgroup (car nart))
279 ;; The component group might be a virtual group.
280 (nmark (gnus-request-update-mark cgroup (cdr nart) mark)))
281 (when (and nart
282 (= mark nmark)
283 (gnus-group-auto-expirable-p cgroup))
284 (setq mark gnus-expirable-mark)))
285 mark)
288 (deffoo nnvirtual-close-group (group &optional server)
289 (when (and (nnvirtual-possibly-change-server server)
290 (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
291 (nnvirtual-update-read-and-marked t t))
295 (deffoo nnvirtual-request-list (&optional server)
296 (nnheader-report 'nnvirtual "LIST is not implemented."))
299 (deffoo nnvirtual-request-newgroups (date &optional server)
300 (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
303 (deffoo nnvirtual-request-list-newsgroups (&optional server)
304 (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
307 (deffoo nnvirtual-request-update-info (group info &optional server)
308 (when (and (nnvirtual-possibly-change-server server)
309 (not nnvirtual-info-installed))
310 ;; Install the precomputed lists atomically, so the virtual group
311 ;; is not left in a half-way state in case of C-g.
312 (gnus-atomic-progn
313 (setcar (cddr info) nnvirtual-mapping-reads)
314 (if (nthcdr 3 info)
315 (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
316 (when nnvirtual-mapping-marks
317 (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
318 (setq nnvirtual-info-installed t))
322 (deffoo nnvirtual-catchup-group (group &optional server all)
323 (when (and (nnvirtual-possibly-change-server server)
324 (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
325 ;; copy over existing marks first, in case they set anything
326 (nnvirtual-update-read-and-marked nil nil)
327 ;; do a catchup on all component groups
328 (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
329 (gnus-expert-user t))
330 ;; Make sure all groups are activated.
331 (mapcar
332 (lambda (g)
333 (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
334 (gnus-activate-group g)))
335 nnvirtual-component-groups)
336 (save-excursion
337 (set-buffer gnus-group-buffer)
338 (gnus-group-catchup-current nil all)))))
341 (deffoo nnvirtual-find-group-art (group article)
342 "Return the real group and article for virtual GROUP and ARTICLE."
343 (nnvirtual-map-article article))
346 ;;; Internal functions.
348 (defun nnvirtual-convert-headers ()
349 "Convert HEAD headers into NOV headers."
350 (save-excursion
351 (set-buffer nntp-server-buffer)
352 (let* ((dependencies (make-vector 100 0))
353 (headers (gnus-get-newsgroup-headers dependencies))
354 header)
355 (erase-buffer)
356 (while (setq header (pop headers))
357 (nnheader-insert-nov header)))))
360 (defun nnvirtual-update-xref-header (group article prefix system-name)
361 "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
362 ;; Move to beginning of Xref field, creating a slot if needed.
363 (beginning-of-line)
364 (looking-at
365 "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
366 (goto-char (match-end 0))
367 (unless (search-forward "\t" (gnus-point-at-eol) 'move)
368 (insert "\t"))
370 ;; Remove any spaces at the beginning of the Xref field.
371 (while (= (char-after (1- (point))) ? )
372 (forward-char -1)
373 (delete-char 1))
375 (insert "Xref: " system-name " " group ":")
376 (princ article (current-buffer))
378 ;; If there were existing xref lines, clean them up to have the correct
379 ;; component server prefix.
380 (let ((xref-end (save-excursion
381 (search-forward "\t" (gnus-point-at-eol) 'move)
382 (point)))
383 (len (length prefix)))
384 (unless (= (point) xref-end)
385 (insert " ")
386 (when (not (string= "" prefix))
387 (while (re-search-forward "[^ ]+:[0-9]+" xref-end t)
388 (save-excursion
389 (goto-char (match-beginning 0))
390 (insert prefix))
391 (setq xref-end (+ xref-end len)))
394 ;; Ensure a trailing \t.
395 (end-of-line)
396 (or (= (char-after (1- (point))) ?\t)
397 (insert ?\t)))
400 (defun nnvirtual-possibly-change-server (server)
401 (or (not server)
402 (nnoo-current-server-p 'nnvirtual server)
403 (nnvirtual-open-server server)))
406 (defun nnvirtual-update-read-and-marked (read-p update-p)
407 "Copy marks from the virtual group to the component groups.
408 If READ-P is not nil, update the (un)read status of the components.
409 If UPDATE-P is not nil, call gnus-group-update-group on the components."
410 (when nnvirtual-current-group
411 (let ((unreads (and read-p
412 (nnvirtual-partition-sequence
413 (gnus-list-of-unread-articles
414 (nnvirtual-current-group)))))
415 (type-marks (mapcar (lambda (ml)
416 (cons (car ml)
417 (nnvirtual-partition-sequence (cdr ml))))
418 (gnus-info-marks (gnus-get-info
419 (nnvirtual-current-group)))))
420 mark type groups carticles info entry)
422 ;; Ok, atomically move all of the (un)read info, clear any old
423 ;; marks, and move all of the current marks. This way if someone
424 ;; hits C-g, you won't leave the component groups in a half-way state.
425 (gnus-atomic-progn
426 ;; move (un)read
427 (let ((gnus-newsgroup-active nil)) ;workaround guns-update-read-articles
428 (while (setq entry (pop unreads))
429 (gnus-update-read-articles (car entry) (cdr entry))))
431 ;; clear all existing marks on the component groups
432 (setq groups nnvirtual-component-groups)
433 (while groups
434 (when (and (setq info (gnus-get-info (pop groups)))
435 (gnus-info-marks info))
436 (gnus-info-set-marks info nil)))
438 ;; Ok, currently type-marks is an assq list with keys of a mark type,
439 ;; with data of an assq list with keys of component group names
440 ;; and the articles which correspond to that key/group pair.
441 (while (setq mark (pop type-marks))
442 (setq type (car mark))
443 (setq groups (cdr mark))
444 (while (setq carticles (pop groups))
445 (gnus-add-marked-articles (car carticles) type (cdr carticles)
446 nil t))))
448 ;; possibly update the display, it is really slow
449 (when update-p
450 (setq groups nnvirtual-component-groups)
451 (while groups
452 (gnus-group-update-group (pop groups) t))))))
455 (defun nnvirtual-current-group ()
456 "Return the prefixed name of the current nnvirtual group."
457 (concat "nnvirtual:" nnvirtual-current-group))
461 ;;; This is currently O(kn^2) to merge n lists of length k.
462 ;;; You could do it in O(knlogn), but we have a small n, and the
463 ;;; overhead of the other approach is probably greater.
464 (defun nnvirtual-merge-sorted-lists (&rest lists)
465 "Merge many sorted lists of numbers."
466 (if (null (cdr lists))
467 (car lists)
468 (sort (apply 'nconc lists) '<)))
471 ;;; We map between virtual articles and real articles in a manner
472 ;;; which keeps the size of the virtual active list the same as
473 ;;; the sum of the component active lists.
474 ;;; To achieve fair mixing of the groups, the last article in
475 ;;; each of N component groups will be in the the last N articles
476 ;;; in the virtual group.
478 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and 6-7
479 ;;; resprectively, then the virtual article numbers look like:
481 ;;; 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15
482 ;;; A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
484 ;;; To compute these mappings we generate a couple tables and then
485 ;;; do some fast operations on them. Tables for the example above:
487 ;;; Offsets - [(A 0) (B -3) (C -1)]
489 ;;; a b c d e
490 ;;; Mapping - ([ 3 0 1 3 0 ]
491 ;;; [ 6 3 2 9 3 ]
492 ;;; [ 8 6 3 15 9 ])
494 ;;; (note column 'e' is different in real algorithm, which is slightly
495 ;;; different than described here, but this gives you the methodology.)
497 ;;; The basic idea is this, when going from component->virtual, apply
498 ;;; the appropriate offset to the article number. Then search the first
499 ;;; column of the table for a row where 'a' is less than or equal to the
500 ;;; modified number. You can see that only group A can therefore go to
501 ;;; the first row, groups A and B to the second, and all to the last.
502 ;;; The third column of the table is telling us the number of groups
503 ;;; which might be able to reach that row (it might increase by more than
504 ;;; 1 if several groups have the same size).
505 ;;; Then column 'b' provides an additional offset you apply when you have
506 ;;; found the correct row. You then multiply by 'c' and add on the groups
507 ;;; _position_ in the offset table. The basic idea here is that on
508 ;;; any given row we are going to map back and forth using X'=X*c+Y and
509 ;;; X=(X'/c), Y=(X' mod c). Then once you've done this transformation,
510 ;;; you apply a final offset from column 'e' to give the virtual article.
512 ;;; Going the other direction, you instead search on column 'd' instead
513 ;;; of 'a', and apply everything in reverse order.
515 ;;; Convert component -> virtual:
516 ;;; set num = num - Offset(group)
517 ;;; find first row in Mapping where num <= 'a'
518 ;;; num = (num-'b')*c + Position(group) + 'e'
520 ;;; Convert virtual -> component:
521 ;;; find first row in Mapping where num <= 'd'
522 ;;; num = num - 'e'
523 ;;; group_pos = num mod 'c'
524 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
526 ;;; Easy no? :)
528 ;;; Well actually, you need to keep column e offset smaller by the 'c'
529 ;;; column for that line, and always add 1 more when going from
530 ;;; component -> virtual. Otherwise you run into a problem with
531 ;;; unique reverse mapping.
533 (defun nnvirtual-map-article (article)
534 "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
535 (let ((table nnvirtual-mapping-table)
536 entry group-pos)
537 (while (and table
538 (> article (aref (car table) 3)))
539 (setq table (cdr table)))
540 (when (and table
541 (> article 0))
542 (setq entry (car table))
543 (setq article (- article (aref entry 4) 1))
544 (setq group-pos (mod article (aref entry 2)))
545 (cons (car (aref nnvirtual-mapping-offsets group-pos))
546 (+ (/ article (aref entry 2))
547 (aref entry 1)
548 (cdr (aref nnvirtual-mapping-offsets group-pos)))
554 (defun nnvirtual-reverse-map-article (group article)
555 "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
556 (let ((table nnvirtual-mapping-table)
557 (group-pos 0)
558 entry)
559 (while (not (string= group (car (aref nnvirtual-mapping-offsets
560 group-pos))))
561 (setq group-pos (1+ group-pos)))
562 (setq article (- article (cdr (aref nnvirtual-mapping-offsets
563 group-pos))))
564 (while (and table
565 (> article (aref (car table) 0)))
566 (setq table (cdr table)))
567 (setq entry (car table))
568 (when (and entry
569 (> article 0)
570 (< group-pos (aref entry 2))) ; article not out of range below
571 (+ (aref entry 4)
572 group-pos
573 (* (- article (aref entry 1))
574 (aref entry 2))
579 (defsubst nnvirtual-reverse-map-sequence (group articles)
580 "Return list of virtual article numbers for all ARTICLES in GROUP.
581 The ARTICLES should be sorted, and can be a compressed sequence.
582 If any of the article numbers has no corresponding virtual article,
583 then it is left out of the result."
584 (when (numberp (cdr-safe articles))
585 (setq articles (list articles)))
586 (let (result a i j new-a)
587 (while (setq a (pop articles))
588 (if (atom a)
589 (setq i a
590 j a)
591 (setq i (car a)
592 j (cdr a)))
593 (while (<= i j)
594 ;; If this is slow, you can optimize by moving article checking
595 ;; into here. You don't have to recompute the group-pos,
596 ;; nor scan the table every time.
597 (when (setq new-a (nnvirtual-reverse-map-article group i))
598 (push new-a result))
599 (setq i (1+ i))))
600 (nreverse result)))
603 (defun nnvirtual-partition-sequence (articles)
604 "Return an association list of component article numbers.
605 These are indexed by elements of nnvirtual-component-groups, based on
606 the sequence ARTICLES of virtual article numbers. ARTICLES should be
607 sorted, and can be a compressed sequence. If any of the article
608 numbers has no corresponding component article, then it is left out of
609 the result."
610 (when (numberp (cdr-safe articles))
611 (setq articles (list articles)))
612 (let ((carticles (mapcar (lambda (g) (list g))
613 nnvirtual-component-groups))
614 a i j article entry)
615 (while (setq a (pop articles))
616 (if (atom a)
617 (setq i a
618 j a)
619 (setq i (car a)
620 j (cdr a)))
621 (while (<= i j)
622 (when (setq article (nnvirtual-map-article i))
623 (setq entry (assoc (car article) carticles))
624 (setcdr entry (cons (cdr article) (cdr entry))))
625 (setq i (1+ i))))
626 (mapcar (lambda (x) (setcdr x (nreverse (cdr x))))
627 carticles)
628 carticles))
631 (defun nnvirtual-create-mapping ()
632 "Build the tables necessary to map between component (group, article) to virtual article.
633 Generate the set of read messages and marks for the virtual group
634 based on the marks on the component groups."
635 (let ((cnt 0)
636 (tot 0)
637 (M 0)
638 (i 0)
639 actives all-unreads all-marks
640 active min max size unreads marks
641 next-M next-tot
642 reads beg)
643 ;; Ok, we loop over all component groups and collect a lot of
644 ;; information:
645 ;; Into actives we place (g size max), where size is max-min+1.
646 ;; Into all-unreads we put (g unreads).
647 ;; Into all-marks we put (g marks).
648 ;; We also increment cnt and tot here, and compute M (max of sizes).
649 (mapc (lambda (g)
650 (setq active (gnus-activate-group g)
651 min (car active)
652 max (cdr active))
653 (when (and active (>= max min) (not (zerop max)))
654 ;; store active information
655 (push (list g (- max min -1) max) actives)
656 ;; collect unread/mark info for later
657 (setq unreads (gnus-list-of-unread-articles g))
658 (setq marks (gnus-info-marks (gnus-get-info g)))
659 (when gnus-use-cache
660 (push (cons 'cache
661 (gnus-cache-articles-in-group g))
662 marks))
663 (push (cons g unreads) all-unreads)
664 (push (cons g marks) all-marks)
665 ;; count groups, total #articles, and max size
666 (setq size (- max min -1))
667 (setq cnt (1+ cnt)
668 tot (+ tot size)
669 M (max M size))))
670 nnvirtual-component-groups)
672 ;; Number of articles in the virtual group.
673 (setq nnvirtual-mapping-len tot)
676 ;; We want the actives list sorted by size, to build the tables.
677 (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
679 ;; Build the offset table. Largest sized groups are at the front.
680 (setq nnvirtual-mapping-offsets
681 (vconcat
682 (nreverse
683 (mapcar (lambda (entry)
684 (cons (nth 0 entry)
685 (- (nth 2 entry) M)))
686 actives))))
688 ;; Build the mapping table.
689 (setq nnvirtual-mapping-table nil)
690 (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
691 (while actives
692 (setq size (car actives))
693 (setq next-M (- M size))
694 (setq next-tot (- tot (* cnt size)))
695 ;; make current row in table
696 (push (vector M next-M cnt tot (- next-tot cnt))
697 nnvirtual-mapping-table)
698 ;; update M and tot
699 (setq M next-M)
700 (setq tot next-tot)
701 ;; subtract the current size from all entries.
702 (setq actives (mapcar (lambda (x) (- x size)) actives))
703 ;; remove anything that went to 0.
704 (while (and actives
705 (= (car actives) 0))
706 (pop actives)
707 (setq cnt (- cnt 1))))
710 ;; Now that the mapping tables are generated, we can convert
711 ;; and combine the separate component unreads and marks lists
712 ;; into single lists of virtual article numbers.
713 (setq unreads (apply 'nnvirtual-merge-sorted-lists
714 (mapcar (lambda (x)
715 (nnvirtual-reverse-map-sequence
716 (car x) (cdr x)))
717 all-unreads)))
718 (setq marks (mapcar
719 (lambda (type)
720 (cons (cdr type)
721 (gnus-compress-sequence
722 (apply
723 'nnvirtual-merge-sorted-lists
724 (mapcar (lambda (x)
725 (nnvirtual-reverse-map-sequence
726 (car x)
727 (cdr (assq (cdr type) (cdr x)))))
728 all-marks)))))
729 gnus-article-mark-lists))
731 ;; Remove any empty marks lists, and store.
732 (setq nnvirtual-mapping-marks nil)
733 (while marks
734 (if (cdr (car marks))
735 (push (car marks) nnvirtual-mapping-marks))
736 (setq marks (cdr marks)))
738 ;; We need to convert the unreads to reads. We compress the
739 ;; sequence as we go, otherwise it could be huge.
740 (while (and (<= (incf i) nnvirtual-mapping-len)
741 unreads)
742 (if (= i (car unreads))
743 (setq unreads (cdr unreads))
744 ;; try to get a range.
745 (setq beg i)
746 (while (and (<= (incf i) nnvirtual-mapping-len)
747 (not (= i (car unreads)))))
748 (setq i (- i 1))
749 (if (= i beg)
750 (push i reads)
751 (push (cons beg i) reads))
753 (when (<= i nnvirtual-mapping-len)
754 (if (= i nnvirtual-mapping-len)
755 (push i reads)
756 (push (cons i nnvirtual-mapping-len) reads)))
758 ;; Store the reads list for later use.
759 (setq nnvirtual-mapping-reads (nreverse reads))
761 ;; Throw flag to show we changed the info.
762 (setq nnvirtual-info-installed nil)
765 (provide 'nnvirtual)
767 ;;; nnvirtual.el ends here