lisp/progmodes/cc-subword.el

   1 ;;; cc-subword.el --- Handling capitalized subwords in a nomenclature
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Masatake YAMATO
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program; see the file COPYING.  If not, write to
  19 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; This package provides `subword' oriented commands and a minor mode
  25 ;; (`c-subword-mode') that substitutes the common word handling
  26 ;; functions with them.
  27
  28 ;; In spite of GNU Coding Standards, it is popular to name a symbol by
  29 ;; mixing uppercase and lowercase letters, e.g. "GtkWidget",
  30 ;; "EmacsFrameClass", "NSGraphicsContext", etc.  Here we call these
  31 ;; mixed case symbols `nomenclatures'.  Also, each capitalized (or
  32 ;; completely uppercase) part of a nomenclature is called a `subword'.
  33 ;; Here are some examples:
  34
  35 ;;  Nomenclature           Subwords
  36 ;;  ===========================================================
  37 ;;  GtkWindow          =>  "Gtk" and "Window"
  38 ;;  EmacsFrameClass    =>  "Emacs", "Frame" and "Class"
  39 ;;  NSGraphicsContext  =>  "NS", "Graphics" and "Context"
  40
  41 ;; The subword oriented commands defined in this package recognize
  42 ;; subwords in a nomenclature to move between them and to edit them as
  43 ;; words.
  44
  45 ;; In the minor mode, all common key bindings for word oriented
  46 ;; commands are overridden by the subword oriented commands:
  47
  48 ;; Key     Word oriented command      Subword oriented command
  49 ;; ============================================================
  50 ;; M-f     `forward-word'             `c-forward-subword'
  51 ;; M-b     `backward-word'            `c-backward-subword'
  52 ;; M-@     `mark-word'                `c-mark-subword'
  53 ;; M-d     `kill-word'                `c-kill-subword'
  54 ;; M-DEL   `backward-kill-word'       `c-backward-kill-subword'
  55 ;; M-t     `transpose-words'          `c-transpose-subwords'
  56 ;; M-c     `capitalize-word'          `c-capitalize-subword'
  57 ;; M-u     `upcase-word'              `c-upcase-subword'
  58 ;; M-l     `downcase-word'            `c-downcase-subword'
  59 ;;
  60 ;; Note: If you have changed the key bindings for the word oriented
  61 ;; commands in your .emacs or a similar place, the keys you've changed
  62 ;; to are also used for the corresponding subword oriented commands.
  63
  64 ;; To make the mode turn on automatically, put the following code in
  65 ;; your .emacs:
  66 ;;
  67 ;; (add-hook 'c-mode-common-hook
  68 ;;        (lambda () (c-subword-mode 1)))
  69 ;;
  70
  71 ;; Acknowledgment:
  72 ;; The regular expressions to detect subwords are mostly based on
  73 ;; the old `c-forward-into-nomenclature' originally contributed by
  74 ;; Terry_Glanfield dot Southern at rxuk dot xerox dot com.
  75
  76 ;; TODO: ispell-word and subword oriented C-w in isearch.
  77
  78 ;;; Code:
  79
  80 (eval-when-compile
  81   (let ((load-path
  82          (if (and (boundp 'byte-compile-dest-file)
  83                   (stringp byte-compile-dest-file))
  84              (cons (file-name-directory byte-compile-dest-file) load-path)
  85            load-path)))
  86     (load "cc-bytecomp" nil t)))
  87
  88 (cc-require 'cc-defs)
  89 (cc-require 'cc-cmds)
  90
  91 ;; Don't complain about the `define-minor-mode' form if it isn't defined.
  92 (cc-bytecomp-defvar c-subword-mode)
  93
  94 ;;; Autoload directives must be on the top level, so we construct an
  95 ;;; autoload form instead.
  96 ;;;###autoload (autoload 'c-subword-mode "cc-subword" "Mode enabling subword movement and editing keys." t)
  97
  98 (if (not (fboundp 'define-minor-mode))
  99     (defun c-subword-mode ()
 100       "(Missing) mode enabling subword movement and editing keys.
 101 This mode is not (yet) available in this version of (X)Emacs.  Sorry!  If
 102 you really want it, please send a request to <bug-gnu-emacs@gnu.org>,
 103 telling us which (X)Emacs version you're using."
 104       (interactive)
 105       (error
 106        "c-subword-mode is not (yet) available in this version of (X)Emacs.  Sorry!"))
 107
 108   (defvar c-subword-mode-map
 109     (let ((map (make-sparse-keymap)))
 110       (dolist (cmd '(forward-word backward-word mark-word
 111                      kill-word backward-kill-word
 112                      transpose-words
 113                      capitalize-word upcase-word downcase-word))
 114         (let ((othercmd (let ((name (symbol-name cmd)))
 115                           (string-match "\\(.*-\\)\\(word.*\\)" name)
 116                           (intern (concat "c-"
 117                                           (match-string 1 name)
 118                                           "sub"
 119                                           (match-string 2 name))))))
 120           (if (fboundp 'command-remapping)
 121               (define-key map (vector 'remap cmd) othercmd)
 122             (substitute-key-definition cmd othercmd map global-map))))
 123       map)
 124     "Keymap used in command `c-subword-mode' minor mode.")
 125
 126   (define-minor-mode c-subword-mode
 127     "Mode enabling subword movement and editing keys.
 128 In spite of GNU Coding Standards, it is popular to name a symbol by
 129 mixing uppercase and lowercase letters, e.g. \"GtkWidget\",
 130 \"EmacsFrameClass\", \"NSGraphicsContext\", etc.  Here we call these
 131 mixed case symbols `nomenclatures'. Also, each capitalized (or
 132 completely uppercase) part of a nomenclature is called a `subword'.
 133 Here are some examples:
 134
 135   Nomenclature           Subwords
 136   ===========================================================
 137   GtkWindow          =>  \"Gtk\" and \"Window\"
 138   EmacsFrameClass    =>  \"Emacs\", \"Frame\" and \"Class\"
 139   NSGraphicsContext  =>  \"NS\", \"Graphics\" and \"Context\"
 140
 141 The subword oriented commands activated in this minor mode recognize
 142 subwords in a nomenclature to move between subwords and to edit them
 143 as words.
 144
 145 \\{c-subword-mode-map}"
 146     nil
 147     nil
 148     c-subword-mode-map
 149     (c-update-modeline))
 150
 151   )
 152
 153 (defun c-forward-subword (&optional arg)
 154   "Do the same as `forward-word' but on subwords.
 155 See the command `c-subword-mode' for a description of subwords.
 156 Optional argument ARG is the same as for `forward-word'."
 157   (interactive "p")
 158   (unless arg (setq arg 1))
 159   (c-keep-region-active)
 160   (cond
 161    ((< 0 arg)
 162     (dotimes (i arg (point))
 163       (c-forward-subword-internal)))
 164    ((> 0 arg)
 165     (dotimes (i (- arg) (point))
 166       (c-backward-subword-internal)))
 167    (t
 168     (point))))
 169
 170 (defun c-backward-subword (&optional arg)
 171   "Do the same as `backward-word' but on subwords.
 172 See the command `c-subword-mode' for a description of subwords.
 173 Optional argument ARG is the same as for `backward-word'."
 174   (interactive "p")
 175   (c-forward-subword (- (or arg 1))))
 176
 177 (defun c-mark-subword (arg)
 178   "Do the same as `mark-word' but on subwords.
 179 See the command `c-subword-mode' for a description of subwords.
 180 Optional argument ARG is the same as for `mark-word'."
 181   ;; This code is almost copied from `mark-word' in GNU Emacs.
 182   (interactive "p")
 183   (cond ((and (eq last-command this-command) (mark t))
 184          (set-mark
 185           (save-excursion
 186             (goto-char (mark))
 187             (c-forward-subword arg)
 188             (point))))
 189         (t
 190          (push-mark
 191           (save-excursion
 192             (c-forward-subword arg)
 193             (point))
 194           nil t))))
 195
 196 (defun c-kill-subword (arg)
 197   "Do the same as `kill-word' but on subwords.
 198 See the command `c-subword-mode' for a description of subwords.
 199 Optional argument ARG is the same as for `kill-word'."
 200   (interactive "p")
 201   (kill-region (point) (c-forward-subword arg)))
 202
 203 (defun c-backward-kill-subword (arg)
 204   "Do the same as `backward-kill-word' but on subwords.
 205 See the command `c-subword-mode' for a description of subwords.
 206 Optional argument ARG is the same as for `backward-kill-word'."
 207   (interactive "p")
 208   (c-kill-subword (- arg)))
 209
 210 (defun c-transpose-subwords (arg)
 211   "Do the same as `transpose-words' but on subwords.
 212 See the command `c-subword-mode' for a description of subwords.
 213 Optional argument ARG is the same as for `transpose-words'."
 214   (interactive "*p")
 215   (transpose-subr 'c-forward-subword arg))
 216
 217 (defun c-capitalize-subword (arg)
 218   "Do the same as `capitalize-word' but on subwords.
 219 See the command `c-subword-mode' for a description of subwords.
 220 Optional argument ARG is the same as for `capitalize-word'."
 221   (interactive "p")
 222   (let ((count (abs arg))
 223         (direction (if (< 0 arg) 1 -1)))
 224     (dotimes (i count)
 225       (when (re-search-forward
 226              (concat "[" c-alpha "]")
 227              nil t)
 228         (goto-char (match-beginning 0)))
 229       (let* ((p (point))
 230              (pp (1+ p))
 231              (np (c-forward-subword direction)))
 232         (upcase-region p pp)
 233         (downcase-region pp np)
 234         (goto-char np)))))
 235
 236 (defun c-downcase-subword (arg)
 237   "Do the same as `downcase-word' but on subwords.
 238 See the command `c-subword-mode' for a description of subwords.
 239 Optional argument ARG is the same as for `downcase-word'."
 240   (interactive "p")
 241   (downcase-region (point) (c-forward-subword arg)))
 242
 243 (defun c-upcase-subword (arg)
 244   "Do the same as `upcase-word' but on subwords.
 245 See the command `c-subword-mode' for a description of subwords.
 246 Optional argument ARG is the same as for `upcase-word'."
 247   (interactive "p")
 248   (upcase-region (point) (c-forward-subword arg)))
 249
 250 \f
 251 ;;
 252 ;; Internal functions
 253 ;;
 254 (defun c-forward-subword-internal ()
 255   (if (and
 256        (save-excursion
 257          (let ((case-fold-search nil))
 258            (re-search-forward
 259             (concat "\\W*\\(\\([" c-upper "]*\\W?\\)[" c-lower c-digit "]*\\)")
 260             nil t)))
 261        (> (match-end 0) (point))) ; So we don't get stuck at a
 262                                   ; "word-constituent" which isn't c-upper,
 263                                   ; c-lower or c-digit
 264       (goto-char
 265        (cond
 266         ((< 1 (- (match-end 2) (match-beginning 2)))
 267          (1- (match-end 2)))
 268         (t
 269          (match-end 0))))
 270     (forward-word 1)))
 271
 272
 273 (defun c-backward-subword-internal ()
 274   (if (save-excursion
 275         (let ((case-fold-search nil))
 276           (re-search-backward
 277            (concat
 278             "\\(\\(\\W\\|[" c-lower c-digit "]\\)\\([" c-upper "]+\\W*\\)"
 279             "\\|\\W\\w+\\)")
 280            nil t)))
 281       (goto-char
 282        (cond
 283         ((and (match-end 3)
 284               (< 1 (- (match-end 3) (match-beginning 3)))
 285               (not (eq (point) (match-end 3))))
 286          (1- (match-end 3)))
 287         (t
 288          (1+ (match-beginning 0)))))
 289     (backward-word 1)))
 290
 291 \f
 292 (cc-provide 'cc-subword)
 293
 294 ;; arch-tag: 2be9d294-7f30-4626-95e6-9964bb93c7a3
 295 ;;; cc-subword.el ends here