lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2005 Free Software Foundation
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: mouse, terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Enable mouse support when running inside an xterm.
  28
  29 ;; This is actually useful when you are running X11 locally, but is
  30 ;; working on remote machine over a modem line or through a gateway.
  31
  32 ;; It works by translating xterm escape codes into generic emacs mouse
  33 ;; events so it should work with any package that uses the mouse.
  34
  35 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  36 ;; functionality, it is still available by holding down the SHIFT key
  37 ;; when you press the mouse button.
  38
  39 ;;; Todo:
  40
  41 ;; The xterm mouse escape codes are supposedly also supported by the
  42 ;; Linux console, but I have not been able to verify this.
  43
  44 ;; Support multi-click -- somehow.
  45
  46 ;;; Code:
  47
  48 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  49
  50 (defvar xterm-mouse-last)
  51
  52 ;; Mouse events symbols must have an 'event-kind property with
  53 ;; the value 'mouse-click.
  54 (dolist (event-type '(mouse-1 mouse-2 mouse-3))
  55   (put event-type 'event-kind 'mouse-click))
  56
  57 (defun xterm-mouse-translate (event)
  58   "Read a click and release event from XTerm."
  59   (save-excursion
  60     (save-window-excursion
  61       (deactivate-mark)
  62       (let* ((xterm-mouse-last)
  63              (down (xterm-mouse-event))
  64              (down-command (nth 0 down))
  65              (down-data (nth 1 down))
  66              (down-where (nth 1 down-data))
  67              (down-binding (key-binding (if (symbolp down-where)
  68                                             (vector down-where down-command)
  69                                           (vector down-command))))
  70              (is-click (string-match "^mouse" (symbol-name (car down)))))
  71
  72         (unless is-click
  73           (unless (and (eq (read-char) ?\e)
  74                        (eq (read-char) ?\[)
  75                        (eq (read-char) ?M))
  76             (error "Unexpected escape sequence from XTerm")))
  77
  78         (let* ((click (if is-click down (xterm-mouse-event)))
  79                (click-command (nth 0 click))
  80                (click-data (nth 1 click))
  81                (click-where (nth 1 click-data)))
  82           (if (memq down-binding '(nil ignore))
  83               (if (and (symbolp click-where)
  84                        (consp click-where))
  85                   (vector (list click-where click-data) click)
  86                 (vector click))
  87             (setq unread-command-events
  88                   (if (eq down-where click-where)
  89                       (list click)
  90                     (list
  91                      ;; Cheat `mouse-drag-region' with move event.
  92                      (list 'mouse-movement click-data)
  93                      ;; Generate a drag event.
  94                      (if (symbolp down-where)
  95                          0
  96                        (list (intern (format "drag-mouse-%d"
  97                                              (+ 1 xterm-mouse-last)))
  98                              down-data click-data)))))
  99             (if (and (symbolp down-where)
 100                      (consp down-where))
 101                 (vector (list down-where down-data) down)
 102               (vector down))))))))
 103
 104 (defvar xterm-mouse-x 0
 105   "Position of last xterm mouse event relative to the frame.")
 106
 107 (defvar xterm-mouse-y 0
 108   "Position of last xterm mouse event relative to the frame.")
 109
 110 ;; Indicator for the xterm-mouse mode.
 111
 112 (defun xterm-mouse-position-function (pos)
 113   "Bound to `mouse-position-function' in XTerm mouse mode."
 114   (setcdr pos (cons xterm-mouse-x xterm-mouse-y))
 115   pos)
 116
 117 ;; read xterm sequences above ascii 127 (#x7f)
 118 (defun xterm-mouse-event-read ()
 119   (let ((c (read-char)))
 120     (if (< c 0)
 121         (+ c #x8000000 128)
 122       c)))
 123
 124 (defun xterm-mouse-event ()
 125   "Convert XTerm mouse event to Emacs mouse event."
 126   (let* ((type (- (xterm-mouse-event-read) #o40))
 127          (x (- (xterm-mouse-event-read) #o40 1))
 128          (y (- (xterm-mouse-event-read) #o40 1))
 129          (mouse (intern
 130                  ;; For buttons > 3, the release-event looks
 131                  ;; differently (see xc/programs/xterm/button.c,
 132                  ;; function EditorButton), and there seems to come in
 133                  ;; a release-event only, no down-event.
 134                  (cond ((>= type 64)
 135                         (format "mouse-%d" (- type 60)))
 136                        ((= type 3)
 137                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 138                        (t
 139                         (setq xterm-mouse-last type)
 140                         (format "down-mouse-%d" (+ 1 type))))))
 141          (w (window-at x y))
 142          (ltrb (window-edges w))
 143          (left (nth 0 ltrb))
 144          (top (nth 1 ltrb)))
 145
 146     (setq xterm-mouse-x x
 147           xterm-mouse-y y)
 148     (if w
 149         (list mouse (posn-at-x-y (- x left) (- y top) w t))
 150       (list mouse
 151             (append (list nil 'menu-bar) (nthcdr 2 (posn-at-x-y x y w t)))))))
 152
 153 ;;;###autoload
 154 (define-minor-mode xterm-mouse-mode
 155   "Toggle XTerm mouse mode.
 156 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 157
 158 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 159 This works in terminal emulators compatible with xterm.  It only
 160 works for simple uses of the mouse.  Basically, only non-modified
 161 single clicks are supported.  When turned on, the normal xterm
 162 mouse functionality for such clicks is still available by holding
 163 down the SHIFT key while pressing the mouse button."
 164   :global t :group 'mouse
 165   (if xterm-mouse-mode
 166       ;; Turn it on
 167       (unless window-system
 168         (setq mouse-position-function #'xterm-mouse-position-function)
 169         (turn-on-xterm-mouse-tracking))
 170     ;; Turn it off
 171     (turn-off-xterm-mouse-tracking 'force)
 172     (setq mouse-position-function nil)))
 173
 174 (defun turn-on-xterm-mouse-tracking ()
 175   "Enable Emacs mouse tracking in xterm."
 176   (if xterm-mouse-mode
 177       (send-string-to-terminal "\e[?1000h")))
 178
 179 (defun turn-off-xterm-mouse-tracking (&optional force)
 180   "Disable Emacs mouse tracking in xterm."
 181   (if (or force xterm-mouse-mode)
 182       (send-string-to-terminal "\e[?1000l")))
 183
 184 ;; Restore normal mouse behaviour outside Emacs.
 185 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 186 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 187 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 188
 189 (provide 'xt-mouse)
 190
 191 ;;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 192 ;;; xt-mouse.el ends here