lisp/gnus/gnus-gravatar.el

   1 ;;; gnus-gravatar.el --- Gnus Gravatar support
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gravatar)
  28 (require 'gnus-art)
  29
  30 (defgroup gnus-gravatar nil
  31   "Gnus Gravatar."
  32   :group 'gnus-visual)
  33
  34 (defcustom gnus-gravatar-size 32
  35   "How big should gravatars be displayed."
  36   :type 'integer
  37   :version "24.1"
  38   :group 'gnus-gravatar)
  39
  40 (defcustom gnus-gravatar-properties '(:ascent center :relief 1)
  41   "List of image properties applied to Gravatar images."
  42   :type 'list
  43   :version "24.1"
  44   :group 'gnus-gravatar)
  45
  46 (defcustom gnus-gravatar-too-ugly gnus-article-x-face-too-ugly
  47   "Regexp matching posters whose avatar shouldn't be shown automatically."
  48   :type '(choice regexp (const nil))
  49   :version "24.1"
  50   :group 'gnus-gravatar)
  51
  52 (defun gnus-gravatar-transform-address (header category &optional force)
  53   (gnus-with-article-headers
  54     (let ((addresses
  55            (mail-header-parse-addresses
  56             ;; mail-header-parse-addresses does not work (reliably) on
  57             ;; decoded headers.
  58             (or
  59              (ignore-errors
  60                (mail-encode-encoded-word-string
  61                 (or (mail-fetch-field header) "")))
  62              (mail-fetch-field header))))
  63           (gravatar-size gnus-gravatar-size)
  64           name)
  65       (dolist (address addresses)
  66         (when (or force
  67                   (not (and gnus-gravatar-too-ugly
  68                             (or (string-match gnus-gravatar-too-ugly
  69                                               (car address))
  70                                 (and (setq name (cdr address))
  71                                      (string-match gnus-gravatar-too-ugly
  72                                                    name))))))
  73           (ignore-errors
  74             (gravatar-retrieve
  75              (car address)
  76              'gnus-gravatar-insert
  77              (list header address category))))))))
  78
  79 (defun gnus-gravatar-insert (gravatar header address category)
  80   "Insert GRAVATAR for ADDRESS in HEADER in current article buffer.
  81 Set image category to CATEGORY."
  82   (unless (eq gravatar 'error)
  83     (gnus-with-article-headers
  84       ;; The buffer can be gone at this time
  85       (when (buffer-live-p (current-buffer))
  86         (gnus-article-goto-header header)
  87         (mail-header-narrow-to-field)
  88         (let ((real-name (cdr address))
  89               (mail-address (car address)))
  90           (when (if real-name             ; have a realname, go for it!
  91                     (and (search-forward real-name nil t)
  92                          (search-backward real-name nil t))
  93                   (and (search-forward mail-address nil t)
  94                        (search-backward mail-address nil t)))
  95             (goto-char (1- (point)))
  96             ;; If we're on the " quoting the name, go backward
  97             (when (looking-at "[\"<]")
  98               (goto-char (1- (point))))
  99             ;; Do not do anything if there's already a gravatar. This can
 100             ;; happens if the buffer has been regenerated in the mean time, for
 101             ;; example we were fetching someaddress, and then we change to
 102             ;; another mail with the same someaddress.
 103             (unless (memq 'gnus-gravatar (text-properties-at (point)))
 104               (let ((inhibit-read-only t)
 105                     (point (point)))
 106                 (unless (featurep 'xemacs)
 107                   (setq gravatar (append gravatar gnus-gravatar-properties)))
 108                 (gnus-put-image gravatar nil category)
 109                 (put-text-property point (point) 'gnus-gravatar address)
 110                 (gnus-add-wash-type category)
 111                 (gnus-add-image category gravatar)))))))))
 112
 113 ;;;###autoload
 114 (defun gnus-treat-from-gravatar (&optional force)
 115   "Display gravatar in the From header.
 116 If gravatar is already displayed, remove it."
 117   (interactive (list t)) ;; When type `W D g'
 118   (gnus-with-article-buffer
 119     (if (memq 'from-gravatar gnus-article-wash-types)
 120         (gnus-delete-images 'from-gravatar)
 121       (gnus-gravatar-transform-address "from" 'from-gravatar force))))
 122
 123 ;;;###autoload
 124 (defun gnus-treat-mail-gravatar (&optional force)
 125   "Display gravatars in the Cc and To headers.
 126 If gravatars are already displayed, remove them."
 127   (interactive (list t)) ;; When type `W D h'
 128     (gnus-with-article-buffer
 129       (if (memq 'mail-gravatar gnus-article-wash-types)
 130           (gnus-delete-images 'mail-gravatar)
 131         (gnus-gravatar-transform-address "cc" 'mail-gravatar force)
 132         (gnus-gravatar-transform-address "to" 'mail-gravatar force))))
 133
 134 (provide 'gnus-gravatar)
 135
 136 ;;; gnus-gravatar.el ends here