lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985-1986, 2001-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Richard King
   6 ;; (according to authors.el)
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Keywords: internal
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file is autoloaded to handle certain conditions
  29 ;; detected by the file-locking code within Emacs.
  30 ;; The two entry points are `ask-user-about-lock' and
  31 ;; `ask-user-about-supersession-threat'.
  32
  33 ;;; Code:
  34
  35 (define-error 'file-locked "File is locked" 'file-error)
  36
  37 ;;;###autoload
  38 (defun ask-user-about-lock (file opponent)
  39   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  40 This function has a choice of three things to do:
  41   do (signal \\='file-locked (list FILE OPPONENT))
  42     to refrain from editing the file
  43   return t (grab the lock on the file)
  44   return nil (edit the file even though it is locked).
  45 You can redefine this function to choose among those three alternatives
  46 in any way you like."
  47   (discard-input)
  48   (save-window-excursion
  49     (let (answer short-opponent short-file)
  50       (setq short-file
  51             (if (> (length file) 22)
  52                 (concat "..." (substring file (- (length file) 22)))
  53               file))
  54       (setq short-opponent
  55             (if (> (length opponent) 25)
  56                 (save-match-data
  57                   (string-match " (pid [0-9]+)" opponent)
  58                   (concat (substring opponent 0 13) "..."
  59                           (match-string 0 opponent)))
  60               opponent))
  61       (while (null answer)
  62         (message "%s locked by %s: (s, q, p, ?)? "
  63                  short-file short-opponent)
  64         (let ((tem (let ((inhibit-quit t)
  65                          (cursor-in-echo-area t))
  66                      (prog1 (downcase (read-char))
  67                             (setq quit-flag nil)))))
  68           (if (= tem help-char)
  69               (ask-user-about-lock-help)
  70             (setq answer (assoc tem '((?s . t)
  71                                       (?q . yield)
  72                                       (?\C-g . yield)
  73                                       (?p . nil)
  74                                       (?? . help))))
  75             (cond ((null answer)
  76                    (beep)
  77                    (message "Please type q, s, or p; or ? for help")
  78                    (sit-for 3))
  79                   ((eq (cdr answer) 'help)
  80                    (ask-user-about-lock-help)
  81                    (setq answer nil))
  82                   ((eq (cdr answer) 'yield)
  83                    (signal 'file-locked (list file opponent)))))))
  84       (cdr answer))))
  85
  86 (defun ask-user-about-lock-help ()
  87   (with-output-to-temp-buffer "*Help*"
  88     (princ "It has been detected that you want to modify a file that someone else has
  89 already started modifying in Emacs.
  90
  91 You can <s>teal the file; the other user becomes the
  92   intruder if (s)he ever unmodifies the file and then changes it again.
  93 You can <p>roceed; you edit at your own (and the other user's) risk.
  94 You can <q>uit; don't modify this file.")
  95     (with-current-buffer standard-output
  96       (help-mode))))
  97
  98 (define-error 'file-supersession nil 'file-error)
  99
 100 (defun userlock--check-content-unchanged (fn)
 101   (with-demoted-errors "Unchanged content check: %S"
 102     ;; Even tho we receive `fn', we know that `fn' refers to the current
 103     ;; buffer's file.
 104     (cl-assert (equal fn (expand-file-name buffer-file-truename)))
 105     ;; Note: rather than read the file and compare to the buffer, we could save
 106     ;; the buffer and compare to the file, but for encrypted data this
 107     ;; wouldn't work well (and would risk exposing the data).
 108     (save-restriction
 109       (widen)
 110       (let ((buf (current-buffer))
 111             (cs buffer-file-coding-system)
 112             (start (point-min))
 113             (end (point-max)))
 114         ;; FIXME: To avoid a slow `insert-file-contents' on large or
 115         ;; remote files, it'd be good to include file size in the
 116         ;; "visited-modtime" check.
 117         (when (with-temp-buffer
 118                 (let ((coding-system-for-read cs)
 119                       (non-essential t))
 120                   (insert-file-contents fn))
 121                 (when (= (buffer-size) (- end start)) ;Minor optimization.
 122                   (= 0 (let ((case-fold-search nil))
 123                          (compare-buffer-substrings
 124                           buf start end
 125                           (current-buffer) (point-min) (point-max))))))
 126           (set-visited-file-modtime)
 127           'unchanged)))))
 128
 129 ;;;###autoload
 130 (defun userlock--ask-user-about-supersession-threat (fn)
 131   ;; Called from filelock.c.
 132   (unless (userlock--check-content-unchanged fn)
 133     (ask-user-about-supersession-threat fn)))
 134
 135 ;;;###autoload
 136 (defun ask-user-about-supersession-threat (fn)
 137   "Ask a user who is about to modify an obsolete buffer what to do.
 138 This function has two choices: it can return, in which case the modification
 139 of the buffer will proceed, or it can (signal \\='file-supersession (file)),
 140 in which case the proposed buffer modification will not be made.
 141
 142 You can rewrite this to use any criterion you like to choose which one to do.
 143 The buffer in question is current when this function is called."
 144   (discard-input)
 145   (save-window-excursion
 146     (let ((prompt
 147            (format "%s changed on disk; \
 148 really edit the buffer? (y, n, r or C-h) "
 149                    (file-name-nondirectory fn)))
 150           (choices '(?y ?n ?r ?? ?\C-h))
 151           answer)
 152       (while (null answer)
 153         (setq answer (read-char-choice prompt choices))
 154         (cond ((memq answer '(?? ?\C-h))
 155                (ask-user-about-supersession-help)
 156                (setq answer nil))
 157               ((eq answer ?r)
 158                ;; Ask for confirmation if buffer modified
 159                (revert-buffer nil (not (buffer-modified-p)))
 160                (signal 'file-supersession
 161                        (list "File reverted" fn)))
 162               ((eq answer ?n)
 163                (signal 'file-supersession
 164                        (list "File changed on disk" fn)))))
 165       (message
 166        "File on disk now will become a backup file if you save these changes.")
 167       (setq buffer-backed-up nil))))
 168
 169 (defun ask-user-about-supersession-help ()
 170   (with-output-to-temp-buffer "*Help*"
 171     (princ "You want to modify a buffer whose disk file has changed
 172 since you last read it in or saved it with this buffer.
 173
 174 If you say `y' to go ahead and modify this buffer,
 175 you risk ruining the work of whoever rewrote the file.
 176 If you say `r' to revert, the contents of the buffer are refreshed
 177 from the file on disk.
 178 If you say `n', the change you started to make will be aborted.
 179
 180 Usually, you should type `n' and then `\\[revert-buffer]',
 181 to get the latest version of the file, then make the change again.")
 182     (with-current-buffer standard-output
 183       (help-mode))))
 184
 185 ;;; userlock.el ends here