lisp/mail/ietf-drums.el

   1 ;;; ietf-drums.el --- Functions for parsing RFC822bis headers
   2
   3 ;; Copyright (C) 1998-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; DRUMS is an IETF Working Group that works (or worked) on the
  24 ;; successor to RFC822, "Standard For The Format Of Arpa Internet Text
  25 ;; Messages".  This library is based on
  26 ;; draft-ietf-drums-msg-fmt-05.txt, released on 1998-08-05.
  27
  28 ;; Pending a real regression self test suite, Simon Josefsson added
  29 ;; various self test expressions snipped from bug reports, and their
  30 ;; expected value, below.  I you believe it could be useful, please
  31 ;; add your own test cases, or write a real self test suite, or just
  32 ;; remove this.
  33
  34 ;; <m3oekvfd50.fsf@whitebox.m5r.de>
  35 ;; (ietf-drums-parse-address "'foo' <foo@example.com>")
  36 ;; => ("foo@example.com" . "'foo'")
  37
  38 ;;; Code:
  39
  40 (eval-when-compile (require 'cl))
  41
  42 (defvar ietf-drums-no-ws-ctl-token "\001-\010\013\014\016-\037\177"
  43   "US-ASCII control characters excluding CR, LF and white space.")
  44 (defvar ietf-drums-text-token "\001-\011\013\014\016-\177"
  45   "US-ASCII characters excluding CR and LF.")
  46 (defvar ietf-drums-specials-token "()<>[]:;@\\,.\""
  47   "Special characters.")
  48 (defvar ietf-drums-quote-token "\\"
  49   "Quote character.")
  50 (defvar ietf-drums-wsp-token " \t"
  51   "White space.")
  52 (defvar ietf-drums-fws-regexp
  53   (concat "[" ietf-drums-wsp-token "]*\n[" ietf-drums-wsp-token "]+")
  54   "Folding white space.")
  55 (defvar ietf-drums-atext-token "-^a-zA-Z0-9!#$%&'*+/=?_`{|}~"
  56   "Textual token.")
  57 (defvar ietf-drums-dot-atext-token "-^a-zA-Z0-9!#$%&'*+/=?_`{|}~."
  58   "Textual token including full stop.")
  59 (defvar ietf-drums-qtext-token
  60   (concat ietf-drums-no-ws-ctl-token "\041\043-\133\135-\177")
  61   "Non-white-space control characters, plus the rest of ASCII excluding
  62 backslash and doublequote.")
  63 (defvar ietf-drums-tspecials "][()<>@,;:\\\"/?="
  64   "Tspecials.")
  65
  66 (defvar ietf-drums-syntax-table
  67   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  68     (modify-syntax-entry ?\\ "/" table)
  69     (modify-syntax-entry ?< "(" table)
  70     (modify-syntax-entry ?> ")" table)
  71     (modify-syntax-entry ?@ "w" table)
  72     (modify-syntax-entry ?/ "w" table)
  73     (modify-syntax-entry ?* "_" table)
  74     (modify-syntax-entry ?\; "_" table)
  75     (modify-syntax-entry ?\' "_" table)
  76     table))
  77
  78 (defun ietf-drums-token-to-list (token)
  79   "Translate TOKEN into a list of characters."
  80   (let ((i 0)
  81         b e c out range)
  82     (while (< i (length token))
  83       (setq c (aref token i))
  84       (incf i)
  85       (cond
  86        ((eq c ?-)
  87         (if b
  88             (setq range t)
  89           (push c out)))
  90        (range
  91         (while (<= b c)
  92           (push (make-char 'ascii b) out)
  93           (incf b))
  94         (setq range nil))
  95        ((= i (length token))
  96         (push (make-char 'ascii c) out))
  97        (t
  98         (when b
  99           (push (make-char 'ascii b) out))
 100         (setq b c))))
 101     (nreverse out)))
 102
 103 (defsubst ietf-drums-init (string)
 104   (set-syntax-table ietf-drums-syntax-table)
 105   (insert string)
 106   (ietf-drums-unfold-fws)
 107   (goto-char (point-min)))
 108
 109 (defun ietf-drums-remove-comments (string)
 110   "Remove comments from STRING."
 111   (with-temp-buffer
 112     (let (c)
 113       (ietf-drums-init string)
 114       (while (not (eobp))
 115         (setq c (char-after))
 116         (cond
 117          ((eq c ?\")
 118           (condition-case err
 119               (forward-sexp 1)
 120             (error (goto-char (point-max)))))
 121          ((eq c ?\()
 122           (delete-region
 123                (point)
 124                (condition-case nil
 125                    (with-syntax-table (copy-syntax-table ietf-drums-syntax-table)
 126                      (modify-syntax-entry ?\" "w")
 127                      (forward-sexp 1)
 128                      (point))
 129                  (error (point-max)))))
 130          (t
 131           (forward-char 1))))
 132       (buffer-string))))
 133
 134 (defun ietf-drums-remove-whitespace (string)
 135   "Remove whitespace from STRING."
 136   (with-temp-buffer
 137     (ietf-drums-init string)
 138     (let (c)
 139       (while (not (eobp))
 140         (setq c (char-after))
 141         (cond
 142          ((eq c ?\")
 143           (forward-sexp 1))
 144          ((eq c ?\()
 145           (forward-sexp 1))
 146          ((memq c '(?\  ?\t ?\n))
 147           (delete-char 1))
 148          (t
 149           (forward-char 1))))
 150       (buffer-string))))
 151
 152 (defun ietf-drums-get-comment (string)
 153   "Return the first comment in STRING."
 154   (with-temp-buffer
 155     (ietf-drums-init string)
 156     (let (result c)
 157       (while (not (eobp))
 158         (setq c (char-after))
 159         (cond
 160          ((eq c ?\")
 161           (forward-sexp 1))
 162          ((eq c ?\()
 163           (setq result
 164                 (buffer-substring
 165                  (1+ (point))
 166                  (progn (forward-sexp 1) (1- (point))))))
 167          (t
 168           (forward-char 1))))
 169       result)))
 170
 171 (defun ietf-drums-strip (string)
 172   "Remove comments and whitespace from STRING."
 173   (ietf-drums-remove-whitespace (ietf-drums-remove-comments string)))
 174
 175 (defun ietf-drums-parse-address (string)
 176   "Parse STRING and return a MAILBOX / DISPLAY-NAME pair."
 177   (with-temp-buffer
 178     (let (display-name mailbox c display-string)
 179       (ietf-drums-init string)
 180       (while (not (eobp))
 181         (setq c (char-after))
 182         (cond
 183          ((or (eq c ? )
 184               (eq c ?\t))
 185           (forward-char 1))
 186          ((eq c ?\()
 187           (forward-sexp 1))
 188          ((eq c ?\")
 189           (push (buffer-substring
 190                  (1+ (point)) (progn (forward-sexp 1) (1- (point))))
 191                 display-name))
 192          ((looking-at (concat "[" ietf-drums-atext-token "@" "]"))
 193           (push (buffer-substring (point) (progn (forward-sexp 1) (point)))
 194                 display-name))
 195          ((eq c ?<)
 196           (setq mailbox
 197                 (ietf-drums-remove-whitespace
 198                  (ietf-drums-remove-comments
 199                   (buffer-substring
 200                    (1+ (point))
 201                    (progn (forward-sexp 1) (1- (point))))))))
 202          (t
 203           (forward-char 1))))
 204       ;; If we found no display-name, then we look for comments.
 205       (if display-name
 206           (setq display-string
 207                 (mapconcat 'identity (reverse display-name) " "))
 208         (setq display-string (ietf-drums-get-comment string)))
 209       (if (not mailbox)
 210           (when (and display-string
 211                      (string-match "@" display-string))
 212             (cons
 213              (mapconcat 'identity (nreverse display-name) "")
 214              (ietf-drums-get-comment string)))
 215         (cons mailbox display-string)))))
 216
 217 (defun ietf-drums-parse-addresses (string &optional rawp)
 218   "Parse STRING and return a list of MAILBOX / DISPLAY-NAME pairs.
 219 If RAWP, don't actually parse the addresses, but instead return
 220 a list of address strings."
 221   (if (null string)
 222       nil
 223     (with-temp-buffer
 224       (ietf-drums-init string)
 225       (let ((beg (point))
 226             pairs c address)
 227         (while (not (eobp))
 228           (setq c (char-after))
 229           (cond
 230            ((memq c '(?\" ?< ?\())
 231             (condition-case nil
 232                 (forward-sexp 1)
 233               (error
 234                (skip-chars-forward "^,"))))
 235            ((eq c ?,)
 236             (setq address
 237                   (if rawp
 238                       (buffer-substring beg (point))
 239                     (condition-case nil
 240                         (ietf-drums-parse-address
 241                          (buffer-substring beg (point)))
 242                       (error nil))))
 243             (if address (push address pairs))
 244             (forward-char 1)
 245             (setq beg (point)))
 246            (t
 247             (forward-char 1))))
 248         (setq address
 249               (if rawp
 250                   (buffer-substring beg (point))
 251                 (condition-case nil
 252                     (ietf-drums-parse-address
 253                      (buffer-substring beg (point)))
 254                   (error nil))))
 255         (if address (push address pairs))
 256         (nreverse pairs)))))
 257
 258 (defun ietf-drums-unfold-fws ()
 259   "Unfold folding white space in the current buffer."
 260   (goto-char (point-min))
 261   (while (re-search-forward ietf-drums-fws-regexp nil t)
 262     (replace-match " " t t))
 263   (goto-char (point-min)))
 264
 265 (defun ietf-drums-parse-date (string)
 266   "Return an Emacs time spec from STRING."
 267   (apply 'encode-time (parse-time-string string)))
 268
 269 (defun ietf-drums-narrow-to-header ()
 270   "Narrow to the header section in the current buffer."
 271   (narrow-to-region
 272    (goto-char (point-min))
 273    (if (re-search-forward "^\r?$" nil 1)
 274        (match-beginning 0)
 275      (point-max)))
 276   (goto-char (point-min)))
 277
 278 (defun ietf-drums-quote-string (string)
 279   "Quote string if it needs quoting to be displayed in a header."
 280   (if (string-match (concat "[^" ietf-drums-atext-token "]") string)
 281       (concat "\"" string "\"")
 282     string))
 283
 284 (defun ietf-drums-make-address (name address)
 285   (if name
 286       (concat (ietf-drums-quote-string name) " <" address ">")
 287     address))
 288
 289 (provide 'ietf-drums)
 290
 291 ;;; ietf-drums.el ends here