lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 (eval-when-compile (require 'cl))
  95
  96 ;;; PRIVATE: defsubst must be defined before they are first used
  97
  98 (defsubst derived-mode-hook-name (mode)
  99   "Construct the mode hook name based on mode name MODE."
 100   (intern (concat (symbol-name mode) "-hook")))
 101
 102 (defsubst derived-mode-map-name (mode)
 103   "Construct a map name based on a MODE name."
 104   (intern (concat (symbol-name mode) "-map")))
 105
 106 (defsubst derived-mode-syntax-table-name (mode)
 107   "Construct a syntax-table name based on a MODE name."
 108   (intern (concat (symbol-name mode) "-syntax-table")))
 109
 110 (defsubst derived-mode-abbrev-table-name (mode)
 111   "Construct an abbrev-table name based on a MODE name."
 112   (intern (concat (symbol-name mode) "-abbrev-table")))
 113
 114 ;; PUBLIC: define a new major mode which inherits from an existing one.
 115
 116 ;;;###autoload
 117 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 118   "Create a new mode as a variant of an existing mode.
 119
 120 The arguments to this command are as follow:
 121
 122 CHILD:     the name of the command for the derived mode.
 123 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 124            or nil if there is no parent.
 125 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 126 DOCSTRING: an optional documentation string--if you do not supply one,
 127            the function will attempt to invent something useful.
 128 BODY:      forms to execute just before running the
 129            hooks for the new mode.  Do not use `interactive' here.
 130
 131 BODY can start with a bunch of keyword arguments.  The following keyword
 132   arguments are currently understood:
 133 :group GROUP
 134         Declare the customization group that corresponds to this mode.
 135 :syntax-table TABLE
 136         Use TABLE instead of the default.
 137         A nil value means to simply use the same syntax-table as the parent.
 138 :abbrev-table TABLE
 139         Use TABLE instead of the default.
 140         A nil value means to simply use the same abbrev-table as the parent.
 141
 142 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 143
 144   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 145
 146 You could then make new key bindings for `LaTeX-thesis-mode-map'
 147 without changing regular LaTeX mode.  In this example, BODY is empty,
 148 and DOCSTRING is generated by default.
 149
 150 On a more complicated level, the following command uses `sgml-mode' as
 151 the parent, and then sets the variable `case-fold-search' to nil:
 152
 153   (define-derived-mode article-mode sgml-mode \"Article\"
 154     \"Major mode for editing technical articles.\"
 155     (setq case-fold-search nil))
 156
 157 Note that if the documentation string had been left out, it would have
 158 been generated automatically, with a reference to the keymap."
 159
 160   (when (and docstring (not (stringp docstring)))
 161     ;; Some trickiness, since what appears to be the docstring may really be
 162     ;; the first element of the body.
 163     (push docstring body)
 164     (setq docstring nil))
 165
 166   (when (eq parent 'fundamental-mode) (setq parent nil))
 167
 168   (let ((map (derived-mode-map-name child))
 169         (syntax (derived-mode-syntax-table-name child))
 170         (abbrev (derived-mode-abbrev-table-name child))
 171         (declare-abbrev t)
 172         (declare-syntax t)
 173         (hook (derived-mode-hook-name child))
 174         (group nil))
 175
 176     ;; Process the keyword args.
 177     (while (keywordp (car body))
 178       (case (pop body)
 179         (:group (setq group (pop body)))
 180         (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 181         (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 182         (t (pop body))))
 183
 184     (setq docstring (derived-mode-make-docstring
 185                      parent child docstring syntax abbrev))
 186
 187     `(progn
 188        (defvar ,map (make-sparse-keymap))
 189        ,(if declare-syntax
 190             `(defvar ,syntax (make-syntax-table)))
 191        ,(if declare-abbrev
 192             `(defvar ,abbrev
 193                (progn (define-abbrev-table ',abbrev nil) ,abbrev)))
 194        (put ',child 'derived-mode-parent ',parent)
 195        ,(if group `(put ',child 'custom-mode-group ,group))
 196
 197        (defun ,child ()
 198          ,docstring
 199          (interactive)
 200                                         ; Run the parent.
 201          (delay-mode-hooks
 202
 203           (,(or parent 'kill-all-local-variables))
 204                                         ; Identify the child mode.
 205           (setq major-mode (quote ,child))
 206           (setq mode-name ,name)
 207                                         ; Identify special modes.
 208           ,(when parent
 209              `(progn
 210                 (if (get (quote ,parent) 'mode-class)
 211                     (put (quote ,child) 'mode-class
 212                          (get (quote ,parent) 'mode-class)))
 213                                         ; Set up maps and tables.
 214                 (unless (keymap-parent ,map)
 215                   (set-keymap-parent ,map (current-local-map)))
 216                 ,(when declare-syntax
 217                    `(let ((parent (char-table-parent ,syntax)))
 218                       (unless (and parent
 219                                    (not (eq parent (standard-syntax-table))))
 220                         (set-char-table-parent ,syntax (syntax-table)))))))
 221
 222           (use-local-map ,map)
 223           ,(when syntax `(set-syntax-table ,syntax))
 224           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 225                                         ; Splice in the body (if any).
 226           ,@body
 227           )
 228                                         ; Run the hooks, if any.
 229          (run-mode-hooks ',hook)))))
 230
 231 ;; PUBLIC: find the ultimate class of a derived mode.
 232
 233 (defun derived-mode-class (mode)
 234   "Find the class of a major MODE.
 235 A mode's class is the first ancestor which is NOT a derived mode.
 236 Use the `derived-mode-parent' property of the symbol to trace backwards.
 237 Since major-modes might all derive from `fundamental-mode', this function
 238 is not very useful."
 239   (while (get mode 'derived-mode-parent)
 240     (setq mode (get mode 'derived-mode-parent)))
 241   mode)
 242 (make-obsolete 'derived-mode-class 'derived-mode-p "21.4")
 243
 244 \f
 245 ;;; PRIVATE
 246
 247 (defun derived-mode-make-docstring (parent child &optional
 248                                            docstring syntax abbrev)
 249   "Construct a docstring for a new mode if none is provided."
 250
 251   (let ((map (derived-mode-map-name child))
 252         (hook (derived-mode-hook-name child)))
 253
 254     (unless (stringp docstring)
 255       ;; Use a default docstring.
 256       (setq docstring
 257             (if (null parent)
 258                 (format "Major-mode.
 259 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 260               (format "Major mode derived from `%s' by `define-derived-mode'.
 261 It inherits all of the parent's attributes, but has its own keymap,
 262 abbrev table and syntax table:
 263
 264   `%s', `%s' and `%s'
 265
 266 which more-or-less shadow %s's corresponding tables."
 267                       parent map abbrev syntax parent))))
 268
 269     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 270       ;; Make sure the docstring mentions the mode's hook.
 271       (setq docstring
 272             (concat docstring
 273                     (if (null parent)
 274                         "\n\nThis mode "
 275                       (concat
 276                        "\n\nIn addition to any hooks its parent mode "
 277                        (if (string-match (regexp-quote (format "`%s'" parent))
 278                                          docstring) nil
 279                          (format "`%s' " parent))
 280                        "might have run,\nthis mode "))
 281                     (format "runs the hook `%s'" hook)
 282                     ", as the final step\nduring initialization.")))
 283
 284     (unless (string-match "\\\\[{[]" docstring)
 285       ;; And don't forget to put the mode's keymap.
 286       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 287
 288     docstring))
 289
 290 \f
 291 ;;; OBSOLETE
 292 ;; The functions below are only provided for backward compatibility with
 293 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 294
 295 (defsubst derived-mode-setup-function-name (mode)
 296   "Construct a setup-function name based on a MODE name."
 297   (intern (concat (symbol-name mode) "-setup")))
 298
 299 \f
 300 ;; Utility functions for defining a derived mode.
 301
 302 ;;;###autoload
 303 (defun derived-mode-init-mode-variables (mode)
 304   "Initialise variables for a new MODE.
 305 Right now, if they don't already exist, set up a blank keymap, an
 306 empty syntax table, and an empty abbrev table -- these will be merged
 307 the first time the mode is used."
 308
 309   (if (boundp (derived-mode-map-name mode))
 310       t
 311     (eval `(defvar ,(derived-mode-map-name mode)
 312                (make-sparse-keymap)
 313                ,(format "Keymap for %s." mode)))
 314     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 315
 316   (if (boundp (derived-mode-syntax-table-name mode))
 317       t
 318     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 319              ;; Make a syntax table which doesn't specify anything
 320              ;; for any char.  Valid data will be merged in by
 321              ;; derived-mode-merge-syntax-tables.
 322              (make-char-table 'syntax-table nil)
 323              ,(format "Syntax table for %s." mode)))
 324     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 325
 326   (if (boundp (derived-mode-abbrev-table-name mode))
 327       t
 328     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 329              (progn
 330                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 331                (make-abbrev-table))
 332              ,(format "Abbrev table for %s." mode)))))
 333 \f
 334 ;; Utility functions for running a derived mode.
 335
 336 (defun derived-mode-set-keymap (mode)
 337   "Set the keymap of the new MODE, maybe merging with the parent."
 338   (let* ((map-name (derived-mode-map-name mode))
 339          (new-map (eval map-name))
 340          (old-map (current-local-map)))
 341     (and old-map
 342          (get map-name 'derived-mode-unmerged)
 343          (derived-mode-merge-keymaps old-map new-map))
 344     (put map-name 'derived-mode-unmerged nil)
 345     (use-local-map new-map)))
 346
 347 (defun derived-mode-set-syntax-table (mode)
 348   "Set the syntax table of the new MODE, maybe merging with the parent."
 349   (let* ((table-name (derived-mode-syntax-table-name mode))
 350          (old-table (syntax-table))
 351          (new-table (eval table-name)))
 352     (if (get table-name 'derived-mode-unmerged)
 353         (derived-mode-merge-syntax-tables old-table new-table))
 354     (put table-name 'derived-mode-unmerged nil)
 355     (set-syntax-table new-table)))
 356
 357 (defun derived-mode-set-abbrev-table (mode)
 358   "Set the abbrev table for MODE if it exists.
 359 Always merge its parent into it, since the merge is non-destructive."
 360   (let* ((table-name (derived-mode-abbrev-table-name mode))
 361          (old-table local-abbrev-table)
 362          (new-table (eval table-name)))
 363     (derived-mode-merge-abbrev-tables old-table new-table)
 364     (setq local-abbrev-table new-table)))
 365
 366 ;;;(defun derived-mode-run-setup-function (mode)
 367 ;;;  "Run the setup function if it exists."
 368
 369 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 370 ;;;    (if (fboundp fname)
 371 ;;;     (funcall fname))))
 372
 373 (defun derived-mode-run-hooks (mode)
 374   "Run the mode hook for MODE."
 375   (let ((hooks-name (derived-mode-hook-name mode)))
 376     (if (boundp hooks-name)
 377         (run-hooks hooks-name))))
 378
 379 ;; Functions to merge maps and tables.
 380
 381 (defun derived-mode-merge-keymaps (old new)
 382   "Merge an OLD keymap into a NEW one.
 383 The old keymap is set to be the last cdr of the new one, so that there will
 384 be automatic inheritance."
 385   ;; ?? Can this just use `set-keymap-parent'?
 386   (let ((tail new))
 387     ;; Scan the NEW map for prefix keys.
 388     (while (consp tail)
 389       (and (consp (car tail))
 390            (let* ((key (vector (car (car tail))))
 391                   (subnew (lookup-key new key))
 392                   (subold (lookup-key old key)))
 393              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 394              (and (keymapp subnew) (keymapp subold)
 395                   (derived-mode-merge-keymaps subold subnew))))
 396       (and (vectorp (car tail))
 397            ;; Search a vector of ASCII char bindings for prefix keys.
 398            (let ((i (1- (length (car tail)))))
 399              (while (>= i 0)
 400                (let* ((key (vector i))
 401                       (subnew (lookup-key new key))
 402                       (subold (lookup-key old key)))
 403                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 404                  (and (keymapp subnew) (keymapp subold)
 405                       (derived-mode-merge-keymaps subold subnew)))
 406                (setq i (1- i)))))
 407       (setq tail (cdr tail))))
 408   (setcdr (nthcdr (1- (length new)) new) old))
 409
 410 (defun derived-mode-merge-syntax-tables (old new)
 411   "Merge an OLD syntax table into a NEW one.
 412 Where the new table already has an entry, nothing is copied from the old one."
 413   (set-char-table-parent new old))
 414
 415 ;; Merge an old abbrev table into a new one.
 416 ;; This function requires internal knowledge of how abbrev tables work,
 417 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 418 ;; as the value of the symbol, and the hook as the function definition.
 419 (defun derived-mode-merge-abbrev-tables (old new)
 420   (if old
 421       (mapatoms
 422        (lambda (symbol)
 423          (or (intern-soft (symbol-name symbol) new)
 424              (define-abbrev new (symbol-name symbol)
 425                (symbol-value symbol) (symbol-function symbol))))
 426        old)))
 427
 428 (provide 'derived)
 429
 430 ;;; derived.el ends here