lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;;; Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.ai.mit.edu>,
   6 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Keywords: unix
   8
   9 ;;; This program is free software; you can redistribute it and/or modify
  10 ;;; it under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 2, or (at your option)
  12 ;;; any later version.
  13 ;;;
  14 ;;; This program is distributed in the hope that it will be useful,
  15 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; A copy of the GNU General Public License can be obtained from this
  20 ;;; program's author (send electronic mail to roland@ai.mit.edu) or from
  21 ;;; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  22 ;;; 02139, USA.
  23 ;;;
  24
  25 ;;; Code:
  26
  27 (require 'dired)
  28
  29 ;; find's -ls corresponds to these switches.
  30 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  31 ;;;###autoload
  32 (defvar find-ls-option (if (eq system-type 'berkeley-unix) '("-ls" . "-gilsb")
  33                          '("-exec ls -ld {} \\;" . "-ld"))
  34   "*Description of the option to `find' to produce an `ls -l'-type listing.
  35 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  36 gives the option (or options) to `find' that produce the desired output.
  37 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output.")
  38
  39 ;;;###autoload
  40 (defvar find-grep-options (if (eq system-type 'berkeley-unix) "-s" "-q")
  41   "*Option to grep to be as silent as possible.
  42 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  43 On other systems, the closest you can come is to use `-l'.")
  44
  45 (defvar find-args nil
  46   "Last arguments given to `find' by \\[find-dired].")
  47
  48 ;; History of find-args values entered in the minibuffer.
  49 (defvar find-args-history nil)
  50
  51 ;;;###autoload
  52 (defun find-dired (dir args)
  53   "Run `find' and go into dired-mode on a buffer of the output.
  54 The command run (after changing into DIR) is
  55
  56     find . \\( ARGS \\) -ls"
  57   (interactive (list (read-file-name "Run find in directory: " nil "" t)
  58                      (read-string "Run find (with args): " find-args
  59                                   '(find-args-history . 1))))
  60   ;; Expand DIR ("" means default-directory), and make sure it has a
  61   ;; trailing slash.
  62   (setq dir (file-name-as-directory (expand-file-name dir)))
  63   ;; Check that it's really a directory.
  64   (or (file-directory-p dir)
  65       (error "find-dired needs a directory: %s" dir))
  66   (switch-to-buffer (get-buffer-create "*Find*"))
  67   (widen)
  68   (kill-all-local-variables)
  69   (setq buffer-read-only nil)
  70   (erase-buffer)
  71   (setq default-directory dir
  72         find-args args                  ; save for next interactive call
  73         args (concat "find . "
  74                      (if (string= args "")
  75                          ""
  76                        (concat "\\( " args " \\) "))
  77                      (car find-ls-option)))
  78   ;; The next statement will bomb in classic dired (no optional arg allowed)
  79   (dired-mode dir (cdr find-ls-option))
  80   ;; This really should rerun the find command, but I don't
  81   ;; have time for that.
  82   (use-local-map (append (make-sparse-keymap) (current-local-map)))
  83   (define-key (current-local-map) "g" 'undefined)
  84   ;; Set subdir-alist so that Tree Dired will work:
  85   (if (fboundp 'dired-simple-subdir-alist)
  86       ;; will work even with nested dired format (dired-nstd.el,v 1.15
  87       ;; and later)
  88       (dired-simple-subdir-alist)
  89     ;; else we have an ancient tree dired (or classic dired, where
  90     ;; this does no harm)
  91     (set (make-local-variable 'dired-subdir-alist)
  92          (list (cons default-directory (point-min-marker)))))
  93   (setq buffer-read-only nil)
  94   ;; Subdir headlerline must come first because the first marker in
  95   ;; subdir-alist points there.
  96   (insert "  " dir ":\n")
  97   ;; Make second line a ``find'' line in analogy to the ``total'' or
  98   ;; ``wildcard'' line.
  99   (insert "  " args "\n")
 100   ;; Start the find process.
 101   (let ((proc (start-process-shell-command "find" (current-buffer) args)))
 102     (set-process-filter proc (function find-dired-filter))
 103     (set-process-sentinel proc (function find-dired-sentinel))
 104     ;; Initialize the process marker; it is used by the filter.
 105     (move-marker (process-mark proc) 1 (current-buffer)))
 106   (setq mode-line-process '(":%s")))
 107
 108 ;;;###autoload
 109 (defun find-name-dired (dir pattern)
 110   "Search DIR recursively for files matching the globbing pattern PATTERN,
 111 and run dired on those files.
 112 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 113 The command run (after changing into DIR) is
 114
 115     find . -name 'PATTERN' -ls"
 116   (interactive
 117    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 118   (find-dired dir (concat "-name '" pattern "'")))
 119
 120 ;; This functionality suggested by
 121 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 122 ;; Subject: find-dired, lookfor-dired
 123 ;; Date: 10 May 91 17:50:00 GMT
 124 ;; Organization: University of Waterloo
 125
 126 (defalias 'lookfor-dired 'find-grep-dired)
 127 ;;;###autoload
 128 (defun find-grep-dired (dir args)
 129   "Find files in DIR containing a regexp ARG and start Dired on output.
 130 The command run (after changing into DIR) is
 131
 132     find . -exec grep -s ARG {} \\\; -ls
 133
 134 Thus ARG can also contain additional grep options."
 135   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 136   ;; find -exec doesn't allow shell i/o redirections in the command,
 137   ;; or we could use `grep -l >/dev/null'
 138   (find-dired dir
 139               (concat "! -type d -exec grep " find-grep-options " "
 140                       args " {} \\\; ")))
 141
 142 (defun find-dired-filter (proc string)
 143   ;; Filter for \\[find-dired] processes.
 144   (let ((buf (process-buffer proc)))
 145     (if (buffer-name buf)               ; not killed?
 146         (save-excursion
 147           (set-buffer buf)
 148           (save-restriction
 149             (widen)
 150             (save-excursion
 151               (let ((buffer-read-only nil)
 152                     (end (point-max)))
 153                 (goto-char end)
 154                 (insert string)
 155                 (goto-char end)
 156                 (or (looking-at "^")
 157                     (forward-line 1))
 158                 (while (looking-at "^")
 159                   (insert "  ")
 160                   (forward-line 1))
 161                 ;; Convert ` ./FILE' to ` FILE'
 162                 ;; This would lose if the current chunk of output
 163                 ;; starts or ends within the ` ./', so back up a bit:
 164                 (goto-char (- end 3))   ; no error if < 0
 165                 (while (search-forward " ./" nil t)
 166                   (delete-region (point) (- (point) 2)))
 167                 ;; Find all the complete lines in the unprocessed
 168                 ;; output and process it to add text properties.
 169                 (goto-char end)
 170                 (if (search-backward "\n" (process-mark proc) t)
 171                     (progn
 172                       (dired-insert-set-properties (process-mark proc)
 173                                                    (1+ (point)))
 174                       (move-marker (process-mark proc) (1+ (point)))))
 175                 ))))
 176       ;; The buffer has been killed.
 177       (delete-process proc))))
 178
 179 (defun find-dired-sentinel (proc state)
 180   ;; Sentinel for \\[find-dired] processes.
 181   (let ((buf (process-buffer proc)))
 182     (if (buffer-name buf)
 183         (save-excursion
 184           (set-buffer buf)
 185           (let ((buffer-read-only nil))
 186             (save-excursion
 187               (goto-char (point-max))
 188               (insert "\nfind " state)
 189               (forward-char -1)         ;Back up before \n at end of STATE.
 190               (insert " at " (substring (current-time-string) 0 19))
 191               (forward-char 1)
 192               (setq mode-line-process
 193                     (concat ":"
 194                             (symbol-name (process-status proc))))
 195               ;; Since the buffer and mode line will show that the
 196               ;; process is dead, we can delete it now.  Otherwise it
 197               ;; will stay around until M-x list-processes.
 198               (delete-process proc)
 199               (force-mode-line-update)))
 200           (message "find-dired %s finished." (current-buffer))))))
 201 \f
 202 (provide 'find-dired)
 203
 204 ;;; find-dired.el ends here