lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.08
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Purpose:
  28 ;;
  29 ;; To make visiting a file in `font-lock-mode' faster by restoring its face
  30 ;; text properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55
  56 ;; Feedback:
  57 ;;
  58 ;; Feedback is welcome.
  59 ;; To submit a bug report (or make comments) please use the mechanism provided:
  60 ;;
  61 ;; M-x fast-lock-submit-bug-report RET
  62 \f
  63 ;; History:
  64 ;;
  65 ;; 0.02--1.00:
  66 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only.
  67 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode.
  68 ;; 1.00--1.01:
  69 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'.
  70 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil.
  71 ;; - Moved save-all conditions to `fast-lock-save-cache'.
  72 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'.
  73 ;; 1.01--2.00: complete rewrite---not worth the space to document.
  74 ;; - Changed structure of text properties cache and threw out file mod checks.
  75 ;; 2.00--2.01:
  76 ;; - Made `condition-case' forms understand `quit'.
  77 ;; - Made `fast-lock' require `font-lock'.
  78 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit).
  79 ;; 2.01--3.00:
  80 ;; - Changed structure of cache to include `font-lock-keywords' (from rms).
  81 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'.
  82 ;; - Removed `fast-lock-read-others'.
  83 ;; - Made `fast-lock-read-cache' ignore cache owner.
  84 ;; - Made `fast-lock-save-cache-external' create cache directory.
  85 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'.
  86 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'.
  87 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw.
  88 ;; - Package now provides itself.
  89 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'.
  90 ;; - Lucid: Use `list-faces' for `face-list'.
  91 ;; - Lucid: Added `set-text-properties'.
  92 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'.
  93 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'.
  94 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'.
  95 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw.
  96 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera).
  97 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw).
  98 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'.
  99 ;; 3.02--3.03:
 100 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'.
 101 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'.
 102 ;; 3.03--3.04:
 103 ;; - Corrected `subrp' test of Lucid code.
 104 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'.
 105 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents.
 106 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty).
 107 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory.
 108 ;; 3.04--3.05:
 109 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'.
 110 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'.
 111 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation.
 112 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey).
 113 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey).
 114 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig).
 115 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'.
 116 ;; - XEmacs: Removed `list-faces' `defalias'.
 117 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies.
 118 ;; - Added `lazy-lock-submit-bug-report'.
 119 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'.
 120 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted.
 121 ;; - Made `fast-lock-save-cache-data' output a message if save attempted.
 122 ;; - Made `fast-lock-cache-data' output a message if load attempted.
 123 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'.
 124 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing.
 125 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig).
 126 ;; - Added `fast-lock-save-events'.
 127 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig).
 128 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'.
 129 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'.
 130 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'.
 131 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig).
 132 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig).
 133 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it.
 134 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name.
 135 ;; - Added `fast-lock-after-fontify-buffer'.
 136 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor).
 137 ;; - Made `fast-lock-get-face-properties' functions use it.
 138 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way.
 139 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped).
 140 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on.
 141 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster).
 142 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster).
 143 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym).
 144 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'.
 145 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary.
 146 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'.
 147 ;; 3.06--3.07:
 148 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook.
 149 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'.
 150 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'.
 151 ;; 3.07--3.08:
 152 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'.
 153 \f
 154 (require 'font-lock)
 155
 156 (eval-when-compile
 157   ;; Shut Emacs' byte-compiler up (cf. stop me getting mail from users).
 158   (setq byte-compile-warnings '(free-vars callargs redefine)))
 159
 160 (defun fast-lock-submit-bug-report ()
 161   "Submit via mail a bug report on fast-lock.el."
 162   (interactive)
 163   (let ((reporter-prompt-for-summary-p t))
 164     (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.08"
 165      '(fast-lock-cache-directories fast-lock-minimum-size
 166        fast-lock-save-others fast-lock-save-events fast-lock-save-faces)
 167      nil nil
 168      (concat "Hi Si.,
 169
 170 I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 171 know how to make a clear and unambiguous report.  To reproduce the bug:
 172
 173 Start a fresh Emacs via `" invocation-name " -no-init-file -no-site-file'.
 174 In the `*scratch*' buffer, evaluate:"))))
 175
 176 ;;;###autoload
 177 (defvar fast-lock-mode nil)             ; for modeline
 178 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 179 (defvar fast-lock-cache-filename nil)   ; for deleting
 180 \f
 181 ;; User Variables:
 182
 183 (defvar fast-lock-cache-directories '("." "~/.emacs-flc")
 184 ; - `internal', keep each file's Font Lock cache file in the same file.
 185 ; - `external', keep each file's Font Lock cache file in the same directory.
 186   "Directories in which Font Lock cache files are saved and read.
 187 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 188 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 189
 190 An attempt will be made to save or read Font Lock cache files using these items
 191 until one succeeds (i.e., until a readable or writable one is found).  If an
 192 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 193 For example:
 194
 195  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 196    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 197     =>
 198  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 199
 200 would cause a file's current directory to be used if the file is under your
 201 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.")
 202
 203 (defvar fast-lock-minimum-size (* 25 1024)
 204   "If non-nil, the minimum size for buffers.
 205 Only buffers more than this can have associated Font Lock cache files saved.
 206 If nil, means size is irrelevant.")
 207
 208 (defvar fast-lock-save-events '(kill-buffer kill-emacs)
 209   "A list of events under which caches will be saved.
 210 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 211 If concurrent editing sessions use the same associated cache file for a file's
 212 buffer, then you should add `save-buffer' to this list.")
 213
 214 (defvar fast-lock-save-others t
 215   "If non-nil, save Font Lock cache files irrespective of file owner.
 216 If nil, means only buffer files known to be owned by you can have associated
 217 Font Lock cache files saved.  Ownership may be unknown for networked files.")
 218
 219 (defvar fast-lock-save-faces
 220   ;; Since XEmacs uses extents for everything, we have to pick the right ones.
 221   ;; In XEmacs 19.13 we can't identify which text properties are Font Lock's.
 222   (if (save-match-data (string-match "XEmacs" (emacs-version)))
 223       '(font-lock-string-face font-lock-doc-string-face font-lock-type-face
 224         font-lock-function-name-face font-lock-comment-face
 225         font-lock-keyword-face font-lock-preprocessor-face)
 226     ;; For Emacs 19.30 I don't think this is generally necessary.
 227     nil)
 228   "A list of faces that will be saved in a Font Lock cache file.
 229 If nil, means information for all faces will be saved.")
 230 \f
 231 ;; User Functions:
 232
 233 ;;;###autoload
 234 (defun fast-lock-mode (&optional arg)
 235   "Toggle Fast Lock mode.
 236 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 237 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 238
 239  (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 240
 241 If Fast Lock mode is enabled, and the current buffer does not contain any text
 242 properties, any associated Font Lock cache is used if its timestamp matches the
 243 buffer's file, and its `font-lock-keywords' match those that you are using.
 244
 245 Font Lock caches may be saved:
 246  - When you save the file's buffer.
 247  - When you kill an unmodified file's buffer.
 248  - When you exit Emacs, for all unmodified or saved buffers.
 249 Depending on the value of `fast-lock-save-events'.
 250 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 251
 252 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 253
 254 Various methods of control are provided for the Font Lock cache.  In general,
 255 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 256 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 257 `fast-lock-save-others' and `fast-lock-save-faces'.
 258
 259 Use \\[fast-lock-submit-bug-report] to send bug reports or feedback."
 260   (interactive "P")
 261   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 262   ;; but many packages temporarily wrap that to nil when doing their own thing.
 263   (set (make-local-variable 'fast-lock-mode)
 264        (and buffer-file-truename
 265             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 266   (if (and fast-lock-mode (not font-lock-mode))
 267       ;; Turned on `fast-lock-mode' rather than using `font-lock-mode-hook'.
 268       (progn
 269         (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 270         (font-lock-mode t))
 271     ;; Let's get down to business.
 272     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 273     (set (make-local-variable 'fast-lock-cache-filename) nil)
 274     (if (and fast-lock-mode (not font-lock-fontified))
 275         (fast-lock-read-cache))))
 276
 277 (defun fast-lock-read-cache ()
 278   "Read the Font Lock cache for the current buffer.
 279
 280 The following criteria must be met for a Font Lock cache file to be read:
 281  - Fast Lock mode must be turned on in the buffer.
 282  - The buffer must not be modified.
 283  - The buffer's `font-lock-keywords' must match the cache's.
 284  - The buffer file's timestamp must match the cache's.
 285  - Criteria imposed by `fast-lock-cache-directories'.
 286
 287 See `fast-lock-mode'."
 288   (interactive)
 289   (let ((directories fast-lock-cache-directories)
 290         (modified (buffer-modified-p)) (inhibit-read-only t)
 291         (fontified font-lock-fontified))
 292     (set (make-local-variable 'font-lock-fontified) nil)
 293     ;; Keep trying directories until fontification is turned off.
 294     (while (and directories (not font-lock-fontified))
 295       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 296         (if (not directory)
 297             nil
 298           (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 299           (condition-case nil
 300               (if (file-readable-p fast-lock-cache-filename)
 301                   (load fast-lock-cache-filename t t t))
 302             (error nil) (quit nil)))
 303         (setq directories (cdr directories))))
 304     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 305     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 306     ;; of `fast-lock-cache-timestamp'.)
 307     (set-buffer-modified-p modified)
 308     (if (not font-lock-fontified)
 309         (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 310
 311 (defun fast-lock-save-cache (&optional buffer)
 312   "Save the Font Lock cache of BUFFER or the current buffer.
 313
 314 The following criteria must be met for a Font Lock cache file to be saved:
 315  - Fast Lock mode must be turned on in the buffer.
 316  - The event must be one of `fast-lock-save-events'.
 317  - The buffer must be at least `fast-lock-minimum-size' bytes long.
 318  - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 319  - The buffer must contain at least one `face' text property.
 320  - The buffer must not be modified.
 321  - The buffer file's timestamp must be the same as the file's on disk.
 322  - The on disk file's timestamp must be different than the buffer's cache.
 323  - Criteria imposed by `fast-lock-cache-directories'.
 324
 325 See `fast-lock-mode'."
 326   (interactive)
 327   (save-excursion
 328     (and buffer (set-buffer buffer))
 329     (let ((file-timestamp (visited-file-modtime)) (saved nil))
 330       (if (and fast-lock-mode
 331                ;;
 332                ;; "Only save if the buffer matches the file, the file has
 333                ;; changed, and it was changed by the current emacs session."
 334                ;;
 335                ;; Only save if the buffer is not modified,
 336                ;; (i.e., so we don't save for something not on disk)
 337                (not (buffer-modified-p))
 338                ;; and the file's timestamp is the same as the buffer's,
 339                ;; (i.e., someone else hasn't written the file in the meantime)
 340                (verify-visited-file-modtime (current-buffer))
 341                ;; and the file's timestamp is different from the cache's.
 342                ;; (i.e., a save has occurred since the cache was read)
 343                (not (equal fast-lock-cache-timestamp file-timestamp))
 344                ;;
 345                ;; Only save if user's restrictions are satisfied.
 346                (or (not fast-lock-minimum-size)
 347                    (<= fast-lock-minimum-size (buffer-size)))
 348                (or fast-lock-save-others
 349                    (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 350                ;;
 351                ;; Only save if there are `face' properties to save.
 352                (text-property-not-all (point-min) (point-max) 'face nil))
 353           ;; Try each directory until we manage to save or the user quits.
 354           (let ((directories fast-lock-cache-directories))
 355             (while (and directories (memq saved '(nil error)))
 356               (let* ((dir (fast-lock-cache-directory (car directories) t))
 357                      (file (and dir (fast-lock-cache-name dir))))
 358                 (if (and file (file-writable-p file))
 359                     (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 360                 (setq directories (cdr directories)))))))))
 361
 362 ;;;###autoload
 363 (defun turn-on-fast-lock ()
 364   "Unconditionally turn on Fast Lock mode."
 365   (fast-lock-mode t))
 366 \f
 367 ;;; API Functions:
 368
 369 (defun fast-lock-after-fontify-buffer ()
 370   ;; Delete the Font Lock cache file used to restore fontification, if any.
 371   (if fast-lock-cache-filename
 372       (if (file-writable-p fast-lock-cache-filename)
 373           (delete-file fast-lock-cache-filename)
 374         (message "File %s font lock cache cannot be deleted" (buffer-name))))
 375   ;; Flag so that a cache will be saved later even if the file is never saved.
 376   (setq fast-lock-cache-timestamp nil))
 377 \f
 378 ;; Miscellaneous Functions:
 379
 380 (defun fast-lock-after-save-hook ()
 381   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 382   (if (memq 'save-buffer fast-lock-save-events)
 383       (fast-lock-save-cache)))
 384
 385 (defun fast-lock-kill-buffer-hook ()
 386   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 387   (if (memq 'kill-buffer fast-lock-save-events)
 388       (fast-lock-save-cache)))
 389
 390 (defun fast-lock-kill-emacs-hook ()
 391   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 392   (if (memq 'kill-emacs fast-lock-save-events)
 393       (mapcar 'fast-lock-save-cache (buffer-list))))
 394
 395 (defun fast-lock-cache-directory (directory create)
 396   "Return usable directory based on DIRECTORY.
 397 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 398 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 399 See `fast-lock-cache-directories'."
 400   (let ((dir
 401          (cond ((not buffer-file-name)
 402                 ;; Should never be nil, but `crypt++' screws it up.
 403                 nil)
 404                ((stringp directory)
 405                 ;; Just a directory.
 406                 directory)
 407                (t
 408                 ;; A directory iff the file name matches the regexp.
 409                 (let ((bufile (expand-file-name buffer-file-truename))
 410                       (case-fold-search nil))
 411                   (if (save-match-data (string-match (car directory) bufile))
 412                       (cdr directory)))))))
 413     (cond ((not dir)
 414            nil)
 415           ((file-accessible-directory-p dir)
 416            dir)
 417           (create
 418            (condition-case nil
 419                (progn (make-directory dir t) dir)
 420              (error nil))))))
 421
 422 ;; If you are wondering why we only hash if the directory is not ".", rather
 423 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 424 ;; relative cache directories (that are not ".") then it is possible that more
 425 ;; than one file would have the same cache name in that directory, if the luser
 426 ;; made a link from one relative cache directory to another.  (Phew!)
 427 (defun fast-lock-cache-name (directory)
 428   "Return full cache path name using caching DIRECTORY.
 429 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 430 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 431 abbreviated file name, with all `/' characters in the name replaced with `#'
 432 characters, and appended with `.flc'.
 433
 434 If the same file has different cache path names when edited on different
 435 machines, e.g., on one machine the cache file name has the prefix `#home',
 436 perhaps due to automount, try putting in your `~/.emacs' something like:
 437
 438  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 439
 440 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 441
 442 See `fast-lock-cache-directory'."
 443   (if (string-equal directory ".")
 444       (concat buffer-file-name ".flc")
 445     (let* ((bufile (expand-file-name buffer-file-truename))
 446            (chars-alist
 447             (if (eq system-type 'emx)
 448                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 449               '((?/ . (?#)) (?# . (?# ?#)))))
 450            (mapchars
 451             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 452       (concat
 453        (file-name-as-directory (expand-file-name directory))
 454        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 455        ".flc"))))
 456 \f
 457 ;; Font Lock Cache Processing Functions:
 458
 459 (defun fast-lock-save-cache-1 (file timestamp)
 460   ;; Save the FILE with the TIMESTAMP as:
 461   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 462   ;; Returns non-nil if a save was attempted to a writable cache file.
 463   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 464         (buname (buffer-name)) (saved t))
 465     (message "Saving %s font lock cache..." buname)
 466     (condition-case nil
 467         (save-excursion
 468           (print (list 'fast-lock-cache-data 2
 469                        (list 'quote timestamp)
 470                        (list 'quote font-lock-keywords)
 471                        (list 'quote (fast-lock-get-face-properties)))
 472                  tpbuf)
 473           (set-buffer tpbuf)
 474           (write-region (point-min) (point-max) file nil 'quietly)
 475           (setq fast-lock-cache-timestamp timestamp
 476                 fast-lock-cache-filename file))
 477       (error (setq saved 'error)) (quit (setq saved 'quit)))
 478     (kill-buffer tpbuf)
 479     (message "Saving %s font lock cache... %s." buname
 480              (cond ((eq saved 'error) "failed")
 481                    ((eq saved 'quit) "aborted")
 482                    (t "done")))
 483     ;; We return non-nil regardless of whether a failure occurred.
 484     saved))
 485
 486 (defun fast-lock-cache-data (version timestamp keywords properties
 487                              &rest ignored)
 488   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 489   (if (consp (cdr-safe timestamp)) (setcdr timestamp (nth 1 timestamp)))
 490   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 491   (let ((current font-lock-keywords))
 492     (setq keywords (font-lock-compile-keywords keywords)
 493           font-lock-keywords (font-lock-compile-keywords current)))
 494   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 495   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 496   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 497   (let ((buf-timestamp (visited-file-modtime))
 498         (buname (buffer-name)) (loaded t))
 499     (if (or (/= version 2)
 500             (buffer-modified-p)
 501             (not (equal timestamp buf-timestamp))
 502             (not (equal keywords font-lock-keywords)))
 503         (setq loaded nil)
 504       (message "Loading %s font lock cache..." buname)
 505       (condition-case nil
 506           (fast-lock-set-face-properties properties)
 507         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 508       (message "Loading %s font lock cache... %s." buname
 509                (cond ((eq loaded 'error) "failed")
 510                      ((eq loaded 'quit) "aborted")
 511                      (t "done"))))
 512     (setq font-lock-fontified (eq loaded t)
 513           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 514 \f
 515 ;; Text Properties Processing Functions:
 516
 517 ;; This is faster, but fails if adjacent characters have different `face' text
 518 ;; properties.  Maybe that's why I dropped it in the first place?
 519 ;(defun fast-lock-get-face-properties ()
 520 ;  "Return a list of all `face' text properties in the current buffer.
 521 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 522 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 523 ;  (save-restriction
 524 ;    (widen)
 525 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 526 ;         (limit (point-max)) end properties value cell)
 527 ;      (while start
 528 ;       (setq end (next-single-property-change start 'face nil limit)
 529 ;             value (get-text-property start 'face))
 530 ;       ;; Make, or add to existing, list of regions with same `face'.
 531 ;       (if (setq cell (assq value properties))
 532 ;           (setcdr cell (cons start (cons end (cdr cell))))
 533 ;         (setq properties (cons (list value start end) properties)))
 534 ;       (setq start (next-single-property-change end 'face)))
 535 ;      properties)))
 536
 537 (defun fast-lock-get-face-properties ()
 538   "Return a list of all `face' text properties in the current buffer.
 539 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 540 where VALUE is a `face' property value and STARTx and ENDx are positions.
 541 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 542   (save-restriction
 543     (widen)
 544     (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 545           properties regions face start end)
 546       (while faces
 547         (setq face (car faces) faces (cdr faces) regions () end (point-min))
 548         ;; Make a list of start/end regions with `face' property face.
 549         (while (setq start (text-property-any end limit 'face face))
 550           (setq end (or (text-property-not-all start limit 'face face) limit)
 551                 regions (cons start (cons end regions))))
 552         ;; Add `face' face's regions, if any, to properties.
 553         (if regions (setq properties (cons (cons face regions) properties))))
 554       properties)))
 555
 556 (defun fast-lock-set-face-properties (properties)
 557   "Set all `face' text properties to PROPERTIES in the current buffer.
 558 Any existing `face' text properties are removed first.  Leaves buffer modified.
 559 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 560   (save-restriction
 561     (widen)
 562     (font-lock-unfontify-region (point-min) (point-max))
 563     (while properties
 564       (let ((plist (list 'face (car (car properties))))
 565             (regions (cdr (car properties))))
 566         ;; Set the `face' property for each start/end region.
 567         (while regions
 568           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 569           (setq regions (nthcdr 2 regions)))
 570         (setq properties (cdr properties))))))
 571 \f
 572 ;; Functions for XEmacs:
 573
 574 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 575     ;; It would be better to use XEmacs 19.12's `map-extents' over extents with
 576     ;; `font-lock' property, but `face' properties are on different extents.
 577     (defun fast-lock-get-face-properties ()
 578       "Return a list of all `face' text properties in the current buffer.
 579 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 580 where VALUE is a `face' property value and STARTx and ENDx are positions.
 581 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 582       (save-restriction
 583         (widen)
 584         (let ((properties ()) cell)
 585           (map-extents
 586            (function
 587             (lambda (extent ignore)
 588               (let ((value (extent-face extent)))
 589                 ;; We're only interested if it's one of `fast-lock-save-faces'.
 590                 (if (and value (or (null fast-lock-save-faces)
 591                                    (memq value fast-lock-save-faces)))
 592                     (let ((start (extent-start-position extent))
 593                           (end (extent-end-position extent)))
 594                       ;; Make or add to existing list of regions with the same
 595                       ;; `face' property value.
 596                       (if (setq cell (assq value properties))
 597                           (setcdr cell (cons start (cons end (cdr cell))))
 598                         (setq properties (cons (list value start end)
 599                                                properties)))))
 600                 ;; Return nil to keep `map-extents' going.
 601                 nil))))
 602           properties))))
 603
 604 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 605     ;; Make extents just like XEmacs's font-lock.el does.
 606     (defun fast-lock-set-face-properties (properties)
 607       "Set all `face' text properties to PROPERTIES in the current buffer.
 608 Any existing `face' text properties are removed first.
 609 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 610       (save-restriction
 611         (widen)
 612         (font-lock-unfontify-region (point-min) (point-max))
 613         (while properties
 614           (let ((face (car (car properties)))
 615                 (regions (cdr (car properties))))
 616             ;; Set the `face' property, etc., for each start/end region.
 617             (while regions
 618               (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 619               (setq regions (nthcdr 2 regions)))
 620             (setq properties (cdr properties)))))))
 621
 622 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 623     ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 624     (add-hook 'font-lock-after-fontify-buffer-hook
 625               'fast-lock-after-fontify-buffer))
 626
 627 (or (fboundp 'font-lock-compile-keywords)
 628     (defalias 'font-lock-compile-keywords 'identity))
 629 \f
 630 ;; Install ourselves:
 631
 632 ;; We don't install ourselves on `font-lock-mode-hook' as packages with similar
 633 ;; functionality exist, and fast-lock.el should be dumpable without forcing
 634 ;; people to use caches or making it difficult for people to use alternatives.
 635 (add-hook 'after-save-hook 'fast-lock-after-save-hook)
 636 (add-hook 'kill-buffer-hook 'fast-lock-kill-buffer-hook)
 637 (add-hook 'kill-emacs-hook 'fast-lock-kill-emacs-hook)
 638
 639 ;; Maybe save on the modeline?
 640 ;;(setcdr (assq 'font-lock-mode minor-mode-alist) '(" Fast"))
 641
 642 (or (assq 'fast-lock-mode minor-mode-alist)
 643     (setq minor-mode-alist (cons '(fast-lock-mode " Fast") minor-mode-alist)))
 644
 645 ;; Provide ourselves:
 646
 647 (provide 'fast-lock)
 648
 649 ;;; fast-lock.el ends here