lisp/vc-rcs.el

   1 ;;; vc-rcs.el --- support for RCS version-control
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2004  Free Software Foundation, Inc.
   5
   6 ;; Author:     FSF (see vc.el for full credits)
   7 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; $Id$
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; See vc.el
  31
  32 ;;; Code:
  33
  34 ;;;
  35 ;;; Customization options
  36 ;;;
  37
  38 (eval-when-compile
  39   (require 'cl)
  40   (require 'vc))
  41
  42 (defcustom vc-rcs-release nil
  43   "*The release number of your RCS installation, as a string.
  44 If nil, VC itself computes this value when it is first needed."
  45   :type '(choice (const :tag "Auto" nil)
  46                  (string :tag "Specified")
  47                  (const :tag "Unknown" unknown))
  48   :group 'vc)
  49
  50 (defcustom vc-rcs-register-switches nil
  51   "*Extra switches for registering a file in RCS.
  52 A string or list of strings.  These are passed to the checkin program
  53 by \\[vc-rcs-register]."
  54   :type '(choice (const :tag "None" nil)
  55                  (string :tag "Argument String")
  56                  (repeat :tag "Argument List"
  57                          :value ("")
  58                          string))
  59   :version "21.1"
  60   :group 'vc)
  61
  62 (defcustom vc-rcs-diff-switches nil
  63   "*A string or list of strings specifying extra switches for rcsdiff under VC."
  64   :type '(choice (const :tag "None" nil)
  65                  (string :tag "Argument String")
  66                  (repeat :tag "Argument List"
  67                          :value ("")
  68                          string))
  69   :version "21.1"
  70   :group 'vc)
  71
  72 (defcustom vc-rcs-header (or (cdr (assoc 'RCS vc-header-alist)) '("\$Id\$"))
  73   "*Header keywords to be inserted by `vc-insert-headers'."
  74   :type '(repeat string)
  75   :version "21.1"
  76   :group 'vc)
  77
  78 (defcustom vc-rcsdiff-knows-brief nil
  79   "*Indicates whether rcsdiff understands the --brief option.
  80 The value is either `yes', `no', or nil.  If it is nil, VC tries
  81 to use --brief and sets this variable to remember whether it worked."
  82   :type '(choice (const :tag "Work out" nil) (const yes) (const no))
  83   :group 'vc)
  84
  85 ;;;###autoload
  86 (defcustom vc-rcs-master-templates
  87   '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s")
  88   "*Where to look for RCS master files.
  89 For a description of possible values, see `vc-check-master-templates'."
  90   :type '(choice (const :tag "Use standard RCS file names"
  91                         '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
  92                  (repeat :tag "User-specified"
  93                          (choice string
  94                                  function)))
  95   :version "21.1"
  96   :group 'vc)
  97
  98 \f
  99 ;;;
 100 ;;; State-querying functions
 101 ;;;
 102
 103 ;;; The autoload cookie below places vc-rcs-registered directly into
 104 ;;; loaddefs.el, so that vc-rcs.el does not need to be loaded for
 105 ;;; every file that is visited.  The definition is repeated below
 106 ;;; so that Help and etags can find it.
 107
 108 ;;;###autoload (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 109 (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 110
 111 (defun vc-rcs-state (file)
 112   "Implementation of `vc-state' for RCS."
 113   (or (boundp 'vc-rcs-headers-result)
 114       (and vc-consult-headers
 115            (vc-rcs-consult-headers file)))
 116   (let ((state
 117          ;; vc-workfile-version might not be known; in that case the
 118          ;; property is nil.  vc-rcs-fetch-master-state knows how to
 119          ;; handle that.
 120          (vc-rcs-fetch-master-state file
 121                                     (vc-file-getprop file
 122                                                      'vc-workfile-version))))
 123     (if (not (eq state 'up-to-date))
 124         state
 125       (if (vc-workfile-unchanged-p file)
 126           'up-to-date
 127         (if (eq (vc-checkout-model file) 'locking)
 128             'unlocked-changes
 129           'edited)))))
 130
 131 (defun vc-rcs-state-heuristic (file)
 132   "State heuristic for RCS."
 133   (let (vc-rcs-headers-result)
 134     (if (and vc-consult-headers
 135              (setq vc-rcs-headers-result
 136                    (vc-rcs-consult-headers file))
 137              (eq vc-rcs-headers-result 'rev-and-lock))
 138         (let ((state (vc-file-getprop file 'vc-state)))
 139           ;; If the headers say that the file is not locked, the
 140           ;; permissions can tell us whether locking is used for
 141           ;; the file or not.
 142           (if (and (eq state 'up-to-date)
 143                    (not (vc-mistrust-permissions file)))
 144               (cond
 145                ((string-match ".rw..-..-." (nth 8 (file-attributes file)))
 146                 (vc-file-setprop file 'vc-checkout-model 'implicit)
 147                 (setq state
 148                       (if (vc-rcs-workfile-is-newer file)
 149                           'edited
 150                         'up-to-date)))
 151                ((string-match ".r-..-..-." (nth 8 (file-attributes file)))
 152                 (vc-file-setprop file 'vc-checkout-model 'locking))))
 153           state)
 154       (if (not (vc-mistrust-permissions file))
 155           (let* ((attributes  (file-attributes file))
 156                  (owner-uid   (nth 2 attributes))
 157                  (permissions (nth 8 attributes)))
 158             (cond ((string-match ".r-..-..-." permissions)
 159                    (vc-file-setprop file 'vc-checkout-model 'locking)
 160                    'up-to-date)
 161                   ((string-match ".rw..-..-." permissions)
 162                    (if (eq (vc-checkout-model file) 'locking)
 163                        (if (file-ownership-preserved-p file)
 164                            'edited
 165                          (vc-user-login-name owner-uid))
 166                      (if (vc-rcs-workfile-is-newer file)
 167                          'edited
 168                        'up-to-date)))
 169                   (t
 170                    ;; Strange permissions.  Fall through to
 171                    ;; expensive state computation.
 172                    (vc-rcs-state file))))
 173         (vc-rcs-state file)))))
 174
 175 (defun vc-rcs-workfile-version (file)
 176   "RCS-specific version of `vc-workfile-version'."
 177   (or (and vc-consult-headers
 178            (vc-rcs-consult-headers file)
 179            (vc-file-getprop file 'vc-workfile-version))
 180       (progn
 181         (vc-rcs-fetch-master-state file)
 182         (vc-file-getprop file 'vc-workfile-version))))
 183
 184 (defun vc-rcs-latest-on-branch-p (file &optional version)
 185   "Return non-nil if workfile version of FILE is the latest on its branch.
 186 When VERSION is given, perform check for that version."
 187   (unless version (setq version (vc-workfile-version file)))
 188   (with-temp-buffer
 189     (string= version
 190              (if (vc-trunk-p version)
 191                  (progn
 192                    ;; Compare VERSION to the head version number.
 193                    (vc-insert-file (vc-name file) "^[0-9]")
 194                    (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 195                ;; If we are not on the trunk, we need to examine the
 196                ;; whole current branch.
 197                (vc-insert-file (vc-name file) "^desc")
 198                (vc-rcs-find-most-recent-rev (vc-branch-part version))))))
 199
 200 (defun vc-rcs-checkout-model (file)
 201   "RCS-specific version of `vc-checkout-model'."
 202   (let (result)
 203     (when vc-consult-headers
 204       (vc-file-setprop file 'vc-checkout-model nil)
 205       (vc-rcs-consult-headers file)
 206       (setq result (vc-file-getprop file 'vc-checkout-model)))
 207     (or result
 208         (progn (vc-rcs-fetch-master-state file)
 209                (vc-file-getprop file 'vc-checkout-model)))))
 210
 211 (defun vc-rcs-workfile-unchanged-p (file)
 212   "RCS-specific implementation of `vc-workfile-unchanged-p'."
 213   ;; Try to use rcsdiff --brief.  If rcsdiff does not understand that,
 214   ;; do a double take and remember the fact for the future
 215   (let* ((version (concat "-r" (vc-workfile-version file)))
 216          (status (if (eq vc-rcsdiff-knows-brief 'no)
 217                      (vc-do-command nil 1 "rcsdiff" file version)
 218                    (vc-do-command nil 2 "rcsdiff" file "--brief" version))))
 219     (if (eq status 2)
 220         (if (not vc-rcsdiff-knows-brief)
 221             (setq vc-rcsdiff-knows-brief 'no
 222                   status (vc-do-command nil 1 "rcsdiff" file version))
 223           (error "rcsdiff failed"))
 224       (if (not vc-rcsdiff-knows-brief) (setq vc-rcsdiff-knows-brief 'yes)))
 225     ;; The workfile is unchanged if rcsdiff found no differences.
 226     (zerop status)))
 227
 228 \f
 229 ;;;
 230 ;;; State-changing functions
 231 ;;;
 232
 233 (defun vc-rcs-register (file &optional rev comment)
 234   "Register FILE into the RCS version-control system.
 235 REV is the optional revision number for the file.  COMMENT can be used
 236 to provide an initial description of FILE.
 237
 238 `vc-register-switches' and `vc-rcs-register-switches' are passed to
 239 the RCS command (in that order).
 240
 241 Automatically retrieve a read-only version of the file with keywords
 242 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 243     (let ((subdir (expand-file-name "RCS" (file-name-directory file))))
 244       (and (not (file-exists-p subdir))
 245            (not (directory-files (file-name-directory file)
 246                                  nil ".*,v$" t))
 247            (yes-or-no-p "Create RCS subdirectory? ")
 248            (make-directory subdir))
 249       (apply 'vc-do-command nil 0 "ci" file
 250              ;; if available, use the secure registering option
 251              (and (vc-rcs-release-p "5.6.4") "-i")
 252              (concat (if vc-keep-workfiles "-u" "-r") rev)
 253              (and comment (concat "-t-" comment))
 254              (vc-switches 'RCS 'register))
 255       ;; parse output to find master file name and workfile version
 256       (with-current-buffer "*vc*"
 257         (goto-char (point-min))
 258         (let ((name (if (looking-at (concat "^\\(.*\\)  <--  "
 259                                             (file-name-nondirectory file)))
 260                         (match-string 1))))
 261           (if (not name)
 262               ;; if we couldn't find the master name,
 263               ;; run vc-rcs-registered to get it
 264               ;; (will be stored into the vc-name property)
 265               (vc-rcs-registered file)
 266             (vc-file-setprop file 'vc-name
 267                              (if (file-name-absolute-p name)
 268                                  name
 269                                (expand-file-name
 270                                 name
 271                                 (file-name-directory file))))))
 272         (vc-file-setprop file 'vc-workfile-version
 273                          (if (re-search-forward
 274                               "^initial revision: \\([0-9.]+\\).*\n"
 275                               nil t)
 276                              (match-string 1))))))
 277
 278 (defun vc-rcs-responsible-p (file)
 279   "Return non-nil if RCS thinks it would be responsible for registering FILE."
 280   ;; TODO: check for all the patterns in vc-rcs-master-templates
 281   (file-directory-p (expand-file-name "RCS" (file-name-directory file))))
 282
 283 (defun vc-rcs-receive-file (file rev)
 284   "Implementation of receive-file for RCS."
 285   (let ((checkout-model (vc-checkout-model file)))
 286     (vc-rcs-register file rev "")
 287     (when (eq checkout-model 'implicit)
 288       (vc-rcs-set-non-strict-locking file))
 289     (vc-rcs-set-default-branch file (concat rev ".1"))))
 290
 291 (defun vc-rcs-unregister (file)
 292   "Unregister FILE from RCS.
 293 If this leaves the RCS subdirectory empty, ask the user
 294 whether to remove it."
 295   (let* ((master (vc-name file))
 296          (dir (file-name-directory master))
 297          (backup-info (find-backup-file-name master)))
 298     (if (not backup-info)
 299         (delete-file master)
 300       (rename-file master (car backup-info) 'ok-if-already-exists)
 301       (dolist (f (cdr backup-info)) (ignore-errors (delete-file f))))
 302     (and (string= (file-name-nondirectory (directory-file-name dir)) "RCS")
 303          ;; check whether RCS dir is empty, i.e. it does not
 304          ;; contain any files except "." and ".."
 305          (not (directory-files dir nil
 306                                "^\\([^.]\\|\\.[^.]\\|\\.\\.[^.]\\).*"))
 307          (yes-or-no-p (format "Directory %s is empty; remove it? " dir))
 308          (delete-directory dir))))
 309
 310 (defun vc-rcs-checkin (file rev comment)
 311   "RCS-specific version of `vc-backend-checkin'."
 312   (let ((switches (vc-switches 'RCS 'checkin)))
 313     (let ((old-version (vc-workfile-version file)) new-version
 314           (default-branch (vc-file-getprop file 'vc-rcs-default-branch)))
 315       ;; Force branch creation if an appropriate
 316       ;; default branch has been set.
 317       (and (not rev)
 318            default-branch
 319            (string-match (concat "^" (regexp-quote old-version) "\\.")
 320                          default-branch)
 321            (setq rev default-branch)
 322            (setq switches (cons "-f" switches)))
 323       (if (and (not rev) old-version)
 324           (setq rev (vc-branch-part old-version)))
 325       (apply 'vc-do-command nil 0 "ci" (vc-name file)
 326              ;; if available, use the secure check-in option
 327              (and (vc-rcs-release-p "5.6.4") "-j")
 328              (concat (if vc-keep-workfiles "-u" "-r") rev)
 329              (concat "-m" comment)
 330              switches)
 331       (vc-file-setprop file 'vc-workfile-version nil)
 332
 333       ;; determine the new workfile version
 334       (set-buffer "*vc*")
 335       (goto-char (point-min))
 336       (when (or (re-search-forward
 337                  "new revision: \\([0-9.]+\\);" nil t)
 338                 (re-search-forward
 339                  "reverting to previous revision \\([0-9.]+\\)" nil t))
 340         (setq new-version (match-string 1))
 341         (vc-file-setprop file 'vc-workfile-version new-version))
 342
 343       ;; if we got to a different branch, adjust the default
 344       ;; branch accordingly
 345       (cond
 346        ((and old-version new-version
 347              (not (string= (vc-branch-part old-version)
 348                            (vc-branch-part new-version))))
 349         (vc-rcs-set-default-branch file
 350                                    (if (vc-trunk-p new-version) nil
 351                                      (vc-branch-part new-version)))
 352         ;; If this is an old RCS release, we might have
 353         ;; to remove a remaining lock.
 354         (if (not (vc-rcs-release-p "5.6.2"))
 355             ;; exit status of 1 is also accepted.
 356             ;; It means that the lock was removed before.
 357             (vc-do-command nil 1 "rcs" (vc-name file)
 358                            (concat "-u" old-version))))))))
 359
 360 (defun vc-rcs-find-version (file rev buffer)
 361   (apply 'vc-do-command
 362          buffer 0 "co" (vc-name file)
 363          "-q" ;; suppress diagnostic output
 364          (concat "-p" rev)
 365          (vc-switches 'RCS 'checkout)))
 366
 367 (defun vc-rcs-checkout (file &optional editable rev)
 368   "Retrieve a copy of a saved version of FILE."
 369   (let ((file-buffer (get-file-buffer file))
 370         switches)
 371     (message "Checking out %s..." file)
 372     (save-excursion
 373       ;; Change buffers to get local value of vc-checkout-switches.
 374       (if file-buffer (set-buffer file-buffer))
 375       (setq switches (vc-switches 'RCS 'checkout))
 376       ;; Save this buffer's default-directory
 377       ;; and use save-excursion to make sure it is restored
 378       ;; in the same buffer it was saved in.
 379       (let ((default-directory default-directory))
 380         (save-excursion
 381           ;; Adjust the default-directory so that the check-out creates
 382           ;; the file in the right place.
 383           (setq default-directory (file-name-directory file))
 384           (let (new-version)
 385             ;; if we should go to the head of the trunk,
 386             ;; clear the default branch first
 387             (and rev (string= rev "")
 388                  (vc-rcs-set-default-branch file nil))
 389             ;; now do the checkout
 390             (apply 'vc-do-command
 391                    nil 0 "co" (vc-name file)
 392                    ;; If locking is not strict, force to overwrite
 393                    ;; the writable workfile.
 394                    (if (eq (vc-checkout-model file) 'implicit) "-f")
 395                    (if editable "-l")
 396                    (if (stringp rev)
 397                        ;; a literal revision was specified
 398                        (concat "-r" rev)
 399                      (let ((workrev (vc-workfile-version file)))
 400                        (if workrev
 401                            (concat "-r"
 402                                    (if (not rev)
 403                                        ;; no revision specified:
 404                                        ;; use current workfile version
 405                                        workrev
 406                                      ;; REV is t ...
 407                                      (if (not (vc-trunk-p workrev))
 408                                          ;; ... go to head of current branch
 409                                          (vc-branch-part workrev)
 410                                        ;; ... go to head of trunk
 411                                        (vc-rcs-set-default-branch file
 412                                                                   nil)
 413                                        ""))))))
 414                    switches)
 415             ;; determine the new workfile version
 416             (with-current-buffer "*vc*"
 417               (setq new-version
 418                     (vc-parse-buffer "^revision \\([0-9.]+\\).*\n" 1)))
 419             (vc-file-setprop file 'vc-workfile-version new-version)
 420             ;; if necessary, adjust the default branch
 421             (and rev (not (string= rev ""))
 422                  (vc-rcs-set-default-branch
 423                   file
 424                   (if (vc-rcs-latest-on-branch-p file new-version)
 425                       (if (vc-trunk-p new-version) nil
 426                         (vc-branch-part new-version))
 427                     new-version)))))
 428         (message "Checking out %s...done" file)))))
 429
 430 (defun vc-rcs-revert (file &optional contents-done)
 431   "Revert FILE to the version it was based on."
 432   (vc-do-command nil 0 "co" (vc-name file) "-f"
 433                  (concat (if (eq (vc-state file) 'edited) "-u" "-r")
 434                          (vc-workfile-version file))))
 435
 436 (defun vc-rcs-cancel-version (file editable)
 437   "Undo the most recent checkin of FILE.
 438 EDITABLE non-nil means previous version should be locked."
 439   (let* ((target (vc-workfile-version file))
 440          (previous (if (vc-trunk-p target) "" (vc-branch-part target)))
 441          (config (current-window-configuration))
 442          (done nil))
 443     (vc-do-command nil 0 "rcs" (vc-name file) (concat "-o" target))
 444     ;; Check out the most recent remaining version.  If it fails, because
 445     ;; the whole branch got deleted, do a double-take and check out the
 446     ;; version where the branch started.
 447     (while (not done)
 448       (condition-case err
 449           (progn
 450             (vc-do-command nil 0 "co" (vc-name file) "-f"
 451                            (concat (if editable "-l" "-u") previous))
 452             (setq done t))
 453         (error (set-buffer "*vc*")
 454                (goto-char (point-min))
 455                (if (search-forward "no side branches present for" nil t)
 456                    (progn (setq previous (vc-branch-part previous))
 457                           (vc-rcs-set-default-branch file previous)
 458                           ;; vc-do-command popped up a window with
 459                           ;; the error message.  Get rid of it, by
 460                           ;; restoring the old window configuration.
 461                           (set-window-configuration config))
 462                  ;; No, it was some other error: re-signal it.
 463                  (signal (car err) (cdr err))))))))
 464
 465 (defun vc-rcs-merge (file first-version &optional second-version)
 466   "Merge changes into current working copy of FILE.
 467 The changes are between FIRST-VERSION and SECOND-VERSION."
 468   (vc-do-command nil 1 "rcsmerge" (vc-name file)
 469                  "-kk"                  ; ignore keyword conflicts
 470                  (concat "-r" first-version)
 471                  (if second-version (concat "-r" second-version))))
 472
 473 (defun vc-rcs-steal-lock (file &optional rev)
 474   "Steal the lock on the current workfile for FILE and revision REV.
 475 Needs RCS 5.6.2 or later for -M."
 476   (vc-do-command nil 0 "rcs" (vc-name file) "-M" (concat "-u" rev))
 477   ;; Do a real checkout after stealing the lock, so that we see
 478   ;; expanded headers.
 479   (vc-do-command nil 0 "co" (vc-name file) "-f" (concat "-l" rev)))
 480
 481
 482 \f
 483 ;;;
 484 ;;; History functions
 485 ;;;
 486
 487 (defun vc-rcs-print-log (file &optional buffer)
 488   "Get change log associated with FILE."
 489   (vc-do-command buffer 0 "rlog" (vc-name file)))
 490
 491 (defun vc-rcs-diff (file &optional oldvers newvers buffer)
 492   "Get a difference report using RCS between two versions of FILE."
 493   (if (not oldvers) (setq oldvers (vc-workfile-version file)))
 494   (apply 'vc-do-command (or buffer "*vc-diff*") 1 "rcsdiff" file
 495          (append (list "-q"
 496                        (concat "-r" oldvers)
 497                        (and newvers (concat "-r" newvers)))
 498                  (vc-switches 'RCS 'diff))))
 499
 500 \f
 501 ;;;
 502 ;;; Snapshot system
 503 ;;;
 504
 505 (defun vc-rcs-assign-name (file name)
 506   "Assign to FILE's latest version a given NAME."
 507   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-n" name ":")))
 508
 509 \f
 510 ;;;
 511 ;;; Miscellaneous
 512 ;;;
 513
 514 (defun vc-rcs-check-headers ()
 515   "Check if the current file has any headers in it."
 516   (save-excursion
 517     (goto-char (point-min))
 518          (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 519 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 520
 521 (defun vc-rcs-clear-headers ()
 522   "Implementation of vc-clear-headers for RCS."
 523   (let ((case-fold-search nil))
 524     (goto-char (point-min))
 525     (while (re-search-forward
 526             (concat "\\$\\(Author\\|Date\\|Header\\|Id\\|Locker\\|Name\\|"
 527                     "RCSfile\\|Revision\\|Source\\|State\\): [^$\n]+\\$")
 528             nil t)
 529       (replace-match "$\\1$"))))
 530
 531 (defun vc-rcs-rename-file (old new)
 532   ;; Just move the master file (using vc-rcs-master-templates).
 533   (vc-rename-master (vc-name old) new vc-rcs-master-templates))
 534
 535 \f
 536 ;;;
 537 ;;; Internal functions
 538 ;;;
 539
 540 (defun vc-rcs-workfile-is-newer (file)
 541   "Return non-nil if FILE is newer than its RCS master.
 542 This likely means that FILE has been changed with respect
 543 to its master version."
 544   (let ((file-time (nth 5 (file-attributes file)))
 545         (master-time (nth 5 (file-attributes (vc-name file)))))
 546     (or (> (nth 0 file-time) (nth 0 master-time))
 547         (and (= (nth 0 file-time) (nth 0 master-time))
 548              (> (nth 1 file-time) (nth 1 master-time))))))
 549
 550 (defun vc-rcs-find-most-recent-rev (branch)
 551   "Find most recent revision on BRANCH."
 552   (goto-char (point-min))
 553   (let ((latest-rev -1) value)
 554     (while (re-search-forward (concat "^\\(" (regexp-quote branch)
 555                                       "\\.\\([0-9]+\\)\\)\ndate[ \t]+[0-9.]+;")
 556                               nil t)
 557       (let ((rev (string-to-number (match-string 2))))
 558         (when (< latest-rev rev)
 559           (setq latest-rev rev)
 560           (setq value (match-string 1)))))
 561     (or value
 562         (vc-branch-part branch))))
 563
 564 (defun vc-rcs-fetch-master-state (file &optional workfile-version)
 565   "Compute the master file's idea of the state of FILE.
 566 If a WORKFILE-VERSION is given, compute the state of that version,
 567 otherwise determine the workfile version based on the master file.
 568 This function sets the properties `vc-workfile-version' and
 569 `vc-checkout-model' to their correct values, based on the master
 570 file."
 571   (with-temp-buffer
 572     (if (or (not (vc-insert-file (vc-name file) "^[0-9]"))
 573             (progn (goto-char (point-min))
 574                    (not (looking-at "^head[ \t\n]+[^;]+;$"))))
 575         (error "File %s is not an RCS master file" (vc-name file)))
 576     (let ((workfile-is-latest nil)
 577           (default-branch (vc-parse-buffer "^branch[ \t\n]+\\([^;]*\\);" 1)))
 578       (vc-file-setprop file 'vc-rcs-default-branch default-branch)
 579       (unless workfile-version
 580         ;; Workfile version not known yet.  Determine that first.  It
 581         ;; is either the head of the trunk, the head of the default
 582         ;; branch, or the "default branch" itself, if that is a full
 583         ;; revision number.
 584         (cond
 585          ;; no default branch
 586          ((or (not default-branch) (string= "" default-branch))
 587           (setq workfile-version
 588                 (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 589           (setq workfile-is-latest t))
 590          ;; default branch is actually a revision
 591          ((string-match "^[0-9]+\\.[0-9]+\\(\\.[0-9]+\\.[0-9]+\\)*$"
 592                         default-branch)
 593           (setq workfile-version default-branch))
 594          ;; else, search for the head of the default branch
 595          (t (vc-insert-file (vc-name file) "^desc")
 596             (setq workfile-version
 597                   (vc-rcs-find-most-recent-rev default-branch))
 598             (setq workfile-is-latest t)))
 599         (vc-file-setprop file 'vc-workfile-version workfile-version))
 600       ;; Check strict locking
 601       (goto-char (point-min))
 602       (vc-file-setprop file 'vc-checkout-model
 603                        (if (re-search-forward ";[ \t\n]*strict;" nil t)
 604                            'locking 'implicit))
 605       ;; Compute state of workfile version
 606       (goto-char (point-min))
 607       (let ((locking-user
 608              (vc-parse-buffer (concat "^locks[ \t\n]+[^;]*[ \t\n]+\\([^:]+\\):"
 609                                       (regexp-quote workfile-version)
 610                                       "[^0-9.]")
 611                               1)))
 612         (cond
 613          ;; not locked
 614          ((not locking-user)
 615           (if (or workfile-is-latest
 616                   (vc-rcs-latest-on-branch-p file workfile-version))
 617               ;; workfile version is latest on branch
 618               'up-to-date
 619             ;; workfile version is not latest on branch
 620             'needs-patch))
 621          ;; locked by the calling user
 622          ((and (stringp locking-user)
 623                (string= locking-user (vc-user-login-name)))
 624           (if (or (eq (vc-checkout-model file) 'locking)
 625                   workfile-is-latest
 626                   (vc-rcs-latest-on-branch-p file workfile-version))
 627               'edited
 628             ;; Locking is not used for the file, but the owner does
 629             ;; have a lock, and there is a higher version on the current
 630             ;; branch.  Not sure if this can occur, and if it is right
 631             ;; to use `needs-merge' in this case.
 632             'needs-merge))
 633          ;; locked by somebody else
 634          ((stringp locking-user)
 635           locking-user)
 636          (t
 637           (error "Error getting state of RCS file")))))))
 638
 639 (defun vc-rcs-consult-headers (file)
 640   "Search for RCS headers in FILE, and set properties accordingly.
 641
 642 Returns: nil            if no headers were found
 643          'rev           if a workfile revision was found
 644          'rev-and-lock  if revision and lock info was found"
 645   (cond
 646    ((not (get-file-buffer file)) nil)
 647    ((let (status version locking-user)
 648      (save-excursion
 649       (set-buffer (get-file-buffer file))
 650       (goto-char (point-min))
 651       (cond
 652        ;; search for $Id or $Header
 653        ;; -------------------------
 654        ;; The `\ 's below avoid an RCS 5.7 bug when checking in this file.
 655        ((or (and (search-forward "$Id\ : " nil t)
 656                  (looking-at "[^ ]+ \\([0-9.]+\\) "))
 657             (and (progn (goto-char (point-min))
 658                         (search-forward "$Header\ : " nil t))
 659                  (looking-at "[^ ]+ \\([0-9.]+\\) ")))
 660         (goto-char (match-end 0))
 661         ;; if found, store the revision number ...
 662         (setq version (match-string-no-properties 1))
 663         ;; ... and check for the locking state
 664         (cond
 665          ((looking-at
 666            (concat "[0-9]+[/-][01][0-9][/-][0-3][0-9] "             ; date
 667             "[0-2][0-9]:[0-5][0-9]+:[0-6][0-9]+\\([+-][0-9:]+\\)? " ; time
 668                    "[^ ]+ [^ ]+ "))                       ; author & state
 669           (goto-char (match-end 0)) ; [0-6] in regexp handles leap seconds
 670           (cond
 671            ;; unlocked revision
 672            ((looking-at "\\$")
 673             (setq locking-user 'none)
 674             (setq status 'rev-and-lock))
 675            ;; revision is locked by some user
 676            ((looking-at "\\([^ ]+\\) \\$")
 677             (setq locking-user (match-string-no-properties 1))
 678             (setq status 'rev-and-lock))
 679            ;; everything else: false
 680            (nil)))
 681          ;; unexpected information in
 682          ;; keyword string --> quit
 683          (nil)))
 684        ;; search for $Revision
 685        ;; --------------------
 686        ((re-search-forward (concat "\\$"
 687                                    "Revision: \\([0-9.]+\\) \\$")
 688                            nil t)
 689         ;; if found, store the revision number ...
 690         (setq version (match-string-no-properties 1))
 691         ;; and see if there's any lock information
 692         (goto-char (point-min))
 693         (if (re-search-forward (concat "\\$" "Locker:") nil t)
 694             (cond ((looking-at " \\([^ ]+\\) \\$")
 695                    (setq locking-user (match-string-no-properties 1))
 696                    (setq status 'rev-and-lock))
 697                   ((looking-at " *\\$")
 698                    (setq locking-user 'none)
 699                    (setq status 'rev-and-lock))
 700                   (t
 701                    (setq locking-user 'none)
 702                    (setq status 'rev-and-lock)))
 703           (setq status 'rev)))
 704        ;; else: nothing found
 705        ;; -------------------
 706        (t nil)))
 707      (if status (vc-file-setprop file 'vc-workfile-version version))
 708      (and (eq status 'rev-and-lock)
 709           (vc-file-setprop file 'vc-state
 710                            (cond
 711                             ((eq locking-user 'none) 'up-to-date)
 712                             ((string= locking-user (vc-user-login-name)) 'edited)
 713                             (t locking-user)))
 714           ;; If the file has headers, we don't want to query the
 715           ;; master file, because that would eliminate all the
 716           ;; performance gain the headers brought us.  We therefore
 717           ;; use a heuristic now to find out whether locking is used
 718           ;; for this file.  If we trust the file permissions, and the
 719           ;; file is not locked, then if the file is read-only we
 720           ;; assume that locking is used for the file, otherwise
 721           ;; locking is not used.
 722           (not (vc-mistrust-permissions file))
 723           (vc-up-to-date-p file)
 724           (if (string-match ".r-..-..-." (nth 8 (file-attributes file)))
 725               (vc-file-setprop file 'vc-checkout-model 'locking)
 726             (vc-file-setprop file 'vc-checkout-model 'implicit)))
 727      status))))
 728
 729 (defun vc-release-greater-or-equal (r1 r2)
 730   "Compare release numbers, represented as strings.
 731 Release components are assumed cardinal numbers, not decimal fractions
 732 \(5.10 is a higher release than 5.9\).  Omitted fields are considered
 733 lower \(5.6.7 is earlier than 5.6.7.1\).  Comparison runs till the end
 734 of the string is found, or a non-numeric component shows up \(5.6.7 is
 735 earlier than \"5.6.7 beta\", which is probably not what you want in
 736 some cases\).  This code is suitable for existing RCS release numbers.
 737 CVS releases are handled reasonably, too \(1.3 < 1.4* < 1.5\)."
 738   (let (v1 v2 i1 i2)
 739     (catch 'done
 740       (or (and (string-match "^\\.?\\([0-9]+\\)" r1)
 741                (setq i1 (match-end 0))
 742                (setq v1 (string-to-number (match-string 1 r1)))
 743                (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
 744                         (setq i2 (match-end 0))
 745                         (setq v2 (string-to-number (match-string 1 r2)))
 746                         (if (> v1 v2) (throw 'done t)
 747                           (if (< v1 v2) (throw 'done nil)
 748                             (throw 'done
 749                                    (vc-release-greater-or-equal
 750                                     (substring r1 i1)
 751                                     (substring r2 i2)))))))
 752                    (throw 'done t)))
 753           (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
 754                    (throw 'done nil))
 755               (throw 'done t)))))
 756
 757 (defun vc-rcs-release-p (release)
 758   "Return t if we have RELEASE or better."
 759   (let ((installation (vc-rcs-system-release)))
 760     (if (and installation
 761              (not (eq installation 'unknown)))
 762         (vc-release-greater-or-equal installation release))))
 763
 764
 765 (defun vc-rcs-system-release ()
 766   "Return the RCS release installed on this system, as a string.
 767 Return symbol UNKNOWN if the release cannot be deducted.  The user can
 768 override this using variable `vc-rcs-release'.
 769
 770 If the user has not set variable `vc-rcs-release' and it is nil,
 771 variable `vc-rcs-release' is set to the returned value."
 772   (or vc-rcs-release
 773       (setq vc-rcs-release
 774             (or (and (zerop (vc-do-command nil nil "rcs" nil "-V"))
 775                      (with-current-buffer (get-buffer "*vc*")
 776                        (vc-parse-buffer "^RCS version \\([0-9.]+ *.*\\)" 1)))
 777                 'unknown))))
 778
 779 (defun vc-rcs-set-non-strict-locking (file)
 780   (vc-do-command nil 0 "rcs" file "-U")
 781   (vc-file-setprop file 'vc-checkout-model 'implicit)
 782   (set-file-modes file (logior (file-modes file) 128)))
 783
 784 (defun vc-rcs-set-default-branch (file branch)
 785   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-b" branch))
 786   (vc-file-setprop file 'vc-rcs-default-branch branch))
 787
 788 (provide 'vc-rcs)
 789
 790 ;; arch-tag: 759b4916-5b0d-431d-b647-b185b8c652cf
 791 ;;; vc-rcs.el ends here