lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; (require 'url)
  28 (require 'url-parse)
  29 ;; (require 'url-util)
  30 (eval-when-compile (require 'mm-decode))
  31 ;; (require 'mailcap)
  32 ;; The following functions in the byte compiler's warnings are known not
  33 ;; to cause any real problem for the following reasons:
  34 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  35 ;;   after mm-dissect-buffer and defined in the same file.
  36 ;; The following are autoloaded instead of `require'd to avoid eagerly
  37 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  38 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  39 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  40 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  41
  42 ;; Implementation status
  43 ;; ---------------------
  44 ;; Function                             Status
  45 ;; ------------------------------------------------------------
  46 ;; add-name-to-file                     Needs DAV Bindings
  47 ;; copy-file                            Broken (assumes 1st item is URL)
  48 ;; delete-directory                     Finished (DAV)
  49 ;; delete-file                          Finished (DAV)
  50 ;; diff-latest-backup-file
  51 ;; directory-file-name                  unnecessary (what about VMS)?
  52 ;; directory-files                      Finished (DAV)
  53 ;; dired-call-process
  54 ;; dired-compress-file
  55 ;; dired-uncache
  56 ;; expand-file-name                     Finished
  57 ;; file-accessible-directory-p
  58 ;; file-attributes                      Finished, better with DAV
  59 ;; file-directory-p                     Needs DAV, finished
  60 ;; file-executable-p                    Finished
  61 ;; file-exists-p                        Finished
  62 ;; file-local-copy
  63 ;; file-modes
  64 ;; file-name-all-completions            Finished (DAV)
  65 ;; file-name-as-directory
  66 ;; file-name-completion                 Finished (DAV)
  67 ;; file-name-directory
  68 ;; file-name-nondirectory
  69 ;; file-name-sans-versions              why?
  70 ;; file-newer-than-file-p
  71 ;; file-ownership-preserved-p           No way to know
  72 ;; file-readable-p                      Finished
  73 ;; file-regular-p                       !directory_p
  74 ;; file-remote-p                        Finished
  75 ;; file-symlink-p                       Needs DAV bindings
  76 ;; file-truename                        Needs DAV bindings
  77 ;; file-writable-p                      Check for LOCK?
  78 ;; find-backup-file-name                why?
  79 ;; get-file-buffer                      why?
  80 ;; insert-directory                     Use DAV
  81 ;; insert-file-contents                 Finished
  82 ;; load
  83 ;; make-directory                       Finished (DAV)
  84 ;; make-symbolic-link                   Needs DAV bindings
  85 ;; rename-file                          Finished (DAV)
  86 ;; set-file-modes                       Use mod_dav specific executable flag?
  87 ;; set-visited-file-modtime             Impossible?
  88 ;; shell-command                        Impossible?
  89 ;; unhandled-file-name-directory
  90 ;; vc-registered                        Finished (DAV)
  91 ;; verify-visited-file-modtime
  92 ;; write-region
  93
  94 (defvar url-handler-regexp
  95   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
  96   "*A regular expression for matching  URLs handled by file-name-handler-alist.
  97 Some valid URL protocols just do not make sense to visit interactively
  98 \(about, data, info, irc, mailto, etc\).  This regular expression
  99 avoids conflicts with local files that look like URLs \(Gnus is
 100 particularly bad at this\).")
 101
 102 ;;;###autoload
 103 (define-minor-mode url-handler-mode
 104   "Use URL to handle URL-like file names."
 105   :global t :group 'url
 106   (if (not (boundp 'file-name-handler-alist))
 107       ;; Can't be turned ON anyway.
 108       (setq url-handler-mode nil)
 109     ;; Remove old entry, if any.
 110     (setq file-name-handler-alist
 111           (delq (rassq 'url-file-handler file-name-handler-alist)
 112                 file-name-handler-alist))
 113     (if url-handler-mode
 114         (push (cons url-handler-regexp 'url-file-handler)
 115               file-name-handler-alist))))
 116
 117 (defun url-run-real-handler (operation args)
 118   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 119                                           (if (eq operation inhibit-file-name-operation)
 120                                               inhibit-file-name-handlers)))
 121         (inhibit-file-name-operation operation))
 122     (apply operation args)))
 123
 124 ;;;###autoload
 125 (defun url-file-handler (operation &rest args)
 126   "Function called from the `file-name-handler-alist' routines.
 127 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 128 the arguments that would have been passed to OPERATION."
 129   (let ((fn (or (get operation 'url-file-handlers)
 130                 (intern-soft (format "url-%s" operation))))
 131         (val nil)
 132         (hooked nil))
 133     (if (and fn (fboundp fn))
 134         (setq hooked t
 135               val (apply fn args))
 136       (setq hooked nil
 137             val (url-run-real-handler operation args)))
 138     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 139                operation args val)
 140     val))
 141
 142 (defun url-file-handler-identity (&rest args)
 143   ;; Identity function
 144   (car args))
 145
 146 ;; These are operations that we can fully support
 147 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 148 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 149 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 150 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 151 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 152 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 153 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 154 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 155
 156 ;; These are operations that we do not support yet (DAV!!!)
 157 (put 'file-writable-p 'url-file-handlers 'ignore)
 158 (put 'file-symlink-p 'url-file-handlers 'ignore)
 159 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 160 ;; files and such since we can't do anything clever with them anyway.
 161 (put 'vc-registered 'url-file-handlers 'ignore)
 162
 163 (defun url-handler-expand-file-name (file &optional base)
 164   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 165   ;; there are two interpretations possible: either it's a local "/foo/bar"
 166   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 167   ;; interpretation is the right one, but when working with Emacs file
 168   ;; names, the first is preferred.
 169   (if (file-name-absolute-p file)
 170       (expand-file-name file "/")
 171     (url-expand-file-name file base)))
 172
 173 ;; directory-file-name and file-name-as-directory are kind of hard to
 174 ;; implement really right for URLs since URLs can have repeated / chars.
 175 ;; We'd want the following behavior:
 176 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 177 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 178 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 179 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 180 (defun url-handler-directory-file-name (dir)
 181   ;; When there's more than a single /, just don't touch the slashes at all.
 182   (if (string-match "//\\'" dir) dir
 183     (url-run-real-handler 'directory-file-name (list dir))))
 184
 185 (defun url-handler-unhandled-file-name-directory (filename)
 186   (let ((url (url-generic-parse-url filename)))
 187     (if (equal (url-type url) "file")
 188         ;; `file' URLs are actually local.  The filename part may be ""
 189         ;; which really stands for "/".
 190         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 191         ;; or some name that represents the local host?
 192         (or (file-name-directory (url-filename url)) "/")
 193       ;; All other URLs are not expected to be directly accessible from
 194       ;; a local process.
 195       nil)))
 196
 197 (defun url-handler-file-remote-p (filename &optional identification connected)
 198   (let ((url (url-generic-parse-url filename)))
 199     (if (and (url-type url) (not (equal (url-type url) "file")))
 200         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 201         ;; we ignore it.
 202         (cond
 203          ((eq identification 'method) (url-type url))
 204          ((eq identification 'user) (url-user url))
 205          ((eq identification 'host) (url-host url))
 206          ((eq identification 'localname) (url-filename url))
 207          (t (url-recreate-url
 208              (url-parse-make-urlobj (url-type url) (url-user url) nil
 209                                     (url-host url) (url-port url)))))
 210       ;; If there is no URL type, or it is a "file://" URL, the
 211       ;; filename is expected to be non remote.  A more subtle check
 212       ;; for "file://" URLs could be applied, as said in
 213       ;; `url-handler-unhandled-file-name-directory'.
 214       nil)))
 215
 216 ;; The actual implementation
 217 ;;;###autoload
 218 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
 219   "Copy URL to NEWNAME.  Both args must be strings.
 220 Signals a `file-already-exists' error if file NEWNAME already exists,
 221 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 222 A number as third arg means request confirmation if NEWNAME already exists.
 223 This is what happens in interactive use with M-x.
 224 Fourth arg KEEP-TIME non-nil means give the new file the same
 225 last-modified time as the old one.  (This works on only some systems.)
 226 A prefix arg makes KEEP-TIME non-nil."
 227   (if (and (file-exists-p newname)
 228            (not ok-if-already-exists))
 229       (error "Opening output file: File already exists, %s" newname))
 230   (let ((buffer (url-retrieve-synchronously url))
 231         (handle nil))
 232     (if (not buffer)
 233         (error "Opening input file: No such file or directory, %s" url))
 234     (with-current-buffer buffer
 235       (setq handle (mm-dissect-buffer t)))
 236     (mm-save-part-to-file handle newname)
 237     (kill-buffer buffer)
 238     (mm-destroy-parts handle)))
 239
 240 ;;;###autoload
 241 (defun url-file-local-copy (url &rest ignored)
 242   "Copy URL into a temporary file on this machine.
 243 Returns the name of the local copy, or nil, if FILE is directly
 244 accessible."
 245   (let ((filename (make-temp-file "url")))
 246     (url-copy-file url filename 'ok-if-already-exists)
 247     filename))
 248
 249 (defun url-insert (buffer &optional beg end)
 250   "Insert the body of a URL object.
 251 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 252 If the headers specify a coding-system, it is applied to the body before it is inserted.
 253 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 254 of the inserted text and CHARSET is the charset that was specified in the header,
 255 or nil if none was found.
 256 BEG and END can be used to only insert a subpart of the body.
 257 They count bytes from the beginning of the body."
 258   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 259          (data (with-current-buffer (mm-handle-buffer handle)
 260                  (if beg
 261                      (buffer-substring (+ (point-min) beg)
 262                                        (if end (+ (point-min) end) (point-max)))
 263                    (buffer-string))))
 264          (charset (mail-content-type-get (mm-handle-type handle)
 265                                           'charset)))
 266     (mm-destroy-parts handle)
 267     (if charset
 268         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 269       (insert data))
 270     (list (length data) charset)))
 271
 272 ;;;###autoload
 273 (defun url-insert-file-contents (url &optional visit beg end replace)
 274   (let ((buffer (url-retrieve-synchronously url)))
 275     (if (not buffer)
 276         (error "Opening input file: No such file or directory, %s" url))
 277     (if visit (setq buffer-file-name url))
 278     (save-excursion
 279       (let* ((start (point))
 280              (size-and-charset (url-insert buffer beg end)))
 281         (kill-buffer buffer)
 282         (when replace
 283           (delete-region (point-min) start)
 284           (delete-region (point) (point-max)))
 285         (unless (cadr size-and-charset)
 286           ;; If the headers don't specify any particular charset, use the
 287           ;; usual heuristic/rules that we apply to files.
 288           (decode-coding-inserted-region start (point) url visit beg end replace))
 289         (list url (car size-and-charset))))))
 290
 291 (defun url-file-name-completion (url directory &optional predicate)
 292   (error "Unimplemented"))
 293
 294 (defun url-file-name-all-completions (file directory)
 295   (error "Unimplemented"))
 296
 297 ;; All other handlers map onto their respective backends.
 298 (defmacro url-handlers-create-wrapper (method args)
 299   `(defun ,(intern (format "url-%s" method)) ,args
 300      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 301               (or (documentation method t) "No original documentation."))
 302      (setq url (url-generic-parse-url url))
 303      (when (url-type url)
 304        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 305                 ,@(remove '&rest (remove '&optional args))))))
 306
 307 (url-handlers-create-wrapper file-exists-p (url))
 308 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 309 (url-handlers-create-wrapper file-symlink-p (url))
 310 (url-handlers-create-wrapper file-writable-p (url))
 311 (url-handlers-create-wrapper file-directory-p (url))
 312 (url-handlers-create-wrapper file-executable-p (url))
 313 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 314 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 315
 316 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 317
 318 (defun url-handlers-set-buffer-mode ()
 319   "Set correct modes for the current buffer if visiting a remote file."
 320   (and (stringp buffer-file-name)
 321        (string-match url-handler-regexp buffer-file-name)
 322        (auto-save-mode 0)))
 323
 324 (provide 'url-handlers)
 325
 326 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
 327 ;;; url-handlers.el ends here