configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(use-lisp-union-type,
 309 [AS_HELP_STRING([--enable-use-lisp-union-type],
 310                 [use a union for the Lisp_Object data type.
 311                 This is only useful for development for catching certain types of bugs.])],
 312 if test "${enableval}" != "no"; then
 313    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 314    [Define this to use a lisp union for the Lisp_Object data type.])
 315 fi)
 316
 317
 318 AC_ARG_ENABLE(profiling,
 319 [AS_HELP_STRING([--enable-profiling],
 320                 [build emacs with profiling support.
 321                  This might not work on all platforms])],
 322 [ac_enable_profiling="${enableval}"],[])
 323 if test x$ac_enable_profiling != x ; then
 324    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 325    PROFILING_LDFLAGS="-pg"
 326 else
 327    PROFILING_CFLAGS=
 328    PROFILING_LDFLAGS=
 329 fi
 330
 331 AC_ARG_ENABLE(autodepend,
 332 [AS_HELP_STRING([--enable-autodepend],
 333                 [automatically generate dependencies to .h-files.
 334                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 335                  found])],
 336 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 337
 338 #### Make srcdir absolute, if it isn't already.  It's important to
 339 #### avoid running the path through pwd unnecessarily, since pwd can
 340 #### give you automounter prefixes, which can go away.  We do all this
 341 #### so Emacs can find its files when run uninstalled.
 342 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 343 unset CDPATH
 344 case "${srcdir}" in
 345   /* ) ;;
 346   . )
 347     ## We may be able to use the $PWD environment variable to make this
 348     ## absolute.  But sometimes PWD is inaccurate.
 349     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 350     ## but that tested only for a well-formed and valid PWD,
 351     ## it did not object when PWD was well-formed and valid but just wrong.
 352     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 353     then
 354       srcdir="$PWD"
 355     else
 356       srcdir="`(cd ${srcdir}; pwd)`"
 357     fi
 358   ;;
 359   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 360 esac
 361
 362 #### Check if the source directory already has a configured system in it.
 363 if test `pwd` != `(cd ${srcdir} && pwd)` \
 364    && test -f "${srcdir}/src/config.h" ; then
 365   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 366    as a build directory right now; it has been configured in its own
 367    right.  To configure in another directory as well, you MUST
 368    use GNU make.  If you do not have GNU make, then you must
 369    now do `make distclean' in ${srcdir},
 370    and then run $0 again.]])
 371 fi
 372
 373 #### Given the configuration name, set machfile and opsysfile to the
 374 #### names of the m/*.h and s/*.h files we should use.
 375
 376 ### Canonicalize the configuration name.
 377
 378 AC_CANONICAL_HOST
 379 canonical=$host
 380 configuration=${host_alias-${build_alias-$host}}
 381
 382 dnl This used to use changequote, but, apart from `changequote is evil'
 383 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 384 dnl the great gob of text.  Thus it's not processed for possible expansion.
 385 dnl Just make sure the brackets remain balanced.
 386 dnl
 387 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 388 dnl indicated by comments.
 389 dnl quotation begins
 390 [
 391
 392 ### If you add support for a new configuration, add code to this
 393 ### switch statement to recognize your configuration name and select
 394 ### the appropriate operating system and machine description files.
 395
 396 ### You would hope that you could choose an m/*.h file pretty much
 397 ### based on the machine portion of the configuration name, and an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each m/*.h file is pretty manufacturer-specific - for
 400 ### example mips.h is MIPS
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 machine='' opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## FreeBSD ports
 414   *-*-freebsd* )
 415     opsys=freebsd
 416     case "${canonical}" in
 417       alpha*)           machine=alpha ;;
 418       amd64-*|x86_64-*) machine=amdx86-64 ;;
 419       arm*)             machine=arm ;;
 420       ia64-*)           machine=ia64 ;;
 421       i[3456]86-*)      machine=intel386 ;;
 422       powerpc-*)        machine=macppc ;;
 423       sparc-*)          machine=sparc ;;
 424       sparc64-*)        machine=sparc ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD kernel + glibc based userland
 429   *-*-kfreebsd*gnu* )
 430     opsys=gnu-kfreebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## NetBSD ports
 443   *-*-netbsd* )
 444     opsys=netbsd
 445     case "${canonical}" in
 446       alpha*)      machine=alpha ;;
 447       x86_64-*)    machine=amdx86-64 ;;
 448       arm-*)       machine=arm ;;
 449       hppa-*)      machine=hp800 ;;
 450       i[3456]86-*) machine=intel386 ;;
 451       m68k-*)      machine=m68k ;;
 452       powerpc-*)   machine=macppc ;;
 453       mips-*)      machine=mips ;;
 454       mipse[bl]-*) machine=mips ;;
 455       sparc*-)     machine=sparc ;;
 456       vax-*)       machine=vax ;;
 457     esac
 458   ;;
 459
 460   ## OpenBSD ports
 461   *-*-openbsd* )
 462     opsys=openbsd
 463     case "${canonical}" in
 464       alpha*)    machine=alpha ;;
 465       x86_64-*)  machine=amdx86-64 ;;
 466       arm-*)     machine=arm ;;
 467       hppa-*)    machine=hp800 ;;
 468       i386-*)    machine=intel386 ;;
 469       powerpc-*) machine=macppc ;;
 470       sparc*)    machine=sparc ;;
 471       vax-*)     machine=vax ;;
 472     esac
 473   ;;
 474
 475   alpha*-*-linux-gnu* )
 476     machine=alpha opsys=gnu-linux
 477   ;;
 478
 479   arm*-*-linux-gnu* )
 480     machine=arm opsys=gnu-linux
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     machine=hp800 opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     machine=hp800 opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   hppa*-*-linux-gnu* )
 512     machine=hp800 opsys=gnu-linux
 513   ;;
 514
 515   ## IBM machines
 516   s390-*-linux-gnu* )
 517     machine=ibms390 opsys=gnu-linux
 518   ;;
 519   s390x-*-linux-gnu* )
 520     machine=ibms390x opsys=gnu-linux
 521   ;;
 522   rs6000-ibm-aix4.[23]* )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   powerpc-ibm-aix4.[23]*  )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   rs6000-ibm-aix[56]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix[56]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534
 535   ## Macintosh PowerPC
 536   powerpc*-*-linux-gnu* )
 537     machine=macppc opsys=gnu-linux
 538   ;;
 539
 540   ## Silicon Graphics machines
 541   ## Iris 4D
 542   mips-sgi-irix6.5 )
 543     machine=iris4d opsys=irix6-5
 544     # Without defining _LANGUAGE_C, things get masked out in the headers
 545     # so that, for instance, grepping for `free' in stdlib.h fails and
 546     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 547     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 548     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 549   ;;
 550
 551   ## Suns
 552   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 553     machine=sparc opsys=gnu-linux
 554   ;;
 555
 556   *-sun-solaris* \
 557     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 558     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 559     case "${canonical}" in
 560       i[3456]86-*-* )     machine=intel386 ;;
 561       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 562       sparc* )          machine=sparc ;;
 563       * )               unported=yes ;;
 564     esac
 565     case "${canonical}" in
 566       *-sunos5.6* | *-solaris2.6* )
 567                 opsys=sol2-6
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 RANLIB="ar -ts"
 570                 ;;
 571       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 572                 opsys=sol2-6
 573                 emacs_check_sunpro_c=yes
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 ;;
 576       *-sunos5* | *-solaris* )
 577                 opsys=sol2-10
 578                 emacs_check_sunpro_c=yes
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 ;;
 581     esac
 582     ## Watch out for a compiler that we know will not work.
 583     case "${canonical}" in
 584      *-solaris* | *-sunos5* )
 585                 if [ "x$CC" = x/usr/ucb/cc ]; then
 586                   ## /usr/ucb/cc doesn't work;
 587                   ## we should find some other compiler that does work.
 588                   unset CC
 589                 fi
 590                 ;;
 591       *) ;;
 592     esac
 593   ;;
 594
 595   ## IA-64
 596   ia64*-*-linux* )
 597     machine=ia64 opsys=gnu-linux
 598   ;;
 599
 600   ## Intel 386 machines where we don't care about the manufacturer.
 601   i[3456]86-*-* )
 602     machine=intel386
 603     case "${canonical}" in
 604       *-cygwin )                opsys=cygwin ;;
 605       *-darwin* )               opsys=darwin
 606                                 CPP="${CC-cc} -E -no-cpp-precomp"
 607                                 ;;
 608       *-linux-gnu* )            opsys=gnu-linux ;;
 609       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 610       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 611       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 613     esac
 614   ;;
 615
 616   ## m68k Linux-based GNU system
 617   m68k-*-linux-gnu* )
 618     machine=m68k opsys=gnu-linux
 619   ;;
 620
 621   ## Mips Linux-based GNU system
 622   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 623     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 624     machine=mips opsys=gnu-linux
 625   ;;
 626
 627   ## AMD x86-64 Linux-based GNU system
 628   x86_64-*-linux-gnu* )
 629     machine=amdx86-64 opsys=gnu-linux
 630   ;;
 631
 632   ## Tensilica Xtensa Linux-based GNU system
 633   xtensa*-*-linux-gnu* )
 634     machine=xtensa opsys=gnu-linux
 635     ;;
 636
 637   ## SuperH Linux-based GNU system
 638   sh[34]*-*-linux-gnu* )
 639     machine=sh3 opsys=gnu-linux
 640   ;;
 641
 642   * )
 643     unported=yes
 644   ;;
 645 esac
 646
 647 ### If the code above didn't choose an operating system, just choose
 648 ### an operating system based on the configuration name.  You really
 649 ### only want to use this when you have no idea what the right
 650 ### operating system is; if you know what operating systems a machine
 651 ### runs, it's cleaner to make it explicit in the case statement
 652 ### above.
 653 if test x"${opsys}" = x; then
 654   case "${canonical}" in
 655     *-gnu* )                            opsys=gnu ;;
 656     * )
 657       unported=yes
 658     ;;
 659   esac
 660 fi
 661
 662 ]
 663 dnl quotation ends
 664
 665 if test $unported = yes; then
 666   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 667 Check `etc/MACHINES' for recognized configuration names.])
 668 fi
 669
 670 machfile="m/${machine}.h"
 671 opsysfile="s/${opsys}.h"
 672
 673
 674 #### Choose a compiler.
 675 test -n "$CC" && cc_specified=yes
 676
 677 # Save the value of CFLAGS that the user specified.
 678 SPECIFIED_CFLAGS="$CFLAGS"
 679
 680 dnl Sets GCC=yes if using gcc.
 681 AC_PROG_CC
 682
 683 # On Suns, sometimes $CPP names a directory.
 684 if test -n "$CPP" && test -d "$CPP"; then
 685   CPP=
 686 fi
 687
 688 ## If not using gcc, and on Solaris, and no CPP specified, see if
 689 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 690 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 691  test x"$CPP" = x; then
 692   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 693   AC_CACHE_VAL(emacs_cv_sunpro_c,
 694   [AC_TRY_LINK([],
 695 [#ifndef __SUNPRO_C
 696 fail;
 697 #endif
 698 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 699   AC_MSG_RESULT($emacs_cv_sunpro_c)
 700
 701   if test x"$emacs_cv_sunpro_c" = xyes; then
 702     NON_GNU_CPP="$CC -E -Xs"
 703   fi
 704 fi
 705
 706 #### Some systems specify a CPP to use unless we are using GCC.
 707 #### Now that we know whether we are using GCC, we can decide whether
 708 #### to use that one.
 709 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 710 then
 711   CPP="$NON_GNU_CPP"
 712 fi
 713
 714 #### Some systems specify a CC to use unless we are using GCC.
 715 #### Now that we know whether we are using GCC, we can decide whether
 716 #### to use that one.
 717 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 718   test x$cc_specified != xyes
 719 then
 720   CC="$NON_GNU_CC"
 721 fi
 722
 723 if test x$GCC = xyes; then
 724   C_OPTIMIZE_SWITCH=-O2
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   C_OPTIMIZE_SWITCH=-O
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 ### Use -Wdeclaration-after-statement if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 ### Use -Wold-style-definition if the compiler supports it
 761 # This can be removed when conversion to standard C is finished.
 762 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 763 SAVE_CFLAGS="$CFLAGS"
 764 CFLAGS="$CFLAGS -Wold-style-definition"
 765 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 766 if test $has_option = yes; then
 767    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 768 fi
 769 AC_MSG_RESULT($has_option)
 770 CFLAGS="$SAVE_CFLAGS"
 771 unset has_option
 772 unset SAVE_CFLAGS
 773
 774
 775 #### Some other nice autoconf tests.
 776
 777 dnl checks for programs
 778 AC_PROG_CPP
 779 AC_PROG_INSTALL
 780 if test "x$RANLIB" = x; then
 781   AC_PROG_RANLIB
 782 fi
 783
 784 ## Although we're running on an amd64 kernel, we're actually compiling for
 785 ## the x86 architecture.  The user should probably have provided an
 786 ## explicit --build to `configure', but if everything else than the kernel
 787 ## is running in i386 mode, we can help them out.
 788 if test "$machine" = "amdx86-64"; then
 789   AC_CHECK_DECL([i386])
 790   if test "$ac_cv_have_decl_i386" = "yes"; then
 791     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 792     machine=intel386
 793     machfile="m/${machine}.h"
 794   fi
 795 fi
 796
 797 AC_PATH_PROG(INSTALL_INFO, install-info)
 798 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 799 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 800 dnl Don't use GZIP, which is used by gzip for additional parameters.
 801 AC_PATH_PROG(GZIP_PROG, gzip)
 802
 803
 804 ## Need makeinfo >= 4.6 (?) to build the manuals.
 805 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 806 dnl By this stage, configure has already checked for egrep and set EGREP,
 807 dnl or exited with an error if no egrep was found.
 808 if test "$MAKEINFO" != "no" && \
 809   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 810    MAKEINFO=no
 811 fi
 812
 813 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 814 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 815 ## therefore in the category of "special tools" not normally required, which
 816 ## configure does not have to check for (eg autoconf itself).
 817 ## In a Bazaar checkout on the other hand, the manuals are not included.
 818 ## So makeinfo is a requirement to build from Bazaar, and configure
 819 ## should test for it as it does for any other build requirement.
 820 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 821 ## with pre-built manuals, from a Bazaar checkout.
 822 if test "$MAKEINFO" = "no"; then
 823   if test "x${with_makeinfo}" = "xno"; then
 824     MAKEINFO=off
 825   elif test ! -e $srcdir/info/emacs; then
 826     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 827 source tree does not seem to have pre-built manuals in the `info' directory.
 828 Either install a suitable version of makeinfo, or re-run configure
 829 with the `--without-makeinfo' option to build without the manuals.] )
 830   fi
 831 fi
 832
 833 dnl Add our options to ac_link now, after it is set up.
 834
 835 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 836 then
 837   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 838 fi
 839
 840 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 841 then
 842   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 843 fi
 844
 845 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 846 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 847 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 848 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 849 dnl if not built to support GNU ld.
 850
 851 late_LDFLAGS=$LDFLAGS
 852 if test "$GCC" = yes; then
 853   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 854 else
 855   LDFLAGS="$LDFLAGS -znocombreloc"
 856 fi
 857
 858 AC_MSG_CHECKING([for -znocombreloc])
 859 AC_LINK_IFELSE([main(){return 0;}],
 860   [AC_MSG_RESULT(yes)],
 861   LDFLAGS=$late_LDFLAGS
 862   [AC_MSG_RESULT(no)])
 863
 864 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 865
 866
 867 # The value of CPP is a quoted variable reference, so we need to do this
 868 # to get its actual value...
 869 CPP=`eval "echo $CPP"`
 870
 871
 872 ### First figure out CFLAGS (which we use for running the compiler here)
 873 ### and REAL_CFLAGS (which we use for real compilation).
 874 ### The two are the same except when using GCC where we might use
 875 ### extra warning and profiling flags.
 876
 877 ### If the CFLAGS env var is specified, we use that value
 878 ### instead of the default.
 879
 880 dnl Note AC_PROG_CC sets CFLAGS to -g -O2 for gcc anyway.
 881 if test "x$SPECIFIED_CFLAGS" = x; then
 882   CFLAGS="-g $C_OPTIMIZE_SWITCH"
 883   if test x$GCC = xyes; then
 884     REAL_CFLAGS="$CFLAGS $C_WARNINGS_SWITCH $PROFILING_CFLAGS"
 885   else
 886     REAL_CFLAGS="$CFLAGS"
 887   fi
 888 else
 889   REAL_CFLAGS="$CFLAGS"
 890 fi
 891
 892
 893 dnl Not used by any currently supported platform.
 894 dnl The function dump-emacs will not be defined and temacs will do
 895 dnl (load "loadup") automatically unless told otherwise.
 896 CANNOT_DUMP=no
 897 case "$opsys" in
 898   your-opsys-here)
 899    CANNOT_DUMP=yes
 900    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 901   ;;
 902 esac
 903 AC_SUBST(CANNOT_DUMP)
 904
 905
 906 UNEXEC_OBJ=unexelf.o
 907 case "$opsys" in
 908   # MSDOS uses unexec.o
 909   # MSWindows uses unexw32.o
 910   aix4-2)
 911    UNEXEC_OBJ=unexaix.o
 912    ;;
 913   cygwin)
 914    UNEXEC_OBJ=unexcw.o
 915    ;;
 916   darwin)
 917    UNEXEC_OBJ=unexmacosx.o
 918    ;;
 919   hpux10-20 | hpux11)
 920    UNEXEC_OBJ=unexhp9k800.o
 921    ;;
 922   sol2-10)
 923    # Use the Solaris dldump() function, called from unexsol.c, to dump
 924    # emacs, instead of the generic ELF dump code found in unexelf.c.
 925    # The resulting binary has a complete symbol table, and is better
 926    # for debugging and other observability tools (debuggers, pstack, etc).
 927    #
 928    # If you encounter a problem using dldump(), please consider sending
 929    # a message to the OpenSolaris tools-linking mailing list:
 930    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 931    #
 932    # It is likely that dldump() works with older Solaris too, but this has
 933    # not been tested, so for now this change is for Solaris 10 or newer.
 934    UNEXEC_OBJ=unexsol.o
 935    ;;
 936 esac
 937
 938 LD_SWITCH_SYSTEM=
 939 case "$opsys" in
 940   freebsd)
 941    ## Let `ld' find image libs and similar things in /usr/local/lib.
 942    ## The system compiler, GCC, has apparently been modified to not
 943    ## look there, contrary to what a stock GCC would do.
 944    LD_SWITCH_SYSTEM=-L/usr/local/lib
 945    ;;
 946
 947   gnu-linux)
 948    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 949    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 950    ;;
 951
 952   netbsd)
 953    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 954    ;;
 955
 956   openbsd)
 957    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 958    ## otherwise Emacs dumps core on elf systems.
 959    LD_SWITCH_SYSTEM="-Z"
 960    ;;
 961 esac
 962 AC_SUBST(LD_SWITCH_SYSTEM)
 963
 964 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 965
 966 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 967 ## which has not been defined yet.  When this was handled with cpp,
 968 ## it was expanded to null when configure sourced the s/*.h file.
 969 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 970 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 971 ## (or somesuch), but because it is supposed to go at the _front_
 972 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 973 ## Compare with the gnu-linux case below, which added to the end
 974 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 975 ## LD_SWITCH_SYSTEM_TEMACS.
 976 case "$opsys" in
 977   netbsd|openbsd)
 978    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 979    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 980 esac
 981
 982
 983 C_SWITCH_MACHINE=
 984 if test "$machine" = "alpha"; then
 985   AC_CHECK_DECL([__ELF__])
 986   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 987     ## With ELF, make sure that all common symbols get allocated to in the
 988     ## data section.  Otherwise, the dump of temacs may miss variables in
 989     ## the shared library that have been initialized.  For example, with
 990     ## GNU libc, __malloc_initialized would normally be resolved to the
 991     ## shared library's .bss section, which is fatal.
 992     if test "x$GCC" = "xyes"; then
 993       C_SWITCH_MACHINE="-fno-common"
 994     else
 995       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 996     fi
 997   else
 998     UNEXEC_OBJ=unexalpha.o
 999   fi
1000 fi
1001 AC_SUBST(C_SWITCH_MACHINE)
1002
1003 AC_SUBST(UNEXEC_OBJ)
1004
1005 C_SWITCH_SYSTEM=
1006 ## Some programs in src produce warnings saying certain subprograms
1007 ## are too complex and need a MAXMEM value greater than 2000 for
1008 ## additional optimization.  --nils@exp-math.uni-essen.de
1009 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1010   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1011 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1012 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1013 AC_SUBST(C_SWITCH_SYSTEM)
1014
1015
1016 LIBS_SYSTEM=
1017 case "$opsys" in
1018   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1019   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1020
1021   freebsd) LIBS_SYSTEM="-lutil" ;;
1022
1023   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1024
1025   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1026
1027   ## Motif needs -lgen.
1028   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1029 esac
1030 AC_SUBST(LIBS_SYSTEM)
1031
1032
1033 ### Make sure subsequent tests use flags consistent with the build flags.
1034
1035 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1036   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1037 else
1038   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1039 fi
1040
1041 dnl For AC_FUNC_GETLOADAVG, at least:
1042 AC_CONFIG_LIBOBJ_DIR(src)
1043
1044 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1045 AC_SYS_LARGEFILE
1046
1047
1048 ## If user specified a crt-dir, use that unconditionally.
1049 if test "X$CRT_DIR" = "X"; then
1050
1051   case "$canonical" in
1052     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1053     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1054     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1055     ## For anything else (eg /usr/lib32), it is up the user to specify
1056     ## the location (bug#5655).
1057     ## Test for crtn.o, not just the directory, because sometimes the
1058     ## directory exists but does not have the relevant files (bug#1287).
1059     ## FIXME better to test for binary compatibility somehow.
1060     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1061     ;;
1062
1063     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1064   esac
1065
1066   case "$opsys" in
1067     hpux10-20) CRT_DIR=/lib ;;
1068   esac
1069
1070   ## Default is /usr/lib.
1071   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1072
1073 else
1074
1075   ## Some platforms don't use any of these files, so it is not
1076   ## appropriate to put this test outside the if block.
1077   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1078     AC_MSG_ERROR([crt*.o not found in specified location.])
1079
1080 fi
1081
1082 AC_SUBST(CRT_DIR)
1083
1084 LIB_MATH=-lm
1085 LIB_STANDARD=
1086 START_FILES=
1087
1088 case $opsys in
1089   cygwin )
1090     LIB_MATH=
1091     START_FILES='ecrt0.o'
1092     ;;
1093   darwin )
1094     ## Adding -lm confuses the dynamic linker, so omit it.
1095     LIB_MATH=
1096     START_FILES='pre-crt0.o'
1097     ;;
1098   freebsd )
1099     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1100     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1101     ;;
1102   gnu-linux | gnu-kfreebsd )
1103     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1104     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1105     ;;
1106   hpux10-20 | hpux11 )
1107     LIB_STANDARD=-lc
1108     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1109     ;;
1110   netbsd | openbsd )
1111     if test -f $CRT_DIR/crti.o; then
1112         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1113         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1114     else
1115         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1116         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1117     fi
1118     ;;
1119 esac
1120
1121 AC_SUBST(LIB_MATH)
1122 AC_SUBST(START_FILES)
1123
1124 dnl This function definition taken from Gnome 2.0
1125 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1126 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1127 dnl also defines GSTUFF_PKG_ERRORS on error
1128 AC_DEFUN([PKG_CHECK_MODULES], [
1129   succeeded=no
1130
1131   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1132
1133   if test "$PKG_CONFIG" = "no" ; then
1134      ifelse([$4], , [AC_MSG_ERROR([
1135       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1136   else
1137      PKG_CONFIG_MIN_VERSION=0.9.0
1138      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1139         AC_MSG_CHECKING(for $2)
1140
1141         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1142             AC_MSG_RESULT(yes)
1143             succeeded=yes
1144
1145             AC_MSG_CHECKING($1_CFLAGS)
1146             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1147             AC_MSG_RESULT($$1_CFLAGS)
1148
1149             AC_MSG_CHECKING($1_LIBS)
1150             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1151             AC_MSG_RESULT($$1_LIBS)
1152         else
1153             AC_MSG_RESULT(no)
1154             $1_CFLAGS=""
1155             $1_LIBS=""
1156             ## If we have a custom action on failure, don't print errors, but
1157             ## do set a variable so people can do so.
1158             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1159             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1160         fi
1161
1162         AC_SUBST($1_CFLAGS)
1163         AC_SUBST($1_LIBS)
1164      else
1165         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1166         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1167      fi
1168   fi
1169
1170   if test $succeeded = yes; then
1171      ifelse([$3], , :, [$3])
1172   else
1173      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1174   fi
1175 ])
1176
1177
1178 if test "${with_sound}" != "no"; then
1179   # Sound support for GNU/Linux and the free BSDs.
1180   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1181     have_sound_header=yes)
1182   # Emulation library used on NetBSD.
1183   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1184   AC_SUBST(LIBSOUND)
1185
1186   ALSA_REQUIRED=1.0.0
1187   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1188   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1189   if test $HAVE_ALSA = yes; then
1190     SAVE_CFLAGS="$CFLAGS"
1191     SAVE_LDFLAGS="$LDFLAGS"
1192     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1193     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1194     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1195                     emacs_alsa_normal=yes,
1196                     emacs_alsa_normal=no)
1197     if test "$emacs_alsa_normal" != yes; then
1198       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1199                      [snd_lib_error_set_handler (0);],
1200                      emacs_alsa_subdir=yes,
1201                      emacs_alsa_subdir=no)
1202       if test "$emacs_alsa_subdir" != yes; then
1203         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1204       fi
1205       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1206     fi
1207
1208     CFLAGS="$SAVE_CFLAGS"
1209     LDFLAGS="$SAVE_LDFLAGS"
1210     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1211     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1212     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1213   fi
1214
1215   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1216   dnl compiles only on the specified platforms.  For others, it
1217   dnl probably doesn't make sense to try.
1218   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1219      case "$opsys" in
1220        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1221        gnu-linux|freebsd|netbsd)
1222          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1223          ;;
1224      esac
1225   fi
1226
1227   AC_SUBST(CFLAGS_SOUND)
1228 fi
1229
1230 dnl checks for header files
1231 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1232   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1233   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1234   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1235   sys/utsname.h pwd.h utmp.h)
1236
1237 AC_MSG_CHECKING(if personality LINUX32 can be set)
1238 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1239                emacs_cv_personality_linux32=yes,
1240                emacs_cv_personality_linux32=no)
1241 AC_MSG_RESULT($emacs_cv_personality_linux32)
1242
1243 if test $emacs_cv_personality_linux32 = yes; then
1244   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1245             [Define to 1 if personality LINUX32 can be set.])
1246 fi
1247
1248 dnl On Solaris 8 there's a compilation warning for term.h because
1249 dnl it doesn't define `bool'.
1250 AC_CHECK_HEADERS(term.h, , , -)
1251 AC_HEADER_STDC
1252 AC_HEADER_TIME
1253 AC_CHECK_DECLS([sys_siglist])
1254 if test $ac_cv_have_decl_sys_siglist != yes; then
1255   # For Tru64, at least:
1256   AC_CHECK_DECLS([__sys_siglist])
1257   if test $ac_cv_have_decl___sys_siglist = yes; then
1258     AC_DEFINE(sys_siglist, __sys_siglist,
1259               [Define to any substitute for sys_siglist.])
1260   fi
1261 fi
1262 AC_HEADER_SYS_WAIT
1263
1264 dnl Some systems have utime.h but don't declare the struct anyplace.
1265 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1266 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1267 #include <sys/time.h>
1268 #include <time.h>
1269 #else
1270 #ifdef HAVE_SYS_TIME_H
1271 #include <sys/time.h>
1272 #else
1273 #include <time.h>
1274 #endif
1275 #endif
1276 #ifdef HAVE_UTIME_H
1277 #include <utime.h>
1278 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1279   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1280 if test $emacs_cv_struct_utimbuf = yes; then
1281   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1282 fi
1283
1284 dnl checks for typedefs
1285 AC_TYPE_SIGNAL
1286
1287 dnl Check for speed_t typedef.
1288 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1289   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1290     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1291 if test $emacs_cv_speed_t = yes; then
1292   AC_DEFINE(HAVE_SPEED_T, 1,
1293            [Define to 1 if `speed_t' is declared by <termios.h>.])
1294 fi
1295
1296 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1297 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1298 #include <sys/time.h>
1299 #include <time.h>
1300 #else
1301 #ifdef HAVE_SYS_TIME_H
1302 #include <sys/time.h>
1303 #else
1304 #include <time.h>
1305 #endif
1306 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1307   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1308 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1309 if test $emacs_cv_struct_timeval = yes; then
1310   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1311 fi
1312
1313 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1314 AC_TRY_COMPILE([#include <math.h>],
1315 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1316   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1317 HAVE_EXCEPTION=$emacs_cv_struct_exception
1318 if test $emacs_cv_struct_exception != yes; then
1319   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1320 fi
1321
1322 AC_CHECK_HEADERS(sys/socket.h)
1323 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1324 #if HAVE_SYS_SOCKET_H
1325 #include <sys/socket.h>
1326 #endif])
1327
1328 dnl checks for structure members
1329 AC_STRUCT_TM
1330 AC_STRUCT_TIMEZONE
1331 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1332                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1333                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1334                 [#include <time.h>])
1335 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1336                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1337                   struct ifreq.ifr_addr], , ,
1338                  [AC_INCLUDES_DEFAULT
1339 #if HAVE_SYS_SOCKET_H
1340 #include <sys/socket.h>
1341 #endif
1342 #if HAVE_NET_IF_H
1343 #include <net/if.h>
1344 #endif])
1345
1346 dnl checks for compiler characteristics
1347
1348 dnl Testing __STDC__ to determine prototype support isn't good enough.
1349 dnl DEC C, for instance, doesn't define it with default options, and
1350 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1351 dnl and void *.
1352 AC_C_PROTOTYPES
1353 AC_C_VOLATILE
1354 AC_C_CONST
1355 dnl This isn't useful because we can't turn on use of `inline' unless
1356 dnl the compiler groks `extern inline'.
1357 dnl AC_C_INLINE
1358 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1359   [AC_TRY_COMPILE(, [void * foo;],
1360                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1361 if test $emacs_cv_void_star = yes; then
1362   AC_DEFINE(POINTER_TYPE, void)
1363 else
1364   AC_DEFINE(POINTER_TYPE, char)
1365 fi
1366 AH_TEMPLATE(POINTER_TYPE,
1367             [Define as `void' if your compiler accepts `void *'; otherwise
1368              define as `char'.])dnl
1369
1370
1371
1372 dnl This could be used for targets which can have both byte sexes.
1373 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1374 dnl AC_C_BIGENDIAN
1375
1376 dnl check for Make feature
1377 AC_PROG_MAKE_SET
1378
1379 DEPFLAGS=
1380 MKDEPDIR=":"
1381 deps_frag=deps.mk
1382 dnl check for GNU Make if we have GCC and autodepend is on.
1383 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1384    AC_MSG_CHECKING([whether we are using GNU Make])
1385    HAVE_GNU_MAKE=no
1386    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1387    if test "x$testval" != x; then
1388       HAVE_GNU_MAKE=yes
1389    else
1390       ac_enable_autodepend=no
1391    fi
1392    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1393    if test $HAVE_GNU_MAKE = yes; then
1394       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1395       SAVE_CFLAGS="$CFLAGS"
1396       CFLAGS="$CFLAGS -MMD -MF deps.d"
1397       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1398       CFLAGS="$SAVE_CFLAGS"
1399       test -f deps.d || ac_enable_autodepend=no
1400       rm -rf deps.d
1401       AC_MSG_RESULT([$ac_enable_autodepend])
1402    fi
1403    if test $ac_enable_autodepend = yes; then
1404       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1405       ## In parallel builds, another make might create depdir between
1406       ## the first test and mkdir, so stick another test on the end.
1407       ## Or use mkinstalldirs?  mkdir -p is not portable.
1408       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1409       deps_frag=autodeps.mk
1410    fi
1411 fi
1412 deps_frag=$srcdir/src/$deps_frag
1413 AC_SUBST(MKDEPDIR)
1414 AC_SUBST(DEPFLAGS)
1415 AC_SUBST_FILE(deps_frag)
1416
1417
1418 dnl checks for operating system services
1419 AC_SYS_LONG_FILE_NAMES
1420
1421 #### Choose a window system.
1422
1423 AC_PATH_X
1424 if test "$no_x" = yes; then
1425   window_system=none
1426 else
1427   window_system=x11
1428 fi
1429
1430 ## Workaround for bug in autoconf <= 2.62.
1431 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1432 ## No need to do anything special for these standard directories.
1433 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1434
1435    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1436
1437 fi
1438
1439 LD_SWITCH_X_SITE_AUX=
1440 LD_SWITCH_X_SITE_AUX_RPATH=
1441 if test "${x_libraries}" != NONE; then
1442   if test -n "${x_libraries}"; then
1443     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1444     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1445     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1446   fi
1447   x_default_search_path=""
1448   x_search_path=${x_libraries}
1449   if test -z "${x_search_path}"; then
1450     x_search_path=/usr/lib
1451   fi
1452   for x_library in `echo ${x_search_path}: | \
1453                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1454     x_search_path="\
1455 ${x_library}/X11/%L/%T/%N%C%S:\
1456 ${x_library}/X11/%l/%T/%N%C%S:\
1457 ${x_library}/X11/%T/%N%C%S:\
1458 ${x_library}/X11/%L/%T/%N%S:\
1459 ${x_library}/X11/%l/%T/%N%S:\
1460 ${x_library}/X11/%T/%N%S"
1461     if test x"${x_default_search_path}" = x; then
1462       x_default_search_path=${x_search_path}
1463     else
1464       x_default_search_path="${x_search_path}:${x_default_search_path}"
1465     fi
1466   done
1467 fi
1468 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1469 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1470
1471 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1472   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1473 fi
1474
1475 if test x"${x_includes}" = x; then
1476   bitmapdir=/usr/include/X11/bitmaps
1477 else
1478   # accumulate include directories that have X11 bitmap subdirectories
1479   bmd_acc="dummyval"
1480   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1481     if test -d "${bmd}/X11/bitmaps"; then
1482       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1483     fi
1484     if test -d "${bmd}/bitmaps"; then
1485       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1486     fi
1487   done
1488   if test ${bmd_acc} != "dummyval"; then
1489     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1490   fi
1491 fi
1492
1493 HAVE_NS=no
1494 NS_IMPL_COCOA=no
1495 NS_IMPL_GNUSTEP=no
1496 tmp_CPPFLAGS="$CPPFLAGS"
1497 tmp_CFLAGS="$CFLAGS"
1498 CPPFLAGS="$CPPFLAGS -x objective-c"
1499 CFLAGS="$CFLAGS -x objective-c"
1500 TEMACS_LDFLAGS2="\${LDFLAGS}"
1501 dnl I don't think it's especially important, but src/Makefile.in
1502 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1503 dnl trailing "/" to it, so now we do it here.
1504 if test "${with_ns}" != no; then
1505   if test "${opsys}" = darwin; then
1506      NS_IMPL_COCOA=yes
1507      ns_appdir=`pwd`/nextstep/Emacs.app/
1508      ns_appbindir=${ns_appdir}Contents/MacOS/
1509      ns_appresdir=${ns_appdir}Contents/Resources
1510      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1511   elif test -f $GNUSTEP_CONFIG_FILE; then
1512      NS_IMPL_GNUSTEP=yes
1513      ns_appdir=`pwd`/nextstep/Emacs.app/
1514      ns_appbindir=${ns_appdir}
1515      ns_appresdir=${ns_appdir}Resources
1516      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1517      dnl FIXME sourcing this several times in subshells seems inefficient.
1518      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1519      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1520      dnl I seemed to need these as well with GNUstep-startup 0.25.
1521      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1522      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1523      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1524        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1525      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1526        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1527      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1528      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1529      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1530      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1531      LIB_STANDARD=
1532      START_FILES=
1533      TEMACS_LDFLAGS2=
1534   fi
1535   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1536                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1537   files are missing or cannot be compiled.])])
1538   NS_HAVE_NSINTEGER=yes
1539   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1540                                      [NSInteger i;])],
1541                     ns_have_nsinteger=yes,
1542                     ns_have_nsinteger=no)
1543   if test $ns_have_nsinteger = no; then
1544     NS_HAVE_NSINTEGER=no
1545   fi
1546 fi
1547 AC_SUBST(TEMACS_LDFLAGS2)
1548
1549 ns_frag=/dev/null
1550 NS_OBJ=
1551 NS_SUPPORT=
1552 if test "${HAVE_NS}" = yes; then
1553   window_system=nextstep
1554   with_xft=no
1555   # set up packaging dirs
1556   exec_prefix=${ns_appbindir}
1557   libexecdir=${ns_appbindir}/libexec
1558   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1559      prefix=${ns_appresdir}
1560   fi
1561   ns_frag=$srcdir/src/ns.mk
1562   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1563   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1564 fi
1565 CFLAGS="$tmp_CFLAGS"
1566 CPPFLAGS="$tmp_CPPFLAGS"
1567 AC_SUBST(NS_OBJ)
1568 AC_SUBST(NS_SUPPORT)
1569 AC_SUBST(LIB_STANDARD)
1570 AC_SUBST_FILE(ns_frag)
1571
1572 case "${window_system}" in
1573   x11 )
1574     HAVE_X_WINDOWS=yes
1575     HAVE_X11=yes
1576     case "${with_x_toolkit}" in
1577       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1578       motif ) USE_X_TOOLKIT=MOTIF ;;
1579       gtk ) with_gtk=yes
1580 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1581 dnl USE_X_TOOLKIT is set.
1582             USE_X_TOOLKIT=none ;;
1583       gtk3 ) with_gtk3=yes
1584              USE_X_TOOLKIT=none ;;
1585       no ) USE_X_TOOLKIT=none ;;
1586 dnl If user did not say whether to use a toolkit, make this decision later:
1587 dnl use the toolkit if we have gtk, or X11R5 or newer.
1588       * ) USE_X_TOOLKIT=maybe ;;
1589     esac
1590   ;;
1591   nextstep | none )
1592     HAVE_X_WINDOWS=no
1593     HAVE_X11=no
1594     USE_X_TOOLKIT=none
1595   ;;
1596 esac
1597
1598 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1599    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1600    if test "$HAVE_XSERVER" = true ||
1601       test -n "$DISPLAY" ||
1602       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1603         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1604 were found.  You should install the relevant development files for X
1605 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1606 sure you have development files for image handling, i.e.
1607 tiff, gif, jpeg, png and xpm.
1608 If you are sure you want Emacs compiled without X window support, pass
1609   --without-x
1610 to configure.])
1611    fi
1612 fi
1613
1614 ### If we're using X11, we should use the X menu package.
1615 HAVE_MENUS=no
1616 case ${HAVE_X11} in
1617   yes ) HAVE_MENUS=yes ;;
1618 esac
1619
1620 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1621 # Assume not, until told otherwise.
1622 GNU_MALLOC=yes
1623 doug_lea_malloc=yes
1624 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1625 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1626 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1627                emacs_cv_var___after_morecore_hook,
1628 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1629   emacs_cv_var___after_morecore_hook=yes,
1630   emacs_cv_var___after_morecore_hook=no)])
1631 if test $emacs_cv_var___after_morecore_hook = no; then
1632   doug_lea_malloc=no
1633 fi
1634
1635
1636 dnl See comments in aix4-2.h about maybe using system malloc there.
1637 system_malloc=no
1638 case "$opsys" in
1639   ## darwin ld insists on the use of malloc routines in the System framework.
1640   darwin|sol2-10) system_malloc=yes ;;
1641 esac
1642
1643 if test "${system_malloc}" = "yes"; then
1644   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1645   GNU_MALLOC=no
1646   GNU_MALLOC_reason="
1647     (The GNU allocators don't work with this system configuration.)"
1648   GMALLOC_OBJ=
1649   VMLIMIT_OBJ=
1650 else
1651   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1652   VMLIMIT_OBJ=vm-limit.o
1653 fi
1654 AC_SUBST(GMALLOC_OBJ)
1655 AC_SUBST(VMLIMIT_OBJ)
1656
1657 if test "$doug_lea_malloc" = "yes" ; then
1658   if test "$GNU_MALLOC" = yes ; then
1659     GNU_MALLOC_reason="
1660       (Using Doug Lea's new malloc from the GNU C Library.)"
1661   fi
1662   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1663             [Define to 1 if you are using the GNU C Library.])
1664
1665   ## Use mmap directly for allocating larger buffers.
1666   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1667   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1668   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1669   case "$opsys" in
1670     gnu*) REL_ALLOC=no ;;
1671   esac
1672 fi
1673
1674 if test x"${REL_ALLOC}" = x; then
1675   REL_ALLOC=${GNU_MALLOC}
1676 fi
1677
1678 use_mmap_for_buffers=no
1679 case "$opsys" in
1680   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1681 esac
1682
1683 AC_FUNC_MMAP
1684 if test $use_mmap_for_buffers = yes; then
1685   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1686   REL_ALLOC=no
1687 fi
1688
1689 LIBS="$LIBS_SYSTEM $LIBS"
1690
1691 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1692 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1693 AC_CHECK_LIB(dnet, dnet_ntoa)
1694 dnl This causes -lresolv to get used in subsequent tests,
1695 dnl which causes failures on some systems such as HPUX 9.
1696 dnl AC_CHECK_LIB(resolv, gethostbyname)
1697
1698 dnl FIXME replace main with a function we actually want from this library.
1699 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1700
1701 AC_CHECK_LIB(pthreads, cma_open)
1702
1703 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1704 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1705 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1706 ## added to LIBS in configure would never contain the pthreads part,
1707 ## but the value used in Makefiles might.  FIXME?
1708 ##
1709 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1710 ## be harmless on older versions of X where it happens to exist.
1711 test "$opsys" = "aix4-2" && \
1712   test $ac_cv_lib_pthreads_cma_open = yes && \
1713   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1714
1715 dnl Check for need for bigtoc support on IBM AIX
1716
1717 case ${host_os} in
1718 aix*)
1719   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1720     case $GCC in
1721     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1722     *) gdb_cv_bigtoc=-bbigtoc ;;
1723     esac
1724
1725     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1726     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1727   ])
1728   ;;
1729 esac
1730
1731 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1732 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1733 # REAL_CPPFLAGS later on.
1734
1735 REAL_CPPFLAGS="$CPPFLAGS"
1736
1737 if test "${HAVE_X11}" = "yes"; then
1738   DEFS="$C_SWITCH_X_SITE $DEFS"
1739   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1740   LIBS="-lX11 $LIBS"
1741   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1742   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1743
1744   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1745   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1746   # but it's more convenient here to set LD_RUN_PATH
1747   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1748   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1749     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1750     export LD_RUN_PATH
1751   fi
1752
1753   if test "${opsys}" = "gnu-linux"; then
1754     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1755     AC_TRY_LINK([],
1756      [XOpenDisplay ("foo");],
1757      [xlinux_first_failure=no],
1758      [xlinux_first_failure=yes])
1759     if test "${xlinux_first_failure}" = "yes"; then
1760       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1761       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1762       OLD_CPPFLAGS="$CPPFLAGS"
1763       OLD_LIBS="$LIBS"
1764       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1765       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1766       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1767       LIBS="$LIBS -b i486-linuxaout"
1768       AC_TRY_LINK([],
1769        [XOpenDisplay ("foo");],
1770        [xlinux_second_failure=no],
1771        [xlinux_second_failure=yes])
1772       if test "${xlinux_second_failure}" = "yes"; then
1773         # If we get the same failure with -b, there is no use adding -b.
1774         # So take it out.  This plays safe.
1775         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1776         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1777         CPPFLAGS="$OLD_CPPFLAGS"
1778         LIBS="$OLD_LIBS"
1779         AC_MSG_RESULT(no)
1780       else
1781         AC_MSG_RESULT(yes)
1782       fi
1783     else
1784       AC_MSG_RESULT(no)
1785     fi
1786   fi
1787
1788   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1789   # header files included from there.
1790   AC_MSG_CHECKING(for Xkb)
1791   AC_TRY_LINK([#include <X11/Xlib.h>
1792 #include <X11/XKBlib.h>],
1793         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1794         emacs_xkb=yes, emacs_xkb=no)
1795   AC_MSG_RESULT($emacs_xkb)
1796   if test $emacs_xkb = yes; then
1797     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1798   fi
1799
1800   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1801 XScreenNumberOfScreen XSetWMProtocols)
1802 fi
1803
1804 if test "${window_system}" = "x11"; then
1805   AC_MSG_CHECKING(X11 version 6)
1806   AC_CACHE_VAL(emacs_cv_x11_version_6,
1807   [AC_TRY_LINK([#include <X11/Xlib.h>],
1808 [#if XlibSpecificationRelease < 6
1809 fail;
1810 #endif
1811 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1812   if test $emacs_cv_x11_version_6 = yes; then
1813     AC_MSG_RESULT(6 or newer)
1814     AC_DEFINE(HAVE_X11R6, 1,
1815               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1816     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1817     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1818     ## XIM support.
1819     case "$opsys" in
1820       sol2-*) : ;;
1821       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1822            [Define if you have usable X11R6-style XIM support.])
1823          ;;
1824     esac
1825   else
1826     AC_MSG_RESULT(before 6)
1827   fi
1828 fi
1829
1830
1831 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1832 HAVE_RSVG=no
1833 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1834   if test "${with_rsvg}" != "no"; then
1835     RSVG_REQUIRED=2.11.0
1836     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1837
1838     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1839     AC_SUBST(RSVG_CFLAGS)
1840     AC_SUBST(RSVG_LIBS)
1841
1842     if test ".${RSVG_CFLAGS}" != "."; then
1843       HAVE_RSVG=yes
1844       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1845       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1846       LIBS="$RSVG_LIBS $LIBS"
1847     fi
1848   fi
1849 fi
1850
1851
1852 HAVE_GTK=no
1853 if test "${with_gtk3}" = "yes"; then
1854   GLIB_REQUIRED=2.6
1855   GTK_REQUIRED=2.90
1856   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1857
1858   dnl Checks for libraries.
1859   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1860   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1861      AC_MSG_ERROR($GTK_PKG_ERRORS)
1862   fi
1863 fi
1864
1865 if test "$pkg_check_gtk" != "yes"; then
1866   HAVE_GTK=no
1867 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1868   GLIB_REQUIRED=2.6
1869   GTK_REQUIRED=2.6
1870   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1871
1872   dnl Checks for libraries.
1873   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1874   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1875      AC_MSG_ERROR($GTK_PKG_ERRORS)
1876   fi
1877 fi
1878 fi
1879
1880 GTK_OBJ=
1881 if test x"$pkg_check_gtk" = xyes; then
1882
1883   AC_SUBST(GTK_CFLAGS)
1884   AC_SUBST(GTK_LIBS)
1885   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1886   CFLAGS="$CFLAGS $GTK_CFLAGS"
1887   LIBS="$GTK_LIBS $LIBS"
1888   dnl Try to compile a simple GTK program.
1889   GTK_COMPILES=no
1890   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1891   if test "${GTK_COMPILES}" != "yes"; then
1892     if test "$USE_X_TOOLKIT" != "maybe"; then
1893       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1894     fi
1895   else
1896     HAVE_GTK=yes
1897     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1898     GTK_OBJ=gtkutil.o
1899     USE_X_TOOLKIT=none
1900     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1901       :
1902     else
1903       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1904        closing open displays.  This is no problem if you just use
1905        one display, but if you use more than one and close one of them
1906        Emacs may crash.]])
1907       sleep 3
1908     fi
1909   fi
1910
1911 fi
1912 AC_SUBST(GTK_OBJ)
1913
1914
1915 if test "${HAVE_GTK}" = "yes"; then
1916
1917   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1918   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1919   if test "$with_toolkit_scroll_bars" != no; then
1920     with_toolkit_scroll_bars=yes
1921   fi
1922
1923   dnl  Check if we have the old file selection dialog declared and
1924   dnl  in the link library.  In 2.x it may be in the library,
1925   dnl  but not declared if deprecated featured has been selected out.
1926   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1927   HAVE_GTK_FILE_SELECTION=no
1928   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1929                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1930 #include <gtk/gtk.h>])
1931   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1932     AC_CHECK_FUNCS(gtk_file_selection_new)
1933   fi
1934
1935   dnl Check if pthreads are available.  Emacs only needs this when using
1936   dnl gtk_file_chooser under Gnome.
1937     HAVE_GTK_AND_PTHREAD=no
1938     AC_CHECK_HEADERS(pthread.h)
1939     if test "$ac_cv_header_pthread_h"; then
1940       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1941     fi
1942     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1943       case "${canonical}" in
1944         *-hpux*) ;;
1945         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1946       esac
1947       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1948                [Define to 1 if you have GTK and pthread (-lpthread).])
1949     fi
1950
1951   dnl Check for functions introduced in 2.14 and later.
1952   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1953                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1954                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1955                  gtk_orientable_set_orientation)
1956
1957 fi
1958
1959 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1960 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1961 dnl also not configured.
1962 HAVE_DBUS=no
1963 DBUS_OBJ=
1964 if test "${with_dbus}" = "yes"; then
1965    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1966    if test "$HAVE_DBUS" = yes; then
1967      LIBS="$LIBS $DBUS_LIBS"
1968      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1969      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1970      DBUS_OBJ=dbusbind.o
1971    fi
1972 fi
1973 AC_SUBST(DBUS_OBJ)
1974
1975 dnl GConf has been tested under GNU/Linux only.
1976 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1977 HAVE_GCONF=no
1978 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1979    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1980    if test "$HAVE_GCONF" = yes; then
1981       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1982    fi
1983 fi
1984
1985 dnl SELinux is available for GNU/Linux only.
1986 HAVE_LIBSELINUX=no
1987 LIBSELINUX_LIBS=
1988 if test "${with_selinux}" = "yes"; then
1989    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1990    if test "$HAVE_LIBSELINUX" = yes; then
1991       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1992       LIBSELINUX_LIBS=-lselinux
1993    fi
1994 fi
1995 AC_SUBST(LIBSELINUX_LIBS)
1996
1997 dnl Do not put whitespace before the #include statements below.
1998 dnl Older compilers (eg sunos4 cc) choke on it.
1999 HAVE_XAW3D=no
2000 LUCID_LIBW=
2001 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2002   if test "$with_xaw3d" != no; then
2003     AC_MSG_CHECKING(for xaw3d)
2004     AC_CACHE_VAL(emacs_cv_xaw3d,
2005     [AC_TRY_LINK([
2006 #include <X11/Intrinsic.h>
2007 #include <X11/Xaw3d/Simple.h>],
2008       [],
2009       emacs_cv_xaw3d=yes,
2010       emacs_cv_xaw3d=no)])
2011   else
2012     emacs_cv_xaw3d=no
2013   fi
2014   if test $emacs_cv_xaw3d = yes; then
2015     AC_MSG_RESULT([yes; using Lucid toolkit])
2016     USE_X_TOOLKIT=LUCID
2017     HAVE_XAW3D=yes
2018     LUCID_LIBW=-lXaw3d
2019     AC_DEFINE(HAVE_XAW3D, 1,
2020               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2021   else
2022     AC_MSG_RESULT(no)
2023     AC_MSG_CHECKING(for libXaw)
2024     AC_CACHE_VAL(emacs_cv_xaw,
2025     [AC_TRY_LINK([
2026 #include <X11/Intrinsic.h>
2027 #include <X11/Xaw/Simple.h>],
2028       [],
2029       emacs_cv_xaw=yes,
2030       emacs_cv_xaw=no)])
2031     if test $emacs_cv_xaw = yes; then
2032       AC_MSG_RESULT([yes; using Lucid toolkit])
2033       USE_X_TOOLKIT=LUCID
2034       LUCID_LIBW=-lXaw
2035     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2036       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2037     else
2038       AC_MSG_RESULT([no; do not use toolkit by default])
2039       USE_X_TOOLKIT=none
2040     fi
2041   fi
2042 fi
2043
2044 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2045
2046 LIBXTR6=
2047 if test "${USE_X_TOOLKIT}" != "none"; then
2048   AC_MSG_CHECKING(X11 toolkit version)
2049   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2050   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2051 [#if XtSpecificationRelease < 6
2052 fail;
2053 #endif
2054 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2055   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2056   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2057     AC_MSG_RESULT(6 or newer)
2058     AC_DEFINE(HAVE_X11XTR6, 1,
2059               [Define to 1 if you have the X11R6 or newer version of Xt.])
2060     LIBXTR6="-lSM -lICE"
2061     case "$opsys" in
2062       ## Use libw.a along with X11R6 Xt.
2063       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2064     esac
2065   else
2066     AC_MSG_RESULT(before 6)
2067   fi
2068
2069 dnl If using toolkit, check whether libXmu.a exists.
2070 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2071   OLDLIBS="$LIBS"
2072   if test x$HAVE_X11XTR6 = xyes; then
2073     LIBS="-lXt -lSM -lICE $LIBS"
2074   else
2075     LIBS="-lXt $LIBS"
2076   fi
2077   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2078   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2079 fi
2080 AC_SUBST(LIBXTR6)
2081
2082 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2083 dnl Why not just test for libxmu in the normal way?
2084 LIBXMU=-lXmu
2085 case "$machine" in
2086   ## These machines don't supply Xmu.
2087   hpux* | aix4-2 )
2088     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2089     ;;
2090 esac
2091 AC_SUBST(LIBXMU)
2092
2093 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2094 if test "${HAVE_X11}" = "yes"; then
2095   if test "${USE_X_TOOLKIT}" != "none"; then
2096     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2097   fi
2098 fi
2099
2100 LIBXP=
2101 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2102   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2103   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2104     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2105 int x = 5;
2106 #else
2107 Motif version prior to 2.1.
2108 #endif],
2109     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2110   if test $emacs_cv_motif_version_2_1 = yes; then
2111     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2112   else
2113     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2114     # We put this in CFLAGS temporarily to precede other -I options
2115     # that might be in CFLAGS temporarily.
2116     # We put this in CPPFLAGS where it precedes the other -I options.
2117     OLD_CPPFLAGS=$CPPFLAGS
2118     OLD_CFLAGS=$CFLAGS
2119     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2120     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2121     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2122       [int x = 5;],
2123       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2124     if test $emacs_cv_lesstif = yes; then
2125       # Make sure this -I option remains in CPPFLAGS after it is set
2126       # back to REAL_CPPFLAGS.
2127       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2128       # have those other -I options anyway.  Ultimately, having this
2129       # directory ultimately in CPPFLAGS will be enough.
2130       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2131       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2132     else
2133       CFLAGS=$OLD_CFLAGS
2134       CPPFLAGS=$OLD_CPPFLAGS
2135     fi
2136   fi
2137 fi
2138
2139 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2140 dnl using Motif or Xaw3d is available, and unless
2141 dnl --with-toolkit-scroll-bars=no was specified.
2142
2143 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2144             [Define to 1 if we should use toolkit scroll bars.])dnl
2145 USE_TOOLKIT_SCROLL_BARS=no
2146 if test "${with_toolkit_scroll_bars}" != "no"; then
2147   if test "${USE_X_TOOLKIT}" != "none"; then
2148     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2149       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2150       HAVE_XAW3D=no
2151       USE_TOOLKIT_SCROLL_BARS=yes
2152     elif test "${HAVE_XAW3D}" = "yes"; then
2153       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2154       USE_TOOLKIT_SCROLL_BARS=yes
2155     fi
2156   elif test "${HAVE_GTK}" = "yes"; then
2157     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2158     USE_TOOLKIT_SCROLL_BARS=yes
2159   elif test "${HAVE_NS}" = "yes"; then
2160     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2161     USE_TOOLKIT_SCROLL_BARS=yes
2162   fi
2163 fi
2164
2165 dnl See if XIM is available.
2166 AC_TRY_COMPILE([
2167           #include <X11/Xlib.h>
2168           #include <X11/Xresource.h>],
2169          [XIMProc  callback;],
2170          [HAVE_XIM=yes
2171          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2172          HAVE_XIM=no)
2173
2174 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2175
2176 if test "${with_xim}" != "no"; then
2177   AC_DEFINE(USE_XIM, 1,
2178             [Define to 1 if we should use XIM, if it is available.])
2179 fi
2180
2181
2182 if test "${HAVE_XIM}" != "no"; then
2183   late_CFLAGS=$CFLAGS
2184   if test "$GCC" = yes; then
2185     CFLAGS="$CFLAGS --pedantic-errors"
2186   fi
2187   AC_TRY_COMPILE([
2188 #include <X11/Xlib.h>
2189 #include <X11/Xresource.h>],
2190 [Display *display;
2191 XrmDatabase db;
2192 char *res_name;
2193 char *res_class;
2194 XIMProc  callback;
2195 XPointer *client_data;
2196 #ifndef __GNUC__
2197 /* If we're not using GCC, it's probably not XFree86, and this is
2198    probably right, but we can't use something like --pedantic-errors.  */
2199 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2200                                            char*, XIMProc, XPointer*);
2201 #endif
2202 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2203    client_data);],
2204     [emacs_cv_arg6_star=yes])
2205   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2206          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2207 either XPointer or XPointer*.])dnl
2208   if test "$emacs_cv_arg6_star" = yes; then
2209     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2210   else
2211     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2212   fi
2213   CFLAGS=$late_CFLAGS
2214 fi
2215
2216 ### Start of font-backend (under any platform) section.
2217 # (nothing here yet -- this is a placeholder)
2218 ### End of font-backend (under any platform) section.
2219
2220 ### Start of font-backend (under X11) section.
2221 if test "${HAVE_X11}" = "yes"; then
2222    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2223
2224    ## Use -lXft if available, unless `--with-xft=no'.
2225    HAVE_XFT=maybe
2226     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2227       with_xft="no";
2228     fi
2229     if test "x${with_xft}" != "xno"; then
2230
2231       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2232       ## Because xftfont.c uses XRenderQueryExtension, we also
2233       ## need to link to -lXrender.
2234       HAVE_XRENDER=no
2235       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2236       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2237         OLD_CPPFLAGS="$CPPFLAGS"
2238         OLD_CFLAGS="$CFLAGS"
2239         OLD_LIBS="$LIBS"
2240         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2241         CFLAGS="$CFLAGS $XFT_CFLAGS"
2242         XFT_LIBS="-lXrender $XFT_LIBS"
2243         LIBS="$XFT_LIBS $LIBS"
2244         AC_CHECK_HEADER(X11/Xft/Xft.h,
2245           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2246
2247         if test "${HAVE_XFT}" = "yes"; then
2248           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2249             AC_SUBST(XFT_LIBS)
2250           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2251         else
2252           CPPFLAGS="$OLD_CPPFLAGS"
2253           CFLAGS="$OLD_CFLAGS"
2254           LIBS="$OLD_LIBS"
2255         fi                        # "${HAVE_XFT}" = "yes"
2256       fi                          # "$HAVE_XFT" != no
2257     fi                            # "x${with_xft}" != "xno"
2258
2259     dnl For the "Does Emacs use" message at the end.
2260     if test "$HAVE_XFT" != "yes"; then
2261        HAVE_XFT=no
2262     fi
2263
2264
2265     HAVE_FREETYPE=no
2266     ## We used to allow building with FreeType and without Xft.
2267     ## However, the ftx font backend driver is not in good shape.
2268     if test "${HAVE_XFT}" = "yes"; then
2269       dnl As we use Xft, we anyway use freetype.
2270       dnl There's no need for additional CFLAGS and LIBS.
2271       HAVE_FREETYPE=yes
2272       FONTCONFIG_CFLAGS=
2273       FONTCONFIG_LIBS=
2274     fi
2275
2276     HAVE_LIBOTF=no
2277     if test "${HAVE_FREETYPE}" = "yes"; then
2278       AC_DEFINE(HAVE_FREETYPE, 1,
2279                 [Define to 1 if using the freetype and fontconfig libraries.])
2280       if test "${with_libotf}" != "no"; then
2281         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2282                           HAVE_LIBOTF=no)
2283         if test "$HAVE_LIBOTF" = "yes"; then
2284           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2285           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2286                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2287                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2288           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2289             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2290                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2291           fi
2292         fi
2293       fi
2294     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2295     dnl Does the new font backend require it, or can it work without it?
2296     fi
2297
2298     HAVE_M17N_FLT=no
2299     if test "${HAVE_LIBOTF}" = yes; then
2300       if test "${with_m17n_flt}" != "no"; then
2301         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2302         if test "$HAVE_M17N_FLT" = "yes"; then
2303           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2304         fi
2305       fi
2306     fi
2307 else
2308     HAVE_XFT=no
2309     HAVE_FREETYPE=no
2310     HAVE_LIBOTF=no
2311     HAVE_M17N_FLT=no
2312 fi
2313
2314 ### End of font-backend (under X11) section.
2315
2316 AC_SUBST(FREETYPE_CFLAGS)
2317 AC_SUBST(FREETYPE_LIBS)
2318 AC_SUBST(FONTCONFIG_CFLAGS)
2319 AC_SUBST(FONTCONFIG_LIBS)
2320 AC_SUBST(LIBOTF_CFLAGS)
2321 AC_SUBST(LIBOTF_LIBS)
2322 AC_SUBST(M17N_FLT_CFLAGS)
2323 AC_SUBST(M17N_FLT_LIBS)
2324
2325 ### Use -lXpm if available, unless `--with-xpm=no'.
2326 HAVE_XPM=no
2327 LIBXPM=
2328 if test "${HAVE_X11}" = "yes"; then
2329   if test "${with_xpm}" != "no"; then
2330     AC_CHECK_HEADER(X11/xpm.h,
2331       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2332     if test "${HAVE_XPM}" = "yes"; then
2333       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2334       AC_EGREP_CPP(no_return_alloc_pixels,
2335       [#include "X11/xpm.h"
2336 #ifndef XpmReturnAllocPixels
2337 no_return_alloc_pixels
2338 #endif
2339       ], HAVE_XPM=no, HAVE_XPM=yes)
2340
2341       if test "${HAVE_XPM}" = "yes"; then
2342         AC_MSG_RESULT(yes)
2343       else
2344         AC_MSG_RESULT(no)
2345       fi
2346     fi
2347   fi
2348
2349   if test "${HAVE_XPM}" = "yes"; then
2350     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2351     LIBXPM=-lXpm
2352   fi
2353 fi
2354 AC_SUBST(LIBXPM)
2355
2356 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2357 HAVE_JPEG=no
2358 LIBJPEG=
2359 if test "${HAVE_X11}" = "yes"; then
2360   if test "${with_jpeg}" != "no"; then
2361     dnl Checking for jpeglib.h can lose because of a redefinition of
2362     dnl  HAVE_STDLIB_H.
2363     AC_CHECK_HEADER(jerror.h,
2364       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2365   fi
2366
2367   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2368   if test "${HAVE_JPEG}" = "yes"; then
2369     AC_DEFINE(HAVE_JPEG)
2370     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2371         [#include <jpeglib.h>
2372          version=JPEG_LIB_VERSION
2373 ],
2374         [AC_DEFINE(HAVE_JPEG)],
2375         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2376         HAVE_JPEG=no])
2377   fi
2378   if test "${HAVE_JPEG}" = "yes"; then
2379     LIBJPEG=-ljpeg
2380   fi
2381 fi
2382 AC_SUBST(LIBJPEG)
2383
2384 ### Use -lpng if available, unless `--with-png=no'.
2385 HAVE_PNG=no
2386 LIBPNG=
2387 if test "${HAVE_X11}" = "yes"; then
2388   if test "${with_png}" != "no"; then
2389     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2390     # in /usr/include/libpng.
2391     AC_CHECK_HEADERS(png.h libpng/png.h)
2392     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2393       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2394     fi
2395   fi
2396
2397   if test "${HAVE_PNG}" = "yes"; then
2398     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2399     LIBPNG="-lpng -lz -lm"
2400   fi
2401 fi
2402 AC_SUBST(LIBPNG)
2403
2404 ### Use -ltiff if available, unless `--with-tiff=no'.
2405 HAVE_TIFF=no
2406 LIBTIFF=
2407 if test "${HAVE_X11}" = "yes"; then
2408   if test "${with_tiff}" != "no"; then
2409     AC_CHECK_HEADER(tiffio.h,
2410       [tifflibs="-lz -lm"
2411       # At least one tiff package requires the jpeg library.
2412       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2413       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2414   fi
2415
2416   if test "${HAVE_TIFF}" = "yes"; then
2417     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2418     dnl FIXME -lz -lm, as per libpng?
2419     LIBTIFF=-ltiff
2420   fi
2421 fi
2422 AC_SUBST(LIBTIFF)
2423
2424 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2425 HAVE_GIF=no
2426 LIBGIF=
2427 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2428   AC_CHECK_HEADER(gif_lib.h,
2429 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2430 # Earlier versions can crash Emacs.
2431     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2432
2433   if test "$HAVE_GIF" = yes; then
2434     LIBGIF=-lgif
2435   elif test "$HAVE_GIF" = maybe; then
2436 # If gif_lib.h but no libgif, try libungif.
2437     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2438     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2439   fi
2440
2441   if test "${HAVE_GIF}" = "yes"; then
2442     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2443   fi
2444 fi
2445 AC_SUBST(LIBGIF)
2446
2447 dnl Check for required libraries.
2448 if test "${HAVE_X11}" = "yes"; then
2449   MISSING=""
2450   WITH_NO=""
2451   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2452     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2453   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2454     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2455   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2456     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2457   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2458     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2459   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2460     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2461
2462   if test "X${MISSING}" != X; then
2463     AC_MSG_ERROR([The following required libraries were not found:
2464     $MISSING
2465 Maybe some development libraries/packages are missing?
2466 If you don't want to link with them give
2467     $WITH_NO
2468 as options to configure])
2469   fi
2470 fi
2471
2472 ### Use -lgpm if available, unless `--with-gpm=no'.
2473 HAVE_GPM=no
2474 LIBGPM=
2475 MOUSE_SUPPORT=
2476 if test "${with_gpm}" != "no"; then
2477   AC_CHECK_HEADER(gpm.h,
2478     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2479
2480   if test "${HAVE_GPM}" = "yes"; then
2481     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2482     LIBGPM=-lgpm
2483     ## May be reset below.
2484     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2485   fi
2486 fi
2487 AC_SUBST(LIBGPM)
2488
2489 dnl Check for malloc/malloc.h on darwin
2490 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2491
2492 C_SWITCH_X_SYSTEM=
2493 ### Use NeXTstep API to implement GUI.
2494 if test "${HAVE_NS}" = "yes"; then
2495   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2496   if test "${NS_IMPL_COCOA}" = "yes"; then
2497     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2498     GNU_OBJC_CFLAGS=
2499   fi
2500   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2501     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2502     # See also .m.o rule in Makefile.in */
2503     # FIXME: are all these flags really needed?  Document here why.  */
2504     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2505     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2506   fi
2507   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2508     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2509   fi
2510   # We also have mouse menus.
2511   HAVE_MENUS=yes
2512   OTHER_FILES=ns-app
2513 fi
2514
2515
2516 ### Use session management (-lSM -lICE) if available
2517 HAVE_X_SM=no
2518 LIBXSM=
2519 if test "${HAVE_X11}" = "yes"; then
2520   AC_CHECK_HEADER(X11/SM/SMlib.h,
2521     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2522
2523   if test "${HAVE_X_SM}" = "yes"; then
2524     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2525     LIBXSM="-lSM -lICE"
2526     case "$LIBS" in
2527       *-lSM*) ;;
2528       *)      LIBS="$LIBXSM $LIBS" ;;
2529     esac
2530   fi
2531 fi
2532 AC_SUBST(LIBXSM)
2533
2534 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2535 AC_CACHE_CHECK(whether netdb declares h_errno,
2536                emacs_cv_netdb_declares_h_errno,
2537 [AC_TRY_LINK([#include <netdb.h>],
2538   [return h_errno;],
2539   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2540 if test $emacs_cv_netdb_declares_h_errno = yes; then
2541   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2542 fi
2543
2544 AC_FUNC_ALLOCA
2545
2546 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2547 dnl FIXME is there an autoconf test that does the right thing, without
2548 dnl needing to call A_M_E afterwards?
2549 if test x"$ac_cv_func_alloca_works" != xyes; then
2550    AC_MSG_ERROR( [a system implementation of alloca is required] )
2551 fi
2552
2553 # fmod, logb, and frexp are found in -lm on most systems.
2554 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2555 AC_CHECK_LIB(m, sqrt)
2556
2557 # Check for mail-locking functions in a "mail" library.  Probably this should
2558 # have the same check as for liblockfile below.
2559 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2560 if test $have_mail = yes; then
2561   LIBS_MAIL=-lmail
2562   LIBS="$LIBS_MAIL $LIBS"
2563   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2564 else
2565   LIBS_MAIL=
2566 fi
2567 dnl Debian, at least:
2568 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2569 if test $have_lockfile = yes; then
2570    LIBS_MAIL=-llockfile
2571    LIBS="$LIBS_MAIL $LIBS"
2572    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2573 else
2574 # If we have the shared liblockfile, assume we must use it for mail
2575 # locking (e.g. Debian).  If we couldn't link against liblockfile
2576 # (no liblockfile.a installed), ensure that we don't need to.
2577   dnl This works for files generally, not just executables.
2578   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2579   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2580                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2581   if test $ac_cv_prog_liblockfile = yes; then
2582     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2583 This probably means that movemail could lose mail.
2584 There may be a `development' package to install containing liblockfile.])
2585   fi
2586 fi
2587 AC_CHECK_FUNCS(touchlock)
2588 AC_CHECK_HEADERS(maillock.h)
2589 AC_SUBST(LIBS_MAIL)
2590
2591 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2592 ## interlock access to the mail spool.  The alternative is a lock file named
2593 ## /usr/spool/mail/$USER.lock.
2594 mail_lock=no
2595 case "$opsys" in
2596   aix4-2) mail_lock="lockf" ;;
2597
2598   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2599
2600   ## On GNU/Linux systems, both methods are used by various mail programs.
2601   ## I assume most people are using newer mailers that have heard of flock.
2602   ## Change this if you need to.
2603   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2604   ## configure gets the right answers, and that means *NOT* using flock.
2605   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2606   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2607   ## Debian maintainer hasn't provided a clean fix for Emacs.
2608   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2609   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2610   ## correct logic.  -- fx
2611   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2612   ## liblockfile is a Free Software replacement for libmail, used on
2613   ## Debian systems and elsewhere. -rfr.
2614   gnu-*)
2615     mail_lock="flock"
2616     if test $have_mail = yes || test $have_lockfile = yes; then
2617       test $ac_cv_header_maillock_h = yes && mail_lock=no
2618     fi
2619     ;;
2620 esac
2621
2622 BLESSMAIL_TARGET=
2623 case "$mail_lock" in
2624   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2625
2626   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2627
2628   *) BLESSMAIL_TARGET="need-blessmail" ;;
2629 esac
2630 AC_SUBST(BLESSMAIL_TARGET)
2631
2632
2633 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2634 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2635 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2636 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2637 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2638 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2639 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2640 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2641 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2642 cfmakeraw cfsetspeed isnan copysign)
2643
2644 AC_CHECK_HEADERS(sys/un.h)
2645
2646 AC_FUNC_MKTIME
2647 if test "$ac_cv_func_working_mktime" = no; then
2648   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2649 fi
2650
2651 AC_FUNC_GETLOADAVG
2652
2653 AC_FUNC_FSEEKO
2654
2655 # Configure getopt.
2656 m4_include([m4/getopt.m4])
2657 gl_GETOPT_IFELSE([
2658   gl_GETOPT_SUBSTITUTE_HEADER
2659   gl_PREREQ_GETOPT
2660   GETOPTOBJS='getopt.o getopt1.o'
2661 ])
2662 AC_SUBST(GETOPTOBJS)
2663
2664 AC_FUNC_GETPGRP
2665
2666 AC_FUNC_STRFTIME
2667
2668 # UNIX98 PTYs.
2669 AC_CHECK_FUNCS(grantpt)
2670
2671 # PTY-related GNU extensions.
2672 AC_CHECK_FUNCS(getpt)
2673
2674 # Check this now, so that we will NOT find the above functions in ncurses.
2675 # That is because we have not set up to link ncurses in lib-src.
2676 # It's better to believe a function is not available
2677 # than to expect to find it in ncurses.
2678 # Also we need tputs and friends to be able to build at all.
2679 have_tputs_et_al=true
2680 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2681 if test "$have_tputs_et_al" != true; then
2682   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2683 Maybe some development libraries/packages are missing?  Try installing
2684 libncurses-dev(el), libterminfo-dev(el) or similar.])
2685 fi
2686 # Must define this when any termcap library is found.
2687 AC_DEFINE(HAVE_LIBNCURSES, 1,
2688           [Define to 1 if you have the `ncurses' library (-lncurses).])
2689 ## FIXME This was the cpp logic, but I am not sure it is right.
2690 ## The above test has not necessarily found libncurses.
2691 HAVE_LIBNCURSES=yes
2692
2693 ## Use terminfo instead of termcap?
2694 ## Note only system files NOT using terminfo are:
2695 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2696 ## darwin|gnu without ncurses.
2697 TERMINFO=no
2698 LIBS_TERMCAP=
2699 case "$opsys" in
2700   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2701   ## hpux10-20: Use the system provided termcap(3) library.
2702   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2703   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2704   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2705
2706   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2707   ##  The ncurses library has been moved out of the System framework in
2708   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2709   ##  option to use it.
2710   darwin|gnu*)
2711     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2712     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2713       TERMINFO=yes
2714       LIBS_TERMCAP="-lncurses"
2715     fi
2716     ;;
2717
2718   freebsd)
2719     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2720     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2721     [AC_TRY_LINK([#include <osreldate.h>],
2722 [#if __FreeBSD_version < 400000
2723 fail;
2724 #endif
2725 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2726
2727     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2728
2729     if test $emacs_cv_freebsd_terminfo = yes; then
2730       TERMINFO=yes
2731       LIBS_TERMCAP="-lncurses"
2732     else
2733       LIBS_TERMCAP="-ltermcap"
2734     fi
2735     ;;
2736
2737   netbsd)
2738     if test $ac_cv_search_tputs = -lterminfo; then
2739       TERMINFO=yes
2740       LIBS_TERMCAP="-lterminfo"
2741     else
2742       LIBS_TERMCAP="-ltermcap"
2743     fi
2744     ;;
2745
2746 esac
2747
2748 case "$opsys" in
2749   ## hpux: Make sure we get select from libc rather than from libcurses
2750   ##  because libcurses on HPUX 10.10 has a broken version of select.
2751   ##  We used to use -lc -lcurses, but this may be cleaner.
2752   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2753
2754   openbsd) LIBS_TERMCAP="-lncurses" ;;
2755
2756   ## Must use system termcap, if we use any termcap.  It does special things.
2757   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2758 esac
2759
2760 TERMCAP_OBJ=tparam.o
2761 if test $TERMINFO = yes; then
2762   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2763
2764   ## Default used to be -ltermcap.  Add a case above if need something else.
2765   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2766
2767   TERMCAP_OBJ=terminfo.o
2768 fi
2769 AC_SUBST(LIBS_TERMCAP)
2770 AC_SUBST(TERMCAP_OBJ)
2771
2772
2773 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2774 resolv=no
2775 AC_TRY_LINK([#include <netinet/in.h>
2776 #include <arpa/nameser.h>
2777 #include <resolv.h>],
2778     [return res_init();],
2779     have_res_init=yes, have_res_init=no)
2780 if test "$have_res_init" = no; then
2781   OLIBS="$LIBS"
2782   LIBS="$LIBS -lresolv"
2783   AC_MSG_CHECKING(for res_init with -lresolv)
2784   AC_TRY_LINK([#include <netinet/in.h>
2785 #include <arpa/nameser.h>
2786 #include <resolv.h>],
2787     [return res_init();],
2788     have_res_init=yes, have_res_init=no)
2789   AC_MSG_RESULT($have_res_init)
2790   if test "$have_res_init" = yes ; then
2791     resolv=yes
2792   fi
2793   LIBS="$OLIBS"
2794 fi
2795
2796 if test "$have_res_init" = yes; then
2797   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2798 fi
2799
2800 # Do we need the Hesiod library to provide the support routines?
2801 LIBHESIOD=
2802 if test "$with_hesiod" != no ; then
2803   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2804   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2805      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2806                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2807   if test "$resolv" = yes ; then
2808     RESOLVLIB=-lresolv
2809   else
2810     RESOLVLIB=
2811   fi
2812   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2813         hesiod=yes, :, $RESOLVLIB)])
2814
2815   if test x"$hesiod" = xyes; then
2816     AC_DEFINE(HAVE_LIBHESIOD, 1,
2817               [Define to 1 if you have the hesiod library (-lhesiod).])
2818     LIBHESIOD=-lhesiod
2819   fi
2820 fi
2821 AC_SUBST(LIBHESIOD)
2822
2823 # Do we need libresolv (due to res_init or Hesiod)?
2824 if test "$resolv" = yes ; then
2825   AC_DEFINE(HAVE_LIBRESOLV, 1,
2826             [Define to 1 if you have the resolv library (-lresolv).])
2827   LIBRESOLV=-lresolv
2828 else
2829   LIBRESOLV=
2830 fi
2831 AC_SUBST(LIBRESOLV)
2832
2833 # These tell us which Kerberos-related libraries to use.
2834 COM_ERRLIB=
2835 CRYPTOLIB=
2836 KRB5LIB=
2837 DESLIB=
2838 KRB4LIB=
2839
2840 if test "${with_kerberos}" != no; then
2841   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2842   if test $have_com_err = yes; then
2843     COM_ERRLIB=-lcom_err
2844     LIBS="$COM_ERRLIB $LIBS"
2845     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2846   fi
2847   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2848   if test $have_crypto = yes; then
2849     CRYPTOLIB=-lcrypto
2850     LIBS="$CRYPTOLIB $LIBS"
2851     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2852   fi
2853   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2854   if test $have_k5crypto = yes; then
2855     CRYPTOLIB=-lk5crypto
2856     LIBS="$CRYPTOLIB $LIBS"
2857     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2858   fi
2859   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2860   if test $have_krb5=yes; then
2861     KRB5LIB=-lkrb5
2862     LIBS="$KRB5LIB $LIBS"
2863     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2864   fi
2865   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2866   if test "${with_kerberos5}" = no; then
2867     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2868     if test $have_des425 = yes; then
2869       DESLIB=-ldes425
2870       LIBS="$DESLIB $LIBS"
2871       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2872     else
2873       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2874       if test $have_des = yes; then
2875         DESLIB=-ldes
2876         LIBS="$DESLIB $LIBS"
2877         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2878       fi
2879     fi
2880     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2881     if test $have_krb4 = yes; then
2882       KRB4LIB=-lkrb4
2883       LIBS="$KRB4LIB $LIBS"
2884       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2885     else
2886       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2887       if test $have_krb = yes; then
2888         KRB4LIB=-lkrb
2889         LIBS="$KRB4LIB $LIBS"
2890         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2891       fi
2892     fi
2893   fi
2894
2895   if test "${with_kerberos5}" != no; then
2896     AC_CHECK_HEADERS(krb5.h,
2897       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2898                         [#include <krb5.h>])])
2899   else
2900     AC_CHECK_HEADERS(des.h,,
2901                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2902                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2903     AC_CHECK_HEADERS(krb.h,,
2904                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2905                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2906   fi
2907   AC_CHECK_HEADERS(com_err.h)
2908 fi
2909
2910 AC_SUBST(COM_ERRLIB)
2911 AC_SUBST(CRYPTOLIB)
2912 AC_SUBST(KRB5LIB)
2913 AC_SUBST(DESLIB)
2914 AC_SUBST(KRB4LIB)
2915
2916 # Solaris requires -lintl if you want strerror (which calls dgettext)
2917 # to return localized messages.
2918 AC_CHECK_LIB(intl, dgettext)
2919
2920 AC_MSG_CHECKING(whether localtime caches TZ)
2921 AC_CACHE_VAL(emacs_cv_localtime_cache,
2922 [if test x$ac_cv_func_tzset = xyes; then
2923 AC_TRY_RUN([#include <time.h>
2924 extern char **environ;
2925 unset_TZ ()
2926 {
2927   char **from, **to;
2928   for (to = from = environ; (*to = *from); from++)
2929     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2930       to++;
2931 }
2932 char TZ_GMT0[] = "TZ=GMT0";
2933 char TZ_PST8[] = "TZ=PST8";
2934 main()
2935 {
2936   time_t now = time ((time_t *) 0);
2937   int hour_GMT0, hour_unset;
2938   if (putenv (TZ_GMT0) != 0)
2939     exit (1);
2940   hour_GMT0 = localtime (&now)->tm_hour;
2941   unset_TZ ();
2942   hour_unset = localtime (&now)->tm_hour;
2943   if (putenv (TZ_PST8) != 0)
2944     exit (1);
2945   if (localtime (&now)->tm_hour == hour_GMT0)
2946     exit (1);
2947   unset_TZ ();
2948   if (localtime (&now)->tm_hour != hour_unset)
2949     exit (1);
2950   exit (0);
2951 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2952 [# If we have tzset, assume the worst when cross-compiling.
2953 emacs_cv_localtime_cache=yes])
2954 else
2955         # If we lack tzset, report that localtime does not cache TZ,
2956         # since we can't invalidate the cache if we don't have tzset.
2957         emacs_cv_localtime_cache=no
2958 fi])dnl
2959 AC_MSG_RESULT($emacs_cv_localtime_cache)
2960 if test $emacs_cv_localtime_cache = yes; then
2961   AC_DEFINE(LOCALTIME_CACHE, 1,
2962             [Define to 1 if localtime caches TZ.])
2963 fi
2964
2965 if test "x$HAVE_TIMEVAL" = xyes; then
2966   AC_CHECK_FUNCS(gettimeofday)
2967   if test $ac_cv_func_gettimeofday = yes; then
2968     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2969                    emacs_cv_gettimeofday_two_arguments,
2970     [AC_TRY_COMPILE([
2971 #ifdef TIME_WITH_SYS_TIME
2972 #include <sys/time.h>
2973 #include <time.h>
2974 #else
2975 #ifdef HAVE_SYS_TIME_H
2976 #include <sys/time.h>
2977 #else
2978 #include <time.h>
2979 #endif
2980 #endif],
2981       [struct timeval time;
2982        gettimeofday (&time, 0);],
2983       emacs_cv_gettimeofday_two_arguments=yes,
2984       emacs_cv_gettimeofday_two_arguments=no)])
2985     if test $emacs_cv_gettimeofday_two_arguments = no; then
2986       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2987                 [Define to 1 if gettimeofday accepts only one argument.])
2988     fi
2989   fi
2990 fi
2991
2992 ok_so_far=yes
2993 AC_CHECK_FUNC(socket, , ok_so_far=no)
2994 if test $ok_so_far = yes; then
2995   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2996 fi
2997 if test $ok_so_far = yes; then
2998   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2999 fi
3000 if test $ok_so_far = yes; then
3001 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3002   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3003             [Define to 1 if you have inet sockets.])
3004 fi
3005
3006 AC_CHECK_HEADERS(sys/ioctl.h)
3007
3008 if test -f /usr/lpp/X11/bin/smt.exp; then
3009   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3010             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3011 fi
3012
3013 AC_MSG_CHECKING(whether system supports dynamic ptys)
3014 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3015   AC_MSG_RESULT(yes)
3016   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3017 else
3018   AC_MSG_RESULT(no)
3019 fi
3020
3021 AC_FUNC_FORK
3022
3023 dnl Adapted from Haible's version.
3024 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3025   [AC_TRY_LINK([#include <langinfo.h>],
3026     [char* cs = nl_langinfo(CODESET);],
3027     emacs_cv_langinfo_codeset=yes,
3028     emacs_cv_langinfo_codeset=no)
3029   ])
3030 if test $emacs_cv_langinfo_codeset = yes; then
3031   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3032     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3033 fi
3034
3035 AC_CHECK_TYPES(size_t)
3036
3037 AC_TYPE_MBSTATE_T
3038
3039 dnl Restrict could probably be used effectively other than in regex.c.
3040 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3041   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3042                   emacs_cv_c_restrict=yes,
3043                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3044                                   emacs_cv_c_restrict=__restrict,
3045                                   emacs_cv_c_restrict=no)])])
3046 case "$emacs_cv_c_restrict" in
3047   yes) emacs_restrict=restrict;;
3048   no) emacs_restrict="";;
3049   *) emacs_restrict="$emacs_cv_c_restrict";;
3050 esac
3051 if test "$emacs_restrict" != __restrict; then
3052   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3053     [Define to compiler's equivalent of C99 restrict keyword.
3054      Don't define if equivalent is `__restrict'.])
3055 fi
3056
3057 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3058   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3059                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3060 if test "$emacs_cv_c_restrict_arr" = yes; then
3061   AC_DEFINE(__restrict_arr, __restrict,
3062     [Define to compiler's equivalent of C99 restrict keyword in array
3063      declarations.  Define as empty for no equivalent.])
3064 fi
3065
3066 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3067 dnl how the tty code is related to POSIX and/or other versions of termios.
3068 dnl The following looks like a useful start.
3069 dnl
3070 dnl AC_SYS_POSIX_TERMIOS
3071 dnl if test $ac_cv_sys_posix_termios = yes; then
3072 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3073 dnl                                and macros for terminal control.])
3074 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3075 dnl fi
3076
3077 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3078
3079 # Set up the CFLAGS for real compilation, so we can substitute it.
3080 CFLAGS="$REAL_CFLAGS"
3081 CPPFLAGS="$REAL_CPPFLAGS"
3082
3083 ## Hack to detect a buggy GCC version.
3084 if test "x$GCC" = xyes \
3085    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3086    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3087    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3088    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3089 fi
3090
3091 #### Find out which version of Emacs this is.
3092 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3093          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3094 if test x"${version}" = x; then
3095   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3096 fi
3097 if test x"${version}" != x"$PACKAGE_VERSION"; then
3098   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3099 fi
3100
3101 ### Specify what sort of things we'll be editing into Makefile and config.h.
3102 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3103 AC_SUBST(version)
3104 AC_SUBST(configuration)
3105 ## Unused?
3106 AC_SUBST(canonical)
3107 AC_SUBST(srcdir)
3108 AC_SUBST(prefix)
3109 AC_SUBST(exec_prefix)
3110 AC_SUBST(bindir)
3111 AC_SUBST(datadir)
3112 AC_SUBST(sharedstatedir)
3113 AC_SUBST(libexecdir)
3114 AC_SUBST(mandir)
3115 AC_SUBST(infodir)
3116 AC_SUBST(lispdir)
3117 AC_SUBST(locallisppath)
3118 AC_SUBST(lisppath)
3119 AC_SUBST(x_default_search_path)
3120 AC_SUBST(etcdir)
3121 AC_SUBST(archlibdir)
3122 AC_SUBST(docdir)
3123 AC_SUBST(bitmapdir)
3124 AC_SUBST(gamedir)
3125 AC_SUBST(gameuser)
3126 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3127 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3128 ## end of LIBX_BASE, but nothing ever set it.
3129 AC_SUBST(LD_SWITCH_X_SITE)
3130 AC_SUBST(C_SWITCH_X_SITE)
3131 AC_SUBST(C_SWITCH_X_SYSTEM)
3132 AC_SUBST(CFLAGS)
3133 ## Used in lwlib/Makefile.in.
3134 AC_SUBST(X_TOOLKIT_TYPE)
3135 AC_SUBST(machfile)
3136 AC_SUBST(opsysfile)
3137 AC_SUBST(GETLOADAVG_LIBS)
3138 AC_SUBST(ns_appdir)
3139 AC_SUBST(ns_appbindir)
3140 AC_SUBST(ns_appresdir)
3141 AC_SUBST(ns_appsrc)
3142 AC_SUBST(GNU_OBJC_CFLAGS)
3143 AC_SUBST(OTHER_FILES)
3144
3145 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3146                    [Define to the canonical Emacs configuration name.])
3147 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3148                    [Define to the options passed to configure.])
3149 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3150                    [Define to the used machine dependent file.])
3151 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3152                    [Define to the used os dependent file.])
3153
3154 XMENU_OBJ=
3155 XOBJ=
3156 FONT_OBJ=
3157 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3158   AC_DEFINE(HAVE_X_WINDOWS, 1,
3159             [Define to 1 if you want to use the X window system.])
3160   XMENU_OBJ=xmenu.o
3161   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3162   FONT_OBJ=xfont.o
3163   if test "$HAVE_XFT" = "yes"; then
3164     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3165   elif test "$HAVE_FREETYPE" = "yes"; then
3166     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3167   fi
3168   AC_SUBST(FONT_OBJ)
3169 fi
3170 AC_SUBST(XMENU_OBJ)
3171 AC_SUBST(XOBJ)
3172 AC_SUBST(FONT_OBJ)
3173
3174 WIDGET_OBJ=
3175 MOTIF_LIBW=
3176 if test "${USE_X_TOOLKIT}" != "none" ; then
3177   WIDGET_OBJ=widget.o
3178   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3179   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3180     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3181   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3182     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3183     MOTIF_LIBW=-lXm
3184     case "$opsys" in
3185       gnu-linux)
3186         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3187         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3188         ;;
3189
3190       unixware)
3191         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3192         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3193         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3194         ;;
3195
3196       aix4-2)
3197         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3198         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3199         ;;
3200     esac
3201     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3202   fi
3203 fi
3204 AC_SUBST(WIDGET_OBJ)
3205
3206 TOOLKIT_LIBW=
3207 case "$USE_X_TOOLKIT" in
3208   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3209   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3210   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3211 esac
3212 AC_SUBST(TOOLKIT_LIBW)
3213
3214 if test "$USE_X_TOOLKIT" = "none"; then
3215   LIBXT_OTHER="\$(LIBXSM)"
3216   OLDXMENU_TARGET="really-oldXMenu"
3217 else
3218   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3219   OLDXMENU_TARGET="really-lwlib"
3220 fi
3221 AC_SUBST(LIBXT_OTHER)
3222
3223 ## The X Menu stuff is present in the X10 distribution, but missing
3224 ## from X11.  If we have X10, just use the installed library;
3225 ## otherwise, use our own copy.
3226 if test "${HAVE_X11}" = "yes" ; then
3227   AC_DEFINE(HAVE_X11, 1,
3228             [Define to 1 if you want to use version 11 of X windows.
3229              Otherwise, Emacs expects to use version 10.])
3230
3231   if test "$USE_X_TOOLKIT" = "none"; then
3232     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3233   else
3234     OLDXMENU="\${lwlibdir}liblw.a"
3235   fi
3236   LIBXMENU="\$(OLDXMENU)"
3237   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3238   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3239 else
3240   ## For a syntactically valid Makefile; not actually used for anything.
3241   ## See comments in src/Makefile.in.
3242   OLDXMENU=nothing
3243   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3244   if test "${HAVE_X_WINDOWS}" = "yes"; then
3245     LIBXMENU="-lXMenu"
3246   else
3247     LIBXMENU=
3248   fi
3249   LIBX_OTHER=
3250   OLDXMENU_DEPS=
3251 fi
3252
3253 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3254   OLDXMENU_TARGET=
3255   OLDXMENU=nothing
3256   LIBXMENU=
3257   OLDXMENU_DEPS=
3258 fi
3259
3260 AC_SUBST(OLDXMENU_TARGET)
3261 AC_SUBST(OLDXMENU)
3262 AC_SUBST(LIBXMENU)
3263 AC_SUBST(LIBX_OTHER)
3264 AC_SUBST(OLDXMENU_DEPS)
3265
3266 if test "${HAVE_MENUS}" = "yes" ; then
3267   AC_DEFINE(HAVE_MENUS, 1,
3268             [Define to 1 if you have mouse menus.
3269              (This is automatic if you use X, but the option to specify it remains.)
3270              It is also defined with other window systems that support xmenu.c.])
3271 fi
3272
3273 if test "${GNU_MALLOC}" = "yes" ; then
3274   AC_DEFINE(GNU_MALLOC, 1,
3275             [Define to 1 if you want to use the GNU memory allocator.])
3276 fi
3277
3278 RALLOC_OBJ=
3279 if test "${REL_ALLOC}" = "yes" ; then
3280   AC_DEFINE(REL_ALLOC, 1,
3281             [Define REL_ALLOC if you want to use the relocating allocator for
3282              buffer space.])
3283
3284   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3285 fi
3286 AC_SUBST(RALLOC_OBJ)
3287
3288 if test "$opsys" = "cygwin"; then
3289   CYGWIN_OBJ="sheap.o"
3290   ## Cygwin differs because of its unexec().
3291   PRE_ALLOC_OBJ=
3292   POST_ALLOC_OBJ=lastfile.o
3293 else
3294   CYGWIN_OBJ=
3295   PRE_ALLOC_OBJ=lastfile.o
3296   POST_ALLOC_OBJ=
3297 fi
3298 AC_SUBST(CYGWIN_OBJ)
3299 AC_SUBST(PRE_ALLOC_OBJ)
3300 AC_SUBST(POST_ALLOC_OBJ)
3301
3302
3303 case "$opsys" in
3304   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3305
3306   darwin)
3307    ## The -headerpad option tells ld (see man page) to leave room at the
3308    ## end of the header for adding load commands.  Needed for dumping.
3309    ## 0x690 is the total size of 30 segment load commands (at 56
3310    ## each); under Cocoa 31 commands are required.
3311    if test "$HAVE_NS" = "yes"; then
3312      libs_nsgui="-framework AppKit"
3313      headerpad_extra=6C8
3314    else
3315      libs_nsgui=
3316      headerpad_extra=690
3317    fi
3318    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3319
3320    ## This is here because src/Makefile.in did some extra fiddling around
3321    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3322    ##   #ifndef LD_SWITCH_SYSTEM
3323    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3324    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3325    ## not using gcc, darwin system not on an alpha (ie darwin, since
3326    ## darwin + alpha does not occur).
3327    ## Because this was done in src/Makefile.in, the resulting part of
3328    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3329    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3330    ## rather than LD_SWITCH_SYSTEM.
3331    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3332      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3333    ;;
3334
3335   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3336   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3337   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3338   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3339   ## had different values in configure (in ac_link) and src/Makefile.in.
3340   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3341   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3342
3343   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3344 esac
3345
3346 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3347   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3348 fi
3349
3350 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3351
3352
3353 LINKER=
3354 ORDINARY_LINK=
3355 case "$opsys" in
3356   ## gnu: GNU needs its own crt0.
3357   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3358
3359   cygwin) LINKER="\$(CC)" ;;
3360
3361   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3362   ## library search parth, i.e. it won't search /usr/lib for libc and
3363   ## friends.  Using -nostartfiles instead avoids this problem, and
3364   ## will also work on earlier NetBSD releases.
3365   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3366
3367   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3368   ##   MkLinux/LinuxPPC needs this.
3369   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3370   gnu-*)
3371     case "$machine" in
3372       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3373     esac
3374     ;;
3375 esac
3376
3377
3378 if test "x$ORDINARY_LINK" = "xyes"; then
3379
3380   LINKER="\$(CC)"
3381   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3382
3383 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3384 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3385 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3386
3387   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3388   ## places that are difficult to figure out at make time.  Fortunately,
3389   ## these same versions allow you to pass arbitrary flags on to the
3390   ## linker, so there is no reason not to use it as a linker.
3391   ##
3392   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3393   ## searching for libraries in its internal directories, so we have to
3394   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3395   LINKER="\$(CC) -nostdlib"
3396 fi
3397
3398 test "x$LINKER" = "x" && LINKER=ld
3399 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3400 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3401
3402 AC_SUBST(LINKER)
3403
3404
3405 ## FIXME? The logic here is not precisely the same as that above.
3406 ## There is no check here for a pre-defined LINKER.
3407 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3408 LIB_GCC=
3409 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3410
3411   case "$opsys" in
3412     ## cygwin: don't link against static libgcc.
3413     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3414
3415     gnu-*)
3416       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3417       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3418       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3419       if test "$machine" = "arm"; then
3420         LIB_GCC="-lgcc_s"
3421       else
3422         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3423         ## immediately undefine it again and redefine it to empty.
3424         ## Was the C_SWITCH_X_SITE part really necessary?
3425 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3426         LIB_GCC=
3427       fi
3428       ;;
3429
3430     ## Ask GCC where to find libgcc.a.
3431     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3432   esac
3433 fi                              dnl if $GCC
3434 AC_SUBST(LIB_GCC)
3435
3436
3437 TOOLTIP_SUPPORT=
3438 WINDOW_SUPPORT=
3439 ## If we're using X11/GNUstep, define some consequences.
3440 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3441   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3442   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3443   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3444   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3445
3446   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3447   test "$HAVE_X_WINDOWS" = "yes" && \
3448     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3449
3450 fi
3451 AC_SUBST(MOUSE_SUPPORT)
3452 AC_SUBST(TOOLTIP_SUPPORT)
3453 AC_SUBST(WINDOW_SUPPORT)
3454
3455
3456 AH_TOP([/* GNU Emacs site configuration template file.
3457    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3458      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3459
3460 This file is part of GNU Emacs.
3461
3462 GNU Emacs is free software: you can redistribute it and/or modify
3463 it under the terms of the GNU General Public License as published by
3464 the Free Software Foundation, either version 3 of the License, or
3465 (at your option) any later version.
3466
3467 GNU Emacs is distributed in the hope that it will be useful,
3468 but WITHOUT ANY WARRANTY; without even the implied warranty of
3469 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3470 GNU General Public License for more details.
3471
3472 You should have received a copy of the GNU General Public License
3473 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3474
3475
3476 /* No code in Emacs #includes config.h twice, but some bits of code
3477    intended to work with other packages as well (like gmalloc.c)
3478    think they can include it as many times as they like.  */
3479 #ifndef EMACS_CONFIG_H
3480 #define EMACS_CONFIG_H
3481 ])dnl
3482
3483 AH_BOTTOM([
3484 /* Define AMPERSAND_FULL_NAME if you use the convention
3485    that & in the full name stands for the login id.  */
3486 /* Turned on June 1996 supposing nobody will mind it.  */
3487 #define AMPERSAND_FULL_NAME
3488
3489 /* If using GNU, then support inline function declarations.  */
3490 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3491    generally, because even if non-gcc compilers accept `inline', they
3492    may reject `extern inline'.  */
3493 #if defined (__GNUC__) && defined (OPTIMIZE)
3494 #define INLINE __inline__
3495 #else
3496 #define INLINE
3497 #endif
3498
3499 /* `subprocesses' should be defined if you want to
3500    have code for asynchronous subprocesses
3501    (as used in M-x compile and M-x shell).
3502    Only MSDOS does not support this (it overrides
3503    this in its config_opsysfile below).  */
3504
3505 #define subprocesses
3506
3507 /* Include the os and machine dependent files.  */
3508 #include config_opsysfile
3509 #include config_machfile
3510
3511 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3512   (There is probably a better place to do this, but right now the Cocoa
3513    side does this in s/darwin.h and we cannot
3514    parallel this exactly since GNUstep is multi-OS.  */
3515 #ifdef HAVE_NS
3516 # ifdef NS_IMPL_GNUSTEP
3517 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3518 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3519 #  define SYSTEM_PURESIZE_EXTRA 30000
3520 # endif /* NS_IMPL_GNUSTEP */
3521 #endif /* HAVE_NS */
3522
3523 /* SIGTYPE is the macro we actually use.  */
3524 #ifndef SIGTYPE
3525 #define SIGTYPE RETSIGTYPE
3526 #endif
3527
3528 #ifdef emacs /* Don't do this for lib-src.  */
3529 /* Tell regex.c to use a type compatible with Emacs.  */
3530 #define RE_TRANSLATE_TYPE Lisp_Object
3531 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3532 #ifdef make_number
3533 /* If make_number is a macro, use it.  */
3534 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3535 #else
3536 /* If make_number is a function, avoid it.  */
3537 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3538 #endif
3539 #endif
3540
3541 /* Avoid link-time collision with system mktime if we will use our own.  */
3542 #if ! HAVE_MKTIME || BROKEN_MKTIME
3543 #define mktime emacs_mktime
3544 #endif
3545
3546 #define my_strftime nstrftime   /* for strftime.c */
3547
3548 /* These default definitions are good for almost all machines.
3549    The exceptions override them in m/MACHINE.h.  */
3550
3551 #ifndef BITS_PER_CHAR
3552 #define BITS_PER_CHAR 8
3553 #endif
3554
3555 #ifndef BITS_PER_SHORT
3556 #define BITS_PER_SHORT 16
3557 #endif
3558
3559 /* Note that lisp.h uses this in a preprocessor conditional, so it
3560    would not work to use sizeof.  That being so, we do all of them
3561    without sizeof, for uniformity's sake.  */
3562 #ifndef BITS_PER_INT
3563 #define BITS_PER_INT 32
3564 #endif
3565
3566 #ifndef BITS_PER_LONG
3567 #ifdef _LP64
3568 #define BITS_PER_LONG 64
3569 #else
3570 #define BITS_PER_LONG 32
3571 #endif
3572 #endif
3573
3574 /* Define if the compiler supports function prototypes.  It may do so but
3575    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3576 #undef PROTOTYPES
3577
3578 #ifdef HAVE_STRING_H
3579 #include <string.h>
3580 #endif
3581
3582 #ifdef HAVE_STDLIB_H
3583 #include <stdlib.h>
3584 #endif
3585
3586 #ifdef HAVE_ALLOCA_H
3587 # include <alloca.h>
3588 #elif defined __GNUC__
3589 # define alloca __builtin_alloca
3590 #elif defined _AIX
3591 # define alloca __alloca
3592 #else
3593 # include <stddef.h>
3594 # ifdef  __cplusplus
3595 extern "C"
3596 # endif
3597 void *alloca (size_t);
3598 #endif
3599
3600 #ifndef HAVE_SIZE_T
3601 typedef unsigned size_t;
3602 #endif
3603
3604 #if defined __GNUC__ && (__GNUC__ > 2 \
3605                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3606 #define NO_RETURN       __attribute__ ((__noreturn__))
3607 #else
3608 #define NO_RETURN       /* nothing */
3609 #endif
3610
3611 /* These won't be used automatically yet.  We also need to know, at least,
3612    that the stack is continuous.  */
3613 #ifdef __GNUC__
3614 #  ifndef GC_SETJMP_WORKS
3615   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3616 #    define GC_SETJMP_WORKS 1
3617 #  endif
3618 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3619 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3620 #  endif
3621 #endif
3622
3623 #endif /* EMACS_CONFIG_H */
3624
3625 /*
3626 Local Variables:
3627 mode: c
3628 End:
3629 */
3630 ])dnl
3631
3632 #### Report on what we decided to do.
3633 #### Report GTK as a toolkit, even if it doesn't use Xt.
3634 #### It makes printing result more understandable as using GTK sets
3635 #### toolkit_scroll_bars to yes by default.
3636 if test "${HAVE_GTK}" = "yes"; then
3637   USE_X_TOOLKIT=GTK
3638 fi
3639
3640 echo "
3641 Configured for \`${canonical}'.
3642
3643   Where should the build process find the source code?    ${srcdir}
3644   What operating system and machine description files should Emacs use?
3645         \`${opsysfile}' and \`${machfile}'
3646   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3647   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3648   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3649   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3650   What window system should Emacs use?                    ${window_system}
3651   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3652
3653 if test -n "${x_includes}"; then
3654 echo "  Where do we find X Windows header files?                ${x_includes}"
3655 else
3656 echo "  Where do we find X Windows header files?                Standard dirs"
3657 fi
3658 if test -n "${x_libraries}"; then
3659 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3660 else
3661 echo "  Where do we find X Windows libraries?                   Standard dirs"
3662 fi
3663
3664 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3665 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3666 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3667 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3668 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3669 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3670 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3671 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3672 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3673 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3674 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3675
3676 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3677 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3678 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3679 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3680
3681 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3682 echo
3683
3684 if test $USE_XASSERTS = yes; then
3685    echo "  Compiling with asserts turned on."
3686    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3687 fi
3688
3689 echo
3690
3691 if test "$HAVE_NS" = "yes"; then
3692    echo
3693    echo "You must run \"make install\" in order to test the built application.
3694 The installed application will go to nextstep/Emacs.app and can be
3695 run or moved from there."
3696    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3697       echo "The application will be fully self-contained."
3698     else
3699       echo "The lisp resources for the application will be installed under ${prefix}.
3700 You may need to run \"make install\" with sudo.  The application will fail
3701 to run if these resources are not installed."
3702    fi
3703    echo
3704 fi
3705
3706 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3707   echo "D-Bus integration has been tested for GNU/Linux only."
3708   echo
3709 fi
3710
3711
3712 # Remove any trailing slashes in these variables.
3713 [test "${prefix}" != NONE &&
3714   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3715 test "${exec_prefix}" != NONE &&
3716   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3717
3718 dnl You might wonder (I did) why epaths.h is generated by running make,
3719 dnl rather than just letting configure generate it from epaths.in.
3720 dnl One reason is that the various paths are not fully expanded (see above);
3721 dnl eg gamedir=${prefix}/var/games/emacs.
3722 dnl Secondly, the GNU Coding standards require that one should be able
3723 dnl to run `make prefix=/some/where/else' and override the values set
3724 dnl by configure.  This also explains the `move-if-change' test and
3725 dnl the use of force in the `epaths-force' rule in Makefile.in.
3726 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3727         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3728         doc/lispref/Makefile src/Makefile \
3729         lwlib/Makefile lisp/Makefile leim/Makefile, [
3730
3731 ### Make the necessary directories, if they don't exist.
3732 for dir in etc lisp ; do
3733   test -d ${dir} || mkdir ${dir}
3734 done
3735
3736 echo creating src/epaths.h
3737 ${MAKE-make} epaths-force
3738
3739 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3740   echo creating src/.gdbinit
3741   echo source $srcdir/src/.gdbinit > src/.gdbinit
3742 fi
3743
3744 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3745
3746 m4_if(dnl       Do not change this comment
3747    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3748 )dnl