lisp/gnus/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h backend
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "\C-c\C-i" gnus-info-find-node
 169     "\C-c\C-b" gnus-bug))
 170
 171 (defface gnus-server-agent
 172   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 173     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 174     (t (:bold t)))
 175   "Face used for displaying AGENTIZED servers"
 176   :group 'gnus-server-visual)
 177 ;; backward-compatibility alias
 178 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 179
 180 (defface gnus-server-opened
 181   '((((class color) (background light)) (:foreground "Green3" :bold t))
 182     (((class color) (background dark)) (:foreground "Green1" :bold t))
 183     (t (:bold t)))
 184   "Face used for displaying OPENED servers"
 185   :group 'gnus-server-visual)
 186 ;; backward-compatibility alias
 187 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 188
 189 (defface gnus-server-closed
 190   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 191     (((class color) (background dark))
 192      (:foreground "Light Steel Blue" :italic t))
 193     (t (:italic t)))
 194   "Face used for displaying CLOSED servers"
 195   :group 'gnus-server-visual)
 196 ;; backward-compatibility alias
 197 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 198
 199 (defface gnus-server-denied
 200   '((((class color) (background light)) (:foreground "Red" :bold t))
 201     (((class color) (background dark)) (:foreground "Pink" :bold t))
 202     (t (:inverse-video t :bold t)))
 203   "Face used for displaying DENIED servers"
 204   :group 'gnus-server-visual)
 205 ;; backward-compatibility alias
 206 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 207
 208 (defface gnus-server-offline
 209   '((((class color) (background light)) (:foreground "Orange" :bold t))
 210     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 211     (t (:inverse-video t :bold t)))
 212   "Face used for displaying OFFLINE servers"
 213   :group 'gnus-server-visual)
 214 ;; backward-compatibility alias
 215 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 216
 217 (defvar gnus-server-font-lock-keywords
 218   '(("(\\(agent\\))" 1 'gnus-server-agent)
 219     ("(\\(opened\\))" 1 'gnus-server-opened)
 220     ("(\\(closed\\))" 1 'gnus-server-closed)
 221     ("(\\(offline\\))" 1 'gnus-server-offline)
 222     ("(\\(denied\\))" 1 'gnus-server-denied)))
 223
 224 (defun gnus-server-mode ()
 225   "Major mode for listing and editing servers.
 226
 227 All normal editing commands are switched off.
 228 \\<gnus-server-mode-map>
 229 For more in-depth information on this mode, read the manual
 230 \(`\\[gnus-info-find-node]').
 231
 232 The following commands are available:
 233
 234 \\{gnus-server-mode-map}"
 235   (interactive)
 236   (when (gnus-visual-p 'server-menu 'menu)
 237     (gnus-server-make-menu-bar))
 238   (kill-all-local-variables)
 239   (gnus-simplify-mode-line)
 240   (setq major-mode 'gnus-server-mode)
 241   (setq mode-name "Server")
 242   (gnus-set-default-directory)
 243   (setq mode-line-process nil)
 244   (use-local-map gnus-server-mode-map)
 245   (buffer-disable-undo)
 246   (setq truncate-lines t)
 247   (setq buffer-read-only t)
 248   (if (featurep 'xemacs)
 249       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 250     (set (make-local-variable 'font-lock-defaults)
 251          '(gnus-server-font-lock-keywords t)))
 252   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 253
 254 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 255   (let* ((gnus-tmp-how (car method))
 256          (gnus-tmp-where (nth 1 method))
 257          (elem (assoc method gnus-opened-servers))
 258          (gnus-tmp-status
 259           (cond
 260            ((eq (nth 1 elem) 'denied) "(denied)")
 261            ((eq (nth 1 elem) 'offline) "(offline)")
 262            (t
 263             (condition-case nil
 264                 (if (or (gnus-server-opened method)
 265                         (eq (nth 1 elem) 'ok))
 266                     "(opened)"
 267                   "(closed)")
 268               ((error) "(error)")))))
 269          (gnus-tmp-agent (if (and gnus-agent
 270                                   (gnus-agent-method-p method))
 271                              " (agent)"
 272                            "")))
 273     (beginning-of-line)
 274     (gnus-add-text-properties
 275      (point)
 276      (prog1 (1+ (point))
 277        ;; Insert the text.
 278        (eval gnus-server-line-format-spec))
 279      (list 'gnus-server (intern gnus-tmp-name)
 280            'gnus-named-server (intern (gnus-method-to-server method))))))
 281
 282 (defun gnus-enter-server-buffer ()
 283   "Set up the server buffer."
 284   (gnus-server-setup-buffer)
 285   (gnus-configure-windows 'server)
 286   (gnus-server-prepare))
 287
 288 (defun gnus-server-setup-buffer ()
 289   "Initialize the server buffer."
 290   (unless (get-buffer gnus-server-buffer)
 291     (save-excursion
 292       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 293       (gnus-server-mode)
 294       (when gnus-carpal
 295         (gnus-carpal-setup-buffer 'server)))))
 296
 297 (defun gnus-server-prepare ()
 298   (gnus-set-format 'server-mode)
 299   (gnus-set-format 'server t)
 300   (let ((alist gnus-server-alist)
 301         (buffer-read-only nil)
 302         (opened gnus-opened-servers)
 303         done server op-ser)
 304     (erase-buffer)
 305     (setq gnus-inserted-opened-servers nil)
 306     ;; First we do the real list of servers.
 307     (while alist
 308       (unless (member (cdar alist) done)
 309         (push (cdar alist) done)
 310         (setq server (pop alist))
 311         (when (and server (car server) (cdr server))
 312           (gnus-server-insert-server-line (car server) (cdr server))))
 313       (when (member (cdar alist) done)
 314         (pop alist)))
 315     ;; Then we insert the list of servers that have been opened in
 316     ;; this session.
 317     (while opened
 318       (when (and (not (member (caar opened) done))
 319                  ;; Just ignore ephemeral servers.
 320                  (not (member (caar opened) gnus-ephemeral-servers)))
 321         (push (caar opened) done)
 322         (gnus-server-insert-server-line
 323          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 324          (caar opened))
 325         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 326       (setq opened (cdr opened))))
 327   (goto-char (point-min))
 328   (gnus-server-position-point))
 329
 330 (defun gnus-server-server-name ()
 331   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 332     (and server (symbol-name server))))
 333
 334 (defun gnus-server-named-server ()
 335   "Returns a server name that matches one of the names returned by
 336 gnus-method-to-server."
 337   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-named-server)))
 338     (and server (symbol-name server))))
 339
 340 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 341
 342 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 343
 344 (defun gnus-server-update-server (server)
 345   (save-excursion
 346     (set-buffer gnus-server-buffer)
 347     (let* ((buffer-read-only nil)
 348            (entry (assoc server gnus-server-alist))
 349            (oentry (assoc (gnus-server-to-method server)
 350                           gnus-opened-servers)))
 351       (when entry
 352         (gnus-dribble-enter
 353          (concat "(gnus-server-set-info \"" server "\" '"
 354                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 355       (when (or entry oentry)
 356         ;; Buffer may be narrowed.
 357         (save-restriction
 358           (widen)
 359           (when (gnus-server-goto-server server)
 360             (gnus-delete-line))
 361           (if entry
 362               (gnus-server-insert-server-line (car entry) (cdr entry))
 363             (gnus-server-insert-server-line
 364              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 365              (car oentry)))
 366           (gnus-server-position-point))))))
 367
 368 (defun gnus-server-set-info (server info)
 369   ;; Enter a select method into the virtual server alist.
 370   (when (and server info)
 371     (gnus-dribble-enter
 372      (concat "(gnus-server-set-info \"" server "\" '"
 373              (gnus-prin1-to-string info) ")"))
 374     (let* ((server (nth 1 info))
 375            (entry (assoc server gnus-server-alist))
 376            (cached (assoc server gnus-server-method-cache)))
 377       (if cached
 378           (setq gnus-server-method-cache
 379                 (delq cached gnus-server-method-cache)))
 380       (if entry (setcdr entry info)
 381         (setq gnus-server-alist
 382               (nconc gnus-server-alist (list (cons server info))))))))
 383
 384 ;;; Interactive server functions.
 385
 386 (defun gnus-server-kill-server (server)
 387   "Kill the server on the current line."
 388   (interactive (list (gnus-server-server-name)))
 389   (unless (gnus-server-goto-server server)
 390     (if server (error "No such server: %s" server)
 391       (error "No server on the current line")))
 392   (unless (assoc server gnus-server-alist)
 393     (error "Read-only server %s" server))
 394   (gnus-dribble-touch)
 395   (let ((buffer-read-only nil))
 396     (gnus-delete-line))
 397   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 398   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 399                                 gnus-server-alist))
 400   (let ((groups (gnus-groups-from-server server)))
 401     (when (and groups
 402                (gnus-yes-or-no-p
 403                 (format "Kill all %s groups from this server? "
 404                         (length groups))))
 405       (dolist (group groups)
 406         (setq gnus-newsrc-alist
 407               (delq (assoc group gnus-newsrc-alist)
 408                     gnus-newsrc-alist))
 409         (when gnus-group-change-level-function
 410           (funcall gnus-group-change-level-function
 411                    group gnus-level-killed 3)))))
 412   (gnus-server-position-point))
 413
 414 (defun gnus-server-yank-server ()
 415   "Yank the previously killed server."
 416   (interactive)
 417   (unless gnus-server-killed-servers
 418     (error "No killed servers to be yanked"))
 419   (let ((alist gnus-server-alist)
 420         (server (gnus-server-server-name))
 421         (killed (car gnus-server-killed-servers)))
 422     (if (not server)
 423         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 424       (if (string= server (caar gnus-server-alist))
 425           (push killed gnus-server-alist)
 426         (while (and (cdr alist)
 427                     (not (string= server (caadr alist))))
 428           (setq alist (cdr alist)))
 429         (if alist
 430             (setcdr alist (cons killed (cdr alist)))
 431           (setq gnus-server-alist (list killed)))))
 432     (gnus-server-update-server (car killed))
 433     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 434     (gnus-server-position-point)))
 435
 436 (defun gnus-server-exit ()
 437   "Return to the group buffer."
 438   (interactive)
 439   (gnus-run-hooks 'gnus-server-exit-hook)
 440   (gnus-kill-buffer (current-buffer))
 441   (gnus-configure-windows 'group t))
 442
 443 (defun gnus-server-list-servers ()
 444   "List all available servers."
 445   (interactive)
 446   (let ((cur (gnus-server-server-name)))
 447     (gnus-server-prepare)
 448     (if cur (gnus-server-goto-server cur)
 449       (goto-char (point-max))
 450       (forward-line -1))
 451     (gnus-server-position-point)))
 452
 453 (defun gnus-server-set-status (method status)
 454   "Make METHOD have STATUS."
 455   (let ((entry (assoc method gnus-opened-servers)))
 456     (if entry
 457         (setcar (cdr entry) status)
 458       (push (list method status) gnus-opened-servers))))
 459
 460 (defun gnus-opened-servers-remove (method)
 461   "Remove METHOD from the list of opened servers."
 462   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 463                                   gnus-opened-servers)))
 464
 465 (defun gnus-server-open-server (server)
 466   "Force an open of SERVER."
 467   (interactive (list (gnus-server-server-name)))
 468   (let ((method (gnus-server-to-method server)))
 469     (unless method
 470       (error "No such server: %s" server))
 471     (gnus-server-set-status method 'ok)
 472     (prog1
 473         (or (gnus-open-server method)
 474             (progn (message "Couldn't open %s" server) nil))
 475       (gnus-server-update-server server)
 476       (gnus-server-position-point))))
 477
 478 (defun gnus-server-open-all-servers ()
 479   "Open all servers."
 480   (interactive)
 481   (let ((servers gnus-inserted-opened-servers))
 482     (while servers
 483       (gnus-server-open-server (car (pop servers))))))
 484
 485 (defun gnus-server-close-server (server)
 486   "Close SERVER."
 487   (interactive (list (gnus-server-server-name)))
 488   (let ((method (gnus-server-to-method server)))
 489     (unless method
 490       (error "No such server: %s" server))
 491     (gnus-server-set-status method 'closed)
 492     (prog1
 493         (gnus-close-server method)
 494       (gnus-server-update-server server)
 495       (gnus-server-position-point))))
 496
 497 (defun gnus-server-offline-server (server)
 498   "Set SERVER to offline."
 499   (interactive (list (gnus-server-server-name)))
 500   (let ((method (gnus-server-to-method server)))
 501     (unless method
 502       (error "No such server: %s" server))
 503     (prog1
 504         (gnus-close-server method)
 505       (gnus-server-set-status method 'offline)
 506       (gnus-server-update-server server)
 507       (gnus-server-position-point))))
 508
 509 (defun gnus-server-close-all-servers ()
 510   "Close all servers."
 511   (interactive)
 512   (dolist (server gnus-inserted-opened-servers)
 513     (gnus-server-close-server (car server))))
 514
 515 (defun gnus-server-deny-server (server)
 516   "Make sure SERVER will never be attempted opened."
 517   (interactive (list (gnus-server-server-name)))
 518   (let ((method (gnus-server-to-method server)))
 519     (unless method
 520       (error "No such server: %s" server))
 521     (gnus-server-set-status method 'denied))
 522   (gnus-server-update-server server)
 523   (gnus-server-position-point)
 524   t)
 525
 526 (defun gnus-server-remove-denials ()
 527   "Make all denied servers into closed servers."
 528   (interactive)
 529   (dolist (server gnus-opened-servers)
 530     (when (eq (nth 1 server) 'denied)
 531       (setcar (nthcdr 1 server) 'closed)))
 532   (gnus-server-list-servers))
 533
 534 (defun gnus-server-copy-server (from to)
 535   (interactive
 536    (list
 537     (or (gnus-server-server-name)
 538         (error "No server on the current line"))
 539     (read-string "Copy to: ")))
 540   (unless from
 541     (error "No server on current line"))
 542   (unless (and to (not (string= to "")))
 543     (error "No name to copy to"))
 544   (when (assoc to gnus-server-alist)
 545     (error "%s already exists" to))
 546   (unless (gnus-server-to-method from)
 547     (error "%s: no such server" from))
 548   (let ((to-entry (cons from (gnus-copy-sequence
 549                               (gnus-server-to-method from)))))
 550     (setcar to-entry to)
 551     (setcar (nthcdr 2 to-entry) to)
 552     (push to-entry gnus-server-killed-servers)
 553     (gnus-server-yank-server)))
 554
 555 (defun gnus-server-add-server (how where)
 556   (interactive
 557    (list (intern (completing-read "Server method: "
 558                                   gnus-valid-select-methods nil t))
 559          (read-string "Server name: ")))
 560   (when (assq where gnus-server-alist)
 561     (error "Server with that name already defined"))
 562   (push (list where how where) gnus-server-killed-servers)
 563   (gnus-server-yank-server))
 564
 565 (defun gnus-server-goto-server (server)
 566   "Jump to a server line."
 567   (interactive
 568    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 569   (let ((to (text-property-any (point-min) (point-max)
 570                                'gnus-server (intern server))))
 571     (when to
 572       (goto-char to)
 573       (gnus-server-position-point))))
 574
 575 (defun gnus-server-edit-server (server)
 576   "Edit the server on the current line."
 577   (interactive (list (gnus-server-server-name)))
 578   (unless server
 579     (error "No server on current line"))
 580   (unless (assoc server gnus-server-alist)
 581     (error "This server can't be edited"))
 582   (let ((info (cdr (assoc server gnus-server-alist))))
 583     (gnus-close-server info)
 584     (gnus-edit-form
 585      info "Editing the server."
 586      `(lambda (form)
 587         (gnus-server-set-info ,server form)
 588         (gnus-server-list-servers)
 589         (gnus-server-position-point)))))
 590
 591 (defun gnus-server-scan-server (server)
 592   "Request a scan from the current server."
 593   (interactive (list (gnus-server-server-name)))
 594   (let ((method (gnus-server-to-method server)))
 595     (if (not (gnus-get-function method 'request-scan))
 596         (error "Server %s can't scan" (car method))
 597       (gnus-message 3 "Scanning %s..." server)
 598       (gnus-request-scan nil method)
 599       (gnus-message 3 "Scanning %s...done" server))))
 600
 601 (defun gnus-server-read-server-in-server-buffer (server)
 602   "Browse a server in server buffer."
 603   (interactive (list (gnus-server-server-name)))
 604   (let (gnus-server-browse-in-group-buffer)
 605     (gnus-server-read-server server)))
 606
 607 (defun gnus-server-read-server (server)
 608   "Browse a server."
 609   (interactive (list (gnus-server-server-name)))
 610   (let ((buf (current-buffer)))
 611     (prog1
 612         (gnus-browse-foreign-server server buf)
 613       (save-excursion
 614         (set-buffer buf)
 615         (gnus-server-update-server (gnus-server-server-name))
 616         (gnus-server-position-point)))))
 617
 618 (defun gnus-server-pick-server (e)
 619   (interactive "e")
 620   (mouse-set-point e)
 621   (gnus-server-read-server (gnus-server-server-name)))
 622
 623 \f
 624 ;;;
 625 ;;; Browse Server Mode
 626 ;;;
 627
 628 (defvar gnus-browse-menu-hook nil
 629   "*Hook run after the creation of the browse mode menu.")
 630
 631 (defvar gnus-browse-mode-hook nil)
 632 (defvar gnus-browse-mode-map nil)
 633 (put 'gnus-browse-mode 'mode-class 'special)
 634
 635 (unless gnus-browse-mode-map
 636   (setq gnus-browse-mode-map (make-keymap))
 637   (suppress-keymap gnus-browse-mode-map)
 638
 639   (gnus-define-keys
 640       gnus-browse-mode-map
 641     " " gnus-browse-read-group
 642     "=" gnus-browse-select-group
 643     "n" gnus-browse-next-group
 644     "p" gnus-browse-prev-group
 645     "\177" gnus-browse-prev-group
 646     [delete] gnus-browse-prev-group
 647     "N" gnus-browse-next-group
 648     "P" gnus-browse-prev-group
 649     "\M-n" gnus-browse-next-group
 650     "\M-p" gnus-browse-prev-group
 651     "\r" gnus-browse-select-group
 652     "u" gnus-browse-unsubscribe-current-group
 653     "l" gnus-browse-exit
 654     "L" gnus-browse-exit
 655     "q" gnus-browse-exit
 656     "Q" gnus-browse-exit
 657     "d" gnus-browse-describe-group
 658     "\C-c\C-c" gnus-browse-exit
 659     "?" gnus-browse-describe-briefly
 660
 661     "\C-c\C-i" gnus-info-find-node
 662     "\C-c\C-b" gnus-bug))
 663
 664 (defun gnus-browse-make-menu-bar ()
 665   (gnus-turn-off-edit-menu 'browse)
 666   (unless (boundp 'gnus-browse-menu)
 667     (easy-menu-define
 668      gnus-browse-menu gnus-browse-mode-map ""
 669      '("Browse"
 670        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 671        ["Read" gnus-browse-read-group t]
 672        ["Select" gnus-browse-select-group t]
 673        ["Describe" gnus-browse-describe-group t]
 674        ["Next" gnus-browse-next-group t]
 675        ["Prev" gnus-browse-prev-group t]
 676        ["Exit" gnus-browse-exit t]))
 677     (gnus-run-hooks 'gnus-browse-menu-hook)))
 678
 679 (defvar gnus-browse-current-method nil)
 680 (defvar gnus-browse-return-buffer nil)
 681
 682 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 683
 684 (defun gnus-browse-foreign-server (server &optional return-buffer)
 685   "Browse the server SERVER."
 686   (setq gnus-browse-current-method (gnus-server-to-method server))
 687   (setq gnus-browse-return-buffer return-buffer)
 688   (let* ((method gnus-browse-current-method)
 689          (orig-select-method gnus-select-method)
 690          (gnus-select-method method)
 691          groups group)
 692     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 693     (cond
 694      ((not (gnus-check-server method))
 695       (gnus-message
 696        1 "Unable to contact server %s: %s" (nth 1 method)
 697        (gnus-status-message method))
 698       nil)
 699      ((not
 700        (prog2
 701            (gnus-message 6 "Reading active file...")
 702            (gnus-request-list method)
 703          (gnus-message 6 "Reading active file...done")))
 704       (gnus-message
 705        1 "Couldn't request list: %s" (gnus-status-message method))
 706       nil)
 707      (t
 708       (with-current-buffer nntp-server-buffer
 709         (let ((cur (current-buffer)))
 710           (goto-char (point-min))
 711           (unless (string= gnus-ignored-newsgroups "")
 712             (delete-matching-lines gnus-ignored-newsgroups))
 713           ;; We treat NNTP as a special case to avoid problems with
 714           ;; garbage group names like `"foo' that appear in some badly
 715           ;; managed active files. -jh.
 716           (if (eq (car method) 'nntp)
 717               (while (not (eobp))
 718                 (ignore-errors
 719                   (push (cons
 720                          (buffer-substring
 721                           (point)
 722                           (progn
 723                             (skip-chars-forward "^ \t")
 724                             (point)))
 725                          (let ((last (read cur)))
 726                            (cons (read cur) last)))
 727                         groups))
 728                 (forward-line))
 729             (while (not (eobp))
 730               (ignore-errors
 731                 (push (cons
 732                        (if (eq (char-after) ?\")
 733                            (read cur)
 734                          (let ((p (point)) (name ""))
 735                            (skip-chars-forward "^ \t\\\\")
 736                            (setq name (buffer-substring p (point)))
 737                            (while (eq (char-after) ?\\)
 738                              (setq p (1+ (point)))
 739                              (forward-char 2)
 740                              (skip-chars-forward "^ \t\\\\")
 741                              (setq name (concat name (buffer-substring
 742                                                       p (point)))))
 743                            name))
 744                        (let ((last (read cur)))
 745                          (cons (read cur) last)))
 746                       groups))
 747               (forward-line)))))
 748       (setq groups (sort groups
 749                          (lambda (l1 l2)
 750                            (string< (car l1) (car l2)))))
 751       (if gnus-server-browse-in-group-buffer
 752           (let* ((gnus-select-method orig-select-method)
 753                  (gnus-group-listed-groups
 754                   (mapcar (lambda (group)
 755                             (let ((name
 756                                    (gnus-group-prefixed-name
 757                                     (car group) method)))
 758                               (gnus-set-active name (cdr group))
 759                               name))
 760                           groups)))
 761             (gnus-configure-windows 'group)
 762             (funcall gnus-group-prepare-function
 763                      gnus-level-killed 'ignore 1 'ignore))
 764         (gnus-get-buffer-create gnus-browse-buffer)
 765         (when gnus-carpal
 766           (gnus-carpal-setup-buffer 'browse))
 767         (gnus-configure-windows 'browse)
 768         (buffer-disable-undo)
 769         (let ((buffer-read-only nil))
 770           (erase-buffer))
 771         (gnus-browse-mode)
 772         (setq mode-line-buffer-identification
 773               (list
 774                (format
 775                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 776         (let ((buffer-read-only nil)
 777               name
 778               (prefix (let ((gnus-select-method orig-select-method))
 779                         (gnus-group-prefixed-name "" method))))
 780           (while (setq group (pop groups))
 781             (gnus-add-text-properties
 782              (point)
 783              (prog1 (1+ (point))
 784                (insert
 785                 (format "%c%7d: %s\n"
 786                         (let ((level (gnus-group-level
 787                                       (concat prefix (setq name (car group))))))
 788                               (cond
 789                                ((<= level gnus-level-subscribed) ? )
 790                                ((<= level gnus-level-unsubscribed) ?U)
 791                                ((= level gnus-level-zombie) ?Z)
 792                                (t ?K)))
 793                         (max 0 (- (1+ (cddr group)) (cadr group)))
 794                         (mm-decode-coding-string
 795                          name
 796                          (inline (gnus-group-name-charset method name))))))
 797              (list 'gnus-group name))))
 798         (switch-to-buffer (current-buffer)))
 799       (goto-char (point-min))
 800       (gnus-group-position-point)
 801       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 802       t))))
 803
 804 (defun gnus-browse-mode ()
 805   "Major mode for browsing a foreign server.
 806
 807 All normal editing commands are switched off.
 808
 809 \\<gnus-browse-mode-map>
 810 The only things you can do in this buffer is
 811
 812 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 813 The group will be inserted into the group buffer upon exit from this
 814 buffer.
 815
 816 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 817
 818 3) `\\[gnus-browse-exit]' to return to the group buffer."
 819   (interactive)
 820   (kill-all-local-variables)
 821   (when (gnus-visual-p 'browse-menu 'menu)
 822     (gnus-browse-make-menu-bar))
 823   (gnus-simplify-mode-line)
 824   (setq major-mode 'gnus-browse-mode)
 825   (setq mode-name "Browse Server")
 826   (setq mode-line-process nil)
 827   (use-local-map gnus-browse-mode-map)
 828   (buffer-disable-undo)
 829   (setq truncate-lines t)
 830   (gnus-set-default-directory)
 831   (setq buffer-read-only t)
 832   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 833
 834 (defun gnus-browse-read-group (&optional no-article number)
 835   "Enter the group at the current line.
 836 If NUMBER, fetch this number of articles."
 837   (interactive "P")
 838   (let ((group (gnus-browse-group-name)))
 839     (if (or (not (gnus-get-info group))
 840             (gnus-ephemeral-group-p group))
 841         (unless (gnus-group-read-ephemeral-group
 842                  group gnus-browse-current-method nil
 843                  (cons (current-buffer) 'browse)
 844                  nil nil nil number)
 845           (error "Couldn't enter %s" group))
 846       (unless (gnus-group-read-group nil no-article group)
 847         (error "Couldn't enter %s" group)))))
 848
 849 (defun gnus-browse-select-group (&optional number)
 850   "Select the current group.
 851 If NUMBER, fetch this number of articles."
 852   (interactive "P")
 853   (gnus-browse-read-group 'no number))
 854
 855 (defun gnus-browse-next-group (n)
 856   "Go to the next group."
 857   (interactive "p")
 858   (prog1
 859       (forward-line n)
 860     (gnus-group-position-point)))
 861
 862 (defun gnus-browse-prev-group (n)
 863   "Go to the next group."
 864   (interactive "p")
 865   (gnus-browse-next-group (- n)))
 866
 867 (defun gnus-browse-unsubscribe-current-group (arg)
 868   "(Un)subscribe to the next ARG groups."
 869   (interactive "p")
 870   (when (eobp)
 871     (error "No group at current line"))
 872   (let ((ward (if (< arg 0) -1 1))
 873         (arg (abs arg)))
 874     (while (and (> arg 0)
 875                 (not (eobp))
 876                 (gnus-browse-unsubscribe-group)
 877                 (zerop (gnus-browse-next-group ward)))
 878       (decf arg))
 879     (gnus-group-position-point)
 880     (when (/= 0 arg)
 881       (gnus-message 7 "No more newsgroups"))
 882     arg))
 883
 884 (defun gnus-browse-group-name ()
 885   (save-excursion
 886     (beginning-of-line)
 887     (let ((name (get-text-property (point) 'gnus-group)))
 888       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 889         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 890                 (or name
 891                     (match-string-no-properties 1)))))))
 892
 893 (defun gnus-browse-describe-group (group)
 894   "Describe the current group."
 895   (interactive (list (gnus-browse-group-name)))
 896   (gnus-group-describe-group nil group))
 897
 898 (defun gnus-browse-unsubscribe-group ()
 899   "Toggle subscription of the current group in the browse buffer."
 900   (let ((sub nil)
 901         (buffer-read-only nil)
 902         group)
 903     (save-excursion
 904       (beginning-of-line)
 905       ;; If this group it killed, then we want to subscribe it.
 906       (unless (eq (char-after) ? )
 907         (setq sub t))
 908       (setq group (gnus-browse-group-name))
 909       (when (gnus-server-equal gnus-browse-current-method "native")
 910         (setq group (gnus-group-real-name group)))
 911       (if sub
 912           (progn
 913             ;; Make sure the group has been properly removed before we
 914             ;; subscribe to it.
 915             (if (gnus-ephemeral-group-p group)
 916                 (gnus-kill-ephemeral-group group))
 917             ;; We need to discern between killed/zombie groups and
 918             ;; just unsubscribed ones.
 919             (gnus-group-change-level
 920              (or (gnus-group-entry group)
 921                  (list t group gnus-level-default-subscribed
 922                        nil nil (if (gnus-server-equal
 923                                     gnus-browse-current-method "native")
 924                                    nil
 925                                  (gnus-method-simplify
 926                                   gnus-browse-current-method))))
 927              gnus-level-default-subscribed (gnus-group-level group)
 928              (and (car (nth 1 gnus-newsrc-alist))
 929                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 930                                 gnus-newsrc-hashtb))
 931              (null (gnus-group-entry group)))
 932             (delete-char 1)
 933             (insert ? ))
 934         (gnus-group-change-level
 935          group gnus-level-unsubscribed gnus-level-default-subscribed)
 936         (delete-char 1)
 937         (insert ?U)))
 938     t))
 939
 940 (defun gnus-browse-exit ()
 941   "Quit browsing and return to the group buffer."
 942   (interactive)
 943   (when (eq major-mode 'gnus-browse-mode)
 944     (gnus-kill-buffer (current-buffer)))
 945   ;; Insert the newly subscribed groups in the group buffer.
 946   (save-excursion
 947     (set-buffer gnus-group-buffer)
 948     (gnus-group-list-groups nil))
 949   (if gnus-browse-return-buffer
 950       (gnus-configure-windows 'server 'force)
 951     (gnus-configure-windows 'group 'force)))
 952
 953 (defun gnus-browse-describe-briefly ()
 954   "Give a one line description of the group mode commands."
 955   (interactive)
 956   (gnus-message 6
 957                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 958
 959 (defun gnus-server-regenerate-server ()
 960   "Issue a command to the server to regenerate all its data structures."
 961   (interactive)
 962   (let ((server (gnus-server-server-name)))
 963     (unless server
 964       (error "No server on the current line"))
 965     (condition-case ()
 966         (gnus-get-function (gnus-server-to-method server)
 967                            'request-regenerate)
 968       (error
 969         (error "This backend doesn't support regeneration")))
 970     (gnus-message 5 "Requesting regeneration of %s..." server)
 971     (unless (gnus-open-server server)
 972       (error "Couldn't open server"))
 973     (if (gnus-request-regenerate server)
 974         (gnus-message 5 "Requesting regeneration of %s...done" server)
 975       (gnus-message 5 "Couldn't regenerate %s" server))))
 976
 977 (provide 'gnus-srvr)
 978
 979 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
 980 ;;; gnus-srvr.el ends here