| blob | 417673067361126422ea780fcadc39cf75694186 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to the
22 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 dnl Boston, MA 02111-1307, USA.
25 AC_PREREQ(2.8)dnl
26 AC_INIT(src/lisp.h)
27 AC_CONFIG_HEADER(src/config.h:src/config.in)
29 lispdir='${datadir}/emacs/${version}/lisp'
30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
32 lisppath='${locallisppath}:${lispdir}'
33 etcdir='${datadir}/emacs/${version}/etc'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
37 AC_ARG_WITH(gcc,
38 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
39 AC_ARG_WITH(pop,
40 [ --without-pop don't support POP mail retrieval with movemail],
41 [if test "$withval" = yes; then
42 AC_DEFINE(MAIL_USE_POP)
43 else :
44 fi],
45 AC_DEFINE(MAIL_USE_POP))
46 AC_ARG_WITH(kerberos,
47 [ --with-kerberos support Kerberos-authenticated POP],
48 [AC_DEFINE(KERBEROS)])
49 AC_ARG_WITH(kerberos5,
50 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
51 [if test "${with_kerberos5+set}" = set; then
52 if test "${with_kerberos+set}" != set; then
53 with_kerberos=yes
54 AC_DEFINE(KERBEROS)
55 fi
56 fi
57 AC_DEFINE(KERBEROS5)])
58 AC_ARG_WITH(hesiod,
59 [ --with-hesiod support Hesiod to get the POP server host],
60 [AC_DEFINE(HESIOD)])
61 dnl This should be the last --with option, because --with-x is
62 dnl added later on when we find the path of X, and it's best to
63 dnl keep them together visually.
64 AC_ARG_WITH(x-toolkit,
65 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
66 [ case "${withval}" in
67 y | ye | yes ) val=athena ;;
68 n | no ) val=no ;;
69 l | lu | luc | luci | lucid ) val=lucid ;;
70 a | at | ath | athe | athen | athena ) val=athena ;;
71 m | mo | mot | moti | motif ) val=motif ;;
72 dnl These don't currently work.
73 dnl o | op | ope | open | open- | open-l | open-lo \
74 dnl | open-loo | open-look ) val=open-look ;;
75 * )
76 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
77 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
78 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
79 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
80 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
81 ;;
82 esac
83 with_x_toolkit=$val
84 ])
85 AC_ARG_WITH(xpm,
86 [ --with-xpm use -lXpm for displaying XPM images])
87 AC_ARG_WITH(jpeg,
88 [ --with-jpeg use -ljpeg for displaying JPEG images])
89 AC_ARG_WITH(tiff,
90 [ --with-tiff use -ltiff for displaying TIFF images])
91 AC_ARG_WITH(gif,
92 [ --with-gif use -lungif for displaying GIF images])
93 AC_ARG_WITH(png,
94 [ --with-png use -lpng for displaying PNG images])
95 AC_ARG_WITH(toolkit-scroll-bars,
96 [ --without-toolkit-scroll-bars
97 don't use Motif or Xaw3d scroll bars])
98 AC_ARG_WITH(xim,
99 [ --without-xim don't use X11 XIM])
101 #### Make srcdir absolute, if it isn't already. It's important to
102 #### avoid running the path through pwd unnecessary, since pwd can
103 #### give you automounter prefixes, which can go away. We do all this
104 #### so Emacs can find its files when run uninstalled.
105 case "${srcdir}" in
106 /* ) ;;
107 . )
108 ## We may be able to use the $PWD environment variable to make this
109 ## absolute. But sometimes PWD is inaccurate.
110 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
111 unset CDPATH
112 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
113 then
114 srcdir="$PWD"
115 else
116 srcdir="`(cd ${srcdir}; pwd)`"
117 fi
118 ;;
119 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
120 esac
122 #### Check if the source directory already has a configured system in it.
123 if test `pwd` != `(cd ${srcdir} && pwd)` \
124 && test -f "${srcdir}/src/config.h" ; then
125 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
126 as a build directory right now; it has been configured in its own
127 right. To configure in another directory as well, you MUST
128 use GNU make. If you do not have GNU make, then you must
129 now do \`make distclean' in ${srcdir},
130 and then run $0 again.])
132 changequote(, )dnl
133 extrasub='/^VPATH[ ]*=/c\
134 changequote([, ])dnl
135 vpath %.c $(srcdir)\
136 vpath %.h $(srcdir)\
137 vpath %.y $(srcdir)\
138 vpath %.l $(srcdir)\
139 vpath %.s $(srcdir)\
140 vpath %.in $(srcdir)\
141 vpath %.texi $(srcdir)'
142 fi
144 #### Given the configuration name, set machfile and opsysfile to the
145 #### names of the m/*.h and s/*.h files we should use.
147 ### Canonicalize the configuration name.
149 AC_CANONICAL_HOST
150 canonical=$host
151 configuration=$host_alias
153 changequote(, )dnl
155 ### If you add support for a new configuration, add code to this
156 ### switch statement to recognize your configuration name and select
157 ### the appropriate operating system and machine description files.
159 ### You would hope that you could choose an m/*.h file pretty much
160 ### based on the machine portion of the configuration name, and an s-
161 ### file based on the operating system portion. However, it turns out
162 ### that each m/*.h file is pretty manufacturer-specific - for
163 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
164 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
165 ### machines. So we basically have to have a special case for each
166 ### configuration name.
167 ###
168 ### As far as handling version numbers on operating systems is
169 ### concerned, make sure things will fail in a fixable way. If
170 ### /etc/MACHINES doesn't say anything about version numbers, be
171 ### prepared to handle anything reasonably. If version numbers
172 ### matter, be sure /etc/MACHINES says something about it.
173 ###
174 ### Eric Raymond says we should accept strings like "sysvr4" to mean
175 ### "System V Release 4"; he writes, "The old convention encouraged
176 ### confusion between `system' and `release' levels'."
178 machine='' opsys='' unported=no
179 case "${canonical}" in
181 ## NetBSD ports
182 *-*-netbsd* )
183 opsys=netbsd
184 case "${canonical}" in
185 alpha*-*-netbsd*) machine=alpha ;;
186 i[3456]86-*-netbsd*) machine=intel386 ;;
187 m68k-*-netbsd*)
188 # This is somewhat bogus.
189 machine=hp9000s300 ;;
190 powerpc-apple-netbsd*) machine=macppc ;;
191 mips-*-netbsd*) machine=pmax ;;
192 mipsel-*-netbsd*) machine=pmax ;;
193 ns32k-*-netbsd*) machine=ns32000 ;;
194 powerpc-*-netbsd*) machine=macppc ;;
195 sparc-*-netbsd*) machine=sparc ;;
196 vax-*-netbsd*) machine=vax ;;
197 arm-*-netbsd*) machine=arm ;;
198 esac
199 ;;
201 ## OpenBSD ports
202 *-*-openbsd* )
203 opsys=openbsd
204 case "${canonical}" in
205 alpha*-*-openbsd*) machine=alpha ;;
206 i386-*-openbsd*) machine=intel386 ;;
207 m68k-*-openbsd*) machine=hp9000s300 ;;
208 mipsel-*-openbsd*) machine=pmax ;;
209 ns32k-*-openbsd*) machine=ns32000 ;;
210 sparc-*-openbsd*) machine=sparc ;;
211 vax-*-openbsd*) machine=vax ;;
212 esac
213 ;;
215 ## Acorn RISCiX:
216 arm-acorn-riscix1.1* )
217 machine=acorn opsys=riscix1-1
218 ;;
219 arm-acorn-riscix1.2* | arm-acorn-riscix )
220 ## This name is riscix12 instead of riscix1.2
221 ## to avoid a file name conflict on MSDOS.
222 machine=acorn opsys=riscix12
223 ;;
225 ## BSDI ports
226 *-*-bsdi* )
227 opsys=bsdi
228 case "${canonical}" in
229 i[345]86-*-bsdi*) machine=intel386 ;;
230 sparc-*-bsdi*) machine=sparc ;;
231 powerpc-*-bsdi*) machine=powerpc ;;
232 esac
233 case "${canonical}" in
234 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
235 *-*-bsdi2.0* ) opsys=bsdos2 ;;
236 *-*-bsdi2* ) opsys=bsdos2-1 ;;
237 *-*-bsdi3* ) opsys=bsdos3 ;;
238 *-*-bsdi4* ) opsys=bsdos4 ;;
239 esac
240 ;;
242 ## Alliant machines
243 ## Strictly speaking, we need the version of the alliant operating
244 ## system to choose the right machine file, but currently the
245 ## configuration name doesn't tell us enough to choose the right
246 ## one; we need to give alliants their own operating system name to
247 ## do this right. When someone cares, they can help us.
248 fx80-alliant-* )
249 machine=alliant4 opsys=bsd4-2
250 ;;
251 i860-alliant-* )
252 machine=alliant-2800 opsys=bsd4-3
253 ;;
255 ## Alpha (DEC) machines.
256 alpha*-dec-osf* )
257 machine=alpha opsys=osf1
258 # This is needed to find X11R6.1 libraries for certain tests.
259 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
260 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
261 case "${canonical}" in
262 # This is necessary on 5.0 to avoid mangling src/Makefile.
263 # Separated out in case it causes problems on earlier versions.
264 alpha*-dec-osf[5-9]*)
265 opsys=osf5-0
266 NON_GNU_CPP='cpp' ;;
267 esac
268 ;;
270 alpha*-*-linux-gnu* )
271 machine=alpha opsys=gnu-linux
272 ;;
274 arm*-*-linux-gnu* )
275 machine=arm opsys=gnu-linux
276 ;;
278 ppc-*-linux | \
279 powerpc-*-linux* )
280 machine=powerpc opsys=gnu-linux
281 ;;
283 ## Altos 3068
284 m68*-altos-sysv* )
285 machine=altos opsys=usg5-2
286 ;;
288 ## Amdahl UTS
289 580-amdahl-sysv* )
290 machine=amdahl opsys=usg5-2-2
291 ;;
293 ## Apollo, Domain/OS
294 m68*-apollo-* )
295 machine=apollo opsys=bsd4-3
296 ;;
298 ## AT&T 3b2, 3b5, 3b15, 3b20
299 we32k-att-sysv* )
300 machine=att3b opsys=usg5-2-2
301 ;;
303 ## AT&T 3b1 - The Mighty Unix PC!
304 m68*-att-sysv* )
305 machine=7300 opsys=usg5-2-2
306 ;;
308 ## Bull dpx20
309 rs6000-bull-bosx* )
310 machine=ibmrs6000 opsys=aix3-2
311 ;;
313 ## Bull dpx2
314 m68*-bull-sysv3* )
315 machine=dpx2 opsys=usg5-3
316 ;;
318 ## Bull sps7
319 m68*-bull-sysv2* )
320 machine=sps7 opsys=usg5-2
321 ;;
323 ## CCI 5/32, 6/32 -- see "Tahoe".
325 ## Celerity
326 ## I don't know what configuration name to use for this; config.sub
327 ## doesn't seem to know anything about it. Hey, Celerity users, get
328 ## in touch with us!
329 celerity-celerity-bsd* )
330 machine=celerity opsys=bsd4-2
331 ;;
333 ## Clipper
334 ## What operating systems does this chip run that Emacs has been
335 ## tested on?
336 clipper-* )
337 machine=clipper
338 ## We'll use the catch-all code at the bottom to guess the
339 ## operating system.
340 ;;
342 ## Convex
343 *-convex-bsd* | *-convex-convexos* )
344 machine=convex opsys=bsd4-3
345 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
346 NON_GNU_CPP="cc -E -P"
347 ;;
349 ## Cubix QBx/386
350 i[3456]86-cubix-sysv* )
351 machine=intel386 opsys=usg5-3
352 ;;
354 ## Cydra 5
355 cydra*-cydrome-sysv* )
356 machine=cydra5 opsys=usg5-3
357 ;;
359 ## Data General AViiON Machines
360 ## DG changed naming conventions with the release of 5.4.4.10, they
361 ## dropped the initial 5.4 but left the intervening R. Because of the
362 ## R this shouldn't conflict with older versions of the OS (which I
363 ## think were named like dgux4.*). In addition, DG new AViiONs series
364 ## uses either Motorola M88k or Intel Pentium CPUs.
365 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
366 machine=aviion opsys=dgux4
367 ;;
368 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
369 ## This name is dgux5-4-3 instead of dgux5-4r3
370 ## to avoid a file name conflict on MSDOS.
371 machine=aviion opsys=dgux5-4-3
372 ;;
373 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
374 machine=aviion opsys=dgux5-4r2
375 ;;
376 m88k-dg-dgux* )
377 machine=aviion opsys=dgux
378 ;;
380 ## Data General AViiON Intel (x86) Machines
381 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
382 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
383 i[345]86-dg-dguxR4* )
384 machine=aviion-intel opsys=dgux4
385 ;;
387 ## DECstations
388 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
389 machine=pmax opsys=bsd4-2
390 ;;
391 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
392 machine=pmax opsys=bsd4-3
393 ;;
394 mips-dec-ultrix* )
395 machine=pmax opsys=ultrix4-3
396 ;;
397 mips-dec-osf* )
398 machine=pmax opsys=osf1
399 ;;
400 mips-dec-mach_bsd4.3* )
401 machine=pmax opsys=mach-bsd4-3
402 ;;
404 ## Motorola Delta machines
405 m68k-motorola-sysv* | m68000-motorola-sysv* )
406 machine=delta opsys=usg5-3
407 if test -z "`type gnucc | grep 'not found'`"
408 then
409 if test -s /etc/167config
410 then CC="gnucc -m68040"
411 else CC="gnucc -m68881"
412 fi
413 else
414 if test -z "`type gcc | grep 'not found'`"
415 then CC=gcc
416 else CC=cc
417 fi
418 fi
419 ;;
420 m88k-motorola-sysv4* )
421 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
422 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
423 # I hope there are not other 4.0 versions for this machine
424 # which really need usg5-4 instead.
425 machine=delta88k opsys=usg5-4-2
426 ;;
427 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
428 machine=delta88k opsys=usg5-3
429 ;;
431 ## Dual machines
432 m68*-dual-sysv* )
433 machine=dual opsys=usg5-2
434 ;;
435 m68*-dual-uniplus* )
436 machine=dual opsys=unipl5-2
437 ;;
439 ## Elxsi 6400
440 elxsi-elxsi-sysv* )
441 machine=elxsi opsys=usg5-2
442 ;;
444 ## Encore machines
445 ns16k-encore-bsd* )
446 machine=ns16000 opsys=umax
447 ;;
449 ## The GEC 63 - apparently, this port isn't really finished yet.
450 # I'm sure we finished off the last of the machines, though. -- fx
452 ## Gould Power Node and NP1
453 pn-gould-bsd4.2* )
454 machine=gould opsys=bsd4-2
455 ;;
456 pn-gould-bsd4.3* )
457 machine=gould opsys=bsd4-3
458 ;;
459 np1-gould-bsd* )
460 machine=gould-np1 opsys=bsd4-3
461 ;;
463 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
464 ## as far as Emacs is concerned).
465 m88k-harris-cxux* )
466 # Build needs to be different on 7.0 and later releases
467 case "`uname -r`" in
468 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
469 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
470 esac
471 NON_GNU_CPP="/lib/cpp"
472 ;;
473 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
474 m68k-harris-cxux* )
475 machine=nh3000 opsys=cxux
476 ;;
477 ## Harris power pc NightHawk running Power UNIX (Series 6000)
478 powerpc-harris-powerunix )
479 machine=nh6000 opsys=powerunix
480 NON_GNU_CPP="cc -Xo -E -P"
481 ;;
482 ## SR2001/SR2201 running HI-UX/MPP
483 hppa1.1-hitachi-hiuxmpp* )
484 machine=sr2k opsys=hiuxmpp
485 ;;
486 ## Honeywell XPS100
487 xps*-honeywell-sysv* )
488 machine=xps100 opsys=usg5-2
489 ;;
491 ## HP 9000 series 200 or 300
492 m68*-hp-bsd* )
493 machine=hp9000s300 opsys=bsd4-3
494 ;;
495 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
496 m68*-hp-hpux* )
497 case "`uname -r`" in
498 ## Someone's system reports A.B8.05 for this.
499 ## I wonder what other possibilities there are.
500 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
501 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
502 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
503 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
504 *) machine=hp9000s300 opsys=hpux ;;
505 esac
506 ;;
508 ## HP 9000 series 700 and 800, running HP/UX
509 hppa*-hp-hpux7* )
510 machine=hp800 opsys=hpux
511 ;;
512 hppa*-hp-hpux8* )
513 machine=hp800 opsys=hpux8
514 ;;
515 hppa*-hp-hpux9shr* )
516 machine=hp800 opsys=hpux9shr
517 ;;
518 hppa*-hp-hpux9* )
519 machine=hp800 opsys=hpux9
520 ;;
521 hppa*-hp-hpux1[0-9]* )
522 machine=hp800 opsys=hpux10
523 ;;
525 ## HP 9000 series 700 and 800, running HP/UX
526 hppa*-hp-hpux* )
527 ## Cross-compilation? Nah!
528 case "`uname -r`" in
529 ## Someone's system reports A.B8.05 for this.
530 ## I wonder what other possibilities there are.
531 *.B8.* ) machine=hp800 opsys=hpux8 ;;
532 *.08.* ) machine=hp800 opsys=hpux8 ;;
533 *.09.* ) machine=hp800 opsys=hpux9 ;;
534 *) machine=hp800 opsys=hpux10 ;;
535 esac
536 ;;
537 hppa*-*-nextstep* )
538 machine=hp800 opsys=nextstep
539 ;;
541 ## Orion machines
542 orion-orion-bsd* )
543 machine=orion opsys=bsd4-2
544 ;;
545 clipper-orion-bsd* )
546 machine=orion105 opsys=bsd4-2
547 ;;
549 ## IBM machines
550 i[3456]86-ibm-aix1.1* )
551 machine=ibmps2-aix opsys=usg5-2-2
552 ;;
553 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
554 machine=ibmps2-aix opsys=usg5-3
555 ;;
556 i370-ibm-aix*)
557 machine=ibm370aix opsys=usg5-3
558 ;;
559 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
560 machine=ibmrs6000 opsys=aix3-1
561 ;;
562 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
563 machine=ibmrs6000 opsys=aix3-2-5
564 ;;
565 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
566 machine=ibmrs6000 opsys=aix4-1
567 ;;
568 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
569 machine=ibmrs6000 opsys=aix4-2
570 ;;
571 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
572 machine=ibmrs6000 opsys=aix4
573 ;;
574 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
575 machine=ibmrs6000 opsys=aix4-1
576 ;;
577 rs6000-ibm-aix* | powerpc-ibm-aix* )
578 machine=ibmrs6000 opsys=aix3-2
579 ;;
580 romp-ibm-bsd4.3* )
581 machine=ibmrt opsys=bsd4-3
582 ;;
583 romp-ibm-bsd4.2* )
584 machine=ibmrt opsys=bsd4-2
585 ;;
586 romp-ibm-aos4.3* )
587 machine=ibmrt opsys=bsd4-3
588 ;;
589 romp-ibm-aos4.2* )
590 machine=ibmrt opsys=bsd4-2
591 ;;
592 romp-ibm-aos* )
593 machine=ibmrt opsys=bsd4-3
594 ;;
595 romp-ibm-bsd* )
596 machine=ibmrt opsys=bsd4-3
597 ;;
598 romp-ibm-aix* )
599 machine=ibmrt-aix opsys=usg5-2-2
600 ;;
602 ## Integrated Solutions `Optimum V'
603 m68*-isi-bsd4.2* )
604 machine=isi-ov opsys=bsd4-2
605 ;;
606 m68*-isi-bsd4.3* )
607 machine=isi-ov opsys=bsd4-3
608 ;;
610 ## Intel 386 machines where we do care about the manufacturer
611 i[3456]86-intsys-sysv* )
612 machine=is386 opsys=usg5-2-2
613 ;;
615 ## Prime EXL
616 i[3456]86-prime-sysv* )
617 machine=i386 opsys=usg5-3
618 ;;
620 ## Sequent Symmetry running Dynix
621 i[3456]86-sequent-bsd* )
622 machine=symmetry opsys=bsd4-3
623 ;;
625 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
626 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
627 machine=sequent-ptx opsys=ptx4
628 NON_GNU_CPP=/lib/cpp
629 ;;
631 ## Sequent Symmetry running DYNIX/ptx
632 ## Use the old cpp rather than the newer ANSI one.
633 i[3456]86-sequent-ptx* )
634 machine=sequent-ptx opsys=ptx
635 NON_GNU_CPP="/lib/cpp"
636 ;;
638 ## ncr machine running svr4.3.
639 i[3456]86-ncr-sysv4.3 )
640 machine=ncr386 opsys=usg5-4-3
641 ;;
643 ## Unspecified sysv on an ncr machine defaults to svr4.2.
644 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
645 i[3456]86-ncr-sysv* )
646 machine=ncr386 opsys=usg5-4-2
647 ;;
649 ## Intel Paragon OSF/1
650 i860-intel-osf1* )
651 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
652 ;;
654 ## Intel 860
655 i860-*-sysv4* )
656 machine=i860 opsys=usg5-4
657 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
658 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
659 ;;
661 ## Macintosh PowerPC
662 powerpc*-*-linux-gnu* )
663 machine=macppc opsys=gnu-linux
664 ;;
666 ## Masscomp machines
667 m68*-masscomp-rtu* )
668 machine=masscomp opsys=rtu
669 ;;
671 ## Megatest machines
672 m68*-megatest-bsd* )
673 machine=mega68 opsys=bsd4-2
674 ;;
676 ## Workstations sold by MIPS
677 ## This is not necessarily all workstations using the MIPS processor -
678 ## Irises are produced by SGI, and DECstations by DEC.
680 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
681 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
682 ## it gives for choosing between the alternatives seems to be "Use
683 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
684 ## the BSD world." I'll assume that these are instructions for
685 ## handling two odd situations, and that every other situation
686 ## should use mips.h and usg5-2-2, they being listed first.
687 mips-mips-usg* )
688 machine=mips4
689 ## Fall through to the general code at the bottom to decide on the OS.
690 ;;
691 mips-mips-riscos4* )
692 machine=mips4 opsys=bsd4-3
693 NON_GNU_CC="cc -systype bsd43"
694 NON_GNU_CPP="cc -systype bsd43 -E"
695 ;;
696 mips-mips-riscos5* )
697 machine=mips4 opsys=riscos5
698 NON_GNU_CC="cc -systype bsd43"
699 NON_GNU_CPP="cc -systype bsd43 -E"
700 ;;
701 mips-mips-bsd* )
702 machine=mips opsys=bsd4-3
703 ;;
704 mips-mips-* )
705 machine=mips opsys=usg5-2-2
706 ;;
708 ## NeXT
709 m68*-next-* | m68k-*-nextstep* )
710 machine=m68k opsys=nextstep
711 ;;
713 ## The complete machine from National Semiconductor
714 ns32k-ns-genix* )
715 machine=ns32000 opsys=usg5-2
716 ;;
718 ## NCR machines
719 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
720 machine=tower32 opsys=usg5-2-2
721 ;;
722 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
723 machine=tower32v3 opsys=usg5-3
724 ;;
726 ## NEC EWS4800
727 mips-nec-sysv4*)
728 machine=ews4800 opsys=ux4800
729 ;;
731 ## Nixdorf Targon 31
732 m68*-nixdorf-sysv* )
733 machine=targon31 opsys=usg5-2-2
734 ;;
736 ## Nu (TI or LMI)
737 m68*-nu-sysv* )
738 machine=nu opsys=usg5-2
739 ;;
741 ## Plexus
742 m68*-plexus-sysv* )
743 machine=plexus opsys=usg5-2
744 ;;
746 ## PowerPC reference platform
747 powerpcle-*-solaris2* )
748 machine=prep
749 opsys=sol2-5
750 ;;
752 ## Pyramid machines
753 ## I don't really have any idea what sort of processor the Pyramid has,
754 ## so I'm assuming it is its own architecture.
755 pyramid-pyramid-bsd* )
756 machine=pyramid opsys=bsd4-2
757 ;;
759 ## Sequent Balance
760 ns32k-sequent-bsd4.2* )
761 machine=sequent opsys=bsd4-2
762 ;;
763 ns32k-sequent-bsd4.3* )
764 machine=sequent opsys=bsd4-3
765 ;;
767 ## Siemens Nixdorf
768 mips-siemens-sysv* | mips-sni-sysv*)
769 machine=mips-siemens opsys=usg5-4
770 NON_GNU_CC=/usr/ccs/bin/cc
771 NON_GNU_CPP=/usr/ccs/lib/cpp
772 ;;
774 ## Silicon Graphics machines
775 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
776 m68*-sgi-iris3.5* )
777 machine=irist opsys=iris3-5
778 ;;
779 m68*-sgi-iris3.6* | m68*-sgi-iris*)
780 machine=irist opsys=iris3-6
781 ;;
782 ## Iris 4D
783 mips-sgi-irix3* )
784 machine=iris4d opsys=irix3-3
785 ;;
786 mips-sgi-irix4* )
787 machine=iris4d opsys=irix4-0
788 ;;
789 mips-sgi-irix6.5 )
790 machine=iris4d opsys=irix6-5
791 # Without defining _LANGUAGE_C, things get masked out in the headers
792 # so that, for instance, grepping for `free' in stdlib.h fails and
793 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
794 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
795 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
796 ;;
797 mips-sgi-irix6* )
798 machine=iris4d opsys=irix6-0
799 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
800 # but presumably it does no harm.
801 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
802 # -32 probably isn't necessary in later v.6s -- anyone know which?
803 NON_GCC_TEST_OPTIONS=-32
804 ;;
805 mips-sgi-irix5.[01]* )
806 machine=iris4d opsys=irix5-0
807 ;;
808 mips-sgi-irix5* | mips-sgi-irix* )
809 machine=iris4d opsys=irix5-2
810 ;;
812 ## SONY machines
813 m68*-sony-bsd4.2* )
814 machine=news opsys=bsd4-2
815 ;;
816 m68*-sony-bsd4.3* )
817 machine=news opsys=bsd4-3
818 ;;
819 m68*-sony-newsos3* | m68*-sony-news3*)
820 machine=news opsys=bsd4-3
821 ;;
822 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
823 machine=news-risc opsys=bsd4-3
824 ;;
825 mips-sony-newsos6* )
826 machine=news-r6 opsys=newsos6
827 ;;
828 mips-sony-news* )
829 machine=news-risc opsys=newsos5
830 ;;
832 ## Stride
833 m68*-stride-sysv* )
834 machine=stride opsys=usg5-2
835 ;;
837 ## Suns
838 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
839 machine=sparc opsys=gnu-linux
840 ;;
842 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
843 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
844 | rs6000-*-solaris2*)
845 case "${canonical}" in
846 m68*-sunos1* ) machine=sun1 ;;
847 m68*-sunos2* ) machine=sun2 ;;
848 m68* ) machine=sun3 ;;
849 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
850 i[3456]86-*-* ) machine=intel386 ;;
851 powerpcle* ) machine=powerpcle ;;
852 powerpc* | rs6000* ) machine=ibmrs6000 ;;
853 sparc* ) machine=sparc ;;
854 * ) unported=yes ;;
855 esac
856 case "${canonical}" in
857 ## The Sun386 didn't get past 4.0.
858 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
859 *-sunos4.0* ) opsys=sunos4-0 ;;
860 *-sunos4.1.[3-9]*noshare )
861 ## This name is sunos413 instead of sunos4-1-3
862 ## to avoid a file name conflict on MSDOS.
863 opsys=sunos413
864 NON_GNU_CPP=/usr/lib/cpp
865 NON_GCC_TEST_OPTIONS=-Bstatic
866 GCC_TEST_OPTIONS=-static
867 ;;
868 *-sunos4.1.[3-9]* | *-sunos4shr*)
869 opsys=sunos4shr
870 NON_GNU_CPP=/usr/lib/cpp
871 ;;
872 *-sunos4* | *-sunos )
873 opsys=sunos4-1
874 NON_GCC_TEST_OPTIONS=-Bstatic
875 GCC_TEST_OPTIONS=-static
876 ;;
877 *-sunos5.3* | *-solaris2.3* )
878 opsys=sol2-3
879 NON_GNU_CPP=/usr/ccs/lib/cpp
880 ;;
881 *-sunos5.4* | *-solaris2.4* )
882 opsys=sol2-4
883 NON_GNU_CPP=/usr/ccs/lib/cpp
884 RANLIB="ar -ts"
885 ;;
886 *-sunos5.5* | *-solaris2.5* )
887 opsys=sol2-5
888 NON_GNU_CPP=/usr/ccs/lib/cpp
889 RANLIB="ar -ts"
890 ;;
891 *-sunos5* | *-solaris* )
892 opsys=sol2-5
893 NON_GNU_CPP=/usr/ccs/lib/cpp
894 ;;
895 * ) opsys=bsd4-2 ;;
896 esac
897 ## Watch out for a compiler that we know will not work.
898 case "${canonical}" in
899 *-solaris* | *-sunos5* )
900 if [ "x$CC" = x/usr/ucb/cc ]; then
901 ## /usr/ucb/cc doesn't work;
902 ## we should find some other compiler that does work.
903 unset CC
904 fi
905 ;;
906 *) ;;
907 esac
908 ;;
909 sparc-*-nextstep* )
910 machine=sparc opsys=nextstep
911 ;;
913 ## Tadpole 68k
914 m68*-tadpole-sysv* )
915 machine=tad68k opsys=usg5-3
916 ;;
918 ## Tahoe machines
919 tahoe-tahoe-bsd4.2* )
920 machine=tahoe opsys=bsd4-2
921 ;;
922 tahoe-tahoe-bsd4.3* )
923 machine=tahoe opsys=bsd4-3
924 ;;
926 ## Tandem Integrity S2
927 mips-tandem-sysv* )
928 machine=tandem-s2 opsys=usg5-3
929 ;;
931 ## Tektronix XD88
932 m88k-tektronix-sysv3* )
933 machine=tekxd88 opsys=usg5-3
934 ;;
936 ## Tektronix 16000 box (6130?)
937 ns16k-tektronix-bsd* )
938 machine=ns16000 opsys=bsd4-2
939 ;;
940 ## Tektronix 4300
941 ## src/m/tek4300.h hints that this is a m68k machine.
942 m68*-tektronix-bsd* )
943 machine=tek4300 opsys=bsd4-3
944 ;;
946 ## Titan P2 or P3
947 ## We seem to have lost the machine-description file titan.h!
948 titan-titan-sysv* )
949 machine=titan opsys=usg5-3
950 ;;
952 ## Ustation E30 (SS5E)
953 m68*-unisys-uniplus* )
954 machine=ustation opsystem=unipl5-2
955 ;;
957 ## Vaxen.
958 vax-dec-* )
959 machine=vax
960 case "${canonical}" in
961 *-bsd4.1* ) opsys=bsd4-1 ;;
962 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
963 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
964 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
965 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
966 *-vms* ) opsys=vms ;;
967 * ) unported=yes
968 esac
969 ;;
971 ## Whitechapel MG1
972 ns16k-whitechapel-* )
973 machine=mg1
974 ## We don't know what sort of OS runs on these; we'll let the
975 ## operating system guessing code below try.
976 ;;
978 ## Wicat
979 m68*-wicat-sysv* )
980 machine=wicat opsys=usg5-2
981 ;;
983 ## IA-64
984 ia64*-*-linux* )
985 machine=ia64 opsys=gnu-linux
986 ;;
988 ## Intel 386 machines where we don't care about the manufacturer
989 i[3456]86-*-* )
990 machine=intel386
991 case "${canonical}" in
992 *-lynxos* ) opsys=lynxos ;;
993 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
994 *-isc2.2* ) opsys=isc2-2 ;;
995 *-isc4.0* ) opsys=isc4-0 ;;
996 *-isc4.* ) opsys=isc4-1
997 GCC_TEST_OPTIONS=-posix
998 NON_GCC_TEST_OPTIONS=-Xp
999 ;;
1000 *-isc* ) opsys=isc3-0 ;;
1001 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1002 *-esix* ) opsys=esix ;;
1003 *-xenix* ) opsys=xenix ;;
1004 *-linux-gnu* ) opsys=gnu-linux ;;
1005 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1006 *-sco3.2v5* ) opsys=sco5
1007 NON_GNU_CPP=/lib/cpp
1008 # Prevent -belf from being passed to $CPP.
1009 # /lib/cpp does not accept it.
1010 OVERRIDE_CPPFLAGS=" "
1011 ;;
1012 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1013 *-386bsd* ) opsys=386bsd ;;
1014 *-freebsd* ) opsys=freebsd ;;
1015 *-nextstep* ) opsys=nextstep ;;
1016 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1017 esac
1018 ;;
1020 ## m68k Linux-based GNU system
1021 m68k-*-linux-gnu* )
1022 machine=m68k opsys=gnu-linux
1023 ;;
1025 ## Mips Linux-based GNU system
1026 mips-*-linux-gnu* )
1027 machine=mips opsys=gnu-linux
1028 ;;
1030 ## UXP/DS
1031 sparc-fujitsu-sysv4* )
1032 machine=sparc opsys=uxpds
1033 NON_GNU_CPP=/usr/ccs/lib/cpp
1034 RANLIB="ar -ts"
1035 ;;
1037 ## UXP/V
1038 f301-fujitsu-uxpv4.1)
1039 machine=f301 opsys=uxpv
1040 ;;
1042 * )
1043 unported=yes
1044 ;;
1045 esac
1047 ### If the code above didn't choose an operating system, just choose
1048 ### an operating system based on the configuration name. You really
1049 ### only want to use this when you have no idea what the right
1050 ### operating system is; if you know what operating systems a machine
1051 ### runs, it's cleaner to make it explicit in the case statement
1052 ### above.
1053 if test x"${opsys}" = x; then
1054 case "${canonical}" in
1055 *-gnu* ) opsys=gnu ;;
1056 *-bsd4.[01] ) opsys=bsd4-1 ;;
1057 *-bsd4.2 ) opsys=bsd4-2 ;;
1058 *-bsd4.3 ) opsys=bsd4-3 ;;
1059 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1060 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1061 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1062 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1063 *-sysv4.2uw* ) opsys=unixware ;;
1064 *-sysv4.1* | *-sysvr4.1* )
1065 NON_GNU_CPP=/usr/lib/cpp
1066 opsys=usg5-4 ;;
1067 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1068 if [ x$NON_GNU_CPP = x ]; then
1069 if [ -f /usr/ccs/lib/cpp ]; then
1070 NON_GNU_CPP=/usr/ccs/lib/cpp
1071 else
1072 NON_GNU_CPP=/lib/cpp
1073 fi
1074 fi
1075 opsys=usg5-4-2 ;;
1076 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1077 * )
1078 unported=yes
1079 ;;
1080 esac
1081 fi
1083 changequote([, ])dnl
1085 if test $unported = yes; then
1086 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1087 Check \`etc/MACHINES' for recognized configuration names.])
1088 fi
1090 machfile="m/${machine}.h"
1091 opsysfile="s/${opsys}.h"
1094 #### Choose a compiler.
1095 test -n "$CC" && cc_specified=yes
1097 # Save the value of CFLAGS that the user specified.
1098 SPECIFIED_CFLAGS="$CFLAGS"
1100 case ${with_gcc} in
1101 "yes" ) CC="gcc" GCC=yes ;;
1102 "no" ) : ${CC=cc} ;;
1103 * ) AC_PROG_CC
1104 esac
1106 # On Suns, sometimes $CPP names a directory.
1107 if test -n "$CPP" && test -d "$CPP"; then
1108 CPP=
1109 fi
1111 #### Some systems specify a CPP to use unless we are using GCC.
1112 #### Now that we know whether we are using GCC, we can decide whether
1113 #### to use that one.
1114 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1115 then
1116 CPP="$NON_GNU_CPP"
1117 fi
1119 #### Some systems specify a CC to use unless we are using GCC.
1120 #### Now that we know whether we are using GCC, we can decide whether
1121 #### to use that one.
1122 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1123 test x$cc_specified != xyes
1124 then
1125 CC="$NON_GNU_CC"
1126 fi
1128 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1129 then
1130 CC="$CC $GCC_TEST_OPTIONS"
1131 fi
1133 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1134 then
1135 CC="$CC $NON_GCC_TEST_OPTIONS"
1136 fi
1138 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1139 then
1140 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1141 fi
1143 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1144 then
1145 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1146 fi
1148 #### Some other nice autoconf tests. If you add a test here which
1149 #### should make an entry in src/config.h, don't forget to add an
1150 #### #undef clause to src/config.h.in for autoconf to modify.
1152 dnl checks for programs
1153 AC_PROG_LN_S
1154 AC_PROG_CPP
1155 AC_PROG_INSTALL
1156 AC_PROG_YACC
1157 if test "x$RANLIB" = x; then
1158 AC_PROG_RANLIB
1159 fi
1161 dnl checks for Unix variants
1162 AC_AIX
1164 #### Extract some information from the operating system and machine files.
1166 AC_CHECKING([the machine- and system-dependent files to find out
1167 - which libraries the lib-src programs will want, and
1168 - whether the GNU malloc routines are usable])
1170 ### First figure out CFLAGS (which we use for running the compiler here)
1171 ### and REAL_CFLAGS (which we use for real compilation).
1172 ### The two are the same except on a few systems, where they are made
1173 ### different to work around various lossages. For example,
1174 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1175 ### as implying static linking.
1177 ### If the CFLAGS env var is specified, we use that value
1178 ### instead of the default.
1180 ### It's not important that this name contain the PID; you can't run
1181 ### two configures in the same directory and have anything work
1182 ### anyway.
1183 tempcname="conftest.c"
1185 echo '
1186 #include "'${srcdir}'/src/'${opsysfile}'"
1187 #include "'${srcdir}'/src/'${machfile}'"
1188 #ifndef LIBS_MACHINE
1189 #define LIBS_MACHINE
1190 #endif
1191 #ifndef LIBS_SYSTEM
1192 #define LIBS_SYSTEM
1193 #endif
1194 #ifndef C_SWITCH_SYSTEM
1195 #define C_SWITCH_SYSTEM
1196 #endif
1197 #ifndef C_SWITCH_MACHINE
1198 #define C_SWITCH_MACHINE
1199 #endif
1200 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1201 configure___ c_switch_system=C_SWITCH_SYSTEM
1202 configure___ c_switch_machine=C_SWITCH_MACHINE
1204 #ifndef LIB_X11_LIB
1205 #define LIB_X11_LIB -lX11
1206 #endif
1208 #ifndef LIBX11_MACHINE
1209 #define LIBX11_MACHINE
1210 #endif
1212 #ifndef LIBX11_SYSTEM
1213 #define LIBX11_SYSTEM
1214 #endif
1215 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1217 #ifdef UNEXEC
1218 configure___ unexec=UNEXEC
1219 #else
1220 configure___ unexec=unexec.o
1221 #endif
1223 #ifdef SYSTEM_MALLOC
1224 configure___ system_malloc=yes
1225 #else
1226 configure___ system_malloc=no
1227 #endif
1229 #ifndef C_DEBUG_SWITCH
1230 #define C_DEBUG_SWITCH -g
1231 #endif
1233 #ifndef C_OPTIMIZE_SWITCH
1234 #ifdef __GNUC__
1235 #define C_OPTIMIZE_SWITCH -O2
1236 #else
1237 #define C_OPTIMIZE_SWITCH -O
1238 #endif
1239 #endif
1241 #ifndef LD_SWITCH_MACHINE
1242 #define LD_SWITCH_MACHINE
1243 #endif
1245 #ifndef LD_SWITCH_SYSTEM
1246 #define LD_SWITCH_SYSTEM
1247 #endif
1249 #ifndef LD_SWITCH_X_SITE_AUX
1250 #define LD_SWITCH_X_SITE_AUX
1251 #endif
1253 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1254 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1256 #ifdef THIS_IS_CONFIGURE
1258 /* Get the CFLAGS for tests in configure. */
1259 #ifdef __GNUC__
1260 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1261 #else
1262 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1263 #endif
1265 #else /* not THIS_IS_CONFIGURE */
1267 /* Get the CFLAGS for real compilation. */
1268 #ifdef __GNUC__
1269 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1270 #else
1271 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1272 #endif
1274 #endif /* not THIS_IS_CONFIGURE */
1275 ' > ${tempcname}
1277 # The value of CPP is a quoted variable reference, so we need to do this
1278 # to get its actual value...
1279 CPP=`eval "echo $CPP"`
1280 changequote(, )dnl
1281 eval `${CPP} -Isrc ${tempcname} \
1282 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1283 if test "x$SPECIFIED_CFLAGS" = x; then
1284 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1285 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1286 else
1287 REAL_CFLAGS="$CFLAGS"
1288 fi
1289 changequote([, ])dnl
1290 rm ${tempcname}
1292 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1294 ### Make sure subsequent tests use flags consistent with the build flags.
1296 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1297 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1298 else
1299 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1300 fi
1302 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1303 AC_SYS_LARGEFILE
1305 # Sound support for GNU/Linux and the free BSDs.
1306 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1307 # Emulation library used on NetBSD.
1308 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1309 AC_SUBST(LIBSOUND)
1311 dnl checks for header files
1312 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1313 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1314 termcap.h stdio_ext.h fcntl.h term.h)
1315 AC_HEADER_STDC
1316 AC_HEADER_TIME
1317 AC_DECL_SYS_SIGLIST
1318 AC_HEADER_SYS_WAIT
1320 dnl Some systems have utime.h but don't declare the struct anyplace.
1321 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1322 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1323 #include <sys/time.h>
1324 #include <time.h>
1325 #else
1326 #ifdef HAVE_SYS_TIME_H
1327 #include <sys/time.h>
1328 #else
1329 #include <time.h>
1330 #endif
1331 #endif
1332 #ifdef HAVE_UTIME_H
1333 #include <utime.h>
1334 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1335 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1336 if test $emacs_cv_struct_utimbuf = yes; then
1337 AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1338 fi
1340 dnl checks for typedefs
1341 AC_TYPE_SIGNAL
1343 dnl Check for speed_t typedef.
1344 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1345 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1346 emacs_cv_speed_t=yes))
1347 if test $emacs_cv_speed_t = yes; then
1348 AC_DEFINE(HAVE_SPEED_T)
1349 fi
1351 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1352 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1353 #include <sys/time.h>
1354 #include <time.h>
1355 #else
1356 #ifdef HAVE_SYS_TIME_H
1357 #include <sys/time.h>
1358 #else
1359 #include <time.h>
1360 #endif
1361 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1362 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1363 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1364 if test $emacs_cv_struct_timeval = yes; then
1365 AC_DEFINE(HAVE_TIMEVAL)
1366 fi
1368 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1369 AC_TRY_COMPILE([#include <math.h>],
1370 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1371 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1372 HAVE_EXCEPTION=$emacs_cv_struct_exception
1373 if test $emacs_cv_struct_exception != yes; then
1374 AC_DEFINE(NO_MATHERR)
1375 fi
1377 dnl checks for structure members
1378 AC_STRUCT_TM
1379 AC_STRUCT_TIMEZONE
1380 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1381 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1382 emacs_cv_tm_gmtoff=yes,
1383 emacs_cv_tm_gmtoff=no))
1384 if test $emacs_cv_tm_gmtoff = yes; then
1385 AC_DEFINE(HAVE_TM_GMTOFF)
1386 fi
1388 dnl checks for compiler characteristics
1390 dnl Testing __STDC__ to determine prototype support isn't good enough.
1391 dnl DEC C, for instance, doesn't define it with default options, and
1392 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1393 dnl and void *.
1394 AC_C_PROTOTYPES
1395 AC_C_VOLATILE
1396 AC_C_CONST
1397 dnl This isn't useful because we can't turn on use of `inline' unless
1398 dnl the compiler groks `extern inline'.
1399 dnl AC_C_INLINE
1400 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1401 [AC_TRY_COMPILE(, [void * foo;],
1402 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1403 if test $emacs_cv_void_star = yes; then
1404 AC_DEFINE(POINTER_TYPE, void)
1405 else
1406 AC_DEFINE(POINTER_TYPE, char)
1407 fi
1409 dnl check for Make feature
1410 AC_PROG_MAKE_SET
1412 dnl checks for operating system services
1413 AC_SYS_LONG_FILE_NAMES
1415 #### Choose a window system.
1417 AC_PATH_X
1418 if test "$no_x" = yes; then
1419 window_system=none
1420 else
1421 window_system=x11
1422 fi
1424 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1425 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1426 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1427 x_default_search_path=""
1428 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1429 x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1430 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1431 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1432 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1433 if test x"${x_default_search_path}" = x; then
1434 x_default_search_path=${x_search_path}
1435 else
1436 x_default_search_path="${x_search_path}:${x_default_search_path}"
1437 fi
1438 done
1439 fi
1440 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1441 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1442 fi
1444 if test x"${x_includes}" = x; then
1445 bitmapdir=/usr/include/X11/bitmaps
1446 else
1447 # accumulate include directories that have X11 bitmap subdirectories
1448 bmd_acc="dummyval"
1449 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1450 if test -d "${bmd}/X11/bitmaps"; then
1451 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1452 fi
1453 if test -d "${bmd}/bitmaps"; then
1454 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1455 fi
1456 done
1457 if test ${bmd_acc} != "dummyval"; then
1458 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1459 fi
1460 fi
1462 case "${window_system}" in
1463 x11 )
1464 HAVE_X_WINDOWS=yes
1465 HAVE_X11=yes
1466 case "${with_x_toolkit}" in
1467 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1468 motif ) USE_X_TOOLKIT=MOTIF ;;
1469 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1470 no ) USE_X_TOOLKIT=none ;;
1471 dnl If user did not say whether to use a toolkit,
1472 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1473 * ) USE_X_TOOLKIT=maybe ;;
1474 esac
1475 ;;
1476 none )
1477 HAVE_X_WINDOWS=no
1478 HAVE_X11=no
1479 USE_X_TOOLKIT=none
1480 ;;
1481 esac
1483 ### If we're using X11, we should use the X menu package.
1484 HAVE_MENUS=no
1485 case ${HAVE_X11} in
1486 yes ) HAVE_MENUS=yes ;;
1487 esac
1489 if test "${opsys}" = "hpux9"; then
1490 case "${x_libraries}" in
1491 *X11R4* )
1492 opsysfile="s/hpux9-x11r4.h"
1493 ;;
1494 esac
1495 fi
1497 if test "${opsys}" = "hpux9shr"; then
1498 case "${x_libraries}" in
1499 *X11R4* )
1500 opsysfile="s/hpux9shxr4.h"
1501 ;;
1502 esac
1503 fi
1505 ### Compute the unexec source name from the object name.
1506 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1508 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1509 # Assume not, until told otherwise.
1510 GNU_MALLOC=yes
1511 doug_lea_malloc=yes
1512 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1513 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1514 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1515 emacs_cv_var___after_morecore_hook,
1516 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1517 emacs_cv_var___after_morecore_hook=yes,
1518 emacs_cv_var___after_morecore_hook=no))
1519 if test $emacs_cv_var___after_morecore_hook = no; then
1520 doug_lea_malloc=no
1521 fi
1522 if test "${system_malloc}" = "yes"; then
1523 GNU_MALLOC=no
1524 GNU_MALLOC_reason="
1525 (The GNU allocators don't work with this system configuration.)"
1526 fi
1527 if test "$doug_lea_malloc" = "yes" ; then
1528 if test "$GNU_MALLOC" = yes ; then
1529 GNU_MALLOC_reason="
1530 (Using Doug Lea's new malloc from the GNU C Library.)"
1531 fi
1532 AC_DEFINE(DOUG_LEA_MALLOC)
1533 fi
1535 if test x"${REL_ALLOC}" = x; then
1536 REL_ALLOC=${GNU_MALLOC}
1537 fi
1539 LIBS="$libsrc_libs $LIBS"
1541 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1542 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1543 AC_CHECK_LIB(dnet, dnet_ntoa)
1544 dnl This causes -lresolv to get used in subsequent tests,
1545 dnl which causes failures on some systems such as HPUX 9.
1546 dnl AC_CHECK_LIB(resolv, gethostbyname)
1548 dnl FIXME replace main with a function we actually want from this library.
1549 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1551 AC_CHECK_LIB(pthreads, cma_open)
1553 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1554 if test -d /usr/X386/include; then
1555 HAVE_XFREE386=yes
1556 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1557 else
1558 HAVE_XFREE386=no
1559 fi
1560 AC_MSG_RESULT($HAVE_XFREE386)
1562 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1563 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1565 REAL_CPPFLAGS="$CPPFLAGS"
1567 if test "${HAVE_X11}" = "yes"; then
1568 DEFS="$C_SWITCH_X_SITE $DEFS"
1569 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1570 LIBS="$LIBX $LIBS"
1571 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1572 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1574 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1575 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1576 # but it's more convenient here to set LD_RUN_PATH
1577 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1578 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1579 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1580 export LD_RUN_PATH
1581 fi
1583 if test "${opsys}" = "gnu-linux"; then
1584 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1585 AC_TRY_LINK([],
1586 [XOpenDisplay ("foo");],
1587 [xlinux_first_failure=no],
1588 [xlinux_first_failure=yes])
1589 if test "${xlinux_first_failure}" = "yes"; then
1590 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1591 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1592 OLD_CPPFLAGS="$CPPFLAGS"
1593 OLD_LIBS="$LIBS"
1594 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1595 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1596 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1597 LIBS="$LIBS -b i486-linuxaout"
1598 AC_TRY_LINK([],
1599 [XOpenDisplay ("foo");],
1600 [xlinux_second_failure=no],
1601 [xlinux_second_failure=yes])
1602 if test "${xlinux_second_failure}" = "yes"; then
1603 # If we get the same failure with -b, there is no use adding -b.
1604 # So take it out. This plays safe.
1605 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1606 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1607 CPPFLAGS="$OLD_CPPFLAGS"
1608 LIBS="$OLD_LIBS"
1609 AC_MSG_RESULT(no)
1610 else
1611 AC_MSG_RESULT(yes)
1612 fi
1613 else
1614 AC_MSG_RESULT(no)
1615 fi
1616 fi
1618 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1619 XScreenNumberOfScreen XSetWMProtocols)
1620 fi
1622 if test "${window_system}" = "x11"; then
1623 AC_MSG_CHECKING(X11 version 6)
1624 AC_CACHE_VAL(emacs_cv_x11_version_6,
1625 AC_TRY_LINK([#include <X11/Xlib.h>],
1626 [#if XlibSpecificationRelease < 6
1627 fail;
1628 #endif
1629 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1630 if test $emacs_cv_x11_version_6 = yes; then
1631 AC_MSG_RESULT(6 or newer)
1632 AC_DEFINE(HAVE_X11R6)
1633 else
1634 AC_MSG_RESULT(before 6)
1635 fi
1636 fi
1638 if test "${window_system}" = "x11"; then
1639 AC_MSG_CHECKING(X11 version 5)
1640 AC_CACHE_VAL(emacs_cv_x11_version_5,
1641 AC_TRY_LINK([#include <X11/Xlib.h>],
1642 [#if XlibSpecificationRelease < 5
1643 fail;
1644 #endif
1645 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1646 if test $emacs_cv_x11_version_5 = yes; then
1647 AC_MSG_RESULT(5 or newer)
1648 HAVE_X11R5=yes
1649 AC_DEFINE(HAVE_X11R5)
1650 else
1651 HAVE_X11R5=no
1652 AC_MSG_RESULT(before 5)
1653 fi
1654 fi
1656 dnl Do not put whitespace before the #include statements below.
1657 dnl Older compilers (eg sunos4 cc) choke on it.
1658 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1659 if test x"${HAVE_X11R5}" = xyes; then
1660 AC_MSG_CHECKING(X11 version 5 with Xaw)
1661 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1662 AC_TRY_LINK([
1663 #include <X11/Intrinsic.h>
1664 #include <X11/Xaw/Simple.h>],
1665 [],
1666 emacs_cv_x11_version_5_with_xaw=yes,
1667 emacs_cv_x11_version_5_with_xaw=no))
1668 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1669 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1670 USE_X_TOOLKIT=LUCID
1671 else
1672 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1673 USE_X_TOOLKIT=none
1674 fi
1675 else
1676 USE_X_TOOLKIT=none
1677 fi
1678 fi
1680 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1682 if test "${USE_X_TOOLKIT}" != "none"; then
1683 AC_MSG_CHECKING(X11 toolkit version)
1684 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1685 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1686 [#if XtSpecificationRelease < 6
1687 fail;
1688 #endif
1689 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1690 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1691 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1692 AC_MSG_RESULT(6 or newer)
1693 AC_DEFINE(HAVE_X11XTR6)
1694 else
1695 AC_MSG_RESULT(before 6)
1696 fi
1698 dnl If using toolkit, check whether libXmu.a exists.
1699 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1700 OLDLIBS="$LIBS"
1701 if test x$HAVE_X11XTR6 = xyes; then
1702 LIBS="-lXt -lSM -lICE $LIBS"
1703 else
1704 LIBS="-lXt $LIBS"
1705 fi
1706 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1707 LIBS="$OLDLIBS"
1708 fi
1710 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1711 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1712 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1713 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1714 int x = 5;
1715 #else
1716 Motif version prior to 2.1.
1717 #endif],
1718 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1719 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1720 if test $emacs_cv_motif_version_2_1 = yes; then
1721 AC_DEFINE(HAVE_MOTIF_2_1)
1722 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes, , -lXext)
1723 if test ${HAVE_LIBXP} = yes; then
1724 AC_DEFINE(HAVE_LIBXP)
1725 fi
1726 fi
1727 fi
1729 ### Is -lXaw3d available?
1730 HAVE_XAW3D=no
1731 if test "${HAVE_X11}" = "yes"; then
1732 if test "${USE_X_TOOLKIT}" != "none"; then
1733 old_c_flags="${CFLAGS}"
1734 CFLAGS="${LD_SWITCH_X_SITE}"
1735 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1736 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes, , -lX11))
1737 CFLAGS="${old_c_flags}"
1739 if test "${HAVE_XAW3D}" = "yes"; then
1740 AC_DEFINE(HAVE_XAW3D)
1741 fi
1742 fi
1743 fi
1745 dnl Use toolkit scroll bars if configured for X toolkit and either
1746 dnl using Motif or Xaw3d is available, and unless
1747 dnl --with-toolkit-scroll-bars=no was specified.
1749 USE_TOOLKIT_SCROLL_BARS=no
1750 if test "${with_toolkit_scroll_bars}" != "no"; then
1751 if test "${USE_X_TOOLKIT}" != "none"; then
1752 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1753 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1754 HAVE_XAW3D=no
1755 USE_TOOLKIT_SCROLL_BARS=yes
1756 elif test "${HAVE_XAW3D}" = "yes"; then
1757 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1758 USE_TOOLKIT_SCROLL_BARS=yes
1759 fi
1760 fi
1761 fi
1763 dnl Don't use X11 input methods if user specifies he doesn't want it
1764 dnl with `--with-xim=no'.
1766 if test "${with_xim}" != "no"; then
1767 AC_DEFINE(USE_XIM)
1768 fi
1770 ### Use -lXpm if available, unless `--with-xpm=no'.
1771 HAVE_XPM=no
1772 if test "${HAVE_X11}" = "yes"; then
1773 if test "${with_xpm}" != "no"; then
1774 old_c_flags="${CFLAGS}"
1775 CFLAGS="${LD_SWITCH_X_SITE}"
1776 AC_CHECK_HEADER(X11/xpm.h,
1777 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1778 if test "${HAVE_XPM}" = "yes"; then
1779 AC_EGREP_CPP(no_return_alloc_pixels,
1780 [#include "X11/xpm.h"
1781 #ifndef XpmReturnAllocPixels
1782 no_return_alloc_pixels
1783 #endif
1784 ], HAVE_XPM=no, HAVE_XPM=yes)
1785 fi
1786 CFLAGS="${old_c_flags}"
1787 fi
1789 if test "${HAVE_XPM}" = "yes"; then
1790 AC_DEFINE(HAVE_XPM)
1791 fi
1792 fi
1794 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1795 HAVE_JPEG=no
1796 if test "${HAVE_X11}" = "yes"; then
1797 if test "${with_jpeg}" != "no"; then
1798 old_c_flags="${CFLAGS}"
1799 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1800 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1801 dnl HAVE_STDLIB_H.
1802 AC_CHECK_HEADER(jerror.h,
1803 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes, , -lX11))
1804 CFLAGS="${old_c_flags}"
1805 fi
1807 if test "${HAVE_JPEG}" = "yes"; then
1808 AC_DEFINE(HAVE_JPEG)
1809 fi
1810 fi
1812 ### Use -lpng if available, unless `--with-png=no'.
1813 HAVE_PNG=no
1814 if test "${HAVE_X11}" = "yes"; then
1815 if test "${with_png}" != "no"; then
1816 old_c_flags="${CFLAGS}"
1817 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1818 AC_CHECK_HEADER(png.h,
1819 AC_CHECK_LIB(png, png_set_expand, HAVE_PNG=yes, , -lX11 -lz -lm))
1820 CFLAGS="${old_c_flags}"
1821 fi
1823 if test "${HAVE_PNG}" = "yes"; then
1824 AC_DEFINE(HAVE_PNG)
1825 fi
1826 fi
1828 ### Use -ltiff if available, unless `--with-tiff=no'.
1829 HAVE_TIFF=no
1830 if test "${HAVE_X11}" = "yes"; then
1831 if test "${with_tiff}" != "no"; then
1832 old_c_flags="${CFLAGS}"
1833 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1834 AC_CHECK_HEADER(tiffio.h,
1835 tifflibs="-lX11 -lz -lm"
1836 # At least one tiff package requires the jpeg library.
1837 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1838 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1839 CFLAGS="${old_c_flags}"
1840 fi
1842 if test "${HAVE_TIFF}" = "yes"; then
1843 AC_DEFINE(HAVE_TIFF)
1844 fi
1845 fi
1847 ### Use -lgif if available, unless `--with-gif=no'.
1848 HAVE_GIF=no
1849 if test "${HAVE_X11}" = "yes"; then
1850 if test "${with_gif}" != "no"; then
1851 old_c_flags="${CFLAGS}"
1852 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1853 AC_CHECK_HEADER(gif_lib.h,
1854 AC_CHECK_LIB(ungif, DGifOpen, HAVE_GIF=yes, , -lX11))
1855 CFLAGS="${old_c_flags}"
1856 fi
1858 if test "${HAVE_GIF}" = "yes"; then
1859 AC_DEFINE(HAVE_GIF)
1860 fi
1861 fi
1863 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1864 AC_CACHE_CHECK(whether netdb declares h_errno,
1865 emacs_cv_netdb_declares_h_errno,
1866 AC_TRY_LINK([#include <netdb.h>],
1867 [return h_errno;],
1868 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1869 if test $emacs_cv_netdb_declares_h_errno = yes; then
1870 AC_DEFINE(HAVE_H_ERRNO)
1871 fi
1873 AC_FUNC_ALLOCA
1875 # fmod, logb, and frexp are found in -lm on most systems.
1876 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1877 AC_CHECK_LIB(m, sqrt)
1879 # Check for mail-locking functions in a "mail" library
1880 AC_CHECK_LIB(mail, maillock)
1881 dnl Debian, at least:
1882 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1883 AC_CHECK_LIB(lockfile, maillock)
1884 # If we have the shared liblockfile, assume we must use it for mail
1885 # locking (e.g. Debian). If we couldn't link against liblockfile
1886 # (no liblockfile.a installed), ensure that we don't need to.
1887 if test "$ac_cv_lib_lockfile_maillock" = no; then
1888 dnl This works for files generally, not just executables.
1889 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
1890 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1891 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1892 if test $ac_cv_prog_liblockfile = yes; then
1893 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1894 This probably means that movemail could lose mail.
1895 There may be a \`development' package to install containing liblockfile.])
1896 else AC_DEFINE(LIBMAIL, -llockfile)
1897 fi
1898 else :
1899 fi
1900 AC_CHECK_FUNCS(touchlock)
1901 AC_CHECK_HEADERS(maillock.h)
1903 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
1904 rename closedir mkdir rmdir sysinfo \
1905 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1906 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1907 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
1908 __fpending mblen mbrlen strsignal setitimer ualarm)
1910 AC_FUNC_MKTIME
1911 if test "$ac_cv_func_working_mktime" = no; then
1912 AC_DEFINE(BROKEN_MKTIME)
1913 fi
1915 AC_FUNC_GETLOADAVG
1917 AC_CHECK_FUNCS(ftello)
1919 # UNIX98 PTYs. AC_SYS_LARGEFILE should have defined _XOPEN_SOURCE
1920 # if we need it.
1921 AC_CHECK_FUNCS(grantpt)
1923 # PTY-related GNU extensions.
1924 AC_CHECK_FUNCS(getpt)
1926 # Check this now, so that we will NOT find the above functions in ncurses.
1927 # That is because we have not set up to link ncurses in lib-src.
1928 # It's better to believe a function is not available
1929 # than to expect to find it in ncurses.
1930 AC_CHECK_LIB(ncurses, tparm)
1932 # These tell us which Kerberos-related libraries to use.
1933 if test "${with_kerberos+set}" = set; then
1934 AC_CHECK_LIB(com_err, com_err)
1935 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
1936 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1937 AC_CHECK_LIB(krb5, krb5_init_context)
1938 if test "${with_kerberos5+set}" != set; then
1939 AC_CHECK_LIB(des425, des_cbc_encrypt,,
1940 AC_CHECK_LIB(des, des_cbc_encrypt))
1941 AC_CHECK_LIB(krb4, krb_get_cred,,
1942 AC_CHECK_LIB(krb, krb_get_cred))
1943 fi
1945 if test "${with_kerberos5+set}" = set; then
1946 AC_CHECK_HEADERS(krb5.h)
1947 else
1948 AC_CHECK_HEADERS(des.h,,
1949 AC_CHECK_HEADERS(kerberosIV/des.h,,
1950 AC_CHECK_HEADERS(kerberos/des.h)))
1951 AC_CHECK_HEADERS(krb.h,,
1952 AC_CHECK_HEADERS(kerberosIV/krb.h,,
1953 AC_CHECK_HEADERS(kerberos/krb.h)))
1954 fi
1955 AC_CHECK_HEADERS(com_err.h)
1956 fi
1958 # Solaris requires -lintl if you want strerror (which calls dgettext)
1959 # to return localized messages.
1960 AC_CHECK_LIB(intl, dgettext)
1962 AC_MSG_CHECKING(whether localtime caches TZ)
1963 AC_CACHE_VAL(emacs_cv_localtime_cache,
1964 [if test x$ac_cv_func_tzset = xyes; then
1965 AC_TRY_RUN([#include <time.h>
1966 extern char **environ;
1967 unset_TZ ()
1968 {
1969 char **from, **to;
1970 for (to = from = environ; (*to = *from); from++)
1971 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1972 to++;
1973 }
1974 char TZ_GMT0[] = "TZ=GMT0";
1975 char TZ_PST8[] = "TZ=PST8";
1976 main()
1977 {
1978 time_t now = time ((time_t *) 0);
1979 int hour_GMT0, hour_unset;
1980 if (putenv (TZ_GMT0) != 0)
1981 exit (1);
1982 hour_GMT0 = localtime (&now)->tm_hour;
1983 unset_TZ ();
1984 hour_unset = localtime (&now)->tm_hour;
1985 if (putenv (TZ_PST8) != 0)
1986 exit (1);
1987 if (localtime (&now)->tm_hour == hour_GMT0)
1988 exit (1);
1989 unset_TZ ();
1990 if (localtime (&now)->tm_hour != hour_unset)
1991 exit (1);
1992 exit (0);
1993 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1994 [# If we have tzset, assume the worst when cross-compiling.
1995 emacs_cv_localtime_cache=yes])
1996 else
1997 # If we lack tzset, report that localtime does not cache TZ,
1998 # since we can't invalidate the cache if we don't have tzset.
1999 emacs_cv_localtime_cache=no
2000 fi])dnl
2001 AC_MSG_RESULT($emacs_cv_localtime_cache)
2002 if test $emacs_cv_localtime_cache = yes; then
2003 AC_DEFINE(LOCALTIME_CACHE)
2004 fi
2006 if test "x$HAVE_TIMEVAL" = xyes; then
2007 AC_CHECK_FUNCS(gettimeofday)
2008 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2009 emacs_cv_gettimeofday_two_arguments,
2010 AC_TRY_COMPILE([
2011 #ifdef TIME_WITH_SYS_TIME
2012 #include <sys/time.h>
2013 #include <time.h>
2014 #else
2015 #ifdef HAVE_SYS_TIME_H
2016 #include <sys/time.h>
2017 #else
2018 #include <time.h>
2019 #endif
2020 #endif],
2021 [struct timeval time;
2022 gettimeofday (&time, 0);],
2023 emacs_cv_gettimeofday_two_arguments=yes,
2024 emacs_cv_gettimeofday_two_arguments=no))
2025 if test $emacs_cv_gettimeofday_two_arguments = no; then
2026 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
2027 fi
2028 fi
2030 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2031 if test "$ac_cv_func_gettimeofday" = yes; then
2032 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2033 [AC_TRY_COMPILE([#include <sys/time.h>],
2034 [struct timezone tz;],
2035 dnl It may be that we can't call gettimeofday with a non-null pointer,
2036 dnl even though we have struct timezone (e.g. HPUX). In that case
2037 dnl we'll lie about struct timezone.
2038 [AC_TRY_RUN([
2039 #ifdef TIME_WITH_SYS_TIME
2040 #include <sys/time.h>
2041 #include <time.h>
2042 #else
2043 #ifdef HAVE_SYS_TIME_H
2044 #include <sys/time.h>
2045 #else
2046 #include <time.h>
2047 #endif
2048 #endif
2049 main () {
2050 struct timeval time;
2051 struct timezone dummy;
2052 exit (gettimeofday (&time, &dummy));
2053 }],
2054 emacs_cv_struct_timezone=yes,
2055 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2056 emacs_cv_struct_timezone=no)])
2057 fi
2059 ok_so_far=yes
2060 AC_CHECK_FUNC(socket, , ok_so_far=no)
2061 if test $ok_so_far = yes; then
2062 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2063 fi
2064 if test $ok_so_far = yes; then
2065 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2066 fi
2067 if test $ok_so_far = yes; then
2068 AC_DEFINE(HAVE_INET_SOCKETS)
2069 fi
2071 if test -f /usr/lpp/X11/bin/smt.exp; then
2072 AC_DEFINE(HAVE_AIX_SMT_EXP)
2073 fi
2075 AC_MSG_CHECKING(whether system supports dynamic ptys)
2076 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2077 AC_MSG_RESULT(yes)
2078 AC_DEFINE(HAVE_DEV_PTMX)
2079 else
2080 AC_MSG_RESULT(no)
2081 fi
2083 AC_FUNC_VFORK
2085 # Fixme: This should be replaced when we have autoconf 2.14.
2086 AC_SIZE_T
2088 # Set up the CFLAGS for real compilation, so we can substitute it.
2089 CFLAGS="$REAL_CFLAGS"
2090 CPPFLAGS="$REAL_CPPFLAGS"
2092 changequote(, )dnl
2093 #### Find out which version of Emacs this is.
2094 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2095 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2096 changequote([, ])dnl
2097 if test x"${version}" = x; then
2098 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2099 fi
2101 ### Specify what sort of things we'll be editing into Makefile and config.h.
2102 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2103 AC_SUBST(version)
2104 AC_SUBST(configuration)
2105 AC_SUBST(canonical)
2106 AC_SUBST(srcdir)
2107 AC_SUBST(prefix)
2108 AC_SUBST(exec_prefix)
2109 AC_SUBST(bindir)
2110 AC_SUBST(datadir)
2111 AC_SUBST(sharedstatedir)
2112 AC_SUBST(libexecdir)
2113 AC_SUBST(mandir)
2114 AC_SUBST(infodir)
2115 AC_SUBST(lispdir)
2116 AC_SUBST(locallisppath)
2117 AC_SUBST(lisppath)
2118 AC_SUBST(x_default_search_path)
2119 AC_SUBST(etcdir)
2120 AC_SUBST(archlibdir)
2121 AC_SUBST(docdir)
2122 AC_SUBST(bitmapdir)
2123 AC_SUBST(c_switch_system)
2124 AC_SUBST(c_switch_machine)
2125 AC_SUBST(LD_SWITCH_X_SITE)
2126 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2127 AC_SUBST(C_SWITCH_X_SITE)
2128 AC_SUBST(CFLAGS)
2129 AC_SUBST(X_TOOLKIT_TYPE)
2130 AC_SUBST(machfile)
2131 AC_SUBST(opsysfile)
2132 AC_SUBST(GETLOADAVG_LIBS)
2134 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
2135 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
2136 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
2137 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
2138 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
2139 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
2140 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
2141 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
2143 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2144 AC_DEFINE(HAVE_X_WINDOWS)
2145 fi
2146 if test "${USE_X_TOOLKIT}" != "none" ; then
2147 AC_DEFINE(USE_X_TOOLKIT)
2148 fi
2149 if test "${HAVE_X11}" = "yes" ; then
2150 AC_DEFINE(HAVE_X11)
2151 fi
2152 if test "${HAVE_XFREE386}" = "yes" ; then
2153 AC_DEFINE(HAVE_XFREE386)
2154 fi
2155 if test "${HAVE_MENUS}" = "yes" ; then
2156 AC_DEFINE(HAVE_MENUS)
2157 fi
2158 if test "${GNU_MALLOC}" = "yes" ; then
2159 AC_DEFINE(GNU_MALLOC)
2160 fi
2161 if test "${REL_ALLOC}" = "yes" ; then
2162 AC_DEFINE(REL_ALLOC)
2163 fi
2165 #### Report on what we decided to do.
2166 echo "
2167 Configured for \`${canonical}'.
2169 Where should the build process find the source code? ${srcdir}
2170 What operating system and machine description files should Emacs use?
2171 \`${opsysfile}' and \`${machfile}'
2172 What compiler should emacs be built with? ${CC} ${CFLAGS}
2173 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2174 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
2175 What window system should Emacs use? ${window_system}
2176 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2178 if test -n "${x_includes}"; then
2179 echo " Where do we find X Windows header files? ${x_includes}"
2180 else
2181 echo " Where do we find X Windows header files? Standard dirs"
2182 fi
2183 if test -n "${x_libraries}"; then
2184 echo " Where do we find X Windows libraries? ${x_libraries}"
2185 else
2186 echo " Where do we find X Windows libraries? Standard dirs"
2187 fi
2189 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2190 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2191 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2192 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2193 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2194 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2195 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2196 echo
2198 # Remove any trailing slashes in these variables.
2199 changequote(, )dnl
2200 test "${prefix}" != NONE &&
2201 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2202 test "${exec_prefix}" != NONE &&
2203 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2204 changequote([, ])dnl
2206 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2207 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2208 lisp/Makefile leim/Makefile, [
2210 ### Make the necessary directories, if they don't exist.
2211 for dir in etc lisp ; do
2212 test -d ${dir} || mkdir ${dir}
2213 done
2215 # Build src/Makefile from ${srcdir}/src/Makefile.c
2216 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2217 # This must be done after src/config.h is built, since we rely on that file.
2219 changequote(, )dnl The horror, the horror.
2220 # Now get this: Some word that is part of the ${srcdir} directory name
2221 # or the ${configuration} value might, just might, happen to be an
2222 # identifier like `sun4' or `i386' or something, and be predefined by
2223 # the C preprocessor to some helpful value like 1, or maybe the empty
2224 # string. Needless to say consequent macro substitutions are less
2225 # than conducive to the makefile finding the correct directory.
2226 undefs="`echo $top_srcdir $configuration $canonical |
2227 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2228 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2229 `"
2230 changequote([, ])dnl
2232 echo creating src/epaths.h
2233 make epaths-force
2235 echo creating lib-src/Makefile
2236 ( cd lib-src
2237 rm -f junk.c junk1.c junk2.c
2238 sed -e '/start of cpp stuff/q' \
2239 < Makefile.c > junk1.c
2240 sed -e '1,/start of cpp stuff/d'\
2241 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2242 < Makefile.c > junk.c
2243 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2244 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2245 cat junk1.c junk2.c > Makefile.new
2246 rm -f junk.c junk1.c junk2.c
2247 chmod 444 Makefile.new
2248 mv -f Makefile.new Makefile
2249 )
2251 echo creating src/Makefile
2252 ( cd src
2253 rm -f junk.c junk1.c junk2.c
2254 sed -e '/start of cpp stuff/q' \
2255 < Makefile.c > junk1.c
2256 sed -e '1,/start of cpp stuff/d'\
2257 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2258 < Makefile.c > junk.c
2259 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2260 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2261 cat junk1.c junk2.c > Makefile.new
2262 rm -f junk.c junk1.c junk2.c
2263 chmod 444 Makefile.new
2264 mv -f Makefile.new Makefile
2265 )
2267 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2268 echo creating src/.gdbinit
2269 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2270 fi
2272 # This is how we know whether to re-run configure in certain cases.
2273 touch src/config.stamp
2275 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])