lisp/macros.el

   1 ;;; macros.el --- non-primitive commands for keyboard macros
   2
   3 ;; Copyright (C) 1985, 86, 87, 92, 94, 95, 04 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Extension commands for keyboard macros.  These permit you to assign
  28 ;; a name to the last-defined keyboard macro, expand and insert the
  29 ;; lisp corresponding to a macro, query the user from within a macro,
  30 ;; or apply a macro to each line in the reason.
  31
  32 ;;; Code:
  33
  34 ;;;###autoload
  35 (defun name-last-kbd-macro (symbol)
  36   "Assign a name to the last keyboard macro defined.
  37 Argument SYMBOL is the name to define.
  38 The symbol's function definition becomes the keyboard macro string.
  39 Such a \"function\" cannot be called from Lisp, but it is a valid editor command."
  40   (interactive "SName for last kbd macro: ")
  41   (or last-kbd-macro
  42       (error "No keyboard macro defined"))
  43   (and (fboundp symbol)
  44        (not (stringp (symbol-function symbol)))
  45        (not (vectorp (symbol-function symbol)))
  46        (error "Function %s is already defined and not a keyboard macro"
  47               symbol))
  48   (if (string-equal symbol "")
  49       (error "No command name given"))
  50   (fset symbol last-kbd-macro))
  51
  52 ;;;###autoload
  53 (defun insert-kbd-macro (macroname &optional keys)
  54   "Insert in buffer the definition of kbd macro NAME, as Lisp code.
  55 Optional second arg KEYS means also record the keys it is on
  56 \(this is the prefix argument, when calling interactively).
  57
  58 This Lisp code will, when executed, define the kbd macro with the same
  59 definition it has now.  If you say to record the keys, the Lisp code
  60 will also rebind those keys to the macro.  Only global key bindings
  61 are recorded since executing this Lisp code always makes global
  62 bindings.
  63
  64 To save a kbd macro, visit a file of Lisp code such as your `~/.emacs',
  65 use this command, and then save the file."
  66   (interactive (list (intern (completing-read "Insert kbd macro (name): "
  67                                               obarray
  68                                               (lambda (elt)
  69                                                 (and (fboundp elt)
  70                                                      (or (stringp (symbol-function elt))
  71                                                          (vectorp (symbol-function elt))
  72                                                          (get elt 'kmacro))))
  73                                               t))
  74                      current-prefix-arg))
  75   (let (definition)
  76     (if (string= (symbol-name macroname) "")
  77         (progn
  78           (setq macroname 'last-kbd-macro definition last-kbd-macro)
  79           (insert "(setq "))
  80       (setq definition (symbol-function macroname))
  81       (insert "(fset '"))
  82     (prin1 macroname (current-buffer))
  83     (insert "\n   ")
  84     (if (stringp definition)
  85         (let ((beg (point)) end)
  86           (prin1 definition (current-buffer))
  87           (setq end (point-marker))
  88           (goto-char beg)
  89           (while (< (point) end)
  90             (let ((char (following-char)))
  91               (cond ((= char 0)
  92                      (delete-region (point) (1+ (point)))
  93                      (insert "\\C-@"))
  94                     ((< char 27)
  95                      (delete-region (point) (1+ (point)))
  96                      (insert "\\C-" (+ 96 char)))
  97                     ((= char ?\C-\\)
  98                      (delete-region (point) (1+ (point)))
  99                      (insert "\\C-\\\\"))
 100                     ((< char 32)
 101                      (delete-region (point) (1+ (point)))
 102                      (insert "\\C-" (+ 64 char)))
 103                     ((< char 127)
 104                      (forward-char 1))
 105                     ((= char 127)
 106                      (delete-region (point) (1+ (point)))
 107                      (insert "\\C-?"))
 108                     ((= char 128)
 109                      (delete-region (point) (1+ (point)))
 110                      (insert "\\M-\\C-@"))
 111                     ((= char (aref "\M-\C-\\" 0))
 112                      (delete-region (point) (1+ (point)))
 113                      (insert "\\M-\\C-\\\\"))
 114                     ((< char 155)
 115                      (delete-region (point) (1+ (point)))
 116                      (insert "\\M-\\C-" (- char 32)))
 117                     ((< char 160)
 118                      (delete-region (point) (1+ (point)))
 119                      (insert "\\M-\\C-" (- char 64)))
 120                     ((= char (aref "\M-\\" 0))
 121                      (delete-region (point) (1+ (point)))
 122                      (insert "\\M-\\\\"))
 123                     ((< char 255)
 124                      (delete-region (point) (1+ (point)))
 125                      (insert "\\M-" (- char 128)))
 126                     ((= char 255)
 127                      (delete-region (point) (1+ (point)))
 128                      (insert "\\M-\\C-?"))))))
 129       (if (vectorp definition)
 130           (let ((len (length definition)) (i 0) char mods)
 131             (while (< i len)
 132               (insert (if (zerop i) ?\[ ?\ ))
 133               (setq char (aref definition i)
 134                     i (1+ i))
 135               (cond ((not (numberp char))
 136                      (prin1 char (current-buffer)))
 137                     (t
 138                      (insert "?")
 139                      (setq mods (event-modifiers char)
 140                            char (event-basic-type char))
 141                      (while mods
 142                        (cond ((eq (car mods) 'control)
 143                               (insert "\\C-"))
 144                              ((eq (car mods) 'meta)
 145                               (insert "\\M-"))
 146                              ((eq (car mods) 'hyper)
 147                               (insert "\\H-"))
 148                              ((eq (car mods) 'super)
 149                               (insert "\\s-"))
 150                              ((eq (car mods) 'alt)
 151                               (insert "\\A-"))
 152                              ((and (eq (car mods) 'shift)
 153                                    (>= char ?a)
 154                                    (<= char ?z))
 155                               (setq char (upcase char)))
 156                              ((eq (car mods) 'shift)
 157                               (insert "\\S-")))
 158                        (setq mods (cdr mods)))
 159                      (cond ((= char ?\\)
 160                             (insert "\\\\"))
 161                            ((= char ?\")
 162                             (insert "\\\""))
 163                            ((= char ?\;)
 164                             (insert "\\;"))
 165                            ((= char 127)
 166                             (insert "\\C-?"))
 167                            ((< char 127)
 168                             (insert char))
 169                            (t (insert "\\" (format "%o" char)))))))
 170             (insert ?\]))
 171         (prin1 definition (current-buffer))))
 172     (insert ")\n")
 173     (if keys
 174         (let ((keys (where-is-internal macroname '(keymap))))
 175           (while keys
 176             (insert "(global-set-key ")
 177             (prin1 (car keys) (current-buffer))
 178             (insert " '")
 179             (prin1 macroname (current-buffer))
 180             (insert ")\n")
 181             (setq keys (cdr keys)))))))
 182
 183 ;;;###autoload
 184 (defun kbd-macro-query (flag)
 185   "Query user during kbd macro execution.
 186   With prefix argument, enters recursive edit, reading keyboard
 187 commands even within a kbd macro.  You can give different commands
 188 each time the macro executes.
 189   Without prefix argument, asks whether to continue running the macro.
 190 Your options are: \\<query-replace-map>
 191 \\[act] Finish this iteration normally and continue with the next.
 192 \\[skip]        Skip the rest of this iteration, and start the next.
 193 \\[exit]        Stop the macro entirely right now.
 194 \\[recenter]    Redisplay the screen, then ask again.
 195 \\[edit]        Enter recursive edit; ask again when you exit from that."
 196   (interactive "P")
 197   (or executing-kbd-macro
 198       defining-kbd-macro
 199       (error "Not defining or executing kbd macro"))
 200   (if flag
 201       (let (executing-kbd-macro defining-kbd-macro)
 202         (recursive-edit))
 203     (if (not executing-kbd-macro)
 204         nil
 205       (let ((loop t)
 206             (msg (substitute-command-keys
 207                   "Proceed with macro?\\<query-replace-map>\
 208  (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) ")))
 209         (while loop
 210           (let ((key (let ((executing-kbd-macro nil)
 211                            (defining-kbd-macro nil))
 212                        (message "%s" msg)
 213                        (read-event)))
 214                 def)
 215             (setq key (vector key))
 216             (setq def (lookup-key query-replace-map key))
 217             (cond ((eq def 'act)
 218                    (setq loop nil))
 219                   ((eq def 'skip)
 220                    (setq loop nil)
 221                    (setq executing-kbd-macro ""))
 222                   ((eq def 'exit)
 223                    (setq loop nil)
 224                    (setq executing-kbd-macro t))
 225                   ((eq def 'recenter)
 226                    (recenter nil))
 227                   ((eq def 'edit)
 228                    (let (executing-kbd-macro defining-kbd-macro)
 229                      (recursive-edit)))
 230                   ((eq def 'quit)
 231                    (setq quit-flag t))
 232                   (t
 233                    (or (eq def 'help)
 234                        (ding))
 235                    (with-output-to-temp-buffer "*Help*"
 236                      (princ
 237                       (substitute-command-keys
 238                        "Specify how to proceed with keyboard macro execution.
 239 Possibilities: \\<query-replace-map>
 240 \\[act] Finish this iteration normally and continue with the next.
 241 \\[skip]        Skip the rest of this iteration, and start the next.
 242 \\[exit]        Stop the macro entirely right now.
 243 \\[recenter]    Redisplay the screen, then ask again.
 244 \\[edit]        Enter recursive edit; ask again when you exit from that."))
 245                      (save-excursion
 246                        (set-buffer standard-output)
 247                        (help-mode)))))))))))
 248
 249 ;;;###autoload
 250 (defun apply-macro-to-region-lines (top bottom &optional macro)
 251   "Apply last keyboard macro to all lines in the region.
 252 For each line that begins in the region, move to the beginning of
 253 the line, and run the last keyboard macro.
 254
 255 When called from lisp, this function takes two arguments TOP and
 256 BOTTOM, describing the current region.  TOP must be before BOTTOM.
 257 The optional third argument MACRO specifies a keyboard macro to
 258 execute.
 259
 260 This is useful for quoting or unquoting included text, adding and
 261 removing comments, or producing tables where the entries are regular.
 262
 263 For example, in Usenet articles, sections of text quoted from another
 264 author are indented, or have each line start with `>'.  To quote a
 265 section of text, define a keyboard macro which inserts `>', put point
 266 and mark at opposite ends of the quoted section, and use
 267 `\\[apply-macro-to-region-lines]' to mark the entire section.
 268
 269 Suppose you wanted to build a keyword table in C where each entry
 270 looked like this:
 271
 272     { \"foo\", foo_data, foo_function },
 273     { \"bar\", bar_data, bar_function },
 274     { \"baz\", baz_data, baz_function },
 275
 276 You could enter the names in this format:
 277
 278     foo
 279     bar
 280     baz
 281
 282 and write a macro to massage a word into a table entry:
 283
 284     \\C-x (
 285        \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function },
 286     \\C-x )
 287
 288 and then select the region of un-tablified names and use
 289 `\\[apply-macro-to-region-lines]' to build the table from the names."
 290   (interactive "r")
 291   (or macro
 292       (progn
 293         (if (null last-kbd-macro)
 294             (error "No keyboard macro has been defined"))
 295         (setq macro last-kbd-macro)))
 296   (save-excursion
 297     (let ((end-marker (copy-marker bottom))
 298           next-line-marker)
 299       (goto-char top)
 300       (if (not (bolp))
 301           (forward-line 1))
 302       (setq next-line-marker (point-marker))
 303       (while (< next-line-marker end-marker)
 304         (goto-char next-line-marker)
 305         (save-excursion
 306           (forward-line 1)
 307           (set-marker next-line-marker (point)))
 308         (save-excursion
 309           (let ((mark-active nil))
 310             (execute-kbd-macro (or macro last-kbd-macro)))))
 311       (set-marker end-marker nil)
 312       (set-marker next-line-marker nil))))
 313
 314 ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query)
 315
 316 (provide 'macros)
 317
 318 ;;; arch-tag: 346ed1a5-1220-4bc8-b533-961ee704361f
 319 ;;; macros.el ends here