lisp/register.el

   1 ;;; register.el --- register commands for Emacs      -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 1985, 1993-1994, 2001-2015 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package of functions emulates and somewhat extends the venerable
  28 ;; TECO's `register' feature, which permits you to save various useful
  29 ;; pieces of buffer state to named variables.  The entry points are
  30 ;; documented in the Emacs user's manual: (info "(emacs) Registers").
  31
  32 (eval-when-compile (require 'cl-lib))
  33
  34 ;;; Code:
  35
  36 ;; FIXME: Clean up namespace usage!
  37
  38 (cl-defstruct
  39   (registerv (:constructor nil)
  40              (:constructor registerv--make (&optional data print-func
  41                                                       jump-func insert-func))
  42              (:copier nil)
  43              (:type vector)
  44              :named)
  45   (data        nil :read-only t)
  46   (print-func  nil :read-only t)
  47   (jump-func   nil :read-only t)
  48   (insert-func nil :read-only t))
  49
  50 (cl-defun registerv-make (data &key print-func jump-func insert-func)
  51   "Create a register value object.
  52
  53 DATA can be any value.
  54 PRINT-FUNC if provided controls how `list-registers' and
  55 `view-register' print the register.  It should be a function
  56 receiving one argument DATA and print text that completes
  57 this sentence:
  58   Register X contains [TEXT PRINTED BY PRINT-FUNC]
  59 JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
  60 INSERT-FUNC if provided, controls how `insert-register' insert the register.
  61 They both receive DATA as argument."
  62   (registerv--make data print-func jump-func insert-func))
  63
  64 (defvar register-alist nil
  65   "Alist of elements (NAME . CONTENTS), one for each Emacs register.
  66 NAME is a character (a number).  CONTENTS is a string, number, marker, list
  67 or a struct returned by `registerv-make'.
  68 A list of strings represents a rectangle.
  69 A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
  70 A list of the form (file-query FILE-NAME POSITION) represents
  71  position POSITION in the file named FILE-NAME, but query before
  72  visiting it.
  73 A list of the form (WINDOW-CONFIGURATION POSITION)
  74  represents a saved window configuration plus a saved value of point.
  75 A list of the form (FRAME-CONFIGURATION POSITION)
  76  represents a saved frame configuration plus a saved value of point.")
  77
  78 (defgroup register nil
  79   "Register commands."
  80   :group 'convenience
  81   :version "24.3")
  82
  83 (defcustom register-separator nil
  84   "Register containing the text to put between collected texts, or nil if none.
  85
  86 When collecting text with \\[append-to-register] (or \\[prepend-to-register]),
  87 contents of this register is added to the beginning (or end, respectively)
  88 of the marked text."
  89   :group 'register
  90   :type '(choice (const :tag "None" nil)
  91                  (character :tag "Use register" :value ?+)))
  92
  93 (defcustom register-preview-delay 1
  94   "If non-nil, time to wait in seconds before popping up a preview window.
  95 If nil, do not show register previews, unless `help-char' (or a member of
  96 `help-event-list') is pressed."
  97   :version "24.4"
  98   :type '(choice number (const :tag "No preview unless requested" nil))
  99   :group 'register)
 100
 101 (defun get-register (register)
 102   "Return contents of Emacs register named REGISTER, or nil if none."
 103   (alist-get register register-alist))
 104
 105 (defun set-register (register value)
 106   "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
 107 See the documentation of the variable `register-alist' for possible VALUEs."
 108   (setf (alist-get register register-alist) value))
 109
 110 (defun register-describe-oneline (c)
 111   "One-line description of register C."
 112   (let ((d (replace-regexp-in-string
 113             "\n[ \t]*" " "
 114             (with-output-to-string (describe-register-1 c)))))
 115     (if (string-match "Register.+? contains \\(?:an? \\|the \\)?" d)
 116         (substring d (match-end 0))
 117       d)))
 118
 119 (defun register-preview-default (r)
 120   "Default function for the variable `register-preview-function'."
 121   (format "%s: %s\n"
 122           (single-key-description (car r))
 123           (register-describe-oneline (car r))))
 124
 125 (defvar register-preview-function #'register-preview-default
 126   "Function to format a register for previewing.
 127 Takes one argument, a cons (NAME . CONTENTS) as found in `register-alist'.
 128 Returns a string.")
 129
 130 (defun register-preview (buffer &optional show-empty)
 131   "Pop up a window to show register preview in BUFFER.
 132 If SHOW-EMPTY is non-nil show the window even if no registers.
 133 Format of each entry is controlled by the variable `register-preview-function'."
 134   (when (or show-empty (consp register-alist))
 135     (with-current-buffer-window
 136      buffer
 137      (cons 'display-buffer-below-selected
 138            '((window-height . fit-window-to-buffer)
 139              (preserve-size . (nil . t))))
 140      nil
 141      (with-current-buffer standard-output
 142        (setq cursor-in-non-selected-windows nil)
 143        (insert (mapconcat register-preview-function register-alist ""))))))
 144
 145 (defun register-read-with-preview (prompt)
 146   "Read and return a register name, possibly showing existing registers.
 147 Prompt with the string PROMPT.  If `register-alist' and
 148 `register-preview-delay' are both non-nil, display a window
 149 listing existing registers after `register-preview-delay' seconds.
 150 If `help-char' (or a member of `help-event-list') is pressed,
 151 display such a window regardless."
 152   (let* ((buffer "*Register Preview*")
 153          (timer (when (numberp register-preview-delay)
 154                   (run-with-timer register-preview-delay nil
 155                                   (lambda ()
 156                                     (unless (get-buffer-window buffer)
 157                                       (register-preview buffer))))))
 158          (help-chars (cl-loop for c in (cons help-char help-event-list)
 159                               when (not (get-register c))
 160                               collect c)))
 161     (unwind-protect
 162         (progn
 163           (while (memq (read-key (propertize prompt 'face 'minibuffer-prompt))
 164                        help-chars)
 165             (unless (get-buffer-window buffer)
 166               (register-preview buffer 'show-empty)))
 167           (if (characterp last-input-event) last-input-event
 168             (error "Non-character input-event")))
 169       (and (timerp timer) (cancel-timer timer))
 170       (let ((w (get-buffer-window buffer)))
 171         (and (window-live-p w) (delete-window w)))
 172       (and (get-buffer buffer) (kill-buffer buffer)))))
 173
 174 (defun point-to-register (register &optional arg)
 175   "Store current location of point in register REGISTER.
 176 With prefix argument, store current frame configuration.
 177 Use \\[jump-to-register] to go to that location or restore that configuration.
 178 Argument is a character, naming the register.
 179
 180 Interactively, reads the register using `register-read-with-preview'."
 181   (interactive (list (register-read-with-preview "Point to register: ")
 182                      current-prefix-arg))
 183   ;; Turn the marker into a file-ref if the buffer is killed.
 184   (add-hook 'kill-buffer-hook 'register-swap-out nil t)
 185   (set-register register
 186                 (if arg (list (current-frame-configuration) (point-marker))
 187                   (point-marker))))
 188
 189 (defun window-configuration-to-register (register &optional _arg)
 190   "Store the window configuration of the selected frame in register REGISTER.
 191 Use \\[jump-to-register] to restore the configuration.
 192 Argument is a character, naming the register.
 193
 194 Interactively, reads the register using `register-read-with-preview'."
 195   (interactive (list (register-read-with-preview
 196                       "Window configuration to register: ")
 197                      current-prefix-arg))
 198   ;; current-window-configuration does not include the value
 199   ;; of point in the current buffer, so record that separately.
 200   (set-register register (list (current-window-configuration) (point-marker))))
 201
 202 ;; It has had the optional arg for ages, but never used it.
 203 (set-advertised-calling-convention 'window-configuration-to-register
 204                                    '(register) "24.4")
 205
 206 (defun frame-configuration-to-register (register &optional _arg)
 207   "Store the window configuration of all frames in register REGISTER.
 208 Use \\[jump-to-register] to restore the configuration.
 209 Argument is a character, naming the register.
 210
 211 Interactively, reads the register using `register-read-with-preview'."
 212   (interactive (list (register-read-with-preview
 213                       "Frame configuration to register: ")
 214                      current-prefix-arg))
 215   ;; current-frame-configuration does not include the value
 216   ;; of point in the current buffer, so record that separately.
 217   (set-register register (list (current-frame-configuration) (point-marker))))
 218
 219 ;; It has had the optional arg for ages, but never used it.
 220 (set-advertised-calling-convention 'frame-configuration-to-register
 221                                    '(register) "24.4")
 222
 223 (make-obsolete 'frame-configuration-to-register 'frameset-to-register "24.4")
 224
 225 (defalias 'register-to-point 'jump-to-register)
 226 (defun jump-to-register (register &optional delete)
 227   "Move point to location stored in a register.
 228 If the register contains a file name, find that file.
 229 \(To put a file name in a register, you must use `set-register'.)
 230 If the register contains a window configuration (one frame) or a frameset
 231 \(all frames), restore that frame or all frames accordingly.
 232 First argument is a character, naming the register.
 233 Optional second arg non-nil (interactively, prefix argument) says to
 234 delete any existing frames that the frameset doesn't mention.
 235 \(Otherwise, these frames are iconified.)
 236
 237 Interactively, reads the register using `register-read-with-preview'."
 238   (interactive (list (register-read-with-preview "Jump to register: ")
 239                      current-prefix-arg))
 240   (let ((val (get-register register)))
 241     (cond
 242      ((registerv-p val)
 243       (cl-assert (registerv-jump-func val) nil
 244               "Don't know how to jump to register %s"
 245               (single-key-description register))
 246       (funcall (registerv-jump-func val) (registerv-data val)))
 247      ((and (consp val) (frame-configuration-p (car val)))
 248       (set-frame-configuration (car val) (not delete))
 249       (goto-char (cadr val)))
 250      ((and (consp val) (window-configuration-p (car val)))
 251       (set-window-configuration (car val))
 252       (goto-char (cadr val)))
 253      ((markerp val)
 254       (or (marker-buffer val)
 255           (user-error "That register's buffer no longer exists"))
 256       (switch-to-buffer (marker-buffer val))
 257       (unless (or (= (point) (marker-position val))
 258                   (eq last-command 'jump-to-register))
 259         (push-mark))
 260       (goto-char val))
 261      ((and (consp val) (eq (car val) 'file))
 262       (find-file (cdr val)))
 263      ((and (consp val) (eq (car val) 'file-query))
 264       (or (find-buffer-visiting (nth 1 val))
 265           (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
 266           (user-error "Register access aborted"))
 267       (find-file (nth 1 val))
 268       (goto-char (nth 2 val)))
 269      (t
 270       (user-error "Register doesn't contain a buffer position or configuration")))))
 271
 272 (defun register-swap-out ()
 273   "Turn markers into file-query references when a buffer is killed."
 274   (and buffer-file-name
 275        (dolist (elem register-alist)
 276          (and (markerp (cdr elem))
 277               (eq (marker-buffer (cdr elem)) (current-buffer))
 278               (setcdr elem
 279                       (list 'file-query
 280                             buffer-file-name
 281                             (marker-position (cdr elem))))))))
 282
 283 (defun number-to-register (number register)
 284   "Store a number in a register.
 285 Two args, NUMBER and REGISTER (a character, naming the register).
 286 If NUMBER is nil, a decimal number is read from the buffer starting
 287 at point, and point moves to the end of that number.
 288 Interactively, NUMBER is the prefix arg (none means nil).
 289
 290 Interactively, reads the register using `register-read-with-preview'."
 291   (interactive (list current-prefix-arg
 292                      (register-read-with-preview "Number to register: ")))
 293   (set-register register
 294                 (if number
 295                     (prefix-numeric-value number)
 296                   (if (looking-at "\\s-*-?[0-9]+")
 297                       (progn
 298                         (goto-char (match-end 0))
 299                         (string-to-number (match-string 0)))
 300                     0))))
 301
 302 (defun increment-register (prefix register)
 303   "Augment contents of REGISTER.
 304 Interactively, PREFIX is in raw form.
 305
 306 If REGISTER contains a number, add `prefix-numeric-value' of
 307 PREFIX to it.
 308
 309 If REGISTER is empty or if it contains text, call
 310 `append-to-register' with `delete-flag' set to PREFIX.
 311
 312 Interactively, reads the register using `register-read-with-preview'."
 313   (interactive (list current-prefix-arg
 314                      (register-read-with-preview "Increment register: ")))
 315   (let ((register-val (get-register register)))
 316     (cond
 317      ((numberp register-val)
 318       (let ((number (prefix-numeric-value prefix)))
 319         (set-register register (+ number register-val))))
 320      ((or (not register-val) (stringp register-val))
 321       (append-to-register register (region-beginning) (region-end) prefix))
 322      (t (user-error "Register does not contain a number or text")))))
 323
 324 (defun view-register (register)
 325   "Display what is contained in register named REGISTER.
 326 The Lisp value REGISTER is a character.
 327
 328 Interactively, reads the register using `register-read-with-preview'."
 329   (interactive (list (register-read-with-preview "View register: ")))
 330   (let ((val (get-register register)))
 331     (if (null val)
 332         (message "Register %s is empty" (single-key-description register))
 333       (with-output-to-temp-buffer "*Output*"
 334         (describe-register-1 register t)))))
 335
 336 (defun list-registers ()
 337   "Display a list of nonempty registers saying briefly what they contain."
 338   (interactive)
 339   (let ((list (copy-sequence register-alist)))
 340     (setq list (sort list (lambda (a b) (< (car a) (car b)))))
 341     (with-output-to-temp-buffer "*Output*"
 342       (dolist (elt list)
 343         (when (get-register (car elt))
 344           (describe-register-1 (car elt))
 345           (terpri))))))
 346
 347 (defun describe-register-1 (register &optional verbose)
 348   (princ "Register ")
 349   (princ (single-key-description register))
 350   (princ " contains ")
 351   (let ((val (get-register register)))
 352     (cond
 353      ((registerv-p val)
 354       (if (registerv-print-func val)
 355           (funcall (registerv-print-func val) (registerv-data val))
 356         (princ "[UNPRINTABLE CONTENTS].")))
 357
 358      ((numberp val)
 359       (princ val))
 360
 361      ((markerp val)
 362       (let ((buf (marker-buffer val)))
 363         (if (null buf)
 364             (princ "a marker in no buffer")
 365           (princ "a buffer position:\n    buffer ")
 366           (princ (buffer-name buf))
 367           (princ ", position ")
 368           (princ (marker-position val)))))
 369
 370      ((and (consp val) (window-configuration-p (car val)))
 371       (princ "a window configuration."))
 372
 373      ((and (consp val) (frame-configuration-p (car val)))
 374       (princ "a frame configuration."))
 375
 376      ((and (consp val) (eq (car val) 'file))
 377       (princ "the file ")
 378       (prin1 (cdr val))
 379       (princ "."))
 380
 381      ((and (consp val) (eq (car val) 'file-query))
 382       (princ "a file-query reference:\n    file ")
 383       (prin1 (car (cdr val)))
 384       (princ ",\n    position ")
 385       (princ (car (cdr (cdr val))))
 386       (princ "."))
 387
 388      ((consp val)
 389       (if verbose
 390           (progn
 391             (princ "the rectangle:\n")
 392             (while val
 393               (princ "    ")
 394               (princ (car val))
 395               (terpri)
 396               (setq val (cdr val))))
 397         (princ "a rectangle starting with ")
 398         (princ (car val))))
 399
 400      ((stringp val)
 401       (setq val (copy-sequence val))
 402       (if (eq yank-excluded-properties t)
 403           (set-text-properties 0 (length val) nil val)
 404         (remove-list-of-text-properties 0 (length val)
 405                                         yank-excluded-properties val))
 406       (if verbose
 407           (progn
 408             (princ "the text:\n")
 409             (princ val))
 410         (cond
 411          ;; Extract first N characters starting with first non-whitespace.
 412          ((string-match (format "[^ \t\n].\\{,%d\\}"
 413                                 ;; Deduct 6 for the spaces inserted below.
 414                                 (min 20 (max 0 (- (window-width) 6))))
 415                         val)
 416           (princ "text starting with\n    ")
 417           (princ (match-string 0 val)))
 418          ((string-match "^[ \t\n]+$" val)
 419           (princ "whitespace"))
 420          (t
 421           (princ "the empty string")))))
 422      (t
 423       (princ "Garbage:\n")
 424       (if verbose (prin1 val))))))
 425
 426 (defun insert-register (register &optional arg)
 427   "Insert contents of register REGISTER.  (REGISTER is a character.)
 428 Normally puts point before and mark after the inserted text.
 429 If optional second arg is non-nil, puts mark before and point after.
 430 Interactively, second arg is nil if prefix arg is supplied and t
 431 otherwise.
 432
 433 Interactively, reads the register using `register-read-with-preview'."
 434   (interactive (progn
 435                  (barf-if-buffer-read-only)
 436                  (list (register-read-with-preview "Insert register: ")
 437                        (not current-prefix-arg))))
 438   (push-mark)
 439   (let ((val (get-register register)))
 440     (cond
 441      ((registerv-p val)
 442       (cl-assert (registerv-insert-func val) nil
 443               "Don't know how to insert register %s"
 444               (single-key-description register))
 445       (funcall (registerv-insert-func val) (registerv-data val)))
 446      ((consp val)
 447       (insert-rectangle val))
 448      ((stringp val)
 449       (insert-for-yank val))
 450      ((numberp val)
 451       (princ val (current-buffer)))
 452      ((and (markerp val) (marker-position val))
 453       (princ (marker-position val) (current-buffer)))
 454      (t
 455       (user-error "Register does not contain text"))))
 456   (if (not arg) (exchange-point-and-mark)))
 457
 458 (defun copy-to-register (register start end &optional delete-flag region)
 459   "Copy region into register REGISTER.
 460 With prefix arg, delete as well.
 461 Called from program, takes five args: REGISTER, START, END, DELETE-FLAG,
 462 and REGION.  START and END are buffer positions indicating what to copy.
 463 The optional argument REGION if non-nil, indicates that we're not just
 464 copying some text between START and END, but we're copying the region.
 465
 466 Interactively, reads the register using `register-read-with-preview'."
 467   (interactive (list (register-read-with-preview "Copy to register: ")
 468                      (region-beginning)
 469                      (region-end)
 470                      current-prefix-arg
 471                      t))
 472   (set-register register (if region
 473                              (funcall region-extract-function delete-flag)
 474                            (prog1 (filter-buffer-substring start end)
 475                              (if delete-flag (delete-region start end)))))
 476   (setq deactivate-mark t)
 477   (cond (delete-flag)
 478         ((called-interactively-p 'interactive)
 479          (indicate-copied-region))))
 480
 481 (defun append-to-register (register start end &optional delete-flag)
 482   "Append region to text in register REGISTER.
 483 With prefix arg, delete as well.
 484 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 485 START and END are buffer positions indicating what to append.
 486
 487 Interactively, reads the register using `register-read-with-preview'."
 488   (interactive (list (register-read-with-preview "Append to register: ")
 489                      (region-beginning)
 490                      (region-end)
 491                      current-prefix-arg))
 492   (let ((reg (get-register register))
 493         (text (filter-buffer-substring start end))
 494         (separator (and register-separator (get-register register-separator))))
 495     (set-register
 496      register (cond ((not reg) text)
 497                     ((stringp reg) (concat reg separator text))
 498                     (t (user-error "Register does not contain text")))))
 499   (setq deactivate-mark t)
 500   (cond (delete-flag
 501          (delete-region start end))
 502         ((called-interactively-p 'interactive)
 503          (indicate-copied-region))))
 504
 505 (defun prepend-to-register (register start end &optional delete-flag)
 506   "Prepend region to text in register REGISTER.
 507 With prefix arg, delete as well.
 508 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 509 START and END are buffer positions indicating what to prepend.
 510
 511 Interactively, reads the register using `register-read-with-preview'."
 512   (interactive (list (register-read-with-preview "Prepend to register: ")
 513                      (region-beginning)
 514                      (region-end)
 515                      current-prefix-arg))
 516   (let ((reg (get-register register))
 517         (text (filter-buffer-substring start end))
 518         (separator (and register-separator (get-register register-separator))))
 519     (set-register
 520      register (cond ((not reg) text)
 521                     ((stringp reg) (concat text separator reg))
 522                     (t (user-error "Register does not contain text")))))
 523   (setq deactivate-mark t)
 524   (cond (delete-flag
 525          (delete-region start end))
 526         ((called-interactively-p 'interactive)
 527          (indicate-copied-region))))
 528
 529 (defun copy-rectangle-to-register (register start end &optional delete-flag)
 530   "Copy rectangular region into register REGISTER.
 531 With prefix arg, delete as well.
 532 To insert this register in the buffer, use \\[insert-register].
 533
 534 Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
 535 START and END are buffer positions giving two corners of rectangle.
 536
 537 Interactively, reads the register using `register-read-with-preview'."
 538   (interactive (list (register-read-with-preview
 539                       "Copy rectangle to register: ")
 540                      (region-beginning)
 541                      (region-end)
 542                      current-prefix-arg))
 543   (let ((rectangle (if delete-flag
 544                        (delete-extract-rectangle start end)
 545                      (extract-rectangle start end))))
 546     (set-register register rectangle)
 547     (when (and (null delete-flag)
 548                (called-interactively-p 'interactive))
 549       (setq deactivate-mark t)
 550       (indicate-copied-region (length (car rectangle))))))
 551
 552 (provide 'register)
 553 ;;; register.el ends here