lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1993-1994, 2001-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Kevin Gallo
   6 ;; Keywords: terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  26 ;; that W32 windows are to be used.  Command line switches are parsed and those
  27 ;; pertaining to W32 are processed and removed from the command line.  The
  28 ;; W32 display is opened and hooks are set for popping up the initial window.
  29
  30 ;; startup.el will then examine startup files, and eventually call the hooks
  31 ;; which create the first window (s).
  32
  33 ;;; Code:
  34 \f
  35
  36 ;; These are the standard X switches from the Xt Initialize.c file of
  37 ;; Release 4.
  38
  39 ;; Command line         Resource Manager string
  40
  41 ;; +rv                  *reverseVideo
  42 ;; +synchronous         *synchronous
  43 ;; -background          *background
  44 ;; -bd                  *borderColor
  45 ;; -bg                  *background
  46 ;; -bordercolor         *borderColor
  47 ;; -borderwidth         .borderWidth
  48 ;; -bw                  .borderWidth
  49 ;; -display             .display
  50 ;; -fg                  *foreground
  51 ;; -fn                  *font
  52 ;; -font                *font
  53 ;; -foreground          *foreground
  54 ;; -geometry            .geometry
  55 ;; -i                   .iconType
  56 ;; -itype               .iconType
  57 ;; -iconic              .iconic
  58 ;; -name                .name
  59 ;; -reverse             *reverseVideo
  60 ;; -rv                  *reverseVideo
  61 ;; -selectionTimeout    .selectionTimeout
  62 ;; -synchronous         *synchronous
  63 ;; -xrm
  64
  65 ;; An alist of X options and the function which handles them.  See
  66 ;; ../startup.el.
  67
  68 ;; (if (not (eq window-system 'w32))
  69 ;;     (error "%s: Loading w32-win.el but not compiled for w32" invocation-name))
  70
  71 (eval-when-compile (require 'cl-lib))
  72 (require 'frame)
  73 (require 'mouse)
  74 (require 'scroll-bar)
  75 (require 'faces)
  76 (require 'select)
  77 (require 'menu-bar)
  78 (require 'dnd)
  79 (require 'w32-vars)
  80
  81 ;; Keep an obsolete alias for w32-focus-frame and w32-select-font in case
  82 ;; they are used by code outside Emacs.
  83 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  84 (declare-function x-select-font "w32font.c"
  85                   (&optional frame exclude-proportional))
  86 (define-obsolete-function-alias 'w32-select-font 'x-select-font "23.1")
  87
  88 (defvar w32-color-map) ;; defined in w32fns.c
  89 (make-obsolete 'w32-default-color-map nil "24.1")
  90
  91 (declare-function w32-send-sys-command "w32fns.c")
  92 (declare-function set-message-beep "w32fns.c")
  93
  94 (declare-function cygwin-convert-file-name-from-windows "cygw32.c"
  95                   (path &optional absolute_p))
  96
  97 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  98 (if (fboundp 'new-fontset)
  99     (require 'fontset))
 100
 101 ;; The following definition is used for debugging scroll bar events.
 102 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
 103
 104 ;; (defun w32-drag-n-drop-debug (event)
 105 ;;   "Print the drag-n-drop EVENT in a readable form."
 106 ;;   (interactive "e")
 107 ;;   (princ event))
 108
 109 (defun w32-handle-dropped-file (window file-name)
 110   (let ((f (if (eq system-type 'cygwin)
 111                (cygwin-convert-file-name-from-windows file-name t)
 112              (subst-char-in-string ?\\ ?/ file-name)))
 113         (coding (if (eq system-type 'windows-nt)
 114                     ;; Native w32 build pretends that its file names
 115                     ;; are encoded in UTF-8, and converts to the
 116                     ;; appropriate encoding internally.
 117                     'utf-8
 118                   (or file-name-coding-system
 119                       default-file-name-coding-system))))
 120
 121     (setq file-name
 122           (mapconcat 'url-hexify-string
 123                      (split-string (encode-coding-string f coding)
 124                                    "/")
 125                      "/")))
 126                 (dnd-handle-one-url window 'private
 127                                     (concat
 128                                      (if (eq system-type 'cygwin)
 129                                          "file://"
 130                                        "file:")
 131                                      file-name)))
 132
 133 (defun w32-drag-n-drop (event &optional new-frame)
 134   "Edit the files listed in the drag-n-drop EVENT.
 135 Switch to a buffer editing the last file dropped."
 136   (interactive "e")
 137   (save-excursion
 138     ;; Make sure the drop target has positive co-ords
 139     ;; before setting the selected frame - otherwise it
 140     ;; won't work.  <skx@tardis.ed.ac.uk>
 141     (let* ((window (posn-window (event-start event)))
 142            (coords (posn-x-y (event-start event)))
 143            (x (car coords))
 144            (y (cdr coords)))
 145       (if (and (> x 0) (> y 0))
 146           (set-frame-selected-window nil window))
 147
 148       (when new-frame
 149         (select-frame (make-frame)))
 150       (raise-frame)
 151       (setq window (selected-window))
 152
 153       (mapc (apply-partially #'w32-handle-dropped-file window)
 154             (car (cdr (cdr event)))))))
 155
 156 (defun w32-drag-n-drop-other-frame (event)
 157   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 158 May create new frames, or reuse existing ones.  The frame editing
 159 the last file dropped is selected."
 160   (interactive "e")
 161   (w32-drag-n-drop event t))
 162
 163 ;; Bind the drag-n-drop event.
 164 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 165 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 166
 167 ;; Keyboard layout/language change events
 168 ;; For now ignore language-change events; in the future
 169 ;; we should switch the Emacs Input Method to match the
 170 ;; new layout/language selected by the user.
 171 (global-set-key [language-change] 'ignore)
 172
 173 (defvar x-resource-name)
 174
 175 \f
 176 ;;;; Function keys
 177
 178  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 179  ;;; navigation feature.
 180 (defun w32-menu-bar-open (&optional frame)
 181    "Start key navigation of the menu bar in FRAME.
 182
 183 This initially activates the first menu-bar item, and you can then navigate
 184 with the arrow keys, select a menu entry with the Return key or cancel with
 185 one or two Escape keypresses.  (Two Escape keypresses are needed when a
 186 menu was already dropped down by pressing Return.)
 187
 188 If FRAME has no menu bar, this function does nothing.
 189
 190 If FRAME is nil or not given, use the selected frame.
 191 If FRAME does not have the menu bar enabled, display a text menu using
 192 `tmm-menubar'."
 193    (interactive "i")
 194    (if menu-bar-mode
 195        (w32-send-sys-command ?\xf100 frame)
 196      (with-selected-frame (or frame (selected-frame))
 197        (tmm-menubar))))
 198 \f
 199
 200 ;; W32 systems have different fonts than commonly found on X, so
 201 ;; we define our own standard fontset here.
 202 (defvar w32-standard-fontset-spec
 203  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 204  "String of fontset spec of the standard fontset.
 205 This defines a fontset consisting of the Courier New variations for
 206 European languages which are distributed with Windows as
 207 \"Multilanguage Support\".
 208
 209 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 210
 211 (defun w32-win-suspend-error ()
 212   "Report an error when a suspend is attempted."
 213   (error "Suspending an Emacs running under W32 makes no sense"))
 214
 215 (defvar dynamic-library-alist)
 216 (defvar libpng-version)                 ; image.c #ifdef HAVE_NTGUI
 217 (defvar libgif-version)
 218 (defvar libjpeg-version)
 219
 220 (defvar libgnutls-version)              ; gnutls.c
 221
 222 ;;; Set default known names for external libraries
 223 (setq dynamic-library-alist
 224       (list
 225        '(xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 226        ;; Versions of libpng 1.4.x and later are incompatible with
 227        ;; earlier versions.  Set up the list of libraries according to
 228        ;; the version we were compiled against.  (If we were compiled
 229        ;; without PNG support, libpng-version's value is -1.)
 230        (if (>= libpng-version 10400)
 231            (let ((major (/ libpng-version 10000))
 232                  (minor (mod (/ libpng-version 100) 10)))
 233              (list 'png
 234                    ;; libpngXY.dll is the default name when building
 235                    ;; with CMake or from a lpngXYY tarball on w32,
 236                    ;; libpngXY-XY.dll is the DLL name when building
 237                    ;; with libtool / autotools
 238                    (format "libpng%d%d.dll" major minor)
 239                    (format "libpng%d%d-%d%d.dll" major minor major minor)))
 240          '(png "libpng12d.dll" "libpng12.dll" "libpng3.dll" "libpng.dll"
 241                ;; these are libpng 1.2.8 from GTK+
 242                "libpng13d.dll" "libpng13.dll"))
 243        '(tiff "libtiff-5.dll" "libtiff3.dll" "libtiff.dll")
 244        (if (> libjpeg-version 62)
 245            ;; Versions of libjpeg after 6b are incompatible with
 246            ;; earlier versions, and each of versions 7, 8, and 9 is
 247            ;; also incompatible with the preceding ones (the core data
 248            ;; structures used for communications with the library
 249            ;; gained additional members with each new version).  So we
 250            ;; must use only the version of the library which Emacs was
 251            ;; compiled against.
 252            (list 'jpeg (format "libjpeg-%d.dll" (/ libjpeg-version 10)))
 253          '(jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll"))
 254        ;; Versions of giflib 5.0.0 and later changed signatures of
 255        ;; several functions used by Emacs, which makes those versions
 256        ;; incompatible with previous ones.  We select the correct
 257        ;; libraries according to the version of giflib we were
 258        ;; compiled against.  (If we were compiled without GIF support,
 259        ;; libgif-version's value is -1.)
 260        (if (>= libgif-version 50100)
 261            ;; Yes, giflib 5.0 uses 6 as the major version of the API,
 262            ;; and giflib 5.1 uses 7, thus "libgif-7.dll" and
 263            ;; "libgif-6.dll" below (giflib 4.x used 5 as the major API
 264            ;; version).  giflib5.dll is from the lua-files project,
 265            ;; and gif.dll is from luapower.
 266            '(gif "libgif-7.dll")
 267          (if (>= libgif-version 50000)
 268              '(gif "libgif-6.dll" "giflib5.dll" "gif.dll")
 269          '(gif "libgif-5.dll" "giflib4.dll" "libungif4.dll" "libungif.dll")))
 270        '(svg "librsvg-2-2.dll")
 271        '(gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 272        '(glib "libglib-2.0-0.dll")
 273        '(gobject "libgobject-2.0-0.dll")
 274        (if (>= libgnutls-version 30400)
 275            '(gnutls "libgnutls-30.dll")
 276          '(gnutls "libgnutls-28.dll" "libgnutls-26.dll"))
 277        '(libxml2 "libxml2-2.dll" "libxml2.dll")
 278        '(zlib "zlib1.dll" "libz-1.dll")
 279        '(lcms2 "liblcms2-2.dll")
 280        '(json "libjansson-4.dll")))
 281
 282 ;;; multi-tty support
 283 (defvar w32-initialized nil
 284   "Non-nil if the w32 window system has been initialized.")
 285
 286 (declare-function x-open-connection "w32fns.c"
 287                   (display &optional xrm-string must-succeed))
 288 (declare-function create-default-fontset "fontset" ())
 289 (declare-function create-fontset-from-fontset-spec "fontset"
 290                   (fontset-spec &optional style-variant noerror))
 291 (declare-function create-fontset-from-x-resource "fontset" ())
 292 (declare-function x-get-resource "frame.c"
 293                   (attribute class &optional component subclass))
 294 (declare-function x-handle-args "common-win" (args))
 295 (declare-function x-parse-geometry "frame.c" (string))
 296 (defvar x-command-line-resources)
 297
 298 (cl-defmethod window-system-initialization (&context (window-system w32)
 299                                             &optional _display)
 300   "Initialize Emacs for W32 GUI frames."
 301   (cl-assert (not w32-initialized))
 302
 303   ;; Do the actual Windows setup here; the above code just defines
 304   ;; functions and variables that we use now.
 305
 306   (setq command-line-args (x-handle-args command-line-args))
 307
 308   ;; Make sure we have a valid resource name.
 309   (or (stringp x-resource-name)
 310       (setq x-resource-name
 311             ;; Change any . or * characters in x-resource-name to hyphens,
 312             ;; so as not to choke when we use it in X resource queries.
 313             (replace-regexp-in-string "[.*]" "-" invocation-name)))
 314
 315   (x-open-connection "w32" x-command-line-resources
 316                      ;; Exit with a fatal error if this fails and we
 317                      ;; are the initial display
 318                      (eq initial-window-system 'w32))
 319
 320   ;; Create the default fontset.
 321   (create-default-fontset)
 322   ;; Create the standard fontset.
 323   (condition-case err
 324       (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 325     (error (display-warning
 326             'initialization
 327             (format "Creation of the standard fontset failed: %s" err)
 328             :error)))
 329   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 330   (create-fontset-from-x-resource)
 331
 332   ;; Apply a geometry resource to the initial frame.  Put it at the end
 333   ;; of the alist, so that anything specified on the command line takes
 334   ;; precedence.
 335   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 336          parsed)
 337     (if res-geometry
 338         (progn
 339           (setq parsed (x-parse-geometry res-geometry))
 340           ;; If the resource specifies a position,
 341           ;; call the position and size "user-specified".
 342           (if (or (assq 'top parsed) (assq 'left parsed))
 343               (setq parsed (cons '(user-position . t)
 344                                  (cons '(user-size . t) parsed))))
 345           ;; All geometry parms apply to the initial frame.
 346           (setq initial-frame-alist (append initial-frame-alist parsed))
 347           ;; The size parms apply to all frames.
 348           (if (and (assq 'height parsed)
 349                    (not (assq 'height default-frame-alist)))
 350               (setq default-frame-alist
 351                     (cons (cons 'height (cdr (assq 'height parsed)))
 352                           default-frame-alist))
 353           (if (and (assq 'width parsed)
 354                    (not (assq 'width default-frame-alist)))
 355               (setq default-frame-alist
 356                     (cons (cons 'width (cdr (assq 'width parsed)))
 357                           default-frame-alist)))))))
 358
 359   ;; Check the reverseVideo resource.
 360   (let ((case-fold-search t))
 361     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 362       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 363           (setq default-frame-alist
 364                 (cons '(reverse . t) default-frame-alist)))))
 365
 366   ;; Don't let Emacs suspend under Windows.
 367   (add-hook 'suspend-hook #'w32-win-suspend-error)
 368
 369   ;; Turn off window-splitting optimization; w32 is usually fast enough
 370   ;; that this is only annoying.
 371   (setq split-window-keep-point t)
 372
 373   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 374   (menu-bar-enable-clipboard)
 375
 376   ;; Don't show the frame name; that's redundant.
 377   (setq-default mode-line-frame-identification "  ")
 378
 379   ;; Set to a system sound if you want a fancy bell.
 380   (set-message-beep 'ok)
 381   (x-apply-session-resources)
 382   (setq w32-initialized t))
 383
 384 (add-to-list 'display-format-alist '("\\`w32\\'" . w32))
 385 (cl-defmethod handle-args-function (args &context (window-system w32))
 386   (x-handle-args args))
 387
 388 (cl-defmethod frame-creation-function (params &context (window-system w32))
 389   (x-create-frame-with-faces params))
 390
 391 ;;;; Selections
 392
 393 (declare-function w32-set-clipboard-data "w32select.c"
 394                   (string &optional ignored))
 395 (declare-function w32-get-clipboard-data "w32select.c")
 396 (declare-function w32-selection-exists-p "w32select.c")
 397
 398 ;;; Fix interface to (X-specific) mouse.el
 399 (defun w32--set-selection (type value)
 400   (if (eq type 'CLIPBOARD)
 401       (w32-set-clipboard-data (replace-regexp-in-string "\0" "\\0" value t t))
 402     (put 'x-selections (or type 'PRIMARY) value)))
 403
 404 (defun w32--get-selection  (&optional type data-type)
 405   (cond ((and (eq type 'CLIPBOARD)
 406               (eq data-type 'STRING))
 407          (with-demoted-errors "w32-get-clipboard-data:%S"
 408            (w32-get-clipboard-data)))
 409         ((eq data-type 'TARGETS)
 410          (if (eq type 'CLIPBOARD)
 411              (w32-selection-targets type)
 412            (if (get 'x-selections (or type 'PRIMARY)) '[STRING])))
 413         (t (get 'x-selections (or type 'PRIMARY)))))
 414
 415 (defun w32--selection-owner-p (selection)
 416   (and (memq selection '(nil PRIMARY SECONDARY))
 417        (get 'x-selections (or selection 'PRIMARY))))
 418
 419 (cl-defmethod gui-backend-set-selection (type value
 420                                          &context (window-system w32))
 421   (w32--set-selection type value))
 422
 423 (cl-defmethod gui-backend-get-selection (type data-type
 424                                          &context (window-system w32))
 425   (w32--get-selection type data-type))
 426
 427 (cl-defmethod gui-backend-selection-owner-p (selection
 428                                              &context (window-system w32))
 429   (w32--selection-owner-p selection))
 430
 431 (cl-defmethod gui-backend-selection-exists-p (selection
 432                                               &context (window-system w32))
 433   (w32-selection-exists-p selection))
 434
 435 (when (eq system-type 'windows-nt)
 436   ;; Make copy&pasting in w32's console interact with the system's clipboard!
 437   ;; We could move those cl-defmethods outside of the `when' and use
 438   ;; "&context (system-type (eql windows-nt))" instead!
 439   (cl-defmethod gui-backend-set-selection (type value
 440                                            &context (window-system nil))
 441     (w32--set-selection type value))
 442
 443   (cl-defmethod gui-backend-get-selection (type data-type
 444                                            &context (window-system nil))
 445     (w32--get-selection type data-type))
 446
 447   (cl-defmethod gui-backend-selection-owner-p (selection
 448                                                &context (window-system nil))
 449     (w32--selection-owner-p selection))
 450
 451   (cl-defmethod gui-selection-exists-p (selection
 452                                         &context (window-system nil))
 453     (w32-selection-exists-p selection)))
 454
 455 ;; The "Windows" keys on newer keyboards bring up the Start menu
 456 ;; whether you want it or not - make Emacs ignore these keystrokes
 457 ;; rather than beep.
 458 (global-set-key [lwindow] 'ignore)
 459 (global-set-key [rwindow] 'ignore)
 460
 461 (declare-function x-server-version "w32fns.c" (&optional terminal))
 462
 463 (defun w32-version ()
 464   "Return the MS-Windows version numbers.
 465 The value is a list of three integers: the major and minor version
 466 numbers, and the build number."
 467   (x-server-version))
 468
 469 (defun w32-using-nt ()
 470   "Return non-nil if running on a Windows NT descendant.
 471 That includes all Windows systems except for 9X/Me."
 472   (getenv "SystemRoot"))
 473
 474 (provide 'w32-win)
 475 (provide 'term/w32-win)
 476
 477 ;;; w32-win.el ends here