lisp/erc/erc-desktop-notifications.el

   1 ;; erc-desktop-notifications.el -- Send notification on PRIVMSG or mentions
   2
   3 ;; Copyright (C) 2012-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: comm
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This implements notifications using `notifications-notify' on
  26 ;; PRIVMSG received and on public nickname mentions.
  27
  28 ;;; Code:
  29
  30 (require 'erc)
  31 (require 'xml)
  32 (require 'notifications)
  33 (require 'erc-match)
  34 (require 'dbus)
  35
  36 (defgroup erc-notifications nil
  37   "Send notifications on PRIVMSG or mentions."
  38   :version "24.3"
  39   :group 'erc)
  40
  41 (defvar erc-notifications-last-notification nil
  42   "Last notification id.")
  43
  44 (defcustom erc-notifications-icon nil
  45   "Icon to use for notification."
  46   :group 'erc-notifications
  47   :type '(choice (const :tag "No icon" nil) file))
  48
  49 (defcustom erc-notifications-bus :session
  50   "D-Bus bus to use for notification."
  51   :version "25.1"
  52   :group 'erc-notifications
  53   :type '(choice (const :tag "Session bus" :session) string))
  54
  55 (defvar dbus-debug) ; used in the macroexpansion of dbus-ignore-errors
  56
  57 (defun erc-notifications-notify (nick msg)
  58   "Notify that NICK send some MSG.
  59 This will replace the last notification sent with this function."
  60   (dbus-ignore-errors
  61     (setq erc-notifications-last-notification
  62           (notifications-notify :bus erc-notifications-bus
  63                                 :title (xml-escape-string nick)
  64                                 :body (xml-escape-string msg)
  65                                 :replaces-id erc-notifications-last-notification
  66                                 :app-icon erc-notifications-icon))))
  67
  68 (defun erc-notifications-PRIVMSG (proc parsed)
  69   (let ((nick (car (erc-parse-user (erc-response.sender parsed))))
  70         (target (car (erc-response.command-args parsed)))
  71         (msg (erc-response.contents parsed)))
  72     (when (and (erc-current-nick-p target)
  73                (not (and (boundp 'erc-track-exclude)
  74                          (member nick erc-track-exclude)))
  75                (not (erc-is-message-ctcp-and-not-action-p msg)))
  76       (erc-notifications-notify nick msg)))
  77   ;; Return nil to continue processing by ERC
  78   nil)
  79
  80 (defun erc-notifications-notify-on-match (match-type nickuserhost msg)
  81   (when (eq match-type 'current-nick)
  82     (let ((nick (nth 0 (erc-parse-user nickuserhost))))
  83       (unless (or (string-match-p "^Server:" nick)
  84                   (when (boundp 'erc-track-exclude)
  85                     (member nick erc-track-exclude)))
  86         (erc-notifications-notify nick msg)))))
  87
  88 ;;;###autoload(autoload 'erc-notifications-mode "erc-desktop-notifications" "" t)
  89 (define-erc-module notifications nil
  90   "Send notifications on private message reception and mentions."
  91   ;; Enable
  92   ((add-hook 'erc-server-PRIVMSG-functions 'erc-notifications-PRIVMSG)
  93    (add-hook 'erc-text-matched-hook 'erc-notifications-notify-on-match))
  94   ;; Disable
  95   ((remove-hook 'erc-server-PRIVMSG-functions 'erc-notifications-PRIVMSG)
  96    (remove-hook 'erc-text-matched-hook 'erc-notifications-notify-on-match)))
  97
  98 (provide 'erc-desktop-notifications)
  99
 100 ;;; erc-desktop-notifications.el ends here
 101
 102 ;; Local Variables:
 103 ;; generated-autoload-file: "erc-loaddefs.el"
 104 ;; End: