lisp/textmodes/makeinfo.el

   1 ;;; makeinfo.el --- run makeinfo conveniently
   2
   3 ;; Copyright (C) 1991, 1993, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Robert J. Chassell
   6 ;; Maintainer: FSF
   7 ;; Keywords: docs convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; The Texinfo mode `makeinfo' related commands are:
  29
  30 ;; makeinfo-region      to run makeinfo on the current region.
  31 ;; makeinfo-buffer      to run makeinfo on the current buffer, or
  32 ;;                        with optional prefix arg, on current region
  33 ;; kill-compilation     to kill currently running makeinfo job
  34 ;; makeinfo-recenter-makeinfo-buffer  to redisplay *compilation* buffer
  35
  36 ;;; Keybindings (defined in `texinfo.el')
  37
  38 ;; makeinfo bindings
  39 ; (define-key texinfo-mode-map "\C-c\C-m\C-r" 'makeinfo-region)
  40 ; (define-key texinfo-mode-map "\C-c\C-m\C-b" 'makeinfo-buffer)
  41 ; (define-key texinfo-mode-map "\C-c\C-m\C-k" 'kill-compilation)
  42 ; (define-key texinfo-mode-map "\C-c\C-m\C-l"
  43 ;   'makeinfo-recenter-compilation-buffer)
  44 \f
  45 ;;; Code:
  46
  47 ;;; Variables used by `makeinfo'
  48
  49 (require 'compile)
  50 (require 'info)
  51
  52 (defgroup makeinfo nil
  53   "Run makeinfo conveniently"
  54   :group 'docs)
  55
  56
  57 (defcustom makeinfo-run-command "makeinfo"
  58   "*Command used to run `makeinfo' subjob.
  59 The name of the file is appended to this string, separated by a space."
  60   :type 'string
  61   :group 'makeinfo)
  62
  63 (defcustom makeinfo-options "--fill-column=70"
  64   "*String containing options for running `makeinfo'.
  65 Do not include `--footnote-style' or `--paragraph-indent';
  66 the proper way to specify those is with the Texinfo commands
  67 `@footnotestyle` and `@paragraphindent'."
  68   :type 'string
  69   :group 'makeinfo)
  70
  71 (require 'texinfo)
  72
  73 (defvar makeinfo-compilation-process nil
  74   "Process that runs `makeinfo'.  Should start out nil.")
  75
  76 (defvar makeinfo-temp-file nil
  77   "Temporary file name used for text being sent as input to `makeinfo'.")
  78
  79 (defvar makeinfo-output-file-name nil
  80   "Info file name used for text output by `makeinfo'.")
  81
  82 (defvar makeinfo-output-node-name nil
  83   "Node name to visit in output file, for `makeinfo-buffer'.")
  84
  85 \f
  86 ;;; The `makeinfo' function definitions
  87
  88 (defun makeinfo-region (region-beginning region-end)
  89   "Make Info file from region of current Texinfo file, and switch to it.
  90
  91 This command does not offer the `next-error' feature since it would
  92 apply to a temporary file, not the original; use the `makeinfo-buffer'
  93 command to gain use of `next-error'."
  94
  95   (interactive "r")
  96   (let (filename-or-header
  97         filename-or-header-beginning
  98         filename-or-header-end)
  99     ;; Cannot use `let' for makeinfo-temp-file or
 100     ;; makeinfo-output-file-name since `makeinfo-compilation-sentinel'
 101     ;; needs them.
 102
 103     (setq makeinfo-temp-file
 104           (concat
 105            (make-temp-file
 106             (substring (buffer-file-name)
 107                        0
 108                        (or (string-match "\\.tex" (buffer-file-name))
 109                            (length (buffer-file-name)))))
 110            ".texinfo"))
 111
 112     (save-excursion
 113       (save-restriction
 114         (widen)
 115         (goto-char (point-min))
 116         (let ((search-end (save-excursion (forward-line 100) (point))))
 117           ;; Find and record the Info filename,
 118           ;; or else explain that a filename is needed.
 119           (if (re-search-forward
 120                "^@setfilename[ \t]+\\([^ \t\n]+\\)[ \t]*"
 121                search-end t)
 122               (setq makeinfo-output-file-name
 123                     (buffer-substring (match-beginning 1) (match-end 1)))
 124             (error
 125              "The texinfo file needs a line saying: @setfilename <name>"))
 126
 127           ;; Find header and specify its beginning and end.
 128           (goto-char (point-min))
 129           (if (and
 130                (prog1
 131                    (search-forward tex-start-of-header search-end t)
 132                  (beginning-of-line)
 133                  ;; Mark beginning of header.
 134                  (setq filename-or-header-beginning (point)))
 135                (prog1
 136                    (search-forward tex-end-of-header nil t)
 137                  (beginning-of-line)
 138                  ;; Mark end of header
 139                  (setq filename-or-header-end (point))))
 140
 141               ;; Insert the header into the temporary file.
 142               (write-region
 143                (min filename-or-header-beginning region-beginning)
 144                filename-or-header-end
 145                makeinfo-temp-file nil nil)
 146
 147             ;; Else no header; insert @filename line into temporary file.
 148             (goto-char (point-min))
 149             (search-forward "@setfilename" search-end t)
 150             (beginning-of-line)
 151             (setq filename-or-header-beginning (point))
 152             (forward-line 1)
 153             (setq filename-or-header-end (point))
 154             (write-region
 155              (min filename-or-header-beginning region-beginning)
 156              filename-or-header-end
 157              makeinfo-temp-file nil nil))
 158
 159           ;; Insert the region into the file.
 160           (write-region
 161            (max region-beginning filename-or-header-end)
 162            region-end
 163            makeinfo-temp-file t nil)
 164
 165           ;; Run the `makeinfo-compile' command in the *compilation* buffer
 166           (save-excursion
 167             (makeinfo-compile
 168              (concat makeinfo-run-command
 169                      " "
 170                      makeinfo-options
 171                      " "
 172                      makeinfo-temp-file)
 173              "Use `makeinfo-buffer' to gain use of the `next-error' command"
 174              nil
 175              'makeinfo-compilation-sentinel-region)))))))
 176
 177 ;;; Actually run makeinfo.  COMMAND is the command to run.
 178 ;;; ERROR-MESSAGE is what to say when next-error can't find another error.
 179 ;;; If PARSE-ERRORS is non-nil, do try to parse error messages.
 180 (defun makeinfo-compile (command error-message parse-errors sentinel)
 181   (let ((buffer
 182          (compile-internal command error-message nil
 183                            (and (not parse-errors)
 184                                 ;; If we do want to parse errors, pass nil.
 185                                 ;; Otherwise, use this function, which won't
 186                                 ;; ever find any errors.
 187                                 (lambda (&rest ignore)
 188                                   (setq compilation-error-list nil))))))
 189     (set-process-sentinel (get-buffer-process buffer) sentinel)))
 190
 191 ;; Delete makeinfo-temp-file after processing is finished,
 192 ;; and visit Info file.
 193 ;; This function is called when the compilation process changes state.
 194 ;; Based on `compilation-sentinel' in compile.el
 195 (defun makeinfo-compilation-sentinel-region (proc msg)
 196   "Sentinel for `makeinfo-compile' run from `makeinfo-region'."
 197   (compilation-sentinel proc msg)
 198   (when (memq (process-status proc) '(signal exit))
 199     (if (file-exists-p makeinfo-temp-file)
 200         (delete-file makeinfo-temp-file))
 201     ;; Always use the version on disk.
 202     (let ((buffer (get-file-buffer makeinfo-output-file-name)))
 203       (if buffer
 204           (with-current-buffer buffer
 205             (revert-buffer t t))
 206         (setq buffer (find-file-noselect makeinfo-output-file-name)))
 207       (if (window-dedicated-p (selected-window))
 208           (switch-to-buffer-other-window buffer)
 209         (switch-to-buffer buffer)))
 210     (goto-char (point-min))))
 211
 212 (defun makeinfo-current-node ()
 213   "Return the name of the node containing point, in a texinfo file."
 214   (save-excursion
 215     (end-of-line)           ; in case point is at the start of an @node line
 216     (if (re-search-backward "^@node\\s-+\\([^,\n]+\\)" (point-min) t)
 217         (match-string 1)
 218       "Top")))
 219
 220 (defun makeinfo-buffer ()
 221   "Make Info file from current buffer.
 222
 223 Use the \\[next-error] command to move to the next error
 224 \(if there are errors\)."
 225
 226   (interactive)
 227   (cond ((null buffer-file-name)
 228          (error "Buffer not visiting any file"))
 229         ((buffer-modified-p)
 230          (if (y-or-n-p "Buffer modified; do you want to save it? ")
 231              (save-buffer))))
 232
 233   ;; Find and record the Info filename,
 234   ;; or else explain that a filename is needed.
 235   (save-excursion
 236     (goto-char (point-min))
 237     (let ((search-end (save-excursion (forward-line 100) (point))))
 238       (if (re-search-forward
 239            "^@setfilename[ \t]+\\([^ \t\n]+\\)[ \t]*"
 240            search-end t)
 241           (setq makeinfo-output-file-name
 242                 (expand-file-name
 243                  (buffer-substring (match-beginning 1) (match-end 1))))
 244         (error
 245          "The texinfo file needs a line saying: @setfilename <name>"))))
 246   (setq makeinfo-output-node-name (makeinfo-current-node))
 247
 248   (save-excursion
 249     (makeinfo-compile
 250      (concat makeinfo-run-command " " makeinfo-options
 251              " " buffer-file-name)
 252      "No more errors."
 253      t
 254      'makeinfo-compilation-sentinel-buffer)))
 255
 256 (defun makeinfo-compilation-sentinel-buffer (proc msg)
 257   "Sentinel for `makeinfo-compile' run from `makeinfo-buffer'."
 258   (compilation-sentinel proc msg)
 259   (when (memq (process-status proc) '(signal exit))
 260     (when (file-exists-p makeinfo-output-file-name)
 261       (Info-revert-find-node
 262        makeinfo-output-file-name makeinfo-output-node-name))))
 263
 264 (defun makeinfo-recenter-compilation-buffer (linenum)
 265   "Redisplay `*compilation*' buffer so most recent output can be seen.
 266 The last line of the buffer is displayed on
 267 line LINE of the window, or centered if LINE is nil."
 268   (interactive "P")
 269   (let ((makeinfo-buffer (get-buffer "*compilation*"))
 270         (old-buffer (current-buffer)))
 271     (if (null makeinfo-buffer)
 272         (message "No *compilation* buffer")
 273       (pop-to-buffer makeinfo-buffer)
 274       (bury-buffer makeinfo-buffer)
 275       (goto-char (point-max))
 276       (recenter (if linenum
 277                     (prefix-numeric-value linenum)
 278                   (/ (window-height) 2)))
 279       (pop-to-buffer old-buffer)
 280       )))
 281
 282 ;;; Place `provide' at end of file.
 283 (provide 'makeinfo)
 284
 285 ;;; arch-tag: 5f810713-3de2-4e20-8030-4bc3dd0d9604
 286 ;;; makeinfo.el ends here