lisp/diff.el

   1 ;;; diff.el --- run `diff' in compilation-mode
   2
   3 ;; Copyright (C) 1992, 1994, 1996, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: unix, tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package helps you explore differences between files, using the
  28 ;; UNIX command diff(1).  The commands are `diff' and `diff-backup'.
  29 ;; You can specify options with `diff-switches'.
  30
  31 ;;; Code:
  32
  33 (require 'compile)
  34
  35 (defgroup diff nil
  36   "Comparing files with `diff'."
  37   :group 'tools)
  38
  39 ;;;###autoload
  40 (defcustom diff-switches "-c"
  41   "*A string or list of strings specifying switches to be be passed to diff."
  42   :type '(choice string (repeat string))
  43   :group 'diff)
  44
  45 ;;;###autoload
  46 (defcustom diff-command "diff"
  47   "*The command to use to run diff."
  48   :type 'string
  49   :group 'diff)
  50
  51 (defvar diff-regexp-alist
  52   '(
  53     ;; -u format: @@ -OLDSTART,OLDEND +NEWSTART,NEWEND @@
  54     ("^@@ -\\([0-9]+\\),[0-9]+ \\+\\([0-9]+\\),[0-9]+ @@$" 1 2)
  55
  56     ;; -c format: *** OLDSTART,OLDEND ****
  57     ("^\\*\\*\\* \\([0-9]+\\),[0-9]+ \\*\\*\\*\\*$" 1 nil)
  58     ;;            --- NEWSTART,NEWEND ----
  59     ("^--- \\([0-9]+\\),[0-9]+ ----$" nil 1)
  60
  61     ;; plain diff format: OLDSTART[,OLDEND]{a,d,c}NEWSTART[,NEWEND]
  62     ("^\\([0-9]+\\)\\(,[0-9]+\\)?[adc]\\([0-9]+\\)\\(,[0-9]+\\)?$" 1 3)
  63
  64     ;; -e (ed) format: OLDSTART[,OLDEND]{a,d,c}
  65     ("^\\([0-9]+\\)\\(,[0-9]+\\)?[adc]$" 1)
  66
  67     ;; -f format: {a,d,c}OLDSTART[ OLDEND]
  68     ;; -n format: {a,d,c}OLDSTART LINES-CHANGED
  69     ("^[adc]\\([0-9]+\\)\\( [0-9]+\\)?$" 1)
  70     )
  71   "Alist of regular expressions to match difference sections in \\[diff] output.
  72 Each element has the form (REGEXP OLD-IDX NEW-IDX).
  73 Any text that REGEXP matches identifies one difference hunk
  74 or the header of a hunk.
  75
  76 The OLD-IDX'th subexpression of REGEXP gives the line number
  77 in the old file, and NEW-IDX'th subexpression gives the line number
  78 in the new file.  If OLD-IDX or NEW-IDX
  79 is nil, REGEXP matches only half a hunk.")
  80
  81 (defvar diff-old-file nil
  82   "This is the old file name in the comparison in this buffer.")
  83 (defvar diff-new-file nil
  84   "This is the new file name in the comparison in this buffer.")
  85 (defvar diff-old-temp-file nil
  86   "This is the name of a temp file to be deleted after diff finishes.")
  87 (defvar diff-new-temp-file nil
  88   "This is the name of a temp file to be deleted after diff finishes.")
  89
  90 ;; See compilation-parse-errors-function (compile.el).
  91 (defun diff-parse-differences (limit-search find-at-least)
  92   (setq compilation-error-list nil)
  93   (message "Parsing differences...")
  94
  95   ;; Don't reparse diffs already seen at last parse.
  96   (if compilation-parsing-end (goto-char compilation-parsing-end))
  97
  98   ;; Construct in REGEXP a regexp composed of all those in dired-regexp-alist.
  99   (let ((regexp (mapconcat (lambda (elt)
 100                              (concat "\\(" (car elt) "\\)"))
 101                            diff-regexp-alist
 102                            "\\|"))
 103         ;; (GROUP-IDX OLD-IDX NEW-IDX)
 104         (groups (let ((subexpr 1))
 105                   (mapcar (lambda (elt)
 106                             (prog1
 107                                 (cons subexpr
 108                                       (mapcar (lambda (n)
 109                                                 (and n
 110                                                      (+ subexpr n)))
 111                                               (cdr elt)))
 112                               (setq subexpr (+ subexpr 1
 113                                                (count-regexp-groupings
 114                                                 (car elt))))))
 115                           diff-regexp-alist)))
 116
 117         (new-error
 118          (function (lambda (file subexpr)
 119                      (setq compilation-error-list
 120                            (cons
 121                             (list (save-excursion
 122                                     ;; Report location of message
 123                                     ;; at beginning of line.
 124                                     (goto-char
 125                                      (match-beginning subexpr))
 126                                     (beginning-of-line)
 127                                     (point-marker))
 128                                   ;; Report location of corresponding text.
 129                                   (list file nil)
 130                                   (string-to-int
 131                                    (buffer-substring
 132                                     (match-beginning subexpr)
 133                                     (match-end subexpr)))
 134                                   nil)
 135                             compilation-error-list)))))
 136
 137         (found-desired nil)
 138         (num-loci-found 0)
 139         g)
 140
 141     (while (and (not found-desired)
 142                 ;; We don't just pass LIMIT-SEARCH to re-search-forward
 143                 ;; because we want to find matches containing LIMIT-SEARCH
 144                 ;; but which extend past it.
 145                 (re-search-forward regexp nil t))
 146
 147       ;; Find which individual regexp matched.
 148       (setq g groups)
 149       (while (and g (null (match-beginning (car (car g)))))
 150         (setq g (cdr g)))
 151       (setq g (car g))
 152
 153       (if (nth 1 g)                     ;OLD-IDX
 154           (funcall new-error diff-old-file (nth 1 g)))
 155       (if (nth 2 g)                     ;NEW-IDX
 156           (funcall new-error diff-new-file (nth 2 g)))
 157
 158       (setq num-loci-found (1+ num-loci-found))
 159       (if (or (and find-at-least
 160                    (>= num-loci-found find-at-least))
 161               (and limit-search (>= (point) limit-search)))
 162               ;; We have found as many new loci as the user wants,
 163               ;; or the user wanted a specific diff, and we're past it.
 164           (setq found-desired t)))
 165     (set-marker compilation-parsing-end
 166                 (if found-desired (point)
 167                   ;; Set to point-max, not point, so we don't perpetually
 168                   ;; parse the last bit of text when it isn't a diff header.
 169                   (point-max)))
 170     (message "Parsing differences...done"))
 171   (setq compilation-error-list (nreverse compilation-error-list)))
 172
 173 (defun diff-process-setup ()
 174   "Set up \`compilation-exit-message-function' for \`diff'."
 175   ;; Avoid frightening people with "abnormally terminated"
 176   ;; if diff finds differences.
 177   (set (make-local-variable 'compilation-exit-message-function)
 178        (lambda (status code msg)
 179          (cond ((not (eq status 'exit))
 180                 (cons msg code))
 181                ((zerop code)
 182                 '("finished (no differences)\n" . "no differences"))
 183                ((= code 1)
 184                 '("finished\n" . "differences found"))
 185                (t
 186                 (cons msg code))))))
 187
 188 ;;;###autoload
 189 (defun diff (old new &optional switches no-async)
 190   "Find and display the differences between OLD and NEW files.
 191 Interactively the current buffer's file name is the default for NEW
 192 and a backup file for NEW is the default for OLD.
 193 With prefix arg, prompt for diff switches.
 194 If NO-ASYNC is non-nil, call diff synchronously."
 195   (interactive
 196    (nconc
 197     (let (oldf newf)
 198       (nreverse
 199        (list
 200         (setq newf (buffer-file-name)
 201               newf (if (and newf (file-exists-p newf))
 202                        (read-file-name
 203                         (concat "Diff new file: (default "
 204                                 (file-name-nondirectory newf) ") ")
 205                         nil newf t)
 206                      (read-file-name "Diff new file: " nil nil t)))
 207         (setq oldf (file-newest-backup newf)
 208               oldf (if (and oldf (file-exists-p oldf))
 209                        (read-file-name
 210                         (concat "Diff original file: (default "
 211                                 (file-name-nondirectory oldf) ") ")
 212                         (file-name-directory oldf) oldf t)
 213                      (read-file-name "Diff original file: "
 214                                      (file-name-directory newf) nil t))))))
 215     (if current-prefix-arg
 216         (list (read-string "Diff switches: "
 217                            (if (stringp diff-switches)
 218                                diff-switches
 219                              (mapconcat 'identity diff-switches " "))))
 220       nil)))
 221   (setq new (expand-file-name new)
 222         old (expand-file-name old))
 223   (let ((old-alt (file-local-copy old))
 224         (new-alt (file-local-copy new))
 225         buf)
 226     (save-excursion
 227         (let ((compilation-process-setup-function 'diff-process-setup)
 228               (command
 229                (mapconcat 'identity
 230                           (append (list diff-command)
 231                                   ;; Use explicitly specified switches
 232                                   (if switches
 233                                       (if (consp switches)
 234                                           switches (list switches))
 235                                     ;; If not specified, use default.
 236                                     (if (consp diff-switches)
 237                                         diff-switches
 238                                       (list diff-switches)))
 239                                   (if (or old-alt new-alt)
 240                                       (list "-L" old "-L" new))
 241                                   (list
 242                                    (shell-quote-argument (or old-alt old)))
 243                                   (list
 244                                    (shell-quote-argument (or new-alt new))))
 245                           " ")))
 246           (setq buf
 247                 (compile-internal command
 248                                   "No more differences" "Diff"
 249                                   'diff-parse-differences
 250                                   nil nil nil nil nil nil no-async))
 251           (set-buffer buf)
 252           (set (make-local-variable 'diff-old-file) old)
 253           (set (make-local-variable 'diff-new-file) new)
 254           (set (make-local-variable 'diff-old-temp-file) old-alt)
 255           (set (make-local-variable 'diff-new-temp-file) new-alt)
 256           (set (make-local-variable 'compilation-finish-function)
 257                (function (lambda (buff msg)
 258                            (if diff-old-temp-file
 259                                (delete-file diff-old-temp-file))
 260                            (if diff-new-temp-file
 261                                (delete-file diff-new-temp-file)))))
 262           ;; When async processes aren't available, the compilation finish
 263           ;; function doesn't get chance to run.  Invoke it by hand.
 264           (or (fboundp 'start-process)
 265               (funcall compilation-finish-function nil nil))
 266           buf))))
 267
 268 ;;;###autoload
 269 (defun diff-backup (file &optional switches)
 270   "Diff this file with its backup file or vice versa.
 271 Uses the latest backup, if there are several numerical backups.
 272 If this file is a backup, diff it with its original.
 273 The backup file is the first file given to `diff'."
 274   (interactive (list (read-file-name "Diff (file with backup): ")
 275                      (if current-prefix-arg
 276                          (read-string "Diff switches: "
 277                                       (if (stringp diff-switches)
 278                                           diff-switches
 279                                         (mapconcat 'identity
 280                                                    diff-switches " ")))
 281                        nil)))
 282   (let (bak ori)
 283     (if (backup-file-name-p file)
 284         (setq bak file
 285               ori (file-name-sans-versions file))
 286       (setq bak (or (diff-latest-backup-file file)
 287                     (error "No backup found for %s" file))
 288             ori file))
 289     (diff bak ori switches)))
 290
 291 (defun diff-latest-backup-file (fn)     ; actually belongs into files.el
 292   "Return the latest existing backup of FILE, or nil."
 293   (let ((handler (find-file-name-handler fn 'diff-latest-backup-file)))
 294     (if handler
 295         (funcall handler 'diff-latest-backup-file fn)
 296       (file-newest-backup fn))))
 297
 298 (provide 'diff)
 299
 300 ;;; arch-tag: 7de2c29b-7ea5-4b85-9b9d-72dd860de2bd
 301 ;;; diff.el ends here