lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer.
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the sorting facilities documented in the Emacs
  29 ;; user's manual.
  30
  31 ;;; Code:
  32
  33 (defgroup sort nil
  34   "Commands to sort text in an Emacs buffer."
  35   :group 'data)
  36
  37 (defcustom sort-fold-case nil
  38   "*Non-nil if the buffer sort functions should ignore case."
  39   :group 'sort
  40   :type 'boolean)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  44   "General text sorting routine to divide buffer into records and sort them.
  45 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  46
  47 We divide the accessible portion of the buffer into disjoint pieces
  48 called sort records.  A portion of each sort record (perhaps all of
  49 it) is designated as the sort key.  The records are rearranged in the
  50 buffer in order by their sort keys.  The records may or may not be
  51 contiguous.
  52
  53 Usually the records are rearranged in order of ascending sort key.
  54 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  55 The variable `sort-fold-case' determines whether alphabetic case affects
  56 the sort order.
  57
  58 The next four arguments are functions to be called to move point
  59 across a sort record.  They will be called many times from within sort-subr.
  60
  61 NEXTRECFUN is called with point at the end of the previous record.
  62 It moves point to the start of the next record.
  63 It should move point to the end of the buffer if there are no more records.
  64 The first record is assumed to start at the position of point when sort-subr
  65 is called.
  66
  67 ENDRECFUN is called with point within the record.
  68 It should move point to the end of the record.
  69
  70 STARTKEYFUN moves from the start of the record to the start of the key.
  71 It may return either a non-nil value to be used as the key, or
  72 else the key is the substring between the values of point after
  73 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  74 starts at the beginning of the record.
  75
  76 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  77 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  78 same as ENDRECFUN."
  79   ;; Heuristically try to avoid messages if sorting a small amt of text.
  80   (let ((messages (> (- (point-max) (point-min)) 50000)))
  81     (save-excursion
  82       (if messages (message "Finding sort keys..."))
  83       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  84                                            startkeyfun endkeyfun))
  85              (old (reverse sort-lists))
  86              (case-fold-search sort-fold-case))
  87         (if (null sort-lists)
  88             ()
  89           (or reverse (setq sort-lists (nreverse sort-lists)))
  90           (if messages (message "Sorting records..."))
  91           (setq sort-lists
  92                 (if (fboundp 'sortcar)
  93                     (sortcar sort-lists
  94                              (cond ((numberp (car (car sort-lists)))
  95                                     ;; This handles both ints and floats.
  96                                     '<)
  97                                    ((consp (car (car sort-lists)))
  98                                     (function
  99                                      (lambda (a b)
 100                                        (> 0 (compare-buffer-substrings
 101                                              nil (car a) (cdr a)
 102                                              nil (car b) (cdr b))))))
 103                                    (t
 104                                     'string<)))
 105                   (sort sort-lists
 106                         (cond ((numberp (car (car sort-lists)))
 107                                'car-less-than-car)
 108                               ((consp (car (car sort-lists)))
 109                                (function
 110                                 (lambda (a b)
 111                                   (> 0 (compare-buffer-substrings
 112                                         nil (car (car a)) (cdr (car a))
 113                                         nil (car (car b)) (cdr (car b)))))))
 114                               (t
 115                                (function
 116                                 (lambda (a b)
 117                                   (string< (car a) (car b)))))))))
 118           (if reverse (setq sort-lists (nreverse sort-lists)))
 119           (if messages (message "Reordering buffer..."))
 120           (sort-reorder-buffer sort-lists old)))
 121       (if messages (message "Reordering buffer... Done"))))
 122   nil)
 123
 124 ;; Parse buffer into records using the arguments as Lisp expressions;
 125 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 126 ;; where KEY is the sort key (a number or string),
 127 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 128
 129 ;; The records appear in the list lastmost first!
 130
 131 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 132   (let ((sort-lists ())
 133         (start-rec nil)
 134         done key)
 135     ;; Loop over sort records.
 136     ;(goto-char (point-min)) -- it is the caller's responsibility to
 137     ;arrange this if necessary
 138     (while (not (eobp))
 139       (setq start-rec (point))          ;save record start
 140       (setq done nil)
 141       ;; Get key value, or move to start of key.
 142       (setq key (catch 'key
 143                   (or (and startkeyfun (funcall startkeyfun))
 144                       ;; If key was not returned as value,
 145                       ;; move to end of key and get key from the buffer.
 146                       (let ((start (point)))
 147                         (funcall (or endkeyfun
 148                                      (prog1 endrecfun (setq done t))))
 149                         (cons start (point))))))
 150       ;; Move to end of this record (start of next one, or end of buffer).
 151       (cond ((prog1 done (setq done nil)))
 152             (endrecfun (funcall endrecfun))
 153             (nextrecfun (funcall nextrecfun) (setq done t)))
 154       (if key (setq sort-lists (cons
 155                                  ;; consing optimization in case in which key
 156                                  ;; is same as record.
 157                                  (if (and (consp key)
 158                                           (equal (car key) start-rec)
 159                                           (equal (cdr key) (point)))
 160                                      (cons key key)
 161                                    (cons key (cons start-rec (point))))
 162                                  sort-lists)))
 163       (and (not done) nextrecfun (funcall nextrecfun)))
 164     sort-lists))
 165
 166 (defun sort-reorder-buffer (sort-lists old)
 167   (let ((inhibit-quit t)
 168         (last (point-min))
 169         (min (point-min)) (max (point-max)))
 170     ;; Make sure insertions done for reordering
 171     ;; do not go after any markers at the end of the sorted region,
 172     ;; by inserting a space to separate them.
 173     (goto-char (point-max))
 174     (insert-before-markers " ")
 175     (narrow-to-region min (1- (point-max)))
 176     (while sort-lists
 177       (goto-char (point-max))
 178       (insert-buffer-substring (current-buffer)
 179                                last
 180                                (nth 1 (car old)))
 181       (goto-char (point-max))
 182       (insert-buffer-substring (current-buffer)
 183                                (nth 1 (car sort-lists))
 184                                (cdr (cdr (car sort-lists))))
 185       (setq last (cdr (cdr (car old)))
 186             sort-lists (cdr sort-lists)
 187             old (cdr old)))
 188     (goto-char (point-max))
 189     (insert-buffer-substring (current-buffer)
 190                              last
 191                              max)
 192     ;; Delete the original copy of the text.
 193     (delete-region min max)
 194     ;; Get rid of the separator " ".
 195     (goto-char (point-max))
 196     (narrow-to-region min (1+ (point)))
 197     (delete-region (point) (1+ (point)))))
 198
 199 ;;;###autoload
 200 (defun sort-lines (reverse beg end)
 201   "Sort lines in region alphabetically; argument means descending order.
 202 Called from a program, there are three arguments:
 203 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 204 The variable `sort-fold-case' determines whether alphabetic case affects
 205 the sort order."
 206   (interactive "P\nr")
 207   (save-excursion
 208     (save-restriction
 209       (narrow-to-region beg end)
 210       (goto-char (point-min))
 211       (sort-subr reverse 'forward-line 'end-of-line))))
 212
 213 ;;;###autoload
 214 (defun sort-paragraphs (reverse beg end)
 215   "Sort paragraphs in region alphabetically; argument means descending order.
 216 Called from a program, there are three arguments:
 217 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 218 The variable `sort-fold-case' determines whether alphabetic case affects
 219 the sort order."
 220   (interactive "P\nr")
 221   (save-excursion
 222     (save-restriction
 223       (narrow-to-region beg end)
 224       (goto-char (point-min))
 225       (sort-subr reverse
 226                  (function
 227                   (lambda ()
 228                     (while (and (not (eobp)) (looking-at paragraph-separate))
 229                       (forward-line 1))))
 230                  'forward-paragraph))))
 231
 232 ;;;###autoload
 233 (defun sort-pages (reverse beg end)
 234   "Sort pages in region alphabetically; argument means descending order.
 235 Called from a program, there are three arguments:
 236 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 237 The variable `sort-fold-case' determines whether alphabetic case affects
 238 the sort order."
 239   (interactive "P\nr")
 240   (save-excursion
 241     (save-restriction
 242       (narrow-to-region beg end)
 243       (goto-char (point-min))
 244       (sort-subr reverse
 245                  (function (lambda () (skip-chars-forward "\n")))
 246                  'forward-page))))
 247 \f
 248 (defvar sort-fields-syntax-table nil)
 249 (if sort-fields-syntax-table nil
 250   (let ((table (make-syntax-table))
 251         (i 0))
 252     (while (< i 256)
 253       (modify-syntax-entry i "w" table)
 254       (setq i (1+ i)))
 255     (modify-syntax-entry ?\  " " table)
 256     (modify-syntax-entry ?\t " " table)
 257     (modify-syntax-entry ?\n " " table)
 258     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 259     (setq sort-fields-syntax-table table)))
 260
 261 (defcustom sort-numeric-base 10
 262   "*The default base used by `sort-numeric-fields'."
 263   :group 'sort
 264   :type 'integer)
 265
 266 ;;;###autoload
 267 (defun sort-numeric-fields (field beg end)
 268   "Sort lines in region numerically by the ARGth field of each line.
 269 Fields are separated by whitespace and numbered from 1 up.
 270 Specified field must contain a number in each line of the region,
 271 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 272 Otherwise, the number is interpreted according to sort-numeric-base.
 273 With a negative arg, sorts by the ARGth field counted from the right.
 274 Called from a program, there are three arguments:
 275 FIELD, BEG and END.  BEG and END specify region to sort."
 276   (interactive "p\nr")
 277   (sort-fields-1 field beg end
 278                  (lambda ()
 279                    (sort-skip-fields field)
 280                    (let* ((case-fold-search t)
 281                           (base
 282                            (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 283                                (cond ((match-beginning 1)
 284                                       (goto-char (match-end 1))
 285                                       16)
 286                                      ((match-beginning 2)
 287                                       (goto-char (match-end 2))
 288                                       8)
 289                                      (t nil)))))
 290                      (string-to-number (buffer-substring (point)
 291                                                          (save-excursion
 292                                                            (forward-sexp 1)
 293                                                            (point)))
 294                                        (or base sort-numeric-base))))
 295                  nil))
 296
 297 ;;;;;###autoload
 298 ;;(defun sort-float-fields (field beg end)
 299 ;;  "Sort lines in region numerically by the ARGth field of each line.
 300 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 301 ;;must contain a floating point number in each line of the region.  With a
 302 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 303 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 304 ;;region to sort."
 305 ;;  (interactive "p\nr")
 306 ;;  (sort-fields-1 field beg end
 307 ;;               (function (lambda ()
 308 ;;                           (sort-skip-fields field)
 309 ;;                           (string-to-number
 310 ;;                            (buffer-substring
 311 ;;                             (point)
 312 ;;                             (save-excursion
 313 ;;                               (re-search-forward
 314 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 315 ;;                               (point))))))
 316 ;;               nil))
 317
 318 ;;;###autoload
 319 (defun sort-fields (field beg end)
 320   "Sort lines in region lexicographically by the ARGth field of each line.
 321 Fields are separated by whitespace and numbered from 1 up.
 322 With a negative arg, sorts by the ARGth field counted from the right.
 323 Called from a program, there are three arguments:
 324 FIELD, BEG and END.  BEG and END specify region to sort.
 325 The variable `sort-fold-case' determines whether alphabetic case affects
 326 the sort order."
 327   (interactive "p\nr")
 328   (sort-fields-1 field beg end
 329                  (function (lambda ()
 330                              (sort-skip-fields field)
 331                              nil))
 332                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 333
 334 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 335   (let ((tbl (syntax-table)))
 336     (if (zerop field) (setq field 1))
 337     (unwind-protect
 338         (save-excursion
 339           (save-restriction
 340             (narrow-to-region beg end)
 341             (goto-char (point-min))
 342             (set-syntax-table sort-fields-syntax-table)
 343             (sort-subr nil
 344                        'forward-line 'end-of-line
 345                        startkeyfun endkeyfun)))
 346       (set-syntax-table tbl))))
 347
 348 ;; Position at the beginning of field N on the current line,
 349 ;; assuming point is initially at the beginning of the line.
 350 (defun sort-skip-fields (n)
 351   (if (> n 0)
 352       ;; Skip across N - 1 fields.
 353       (let ((i (1- n)))
 354         (while (> i 0)
 355           (skip-chars-forward " \t")
 356           (skip-chars-forward "^ \t\n")
 357           (setq i (1- i)))
 358         (skip-chars-forward " \t")
 359         (if (eolp)
 360             (error "Line has too few fields: %s"
 361                    (buffer-substring
 362                     (save-excursion (beginning-of-line) (point))
 363                     (save-excursion (end-of-line) (point))))))
 364     (end-of-line)
 365     ;; Skip back across - N - 1 fields.
 366     (let ((i (1- (- n))))
 367       (while (> i 0)
 368         (skip-chars-backward " \t")
 369         (skip-chars-backward "^ \t\n")
 370         (setq i (1- i)))
 371       (skip-chars-backward " \t"))
 372     (if (bolp)
 373         (error "Line has too few fields: %s"
 374                (buffer-substring
 375                 (save-excursion (beginning-of-line) (point))
 376                 (save-excursion (end-of-line) (point)))))
 377     ;; Position at the front of the field
 378     ;; even if moving backwards.
 379     (skip-chars-backward "^ \t\n")))
 380 \f
 381 (defvar sort-regexp-fields-regexp)
 382 (defvar sort-regexp-record-end)
 383
 384 ;; Move to the beginning of the next match for record-regexp,
 385 ;; and set sort-regexp-record-end to the end of that match.
 386 ;; If the next match is empty and does not advance point,
 387 ;; skip one character and try again.
 388 (defun sort-regexp-fields-next-record ()
 389   (let ((oldpos (point)))
 390     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 391          (setq sort-regexp-record-end (match-end 0))
 392          (if (= sort-regexp-record-end oldpos)
 393              (progn
 394                (forward-char 1)
 395                (re-search-forward sort-regexp-fields-regexp nil 'move)
 396                (setq sort-regexp-record-end (match-end 0)))
 397            t)
 398          (goto-char (match-beginning 0)))))
 399
 400 ;;;###autoload
 401 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 402   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 403 RECORD-REGEXP specifies the textual units which should be sorted.
 404   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 405 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 406   is to be used for sorting.
 407   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 408   RECORD-REGEXP is used.
 409   If it is \"\\\\&\" then the whole record is used.
 410   Otherwise, it is a regular-expression for which to search within the record.
 411 If a match for KEY is not found within a record then that record is ignored.
 412
 413 With a negative prefix arg sorts in reverse order.
 414
 415 The variable `sort-fold-case' determines whether alphabetic case affects
 416 the sort order.
 417
 418 For example: to sort lines in the region by the first word on each line
 419  starting with the letter \"f\",
 420  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 421   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 422   ;; other sort-.*fields functions but then again this was before, since it
 423   ;; didn't use the magnitude of the arg to specify anything.
 424   (interactive "P\nsRegexp specifying records to sort:
 425 sRegexp specifying key within record: \nr")
 426   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 427          (setq key-regexp 0))
 428         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 429          (setq key-regexp (- (aref key-regexp 1) ?0))))
 430   (save-excursion
 431     (save-restriction
 432       (narrow-to-region beg end)
 433       (goto-char (point-min))
 434       (let (sort-regexp-record-end
 435             (sort-regexp-fields-regexp record-regexp))
 436         (re-search-forward sort-regexp-fields-regexp)
 437         (setq sort-regexp-record-end (point))
 438         (goto-char (match-beginning 0))
 439         (sort-subr reverse
 440                    'sort-regexp-fields-next-record
 441                    (function (lambda ()
 442                                (goto-char sort-regexp-record-end)))
 443                    (function (lambda ()
 444                                (let ((n 0))
 445                                  (cond ((numberp key-regexp)
 446                                         (setq n key-regexp))
 447                                        ((re-search-forward
 448                                           key-regexp sort-regexp-record-end t)
 449                                         (setq n 0))
 450                                        (t (throw 'key nil)))
 451                                  (condition-case ()
 452                                      (cons (match-beginning n)
 453                                            (match-end n))
 454                                    ;; if there was no such register
 455                                    (error (throw 'key nil)))))))))))
 456
 457 \f
 458 (defvar sort-columns-subprocess t)
 459
 460 ;;;###autoload
 461 (defun sort-columns (reverse &optional beg end)
 462   "Sort lines in region alphabetically by a certain range of columns.
 463 For the purpose of this command, the region BEG...END includes
 464 the entire line that point is in and the entire line the mark is in.
 465 The column positions of point and mark bound the range of columns to sort on.
 466 A prefix argument means sort into REVERSE order.
 467 The variable `sort-fold-case' determines whether alphabetic case affects
 468 the sort order.
 469
 470 Note that `sort-columns' rejects text that contains tabs,
 471 because tabs could be split across the specified columns
 472 and it doesn't know how to handle that.  Also, when possible,
 473 it uses the `sort' utility program, which doesn't understand tabs.
 474 Use \\[untabify] to convert tabs to spaces before sorting."
 475   (interactive "P\nr")
 476   (save-excursion
 477     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 478       (goto-char (min beg end))
 479       (setq col-beg1 (current-column))
 480       (beginning-of-line)
 481       (setq beg1 (point))
 482       (goto-char (max beg end))
 483       (setq col-end1 (current-column))
 484       (forward-line)
 485       (setq end1 (point))
 486       (setq col-start (min col-beg1 col-end1))
 487       (setq col-end (max col-beg1 col-end1))
 488       (if (search-backward "\t" beg1 t)
 489           (error "sort-columns does not work with tabs.  Use M-x untabify"))
 490       (if (not (or (eq system-type 'vax-vms)
 491                    (text-properties-at beg1)
 492                    (< (next-property-change beg1 nil end1) end1)))
 493           ;; Use the sort utility if we can; it is 4 times as fast.
 494           ;; Do not use it if there are any properties in the region,
 495           ;; since the sort utility would lose the properties.
 496           (let ((sort-args (list (if reverse "-rt\n" "-t\n")
 497                                  (concat "+0." (int-to-string col-start))
 498                                  (concat "-0." (int-to-string col-end)))))
 499             (when sort-fold-case
 500               (push "-f" sort-args))
 501             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 502         ;; On VMS, use Emacs's own facilities.
 503         (save-excursion
 504           (save-restriction
 505             (narrow-to-region beg1 end1)
 506             (goto-char beg1)
 507             (sort-subr reverse 'forward-line 'end-of-line
 508                        #'(lambda () (move-to-column col-start) nil)
 509                        #'(lambda () (move-to-column col-end) nil))))))))
 510
 511 ;;;###autoload
 512 (defun reverse-region (beg end)
 513   "Reverse the order of lines in a region.
 514 From a program takes two point or marker arguments, BEG and END."
 515   (interactive "r")
 516   (if (> beg end)
 517       (let (mid) (setq mid end end beg beg mid)))
 518   (save-excursion
 519     ;; put beg at the start of a line and end and the end of one --
 520     ;; the largest possible region which fits this criteria
 521     (goto-char beg)
 522     (or (bolp) (forward-line 1))
 523     (setq beg (point))
 524     (goto-char end)
 525     ;; the test for bolp is for those times when end is on an empty line;
 526     ;; it is probably not the case that the line should be included in the
 527     ;; reversal; it isn't difficult to add it afterward.
 528     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 529     (setq end (point-marker))
 530     ;; the real work.  this thing cranks through memory on large regions.
 531     (let (ll (do t))
 532       (while do
 533         (goto-char beg)
 534         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 535                        ll))
 536         (setq do (/= (point) end))
 537         (delete-region beg (if do (1+ (point)) (point))))
 538       (while (cdr ll)
 539         (insert (car ll) "\n")
 540         (setq ll (cdr ll)))
 541       (insert (car ll)))))
 542
 543 (provide 'sort)
 544
 545 ;;; sort.el ends here