lisp/gnus/rfc2104.el

   1 ;;; rfc2104.el --- RFC2104 Hashed Message Authentication Codes
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a high performance implementation of RFC2104.
  27 ;;
  28 ;; Example:
  29 ;;
  30 ;; (require 'md5)
  31 ;; (rfc2104-hash 'md5 64 16 "Jefe" "what do ya want for nothing?")
  32 ;; "750c783e6ab0b503eaa86e310a5db738"
  33 ;;
  34 ;; (require 'sha1)
  35 ;; (rfc2104-hash 'sha1 64 20 "Jefe" "what do ya want for nothing?")
  36 ;; "effcdf6ae5eb2fa2d27416d5f184df9c259a7c79"
  37 ;;
  38 ;; 64 is block length of hash function (64 for MD5 and SHA), 16 is
  39 ;; resulting hash length (16 for MD5, 20 for SHA).
  40 ;;
  41 ;; Tested with Emacs 20.2 and XEmacs 20.3.
  42 ;;
  43 ;; Test case reference: RFC 2202.
  44
  45 ;;; History:
  46
  47 ;; 1998-08-16  initial release posted to gnu.emacs.sources
  48 ;; 1998-08-17  use append instead of char-list-to-string
  49 ;; 1998-08-26  don't require hexl
  50 ;; 1998-09-25  renamed from hmac.el to rfc2104.el, also renamed functions
  51 ;; 1999-10-23  included in pgnus
  52 ;; 2000-08-15  `rfc2104-hexstring-to-bitstring'
  53 ;; 2000-05-12  added sha-1 example, added test case reference
  54 ;; 2003-11-13  change rfc2104-hexstring-to-bitstring to ...-byte-list
  55 ;; 2008-04-25  rewrite rfc2104-hash for speed
  56
  57 ;;; Code:
  58
  59 (eval-when-compile (require 'cl))
  60
  61 ;; Magic character for inner HMAC round. 0x36 == 54 == '6'
  62 (defconst rfc2104-ipad ?\x36)
  63
  64 ;; Magic character for outer HMAC round. 0x5C == 92 == '\'
  65 (defconst rfc2104-opad ?\x5C)
  66
  67 (defconst rfc2104-nybbles
  68   (let ((v (make-vector
  69             ;; Find upper bound to save some space.
  70             (1+ (max ?0 ?9 ?a ?f ?A ?F))
  71             ;; Use non-numeric default to catch bogus hex strings.
  72             nil))
  73         (ls '((?0 . 0)   (?a . 10)   (?A . 10)
  74               (?1 . 1)   (?b . 11)   (?B . 11)
  75               (?2 . 2)   (?c . 12)   (?C . 12)
  76               (?3 . 3)   (?d . 13)   (?D . 13)
  77               (?4 . 4)   (?e . 14)   (?E . 14)
  78               (?5 . 5)   (?f . 15)   (?F . 15)
  79               (?6 . 6)
  80               (?7 . 7)
  81               (?8 . 8)
  82               (?9 . 9))))
  83     (while ls
  84       (aset v (caar ls) (cdar ls))
  85       (setq ls (cdr ls)))
  86     v))
  87
  88 (defun rfc2104-hash (hash block-length hash-length key text)
  89   (let* (;; if key is longer than B, reset it to HASH(key)
  90          (key (if (> (length key) block-length)
  91                   (funcall hash key) key))
  92          (len (length key))
  93          (ipad (make-string    block-length              rfc2104-ipad))
  94          (opad (make-string (+ block-length hash-length) rfc2104-opad))
  95          c partial)
  96     ;; Prefix *pad with key, appropriately XORed.
  97     (do ((i 0 (1+ i)))
  98         ((= len i))
  99       (setq c (aref key i))
 100       (aset ipad i (logxor rfc2104-ipad c))
 101       (aset opad i (logxor rfc2104-opad c)))
 102     ;; Perform inner hash.
 103     (setq partial (string-make-unibyte (funcall hash (concat ipad text))))
 104     ;; Pack latter part of opad.
 105     (do ((r 0 (+ 2 r))
 106          (w block-length (1+ w)))
 107         ((= (* 2 hash-length) r))
 108       (aset opad w
 109             (+ (* 16 (aref rfc2104-nybbles (aref partial     r)))
 110                (      aref rfc2104-nybbles (aref partial (1+ r))))))
 111     ;; Perform outer hash.
 112     (string-make-unibyte (funcall hash opad))))
 113
 114 (provide 'rfc2104)
 115
 116 ;; arch-tag: cf671d5c-a45f-4a09-815e-704e59e43950
 117 ;;; rfc2104.el ends here