lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2
   3 ;; Copyright (C) 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;; Keywords: mouse frames
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With a numeric argument, if the argument is positive, turn on the
  48 tool bar; otherwise, turn off the tool bar.
  49
  50 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  51 conveniently adding tool bar items."
  52   :init-value t
  53   :global t
  54   ;; It's defined in C/cus-start, this stops the d-m-m macro defining it again.
  55   :variable tool-bar-mode
  56   (let ((val (if tool-bar-mode 1 0)))
  57     (dolist (frame (frame-list))
  58       (set-frame-parameter frame 'tool-bar-lines val))
  59     ;; If the user has given `default-frame-alist' a `tool-bar-lines'
  60     ;; parameter, replace it.
  61     (if (assq 'tool-bar-lines default-frame-alist)
  62         (setq default-frame-alist
  63               (cons (cons 'tool-bar-lines val)
  64                     (assq-delete-all 'tool-bar-lines
  65                                      default-frame-alist)))))
  66   (and tool-bar-mode
  67        (= 1 (length (default-value 'tool-bar-map))) ; not yet setup
  68        (tool-bar-setup)))
  69
  70 ;;;###autoload
  71 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  72 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  73   "Toggle tool bar on or off, based on the status of the current frame.
  74 See `tool-bar-mode' for more information."
  75   (interactive (list (or current-prefix-arg 'toggle)))
  76   (if (eq arg 'toggle)
  77       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  78     (tool-bar-mode arg)))
  79
  80 (defvar tool-bar-map (make-sparse-keymap)
  81   "Keymap for the tool bar.
  82 Define this locally to override the global tool bar.")
  83
  84 (global-set-key [tool-bar]
  85                 `(menu-item ,(purecopy "tool bar") ignore
  86                             :filter tool-bar-make-keymap))
  87
  88 (declare-function image-mask-p "image.c" (spec &optional frame))
  89
  90 (defconst tool-bar-keymap-cache (make-hash-table :weakness t :test 'equal))
  91
  92 (defun tool-bar-make-keymap (&optional _ignore)
  93   "Generate an actual keymap from `tool-bar-map'.
  94 Its main job is to figure out which images to use based on the display's
  95 color capability and based on the available image libraries."
  96   (let ((key (cons (frame-terminal) tool-bar-map)))
  97     (or (gethash key tool-bar-keymap-cache)
  98         (puthash key (tool-bar-make-keymap-1) tool-bar-keymap-cache))))
  99
 100 (defun tool-bar-make-keymap-1 ()
 101   "Generate an actual keymap from `tool-bar-map', without caching."
 102   (mapcar (lambda (bind)
 103             (let (image-exp plist)
 104               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
 105                          ;; For the format of menu-items, see node
 106                          ;; `Extended Menu Items' in the Elisp manual.
 107                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 108                                              bind))
 109                          (setq image-exp (plist-get plist :image))
 110                          (consp image-exp)
 111                          (not (eq (car image-exp) 'image))
 112                          (fboundp (car image-exp)))
 113                 (if (not (display-images-p))
 114                     (setq bind nil)
 115                   (let ((image (eval image-exp)))
 116                     (unless (and image (image-mask-p image))
 117                       (setq image (append image '(:mask heuristic))))
 118                     (setq bind (copy-sequence bind)
 119                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 120                                         bind))
 121                     (plist-put plist :image image))))
 122               bind))
 123           tool-bar-map))
 124
 125 ;;;###autoload
 126 (defun tool-bar-add-item (icon def key &rest props)
 127   "Add an item to the tool bar.
 128 ICON names the image, DEF is the key definition and KEY is a symbol
 129 for the fake function key in the menu keymap.  Remaining arguments
 130 PROPS are additional items to add to the menu item specification.  See
 131 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 132
 133 ICON is the base name of a file containing the image to use.  The
 134 function will first try to use low-color/ICON.xpm if `display-color-cells'
 135 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 136 ICON.xbm, using `find-image'.
 137
 138 Use this function only to make bindings in the global value of `tool-bar-map'.
 139 To define items in any other map, use `tool-bar-local-item'."
 140   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 141
 142 (defun tool-bar--image-expression (icon)
 143   "Return an expression that evaluates to an image spec for ICON."
 144   (let* ((fg (face-attribute 'tool-bar :foreground))
 145          (bg (face-attribute 'tool-bar :background))
 146          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 147                         (if (eq bg 'unspecified) nil (list :background bg))))
 148          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 149          (xpm-lo-spec (list :type 'xpm :file
 150                             (concat "low-color/" icon ".xpm")))
 151          (pbm-spec (append (list :type 'pbm :file
 152                                  (concat icon ".pbm")) colors))
 153          (xbm-spec (append (list :type 'xbm :file
 154                                  (concat icon ".xbm")) colors)))
 155     `(find-image (cond ((not (display-color-p))
 156                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 157                        ((< (display-color-cells) 256)
 158                         ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 159                        (t
 160                         ',(list xpm-spec pbm-spec xbm-spec))))))
 161
 162 ;;;###autoload
 163 (defun tool-bar-local-item (icon def key map &rest props)
 164   "Add an item to the tool bar in map MAP.
 165 ICON names the image, DEF is the key definition and KEY is a symbol
 166 for the fake function key in the menu keymap.  Remaining arguments
 167 PROPS are additional items to add to the menu item specification.  See
 168 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 169
 170 ICON is the base name of a file containing the image to use.  The
 171 function will first try to use low-color/ICON.xpm if `display-color-cells'
 172 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 173 ICON.xbm, using `find-image'."
 174   (let* ((image-exp (tool-bar--image-expression icon)))
 175     (define-key-after map (vector key)
 176       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 177
 178 ;;;###autoload
 179 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 180   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 181 This makes a binding for COMMAND in `tool-bar-map', copying its
 182 binding from the menu bar in MAP (which defaults to `global-map'), but
 183 modifies the binding by adding an image specification for ICON.  It
 184 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 185 properties to add to the binding.
 186
 187 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 188
 189 Use this function only to make bindings in the global value of `tool-bar-map'.
 190 To define items in any other map, use `tool-bar-local-item-from-menu'."
 191   (apply 'tool-bar-local-item-from-menu command icon
 192          (default-value 'tool-bar-map) map props))
 193
 194 ;;;###autoload
 195 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 196   "Define local tool bar binding for COMMAND using the given ICON.
 197 This makes a binding for COMMAND in IN-MAP, copying its binding from
 198 the menu bar in FROM-MAP (which defaults to `global-map'), but
 199 modifies the binding by adding an image specification for ICON.  It
 200 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 201 properties to add to the binding.
 202
 203 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 204 holds a keymap."
 205   (unless from-map
 206     (setq from-map global-map))
 207   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 208          (keys (where-is-internal command menu-bar-map))
 209          (image-exp (tool-bar--image-expression icon))
 210          submap key)
 211     ;; We'll pick up the last valid entry in the list of keys if
 212     ;; there's more than one.
 213     ;; FIXME: Aren't they *all* "valid"??  --Stef
 214     (dolist (k keys)
 215       ;; We're looking for a binding of the command in a submap of
 216       ;; the menu bar map, so the key sequence must be two or more
 217       ;; long.
 218       (if (and (vectorp k)
 219                (> (length k) 1))
 220           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 221                 ;; Last element in the bound key sequence:
 222                 (kk (aref k (1- (length k)))))
 223             (if (and (keymapp m)
 224                      (symbolp kk))
 225                 (setq submap m
 226                       key kk)))))
 227     (when (and (symbolp submap) (boundp submap))
 228       (setq submap (eval submap)))
 229     (let ((defn (assq key (cdr submap))))
 230       (if (eq (cadr defn) 'menu-item)
 231           (define-key-after in-map (vector key)
 232             (append (cdr defn) (list :image image-exp) props))
 233         (setq defn (cdr defn))
 234         (define-key-after in-map (vector key)
 235           (let ((rest (cdr defn)))
 236             ;; If the rest of the definition starts
 237             ;; with a list of menu cache info, get rid of that.
 238             (if (and (consp rest) (consp (car rest)))
 239                 (setq rest (cdr rest)))
 240             (append `(menu-item ,(car defn) ,rest)
 241                     (list :image image-exp) props)))))))
 242
 243 ;;; Set up some global items.  Additions/deletions up for grabs.
 244
 245 (defun tool-bar-setup ()
 246   (setq tool-bar-separator-image-expression
 247         (tool-bar--image-expression "separator"))
 248   (tool-bar-add-item-from-menu 'find-file "new" nil :label "New File"
 249                                :vert-only t)
 250   (tool-bar-add-item-from-menu 'menu-find-file-existing "open" nil
 251                                :label "Open" :vert-only t)
 252   (tool-bar-add-item-from-menu 'dired "diropen" nil :vert-only t)
 253   (tool-bar-add-item-from-menu 'kill-this-buffer "close" nil :vert-only t)
 254   (tool-bar-add-item-from-menu 'save-buffer "save" nil
 255                                :label "Save")
 256   (define-key-after (default-value 'tool-bar-map) [separator-1] menu-bar-separator)
 257   (tool-bar-add-item-from-menu 'undo "undo" nil)
 258   (define-key-after (default-value 'tool-bar-map) [separator-2] menu-bar-separator)
 259   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 260                                "cut" nil :vert-only t)
 261   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 262                                "copy" nil :vert-only t)
 263   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 264                                "paste" nil :vert-only t)
 265   (define-key-after (default-value 'tool-bar-map) [separator-3] menu-bar-separator)
 266   (tool-bar-add-item-from-menu 'isearch-forward "search"
 267                                nil :label "Search" :vert-only t)
 268   ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 269
 270   ;; There's no icon appropriate for News and we need a command rather
 271   ;; than a lambda for Read Mail.
 272   ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 273
 274   ;; Help button on a tool bar is rather non-standard...
 275   ;; (let ((tool-bar-map (default-value 'tool-bar-map)))
 276   ;;   (tool-bar-add-item "help" (lambda ()
 277   ;;                            (interactive)
 278   ;;                            (popup-menu menu-bar-help-menu))
 279   ;;                   'help
 280   ;;                   :help "Pop up the Help menu"))
 281 )
 282
 283 (if (featurep 'move-toolbar)
 284     (defcustom tool-bar-position 'top
 285       "Specify on which side the tool bar shall be.
 286 Possible values are `top' (tool bar on top), `bottom' (tool bar at bottom),
 287 `left' (tool bar on left) and `right' (tool bar on right).
 288 Customize `tool-bar-mode' if you want to show or hide the tool bar."
 289       :type '(choice (const top)
 290                      (const bottom)
 291                      (const left)
 292                      (const right))
 293       :group 'frames
 294       :initialize 'custom-initialize-default
 295       :set (lambda (sym val)
 296              (set-default sym val)
 297              (modify-all-frames-parameters
 298               (list (cons 'tool-bar-position val))))))
 299
 300
 301 (provide 'tool-bar)
 302
 303 ;;; tool-bar.el ends here