lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2017 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  30 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  31
  32 ;; At load time dired-x.el will install itself and bind some dired keys.
  33 ;; Some dired.el and dired-aux.el functions have extra features if
  34 ;; dired-x is loaded.
  35
  36 ;; User customization: M-x customize-group RET dired-x RET.
  37
  38 ;; *Please* see the `dired-x' info pages for more details.
  39
  40 \f
  41 ;;; Code:
  42
  43 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  44 ;; but maybe not if a dired-x function is being autoloaded.
  45 (require 'dired)
  46
  47 ;;; User-defined variables.
  48
  49 (defgroup dired-x nil
  50   "Extended directory editing (dired-x)."
  51   :group 'dired)
  52
  53 (defgroup dired-keys nil
  54   "Dired keys customizations."
  55   :prefix "dired-"
  56   :group 'dired-x)
  57
  58 (defcustom dired-bind-vm nil
  59   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  60 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  61 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  62 will run `rmail' on these files.  New RMAIL files use the standard
  63 mbox format, and so cannot be distinguished in this way."
  64   :type 'boolean
  65   :group 'dired-keys)
  66
  67 (defcustom dired-bind-jump t
  68   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  69 Setting this variable directly after dired-x is loaded has no effect -
  70 use \\[customize]."
  71   :type 'boolean
  72   :set (lambda (sym val)
  73          (if (set sym val)
  74              (progn
  75                (define-key ctl-x-map "\C-j" 'dired-jump)
  76                (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window))
  77            (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j"))
  78                (define-key ctl-x-map "\C-j" nil))
  79            (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j"))
  80                (define-key ctl-x-4-map "\C-j" nil))))
  81   :group 'dired-keys)
  82
  83 (defcustom dired-bind-man t
  84   "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not.
  85 Setting this variable directly after dired-x is loaded has no effect -
  86 use \\[customize]."
  87   :type 'boolean
  88   :set (lambda (sym val)
  89          (if (set sym val)
  90              (define-key dired-mode-map "N" 'dired-man)
  91            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
  92                (define-key dired-mode-map "N" nil))))
  93   :group 'dired-keys)
  94
  95 (defcustom dired-bind-info t
  96   "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not.
  97 Setting this variable directly after dired-x is loaded has no effect -
  98 use \\[customize]."
  99   :type 'boolean
 100   :set (lambda (sym val)
 101          (if (set sym val)
 102              (define-key dired-mode-map "I" 'dired-info)
 103            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 104                (define-key dired-mode-map "I" nil))))
 105   :group 'dired-keys)
 106
 107 (defcustom dired-vm-read-only-folders nil
 108   "If non-nil, \\[dired-vm] will visit all folders read-only.
 109 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 110 files not writable by you are visited read-only."
 111   :type '(choice (const :tag "off" nil)
 112                  (const :tag "on" t)
 113                  (other :tag "non-writable only" if-file-read-only))
 114   :group 'dired-x)
 115
 116 (defcustom dired-omit-size-limit 30000
 117   "Maximum size for the \"omitting\" feature.
 118 If nil, there is no maximum size."
 119   :type '(choice (const :tag "no maximum" nil) integer)
 120   :group 'dired-x)
 121
 122 (defcustom dired-omit-case-fold 'filesystem
 123   "Determine whether \"omitting\" patterns are case-sensitive.
 124 When nil, always be case-sensitive; when t, always be
 125 case-insensitive; the default value, `filesystem', causes case
 126 folding to be used on case-insensitive filesystems only."
 127   :type '(choice (const :tag "Always case-sensitive" nil)
 128                  (const :tag "Always case-insensitive" t)
 129                  (const :tag "According to filesystem" filesystem))
 130   :group 'dired-x
 131   :version "26.1")
 132
 133 (declare-function file-name-case-insensitive-p "fileio.c" (filename))
 134 (defun dired-omit-case-fold-p (dir)
 135   "Non-nil if `dired-omit-mode' should be case-insensitive in DIR."
 136   (if (eq dired-omit-case-fold 'filesystem)
 137       (file-name-case-insensitive-p dir)
 138     dired-omit-case-fold))
 139
 140 ;; For backward compatibility
 141 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 142 (define-minor-mode dired-omit-mode
 143   "Toggle omission of uninteresting files in Dired (Dired-Omit mode).
 144 With a prefix argument ARG, enable Dired-Omit mode if ARG is
 145 positive, and disable it otherwise.  If called from Lisp, enable
 146 the mode if ARG is omitted or nil.
 147
 148 Dired-Omit mode is a buffer-local minor mode.  When enabled in a
 149 Dired buffer, Dired does not list files whose filenames match
 150 regexp `dired-omit-files', nor files ending with extensions in
 151 `dired-omit-extensions'.
 152
 153 To enable omitting in every Dired buffer, you can put this in
 154 your init file:
 155
 156   (add-hook \\='dired-mode-hook (lambda () (dired-omit-mode)))
 157
 158 See Info node `(dired-x) Omitting Variables' for more information."
 159   :group 'dired-x
 160   (if dired-omit-mode
 161       ;; This will mention how many lines were omitted:
 162       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 163     (revert-buffer)))
 164
 165 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 166
 167 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 168   "Filenames matching this regexp will not be displayed.
 169 This only has effect when `dired-omit-mode' is t.  See interactive function
 170 `dired-omit-mode' (\\[dired-omit-mode]) and variable
 171 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 172 files and lock files."
 173   :type 'regexp
 174   :group 'dired-x)
 175
 176 (defcustom dired-omit-verbose t
 177   "When non-nil, show messages when omitting files.
 178 When nil, don't show messages."
 179   :version "24.1"
 180   :type 'boolean
 181   :group 'dired-x)
 182
 183 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 184   "If non-nil, Dired always finds a directory in a buffer of its own.
 185 If nil, Dired finds the directory as a subdirectory in some other buffer
 186 if it is present as one.
 187
 188 If there are several Dired buffers for a directory, the most recently
 189 used is chosen.
 190
 191 Dired avoids switching to the current buffer, so that if you have
 192 a normal and a wildcard buffer for the same directory, \\[dired] will
 193 toggle between those two."
 194   :type 'boolean
 195   :group 'dired-x)
 196
 197 (defcustom dired-enable-local-variables t
 198   "Control use of local-variables lists in Dired.
 199 This temporarily overrides the value of `enable-local-variables' when
 200 listing a directory.  See also `dired-local-variables-file'."
 201   :risky t
 202   :type '(choice (const :tag "Query Unsafe" t)
 203                  (const :tag "Safe Only" :safe)
 204                  (const :tag "Do all" :all)
 205                  (const :tag "Ignore" nil)
 206                  (other :tag "Query" other))
 207   :group 'dired-x)
 208
 209 (make-obsolete-variable 'dired-enable-local-variables
 210                         "use a standard `dir-locals-file' instead." "24.1")
 211
 212 (defcustom dired-guess-shell-gnutar
 213   (catch 'found
 214     (dolist (exe '("tar" "gtar"))
 215       (if (with-temp-buffer
 216             (ignore-errors (call-process exe nil t nil "--version"))
 217             (and (re-search-backward "GNU tar" nil t) t))
 218           (throw 'found exe))))
 219   "If non-nil, name of GNU tar executable.
 220 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 221 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 222 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 223   ;; Changed from system-type test to testing --version output.
 224   ;; Maybe test --help for -z instead?
 225   :version "24.1"
 226   :type '(choice (const :tag "Not GNU tar" nil)
 227                  (string :tag "Command name"))
 228   :group 'dired-x)
 229
 230 (defcustom dired-guess-shell-gzip-quiet t
 231   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 232   :type 'boolean
 233   :group 'dired-x)
 234
 235 (defcustom dired-guess-shell-znew-switches nil
 236   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 237   :type '(choice (const :tag "None" nil)
 238                  (string :tag "Switches"))
 239   :group 'dired-x)
 240
 241 (defcustom dired-clean-up-buffers-too t
 242   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 243   :type 'boolean
 244   :group 'dired-x)
 245
 246 (defcustom dired-clean-confirm-killing-deleted-buffers t
 247   "If nil, don't ask whether to kill buffers visiting deleted files."
 248   :version "26.1"
 249   :type 'boolean
 250   :group 'dired-x)
 251
 252 ;;; KEY BINDINGS.
 253
 254 (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode)
 255 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 256 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 257 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 258 (define-key dired-mode-map "*." 'dired-mark-extension)
 259 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 260 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 261 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 262 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 263 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 264 (define-key dired-mode-map "V" 'dired-do-run-mail)
 265
 266 ;;; MENU BINDINGS
 267
 268 (require 'easymenu)
 269
 270 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 271   (easy-menu-add-item menu '("Operate")
 272                       ["Find Files" dired-do-find-marked-files
 273                        :help "Find current or marked files"]
 274                       "Shell Command...")
 275   (easy-menu-add-item menu '("Operate")
 276                       ["Relative Symlink to..." dired-do-relsymlink
 277                        :visible (fboundp 'make-symbolic-link)
 278                        :help "Make relative symbolic links for current or \
 279 marked files"]
 280                       "Hardlink to...")
 281   (easy-menu-add-item menu '("Mark")
 282                       ["Flag Extension..." dired-flag-extension
 283                        :help "Flag files with a certain extension for deletion"]
 284                       "Mark Executables")
 285   (easy-menu-add-item menu '("Mark")
 286                       ["Mark Extension..." dired-mark-extension
 287                        :help "Mark files with a certain extension"]
 288                       "Unmark All")
 289   (easy-menu-add-item menu '("Mark")
 290                       ["Mark Omitted" dired-mark-omitted
 291                        :help "Mark files matching `dired-omit-files' \
 292 and `dired-omit-extensions'"]
 293                       "Unmark All")
 294   (easy-menu-add-item menu '("Regexp")
 295                       ["Relative Symlink..." dired-do-relsymlink-regexp
 296                        :visible (fboundp 'make-symbolic-link)
 297                        :help "Make relative symbolic links for files \
 298 matching regexp"]
 299                       "Hardlink...")
 300   (easy-menu-add-item menu '("Immediate")
 301                       ["Omit Mode" dired-omit-mode
 302                        :style toggle :selected dired-omit-mode
 303                        :help "Enable or disable omitting \"uninteresting\" \
 304 files"]
 305                       "Refresh"))
 306
 307 \f
 308 ;; Install into appropriate hooks.
 309
 310 (add-hook 'dired-mode-hook 'dired-extra-startup)
 311 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 312
 313 (defun dired-extra-startup ()
 314   "Automatically put on `dired-mode-hook' to get extra Dired features:
 315 \\<dired-mode-map>
 316   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 317   \\[dired-info]\t-- run info on file
 318   \\[dired-man]\t-- run man on file
 319   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 320   \\[dired-omit-mode]\t-- toggle omitting of files
 321   \\[dired-mark-sexp]\t-- mark by Lisp expression
 322
 323 To see the options you can set, use M-x customize-group RET dired-x RET.
 324 See also the functions:
 325   `dired-flag-extension'
 326   `dired-virtual'
 327   `dired-jump'
 328   `dired-man'
 329   `dired-vm'
 330   `dired-rmail'
 331   `dired-info'
 332   `dired-do-find-marked-files'"
 333   (interactive)
 334   ;; These must be done in each new dired buffer.
 335   (dired-hack-local-variables)
 336   (dired-omit-startup))
 337
 338 \f
 339 ;;; EXTENSION MARKING FUNCTIONS.
 340
 341 (defun dired--mark-suffix-interactive-spec ()
 342   (let* ((default
 343            (let ((file (dired-get-filename nil t)))
 344              (when file
 345                (file-name-extension file))))
 346          (suffix
 347           (read-string (format "%s extension%s: "
 348                                (if (equal current-prefix-arg '(4))
 349                                    "UNmarking"
 350                                  "Marking")
 351                                (if default
 352                                    (format " (default %s)" default)
 353                                  "")) nil nil default))
 354          (marker
 355           (pcase current-prefix-arg
 356             ('(4) ?\s)
 357             ('(16)
 358              (let* ((dflt (char-to-string dired-marker-char))
 359                     (input (read-string
 360                             (format
 361                              "Marker character to use (default %s): " dflt)
 362                             nil nil dflt)))
 363                (aref input 0)))
 364             (_ dired-marker-char))))
 365     (list suffix marker)))
 366
 367 ;; Mark files with some extension.
 368 (defun dired-mark-extension (extension &optional marker-char)
 369   "Mark all files with a certain EXTENSION for use in later commands.
 370 A `.' is automatically prepended to EXTENSION when not present.
 371 EXTENSION may also be a list of extensions instead of a single one.
 372 Optional MARKER-CHAR is marker to use.
 373 Interactively, ask for EXTENSION.
 374 Prefixed with one C-u, unmark files instead.
 375 Prefixed with two C-u's, prompt for MARKER-CHAR and mark files with it."
 376   (interactive (dired--mark-suffix-interactive-spec))
 377   (unless (listp extension)
 378     (setq extension (list extension)))
 379   (dired-mark-files-regexp
 380    (concat ".";; don't match names with nothing but an extension
 381            "\\("
 382            (mapconcat
 383             (lambda (x)
 384               (regexp-quote
 385                (if (string-prefix-p "." x) x (concat "." x))))
 386             extension "\\|")
 387            "\\)$")
 388    marker-char))
 389
 390 ;; Mark files ending with some suffix.
 391 (defun dired-mark-suffix (suffix &optional marker-char)
 392   "Mark all files with a certain SUFFIX for use in later commands.
 393 A `.' is *not* automatically prepended to the string entered;  see
 394 also `dired-mark-extension', which is similar but automatically
 395 prepends `.' when not present.
 396 SUFFIX may also be a list of suffixes instead of a single one.
 397 Optional MARKER-CHAR is marker to use.
 398 Interactively, ask for SUFFIX.
 399 Prefixed with one C-u, unmark files instead.
 400 Prefixed with two C-u's, prompt for MARKER-CHAR and mark files with it."
 401   (interactive (dired--mark-suffix-interactive-spec))
 402   (unless (listp suffix)
 403     (setq suffix (list suffix)))
 404   (dired-mark-files-regexp
 405    (concat ".";; don't match names with nothing but an extension
 406            "\\("
 407            (mapconcat 'regexp-quote suffix "\\|")
 408            "\\)$")
 409    marker-char))
 410
 411 (defun dired-flag-extension (extension)
 412   "In Dired, flag all files with a certain EXTENSION for deletion.
 413 A `.' is *not* automatically prepended to the string entered."
 414   (interactive "sFlagging extension: ")
 415   (dired-mark-extension extension dired-del-marker))
 416
 417 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 418
 419 (defvar dired-patch-unclean-extensions
 420   '(".rej" ".orig")
 421   "List of extensions of dispensable files created by the `patch' program.")
 422
 423 (defvar dired-tex-unclean-extensions
 424   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 425   "List of extensions of dispensable files created by TeX.")
 426
 427 (defvar dired-latex-unclean-extensions
 428   '(".idx" ".lof" ".lot" ".glo")
 429   "List of extensions of dispensable files created by LaTeX.")
 430
 431 (defvar dired-bibtex-unclean-extensions
 432   '(".blg" ".bbl")
 433   "List of extensions of dispensable files created by BibTeX.")
 434
 435 (defvar dired-texinfo-unclean-extensions
 436   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 437     ".tp" ".tps" ".vr" ".vrs")
 438   "List of extensions of dispensable files created by texinfo.")
 439
 440 (defun dired-clean-patch ()
 441   "Flag dispensable files created by patch for deletion.
 442 See variable `dired-patch-unclean-extensions'."
 443   (interactive)
 444   (dired-flag-extension dired-patch-unclean-extensions))
 445
 446 (defun dired-clean-tex ()
 447   "Flag dispensable files created by [La]TeX etc. for deletion.
 448 See variables `dired-tex-unclean-extensions',
 449 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 450 `dired-texinfo-unclean-extensions'."
 451   (interactive)
 452   (dired-flag-extension (append dired-texinfo-unclean-extensions
 453                                 dired-latex-unclean-extensions
 454                                 dired-bibtex-unclean-extensions
 455                                 dired-tex-unclean-extensions)))
 456
 457 (defun dired-very-clean-tex ()
 458   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 459 See variables `dired-texinfo-unclean-extensions',
 460 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 461 `dired-texinfo-unclean-extensions'."
 462   (interactive)
 463   (dired-flag-extension (append dired-texinfo-unclean-extensions
 464                                 dired-latex-unclean-extensions
 465                                 dired-bibtex-unclean-extensions
 466                                 dired-tex-unclean-extensions
 467                                 (list ".dvi"))))
 468 \f
 469 (defvar tar-superior-buffer)
 470 ;;; JUMP.
 471
 472 ;;;###autoload
 473 (defun dired-jump (&optional other-window file-name)
 474   "Jump to Dired buffer corresponding to current buffer.
 475 If in a file, Dired the current directory and move to file's line.
 476 If in Dired already, pop up a level and goto old directory's line.
 477 In case the proper Dired file line cannot be found, refresh the dired
 478 buffer and try again.
 479 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
 480 When FILE-NAME is non-nil, jump to its line in Dired.
 481 Interactively with prefix argument, read FILE-NAME."
 482   (interactive
 483    (list nil (and current-prefix-arg
 484                   (read-file-name "Jump to Dired file: "))))
 485   (if (bound-and-true-p tar-subfile-mode)
 486       (switch-to-buffer tar-superior-buffer)
 487     ;; Expand file-name before `dired-goto-file' call:
 488     ;; `dired-goto-file' requires its argument to be an absolute
 489     ;; file name; the result of `read-file-name' could be
 490     ;; an abbreviated file name (Bug#24409).
 491     (let* ((file (or (and file-name (expand-file-name file-name))
 492                      buffer-file-name))
 493            (dir (if file (file-name-directory file) default-directory)))
 494       (if (and (eq major-mode 'dired-mode) (null file-name))
 495           (progn
 496             (setq dir (dired-current-directory))
 497             (dired-up-directory other-window)
 498             (unless (dired-goto-file dir)
 499               ;; refresh and try again
 500               (dired-insert-subdir (file-name-directory dir))
 501               (dired-goto-file dir)))
 502         (if other-window
 503             (dired-other-window dir)
 504           (dired dir))
 505         (if file
 506             (or (dired-goto-file file)
 507                 ;; refresh and try again
 508                 (progn
 509                   (dired-insert-subdir (file-name-directory file))
 510                   (dired-goto-file file))
 511                 ;; Toggle omitting, if it is on, and try again.
 512                 (when dired-omit-mode
 513                   (dired-omit-mode)
 514                   (dired-goto-file file))))))))
 515
 516 ;;;###autoload
 517 (defun dired-jump-other-window (&optional file-name)
 518   "Like \\[dired-jump] (`dired-jump') but in other window."
 519   (interactive
 520    (list (and current-prefix-arg
 521               (read-file-name "Jump to Dired file: "))))
 522   (dired-jump t file-name))
 523 \f
 524 ;;; OMITTING.
 525
 526 ;; Enhanced omitting of lines from directory listings.
 527 ;; Marked files are never omitted.
 528
 529 ;; should probably get rid of this and always use 'no-dir.
 530 ;; sk 28-Aug-1991 09:37
 531 (defvar dired-omit-localp 'no-dir
 532   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 533 If it is `no-dir', omitting is much faster, but you can only match
 534 against the non-directory part of the file name.  Set it to nil if you
 535 need to match the entire file name.")
 536
 537 ;; \017=^O for Omit - other packages can chose other control characters.
 538 (defvar dired-omit-marker-char ?\017
 539   "Temporary marker used by Dired-Omit.
 540 Should never be used as marker by the user or other packages.")
 541
 542 (defun dired-omit-startup ()
 543   (or (assq 'dired-omit-mode minor-mode-alist)
 544       (setq minor-mode-alist
 545             (append '((dired-omit-mode
 546                        (:eval (if (eq major-mode 'dired-mode)
 547                                   " Omit" ""))))
 548                     minor-mode-alist))))
 549
 550 (defun dired-mark-omitted ()
 551   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 552   (interactive)
 553   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 554   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp
 555                              (dired-omit-case-fold-p (if (stringp dired-directory)
 556                                                          dired-directory
 557                                                        (car dired-directory)))))
 558
 559 (defcustom dired-omit-extensions
 560   (append completion-ignored-extensions
 561           dired-latex-unclean-extensions
 562           dired-bibtex-unclean-extensions
 563           dired-texinfo-unclean-extensions)
 564   "If non-nil, a list of extensions (strings) to omit from Dired listings.
 565 Defaults to elements of `completion-ignored-extensions',
 566 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 567 `dired-texinfo-unclean-extensions'.
 568
 569 See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and
 570 variables `dired-omit-mode' and `dired-omit-files'."
 571   :type '(repeat string)
 572   :group 'dired-x)
 573
 574 (defun dired-omit-expunge (&optional regexp)
 575   "Erases all unmarked files matching REGEXP.
 576 Does nothing if global variable `dired-omit-mode' is nil, or if called
 577   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 578 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 579   filenames ending in `dired-omit-extensions'.
 580 If REGEXP is the empty string, this function is a no-op.
 581
 582 This functions works by temporarily binding `dired-marker-char' to
 583 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 584   (interactive "sOmit files (regexp): ")
 585   (if (and dired-omit-mode
 586            (or (called-interactively-p 'interactive)
 587                (not dired-omit-size-limit)
 588                (< (buffer-size) dired-omit-size-limit)
 589                (progn
 590                  (when dired-omit-verbose
 591                    (message "Not omitting: directory larger than %d characters."
 592                             dired-omit-size-limit))
 593                  (setq dired-omit-mode nil)
 594                  nil)))
 595       (let ((omit-re (or regexp (dired-omit-regexp)))
 596             (old-modified-p (buffer-modified-p))
 597             count)
 598         (or (string= omit-re "")
 599             (let ((dired-marker-char dired-omit-marker-char))
 600               (when dired-omit-verbose (message "Omitting..."))
 601               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp
 602                                              (dired-omit-case-fold-p (if (stringp dired-directory)
 603                                                                          dired-directory
 604                                                                        (car dired-directory))))
 605                   (progn
 606                     (setq count (dired-do-kill-lines
 607                                  nil
 608                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 609                     (force-mode-line-update))
 610                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 611         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 612         ;; in mode-line of omitted buffers.
 613         (set-buffer-modified-p (and old-modified-p
 614                                     (save-excursion
 615                                       (goto-char (point-min))
 616                                       (re-search-forward dired-re-mark nil t))))
 617         count)))
 618
 619 (defun dired-omit-regexp ()
 620   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 621           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 622           (if dired-omit-extensions
 623               (concat ".";; a non-extension part should exist
 624                       "\\("
 625                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 626                       "\\)$")
 627             "")))
 628
 629 ;; Returns t if any work was done, nil otherwise.
 630 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp case-fold-p)
 631   "Mark unmarked files matching REGEXP, displaying MSG.
 632 REGEXP is matched against the entire file name.  When called
 633 interactively, prompt for REGEXP.
 634 With prefix argument, unflag all those files.
 635 Optional fourth argument LOCALP is as in `dired-get-filename'.
 636 Optional fifth argument CASE-FOLD-P specifies the value of
 637 `case-fold-search' used for matching REGEXP."
 638   (interactive
 639    (list (read-regexp
 640           "Mark unmarked files matching regexp (default all): "
 641           nil 'dired-regexp-history)
 642          nil current-prefix-arg nil))
 643   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 644     (dired-mark-if
 645      (and
 646       ;; not already marked
 647       (= (following-char) ?\s)
 648       ;; uninteresting
 649       (let ((fn (dired-get-filename localp t))
 650             ;; Match patterns case-insensitively on case-insensitive
 651             ;; systems
 652             (case-fold-search case-fold-p))
 653         (and fn (string-match-p regexp fn))))
 654      msg)))
 655
 656 \f
 657 ;;; VIRTUAL DIRED MODE.
 658
 659 ;; For browsing `ls -lR' listings in a dired-like fashion.
 660
 661 (defalias 'virtual-dired 'dired-virtual)
 662 (defun dired-virtual (dirname &optional switches)
 663   "Put this buffer into Virtual Dired mode.
 664
 665 In Virtual Dired mode, all commands that do not actually consult the
 666 filesystem will work.
 667
 668 This is useful if you want to peruse and move around in an ls -lR
 669 output file, for example one you got from an ftp server.  With
 670 ange-ftp, you can even Dired a directory containing an ls-lR file,
 671 visit that file and turn on Virtual Dired mode.  But don't try to save
 672 this file, as dired-virtual indents the listing and thus changes the
 673 buffer.
 674
 675 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 676 resume it in a later session.
 677
 678 Type \\<dired-mode-map>\\[revert-buffer] \
 679 in the Virtual Dired buffer and answer `y' to convert
 680 the virtual to a real Dired buffer again.  You don't have to do this, though:
 681 you can relist single subdirs using \\[dired-do-redisplay]."
 682
 683   ;; DIRNAME is the top level directory of the buffer.  It will become
 684   ;; its `default-directory'.  If nil, the old value of
 685   ;; default-directory is used.
 686
 687   ;; Optional SWITCHES are the ls switches to use.
 688
 689   ;; Shell wildcards will be used if there already is a `wildcard'
 690   ;; line in the buffer (thus it is a saved Dired buffer), but there
 691   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 692   ;; hand if you want them.
 693
 694   (interactive
 695    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 696   (goto-char (point-min))
 697   (or (looking-at-p "  ")
 698       ;; if not already indented, do it now:
 699       (indent-region (point-min) (point-max) 2))
 700   (or dirname (setq dirname default-directory))
 701   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 702   (setq default-directory dirname)      ; contains no wildcards
 703   (let ((wildcard (save-excursion
 704                     (goto-char (point-min))
 705                     (forward-line 1)
 706                     (and (looking-at "^  wildcard ")
 707                          (buffer-substring (match-end 0)
 708                                            (line-end-position))))))
 709   (if wildcard
 710         (setq dirname (expand-file-name wildcard default-directory))))
 711   ;; If raw ls listing (not a saved old dired buffer), give it a
 712   ;; decent subdir headerline:
 713   (goto-char (point-min))
 714   (or (looking-at-p dired-subdir-regexp)
 715       (insert "  "
 716               (directory-file-name (file-name-directory default-directory))
 717               ":\n"))
 718   (dired-mode dirname (or switches dired-listing-switches))
 719   (setq mode-name "Virtual Dired"
 720         revert-buffer-function 'dired-virtual-revert)
 721   (set (make-local-variable 'dired-subdir-alist) nil)
 722   (dired-build-subdir-alist)
 723   (goto-char (point-min))
 724   (dired-initial-position dirname))
 725
 726 (defun dired-virtual-guess-dir ()
 727   "Guess and return appropriate working directory of this buffer.
 728 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 729 based upon buffer contents.  If nothing could be guessed, returns
 730 nil."
 731
 732   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 733         (subexpr 2))
 734     (goto-char (point-min))
 735     (cond ((looking-at regexp)
 736            ;; If a saved dired buffer, look to which dir and
 737            ;; perhaps wildcard it belongs:
 738            (let ((dir (buffer-substring (match-beginning subexpr)
 739                                         (match-end subexpr))))
 740              (file-name-as-directory dir)))
 741           ;; Else no match for headerline found.  It's a raw ls listing.
 742           ;; In raw ls listings the directory does not have a headerline
 743           ;; try parent of first subdir, if any
 744           ((re-search-forward regexp nil t)
 745            (file-name-directory
 746             (directory-file-name
 747              (file-name-as-directory
 748               (buffer-substring (match-beginning subexpr)
 749                                 (match-end subexpr))))))
 750           (t                            ; if all else fails
 751            nil))))
 752
 753
 754 (defun dired-virtual-revert (&optional _arg _noconfirm)
 755   (if (not
 756        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 757       (error "Cannot revert a Virtual Dired buffer")
 758     (setq mode-name "Dired"
 759           revert-buffer-function 'dired-revert)
 760     (revert-buffer)))
 761
 762 ;; A zero-arg version of dired-virtual.
 763 (defun dired-virtual-mode ()
 764   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 765 Useful on `magic-mode-alist' with the regexp
 766
 767   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 768
 769 to put saved Dired buffers automatically into Virtual Dired mode.
 770
 771 Also useful for `auto-mode-alist' like this:
 772
 773   (add-to-list \\='auto-mode-alist
 774                \\='(\"[^/]\\\\.dired\\\\\\='\" . dired-virtual-mode))"
 775   (interactive)
 776   (dired-virtual (dired-virtual-guess-dir)))
 777
 778 \f
 779 ;;; SMART SHELL.
 780
 781 ;; An Emacs buffer can have but one working directory, stored in the
 782 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 783 ;; several subdirectories inserted, but still has but one working directory:
 784 ;; that of the top level Dired directory in that buffer.  For some commands
 785 ;; it is appropriate that they use the current Dired directory instead of
 786 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 787 ;; mechanism is provided for special handling of the working directory in
 788 ;; special major modes.
 789
 790 (define-obsolete-variable-alias 'default-directory-alist
 791   'dired-default-directory-alist "24.1")
 792
 793 ;; It's easier to add to this alist than redefine function
 794 ;; default-directory while keeping the old information.
 795 (defconst dired-default-directory-alist
 796   '((dired-mode . (if (fboundp 'dired-current-directory)
 797                       (dired-current-directory)
 798                     default-directory)))
 799   "Alist of major modes and their opinion on `default-directory'.
 800 Each element has the form (MAJOR . EXPRESSION).
 801 The function `dired-default-directory' evaluates EXPRESSION to
 802 determine a default directory.")
 803
 804 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 805 (make-obsolete-variable 'dired-default-directory-alist
 806                         "this feature is due to be removed." "24.1")
 807
 808 (defun dired-default-directory ()
 809   "Return the `dired-default-directory-alist' entry for the current major-mode.
 810 If none, return `default-directory'."
 811   ;; It looks like this was intended to be something of a "general"
 812   ;; feature, but it only ever seems to have been used in
 813   ;; dired-smart-shell-command, and doesn't seem worth keeping around.
 814   (declare (obsolete nil "24.1"))
 815   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 816       default-directory))
 817
 818 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 819   "Like function `shell-command', but in the current Virtual Dired directory."
 820   (interactive
 821    (list
 822     (read-shell-command "Shell command: " nil nil
 823                         (cond
 824                          (buffer-file-name (file-relative-name buffer-file-name))
 825                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 826     current-prefix-arg
 827     shell-command-default-error-buffer))
 828   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 829                                     (dired-current-directory))
 830                                default-directory)))
 831     (shell-command command output-buffer error-buffer)))
 832
 833 \f
 834 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 835
 836 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 837 ;;
 838 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 839 ;;
 840 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 841 ;;
 842 ;; * `dired-hack-local-variables' checks the value of
 843 ;;   `dired-local-variables-file'
 844 ;;
 845 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 846 ;;   filename found in the directory of the Dired Buffer being created.
 847 ;;
 848 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 849 ;;   include it in the Dired Buffer at the bottom.
 850 ;;
 851 ;; * Set `enable-local-variables' temporarily to the user variable
 852 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 853 ;;   Dired Buffer.
 854
 855 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 856   "Filename, as string, containing local Dired buffer variables to be hacked.
 857 If this file found in current directory, then it will be inserted into dired
 858 buffer and `hack-local-variables' will be run.  See Info node
 859 `(emacs)File Variables' for more information on local variables.
 860 See also `dired-enable-local-variables'."
 861   :type 'file
 862   :group 'dired)
 863
 864 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 865
 866 (defun dired-hack-local-variables ()
 867   "Evaluate local variables in `dired-local-variables-file' for Dired buffer."
 868   (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1"))
 869   (and (stringp dired-local-variables-file)
 870        (file-exists-p dired-local-variables-file)
 871        (let ((opoint (point-max))
 872              (inhibit-read-only t)
 873              ;; In case user has `enable-local-variables' set to nil we
 874              ;; override it locally with dired's variable.
 875              (enable-local-variables dired-enable-local-variables))
 876          ;; Insert 'em.
 877          (save-excursion
 878            (goto-char opoint)
 879            (insert "\^L\n")
 880            (insert-file-contents dired-local-variables-file))
 881          ;; Hack 'em.
 882          (unwind-protect
 883              (let ((buffer-file-name dired-local-variables-file))
 884                (hack-local-variables))
 885            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 886            (delete-region opoint (point-max)))
 887          ;; Make sure that the mode line shows the proper information.
 888          (dired-sort-set-mode-line))))
 889
 890 ;; Does not seem worth a dedicated command.
 891 ;; See the more general features in files-x.el.
 892 (defun dired-omit-here-always ()
 893   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 894 If in a Dired buffer, reverts it."
 895   (declare (obsolete add-dir-local-variable "24.1"))
 896   (interactive)
 897   (if (file-exists-p dired-local-variables-file)
 898       (error "Old-style dired-local-variables-file `./%s' found;
 899 replace it with a dir-locals-file `./%s'"
 900              dired-local-variables-file
 901              dir-locals-file))
 902   (if (file-exists-p dir-locals-file)
 903       (message "File `./%s' already exists." dir-locals-file)
 904     (add-dir-local-variable 'dired-mode 'subdirs nil)
 905     (add-dir-local-variable 'dired-mode 'dired-omit-mode t)
 906     ;; Run extra-hooks and revert directory.
 907     (when (derived-mode-p 'dired-mode)
 908       (hack-dir-local-variables-non-file-buffer)
 909       (dired-extra-startup)
 910       (dired-revert))))
 911
 912 \f
 913 ;;; GUESS SHELL COMMAND.
 914
 915 ;; Brief Description:
 916 ;;;
 917 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 918 ;;;
 919 ;; * `dired-guess-shell-command' provides smarter defaults for
 920 ;;;    dired-aux.el's `dired-read-shell-command'.
 921 ;;;
 922 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 923 ;;;    marked files.
 924 ;;;
 925 ;; * Parse `dired-guess-shell-alist-user' and
 926 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 927 ;;;   that matches the first file in the file list.
 928 ;;;
 929 ;; * If the REGEXP matches all the entries of the file list then evaluate
 930 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 931 ;;;   string.  COMMAND may be a list of commands.
 932 ;;;
 933 ;; * Return this command to `dired-guess-shell-command' which prompts user
 934 ;;;   with it.  The list of commands is put into the list of default values.
 935 ;;;   If a command is used successfully then it is stored permanently in
 936 ;;;   `dired-shell-command-history'.
 937
 938 ;; Guess what shell command to apply to a file.
 939 (defvar dired-shell-command-history nil
 940   "History list for commands that read dired-shell commands.")
 941
 942 ;; Default list of shell commands.
 943
 944 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 945 ;; install GNU zip's version of zcat.
 946
 947 (autoload 'Man-support-local-filenames "man")
 948
 949 (defvar dired-guess-shell-alist-default
 950   (list
 951    (list "\\.tar\\'"
 952          '(if dired-guess-shell-gnutar
 953               (concat dired-guess-shell-gnutar " xvf")
 954             "tar xvf")
 955          ;; Extract files into a separate subdirectory
 956          '(if dired-guess-shell-gnutar
 957               (concat "mkdir " (file-name-sans-extension file)
 958                       "; " dired-guess-shell-gnutar " -C "
 959                       (file-name-sans-extension file) " -xvf")
 960             (concat "mkdir " (file-name-sans-extension file)
 961                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 962          ;; List archive contents.
 963          '(if dired-guess-shell-gnutar
 964               (concat dired-guess-shell-gnutar " tvf")
 965             "tar tvf"))
 966
 967    ;; REGEXPS for compressed archives must come before the .Z rule to
 968    ;; be recognized:
 969    (list "\\.tar\\.Z\\'"
 970          ;; Untar it.
 971          '(if dired-guess-shell-gnutar
 972               (concat dired-guess-shell-gnutar " zxvf")
 973             (concat "zcat * | tar xvf -"))
 974          ;; Optional conversion to gzip format.
 975          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 976                   " " dired-guess-shell-znew-switches))
 977
 978    ;; gzip'ed archives
 979    (list "\\.t\\(ar\\.\\)?gz\\'"
 980          '(if dired-guess-shell-gnutar
 981               (concat dired-guess-shell-gnutar " zxvf")
 982             (concat "gunzip -qc * | tar xvf -"))
 983          ;; Extract files into a separate subdirectory
 984          '(if dired-guess-shell-gnutar
 985               (concat "mkdir " (file-name-sans-extension file)
 986                       "; " dired-guess-shell-gnutar " -C "
 987                       (file-name-sans-extension file) " -zxvf")
 988             (concat "mkdir " (file-name-sans-extension file)
 989                     "; gunzip -qc * | tar -C "
 990                     (file-name-sans-extension file) " -xvf -"))
 991          ;; Optional decompression.
 992          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 993          ;; List archive contents.
 994          '(if dired-guess-shell-gnutar
 995               (concat dired-guess-shell-gnutar " ztvf")
 996             (concat "gunzip -qc * | tar tvf -")))
 997
 998    ;; bzip2'ed archives
 999    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
1000          "bunzip2 -c * | tar xvf -"
1001          ;; Extract files into a separate subdirectory
1002          '(concat "mkdir " (file-name-sans-extension file)
1003                   "; bunzip2 -c * | tar -C "
1004                   (file-name-sans-extension file) " -xvf -")
1005          ;; Optional decompression.
1006          "bunzip2")
1007
1008    ;; xz'ed archives
1009    (list "\\.t\\(ar\\.\\)?xz\\'"
1010          "unxz -c * | tar xvf -"
1011          ;; Extract files into a separate subdirectory
1012          '(concat "mkdir " (file-name-sans-extension file)
1013                   "; unxz -c * | tar -C "
1014                   (file-name-sans-extension file) " -xvf -")
1015          ;; Optional decompression.
1016          "unxz")
1017
1018    '("\\.shar\\.Z\\'" "zcat * | unshar")
1019    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
1020
1021    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
1022    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
1023          ;; Optional decompression.
1024          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1025    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
1026          ;; Optional conversion to gzip format.
1027          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1028                   " " dired-guess-shell-znew-switches))
1029
1030    '("\\.patch\\'" "cat * | patch")
1031    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
1032          ;; Optional decompression.
1033          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1034    (list "\\.patch\\.Z\\'" "zcat * | patch"
1035          ;; Optional conversion to gzip format.
1036          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1037                   " " dired-guess-shell-znew-switches))
1038
1039    ;; The following four extensions are useful with dired-man ("N" key)
1040    ;; FIXME "man ./" does not work with dired-do-shell-command,
1041    ;; because there seems to be no way for us to modify the filename,
1042    ;; only the command.  Hmph.  `dired-man' works though.
1043    (list "\\.\\(?:[0-9]\\|man\\)\\'"
1044          '(let ((loc (Man-support-local-filenames)))
1045             (cond ((eq loc 'man-db) "man -l")
1046                   ((eq loc 'man) "man ./")
1047                   (t
1048                    "cat * | tbl | nroff -man -h | col -b"))))
1049    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
1050          '(let ((loc (Man-support-local-filenames)))
1051             (cond ((eq loc 'man-db)
1052                    "man -l")
1053                   ((eq loc 'man)
1054                    "man ./")
1055                   (t "gunzip -qc * | tbl | nroff -man -h | col -b")))
1056          ;; Optional decompression.
1057          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1058    (list "\\.[0-9]\\.Z\\'"
1059          '(let ((loc (Man-support-local-filenames)))
1060             (cond ((eq loc 'man-db) "man -l")
1061                   ((eq loc 'man) "man ./")
1062                   (t "zcat * | tbl | nroff -man -h | col -b")))
1063          ;; Optional conversion to gzip format.
1064          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1065                   " " dired-guess-shell-znew-switches))
1066    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
1067
1068    '("\\.dvi\\'" "xdvi" "dvips")        ; preview and printing
1069    '("\\.au\\'" "play")                 ; play Sun audiofiles
1070    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
1071    '("\\.ogg\\'" "ogg123")
1072    '("\\.mp3\\'" "mpg123")
1073    '("\\.wav\\'" "play")
1074    '("\\.uu\\'" "uudecode")             ; for uudecoded files
1075    '("\\.hqx\\'" "mcvert")
1076    '("\\.sh\\'" "sh")                   ; execute shell scripts
1077    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
1078    '("\\.gp\\'" "gnuplot")
1079    '("\\.p[bgpn]m\\'" "xloadimage")
1080    '("\\.gif\\'" "xloadimage")          ; view gif pictures
1081    '("\\.tif\\'" "xloadimage")
1082    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
1083    '("\\.jpe?g\\'" "xloadimage")
1084    '("\\.fig\\'" "xfig")                ; edit fig pictures
1085    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1086    '("\\.tex\\'" "latex" "tex")
1087    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1088    '("\\.pdf\\'" "xpdf")
1089    '("\\.doc\\'" "antiword" "strings")
1090    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1091    '("\\.dia\\'" "dia")
1092    '("\\.mgp\\'" "mgp")
1093
1094    ;; Some other popular archivers.
1095    (list "\\.zip\\'" "unzip" "unzip -l"
1096          ;; Extract files into a separate subdirectory
1097          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1098                   " -d " (file-name-sans-extension file)))
1099    '("\\.zoo\\'" "zoo x//")
1100    '("\\.lzh\\'" "lharc x")
1101    '("\\.arc\\'" "arc x")
1102    '("\\.shar\\'" "unshar")
1103    '("\\.rar\\'" "unrar x")
1104    '("\\.7z\\'" "7z x")
1105
1106    ;; Compression.
1107    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1108    (list "\\.dz\\'" "dictunzip")
1109    (list "\\.bz2\\'" "bunzip2")
1110    (list "\\.xz\\'" "unxz")
1111    (list "\\.Z\\'" "uncompress"
1112          ;; Optional conversion to gzip format.
1113          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1114                   " " dired-guess-shell-znew-switches))
1115
1116    '("\\.sign?\\'" "gpg --verify"))
1117
1118   "Default alist used for shell command guessing.
1119 See `dired-guess-shell-alist-user'.")
1120
1121 (defcustom dired-guess-shell-alist-user nil
1122   "User-defined alist of rules for suggested commands.
1123 These rules take precedence over the predefined rules in the variable
1124 `dired-guess-shell-alist-default' (to which they are prepended).
1125
1126 Each element of this list looks like
1127
1128     (REGEXP COMMAND...)
1129
1130 where each COMMAND can either be a string or a Lisp expression that evaluates
1131 to a string.  This expression can access the file name as the variable `file'.
1132 If several COMMANDs are given, the first one will be the default
1133 and the rest will be added temporarily to the history and can be retrieved
1134 with \\[previous-history-element] (M-p) .
1135
1136 The variable `dired-guess-shell-case-fold-search' controls whether
1137 REGEXP is matched case-sensitively."
1138   :group 'dired-x
1139   :type '(alist :key-type regexp :value-type (repeat sexp)))
1140
1141 (defcustom dired-guess-shell-case-fold-search t
1142   "If non-nil, `dired-guess-shell-alist-default' and
1143 `dired-guess-shell-alist-user' are matched case-insensitively."
1144   :group 'dired-x
1145   :type 'boolean)
1146
1147 (defun dired-guess-default (files)
1148   "Return a shell command, or a list of commands, appropriate for FILES.
1149 See `dired-guess-shell-alist-user'."
1150
1151   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1152          ;; Prepend the user's alist to the default alist.
1153          (alist (append dired-guess-shell-alist-user
1154                         dired-guess-shell-alist-default))
1155          (file (car files))
1156          (flist (cdr files))
1157          elt regexp cmds)
1158
1159     ;; Find the first match in the alist for first file in FILES.
1160     (while alist
1161       (setq elt (car alist)
1162             regexp (car elt)
1163             alist (cdr alist))
1164       (if (string-match-p regexp file)
1165           (setq cmds (cdr elt)
1166                 alist nil)))
1167
1168     ;; If more than one file, see if all of FILES match regular expression.
1169     (while (and flist
1170                 (string-match-p regexp (car flist)))
1171       (setq flist (cdr flist)))
1172
1173     ;; If flist is still non-nil, then do not guess since this means that not
1174     ;; all the files in FILES were matched by the regexp.
1175     (setq cmds (and (not flist) cmds))
1176
1177     ;; Return commands or nil if flist is still non-nil.
1178     ;; Evaluate the commands in order that any logical testing will be done.
1179     (if (cdr cmds)
1180         (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds))
1181       (eval (car cmds) `((file . ,file))))))            ; single command
1182
1183 (defun dired-guess-shell-command (prompt files)
1184   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1185   (let ((default (dired-guess-default files))
1186         default-list val)
1187     (if (null default)
1188         ;; Nothing to guess
1189         (read-shell-command prompt nil 'dired-shell-command-history)
1190       (setq prompt (replace-regexp-in-string ": $" " " prompt))
1191       (if (listp default)
1192           ;; More than one guess
1193           (setq default-list default
1194                 default (car default)
1195                 prompt (concat
1196                         prompt
1197                         (format "{%d guesses} " (length default-list))))
1198         ;; Just one guess
1199         (setq default-list (list default)))
1200       ;; Put the first guess in the prompt but not in the initial value.
1201       (setq prompt (concat prompt (format "[%s]: " default)))
1202       ;; All guesses can be retrieved with M-n
1203       (setq val (read-shell-command prompt nil
1204                                     'dired-shell-command-history
1205                                     default-list))
1206       ;; If we got a return, then return default.
1207       (if (equal val "") default val))))
1208
1209 \f
1210 ;;; RELATIVE SYMBOLIC LINKS.
1211
1212 (declare-function make-symbolic-link "fileio.c")
1213
1214 (defvar dired-keep-marker-relsymlink ?S
1215   "See variable `dired-keep-marker-move'.")
1216
1217 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1218   "Make a symbolic link (pointing to FILE1) in FILE2.
1219 The link is relative (if possible), for example
1220
1221     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1222
1223 results in
1224
1225     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1226   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1227   (let (name1 name2 len1 len2 (index 0) sub)
1228     (setq file1 (expand-file-name file1)
1229           file2 (expand-file-name file2)
1230           len1 (length file1)
1231           len2 (length file2))
1232     ;; Find common initial file name components:
1233     (let (next)
1234       (while (and (setq next (string-match "/" file1 index))
1235                   (< (setq next (1+ next)) (min len1 len2))
1236                   ;; For the comparison, both substrings must end in
1237                   ;; `/', so NEXT is *one plus* the result of the
1238                   ;; string-match.
1239                   ;; E.g., consider the case of linking "/tmp/a/abc"
1240                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1241                   ;; of "/tmp/" as common initial component
1242                   (string-equal (substring file1 0 next)
1243                                 (substring file2 0 next)))
1244         (setq index next))
1245       (setq name2 file2
1246             sub (substring file1 0 index)
1247             name1 (substring file1 index)))
1248     (if (string-equal sub "/")
1249         ;; No common initial file name found
1250         (setq name1 file1)
1251       ;; Else they have a common parent directory
1252       (let ((tem (substring file2 index))
1253             (start 0)
1254             (count 0))
1255         ;; Count number of slashes we must compensate for ...
1256         (while (setq start (string-match "/" tem start))
1257           (setq count (1+ count)
1258                 start (1+ start)))
1259         ;; ... and prepend a "../" for each slash found:
1260         (dotimes (_ count)
1261           (setq name1 (concat "../" name1)))))
1262     (make-symbolic-link
1263      (directory-file-name name1)        ; must not link to foo/
1264                                         ; (trailing slash!)
1265      name2 ok-if-already-exists)))
1266
1267 (autoload 'dired-do-create-files "dired-aux")
1268
1269 ;;;###autoload
1270 (defun dired-do-relsymlink (&optional arg)
1271    "Relative symlink all marked (or next ARG) files into a directory.
1272 Otherwise make a relative symbolic link to the current file.
1273 This creates relative symbolic links like
1274
1275     foo -> ../bar/foo
1276
1277 not absolute ones like
1278
1279     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1280
1281 For absolute symlinks, use \\[dired-do-symlink]."
1282   (interactive "P")
1283   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1284                            "RelSymLink" arg dired-keep-marker-relsymlink))
1285
1286 (autoload 'dired-mark-read-regexp "dired-aux")
1287 (autoload 'dired-do-create-files-regexp "dired-aux")
1288
1289 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1290   "RelSymlink all marked files containing REGEXP to NEWNAME.
1291 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1292 for more info."
1293   (interactive (dired-mark-read-regexp "RelSymLink"))
1294   (dired-do-create-files-regexp
1295    #'dired-make-relative-symlink
1296    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1297
1298 \f
1299 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1300
1301 ;; Brief Description:
1302 ;;;
1303 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1304 ;;;
1305 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1306 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1307 ;;;
1308 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1309 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1310 ;;;
1311 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1312 ;;;   list each time.
1313 ;;;
1314 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1315 ;;;   element of FILE-LIST.
1316 ;;;
1317 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1318 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1319 ;;;   cognizant of the window-configuration.
1320 ;;;
1321 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1322 ;;;   of FILE-LIST giving each a window of height `size'.
1323
1324 (defun dired-do-find-marked-files (&optional noselect)
1325   "Find all marked files displaying all of them simultaneously.
1326 With optional NOSELECT just find files but do not select them.
1327
1328 The current window is split across all files marked, as evenly as possible.
1329 Remaining lines go to bottom-most window.  The number of files that can be
1330 displayed this way is restricted by the height of the current window and
1331 `window-min-height'.
1332
1333 To keep Dired buffer displayed, type \\[split-window-below] first.
1334 To display just marked files, type \\[delete-other-windows] first."
1335   (interactive "P")
1336   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1337
1338 (defun dired-simultaneous-find-file (file-list noselect)
1339   "Visit all files in FILE-LIST and display them simultaneously.
1340 The current window is split across all files in FILE-LIST, as evenly as
1341 possible.  Remaining lines go to the bottom-most window.  The number of
1342 files that can be displayed this way is restricted by the height of the
1343 current window and the variable `window-min-height'.  With non-nil
1344 NOSELECT the files are merely found but not selected."
1345   ;; We don't make this function interactive because it is usually too clumsy
1346   ;; to specify FILE-LIST interactively unless via dired.
1347   (let (size)
1348     (if noselect
1349         ;; Do not select the buffer.
1350         (find-file-noselect (car file-list))
1351       ;; We will have to select the buffer.  Calculate and check window size.
1352       (setq size (/ (window-height) (length file-list)))
1353       (or (<= window-min-height size)
1354           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1355       (find-file (car file-list)))
1356     ;; Decrement.
1357     (dolist (file (cdr file-list))
1358       (if noselect
1359           ;; Do not select the buffer.
1360           (find-file-noselect file)
1361         ;; Vertically split off a window of desired size.  Upper window will
1362         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1363         (select-window (split-window nil size))
1364         (find-file file)))))
1365
1366 \f
1367 ;;; MISCELLANEOUS COMMANDS.
1368
1369 ;; Run man on files.
1370
1371 (declare-function Man-getpage-in-background "man" (topic))
1372
1373 (defvar manual-program) ; from man.el
1374
1375 (defun dired-man ()
1376   "Run `man' on this file."
1377 ;; Used also to say: "Display old buffer if buffer name matches filename."
1378 ;; but I have no idea what that means.
1379   (interactive)
1380   (require 'man)
1381   (let* ((file (dired-get-filename))
1382          (manual-program (replace-regexp-in-string "\\*" "%s"
1383                           (dired-guess-shell-command
1384                            "Man command: " (list file)))))
1385     (Man-getpage-in-background file)))
1386
1387 ;; Run Info on files.
1388
1389 (defun dired-info ()
1390   "Run `info' on this file."
1391   (interactive)
1392   (info (dired-get-filename)))
1393
1394 ;; Run mail on mail folders.
1395
1396 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1397 (defvar vm-folder-directory)
1398
1399 (defun dired-vm (&optional read-only)
1400   "Run VM on this file.
1401 With optional prefix argument, visits the folder read-only.
1402 Otherwise obeys the value of `dired-vm-read-only-folders'."
1403   (interactive "P")
1404   (let ((dir (dired-current-directory))
1405         (fil (dired-get-filename)))
1406     (vm-visit-folder fil (or read-only
1407                              (eq t dired-vm-read-only-folders)
1408                              (and dired-vm-read-only-folders
1409                                   (not (file-writable-p fil)))))
1410     ;; So that pressing `v' inside VM does prompt within current directory:
1411     (set (make-local-variable 'vm-folder-directory) dir)))
1412
1413 (defun dired-rmail ()
1414   "Run RMAIL on this file."
1415   (interactive)
1416   (rmail (dired-get-filename)))
1417
1418 (defun dired-do-run-mail ()
1419   "Visit the current file as a mailbox, using VM or RMAIL.
1420 Prompt for confirmation first; if the user says yes, call
1421 `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail'
1422 otherwise."
1423   (interactive)
1424   (let ((file (dired-get-filename t)))
1425     (if dired-bind-vm
1426         (if (y-or-n-p (format-message
1427                        "Visit `%s' as a mail folder with VM?" file))
1428             (dired-vm))
1429       ;; Read mail folder using rmail.
1430       (if (y-or-n-p (format-message
1431                      "Visit `%s' as a mailbox with RMAIL?" file))
1432           (dired-rmail)))))
1433
1434 \f
1435 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1436
1437 ;; This should be a builtin
1438 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1439   "Return t if BUFFER1 is more recently used than BUFFER2.
1440 Considers buffers closer to the car of `buffer-list' to be more recent."
1441   (and (not (equal buffer1 buffer2))
1442        (memq buffer1 (buffer-list))
1443        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1444
1445 \f
1446 ;; Needed if ls -lh is supported and also for GNU ls -ls.
1447 (defun dired-x--string-to-number (str)
1448   "Like `string-to-number' but recognize a trailing unit prefix.
1449 For example, 2K is expanded to 2048.0.  The caller should make
1450 sure that a trailing letter in STR is one of BKkMGTPEZY."
1451   (let* ((val (string-to-number str))
1452          (u (unless (zerop val)
1453               (aref str (1- (length str))))))
1454     (when (and u (> u ?9))
1455       (when (= u ?k)
1456         (setq u ?K))
1457       (let ((units '(?B ?K ?M ?G ?T ?P ?E ?Z ?Y)))
1458         (while (and units (/= (pop units) u))
1459           (setq val (* 1024.0 val)))))
1460     val))
1461
1462 (defun dired-mark-sexp (predicate &optional unflag-p)
1463   "Mark files for which PREDICATE returns non-nil.
1464 With a prefix arg, unmark or unflag those files instead.
1465
1466 PREDICATE is a lisp expression that can refer to the following symbols:
1467
1468     inode  [integer] the inode of the file (only for ls -i output)
1469     s      [integer] the size of the file for ls -s output
1470                      (usually in blocks or, with -k, in KByte)
1471     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1472     nlink  [integer] number of links to file
1473     uid    [string]  owner
1474     gid    [string]  group  (If the gid is not displayed by ls,
1475                      this will still be set (to the same as uid))
1476     size   [integer] file size in bytes
1477     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1478     name   [string]  the name of the file
1479     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1480
1481 For example, use
1482
1483         (equal 0 size)
1484
1485 to mark all zero length files.
1486
1487 There's an ambiguity when a single integer not followed by a unit
1488 prefix precedes the file mode: It is then parsed as inode number
1489 and not as block size (this always works for GNU coreutils ls).
1490
1491 Another limitation is that the uid field is needed for the
1492 function to work correctly.  In particular, the field is not
1493 present for some values of `ls-lisp-emulation'.
1494
1495 This function operates only on the buffer content and does not
1496 refer at all to the underlying file system.  Contrast this with
1497 `find-dired', which might be preferable for the task at hand."
1498   ;; Using sym="" instead of nil avoids the trap of
1499   ;; (string-match "foo" sym) into which a user would soon fall.
1500   ;; Give `equal' instead of `=' in the example, as this works on
1501   ;; integers and strings.
1502   (interactive
1503    (list (read--expression
1504           (format "%s if (lisp expr): "
1505                   (if current-prefix-arg
1506                       "UNmark"
1507                     "Mark")))
1508          current-prefix-arg))
1509   (message "%s" predicate)
1510   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1511         inode s mode nlink uid gid size time name sym)
1512     (dired-mark-if
1513      (save-excursion
1514        (and
1515         ;; Sets vars
1516         ;;                inode s mode nlink uid gid size time name sym
1517
1518         ;; according to current file line.  Returns t for success, nil if
1519         ;; there is no file line.  Upon success, all variables are set, either
1520         ;; to nil or the appropriate value, so they need not be initialized.
1521         ;; Moves point within the current line.
1522         (dired-move-to-filename)
1523         (let ((mode-len 10) ; length of mode string
1524               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1525               ;; GNU ls -hs suffixes the block count with a unit and
1526               ;; prints it as a float, FreeBSD does neither.
1527               (dired-re-inode-size "\\=\\s *\\([0-9]+\\s +\\)?\
1528 \\(?:\\([0-9]+\\(?:\\.[0-9]*\\)?[BkKMGTPEZY]?\\)? ?\\)"))
1529           (beginning-of-line)
1530           (forward-char 2)
1531           (search-forward-regexp dired-re-inode-size nil t)
1532           ;; XXX Might be a size not followed by a unit prefix.
1533           ;; We could set s to inode if it were otherwise nil,
1534           ;; with a similar reasoning as below for setting gid to uid,
1535           ;; but it would be even more whimsical.
1536           (setq inode (when (match-string 1)
1537                         (string-to-number (match-string 1))))
1538           (setq s (when (match-string 2)
1539                     (dired-x--string-to-number (match-string 2))))
1540           (setq mode (buffer-substring (point) (+ mode-len (point))))
1541           (forward-char mode-len)
1542           ;; Skip any extended attributes marker ("." or "+").
1543           (or (= (following-char) ?\s)
1544               (forward-char 1))
1545           (setq nlink (read (current-buffer)))
1546           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1547           ;; Another issue is that GNU ls -n right-justifies numerical
1548           ;; UIDs and GIDs, while FreeBSD left-justifies them, so
1549           ;; don't rely on a specific whitespace layout.  Both of them
1550           ;; right-justify all other numbers, though.
1551           ;; XXX Return a number if the uid or gid seems to be
1552           ;; numerical?
1553           (setq uid (buffer-substring (progn
1554                                         (skip-chars-forward " \t")
1555                                         (point))
1556                                       (progn
1557                                         (skip-chars-forward "^ \t")
1558                                         (point))))
1559           (dired-move-to-filename)
1560           (save-excursion
1561             (setq time
1562                   ;; The regexp below tries to match from the last
1563                   ;; digit of the size field through a space after the
1564                   ;; date.  Also, dates may have different formats
1565                   ;; depending on file age, so the date column need
1566                   ;; not be aligned to the right.
1567                   (buffer-substring (save-excursion
1568                                       (skip-chars-backward " \t")
1569                                       (point))
1570                                     (progn
1571                                       (re-search-backward
1572                                        directory-listing-before-filename-regexp)
1573                                       (skip-chars-forward "^ \t")
1574                                       (1+ (point))))
1575                   size (dired-x--string-to-number
1576                         ;; We know that there's some kind of number
1577                         ;; before point because the regexp search
1578                         ;; above succeeded.  I don't think it's worth
1579                         ;; doing an extra check for leading garbage.
1580                         (buffer-substring (point)
1581                                           (progn
1582                                             (skip-chars-backward "^ \t")
1583                                             (point))))
1584                   ;; If no gid is displayed, gid will be set to uid
1585                   ;; but the user will then not reference it anyway in
1586                   ;; PREDICATE.
1587                   gid (buffer-substring (progn
1588                                           (skip-chars-backward " \t")
1589                                           (point))
1590                                         (progn
1591                                           (skip-chars-backward "^ \t")
1592                                           (point)))))
1593           (setq name (buffer-substring (point)
1594                                        (or
1595                                         (dired-move-to-end-of-filename t)
1596                                         (point)))
1597                 sym (if (looking-at " -> ")
1598                         (buffer-substring (progn (forward-char 4) (point))
1599                                           (line-end-position))
1600                       ""))
1601           t)
1602         (eval predicate
1603               `((inode . ,inode)
1604                 (s . ,s)
1605                 (mode . ,mode)
1606                 (nlink . ,nlink)
1607                 (uid . ,uid)
1608                 (gid . ,gid)
1609                 (size . ,size)
1610                 (time . ,time)
1611                 (name . ,name)
1612                 (sym . ,sym)))))
1613      (format "'%s file" predicate))))
1614
1615 \f
1616 ;;; FIND FILE AT POINT.
1617
1618 (defcustom dired-x-hands-off-my-keys t
1619   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1620 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1621 If you change this variable without using \\[customize] after `dired-x.el'
1622 is loaded then call \\[dired-x-bind-find-file]."
1623   :type 'boolean
1624   :initialize 'custom-initialize-default
1625   :set (lambda (symbol value)
1626          (set symbol value)
1627          (dired-x-bind-find-file))
1628   :group 'dired-x)
1629
1630 (defun dired-x-bind-find-file ()
1631   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1632 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1633 Binding direction based on `dired-x-hands-off-my-keys'."
1634   (interactive)
1635   (if (called-interactively-p 'interactive)
1636       (setq dired-x-hands-off-my-keys
1637             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1638   (unless dired-x-hands-off-my-keys
1639     (define-key (current-global-map) [remap find-file]
1640       'dired-x-find-file)
1641     (define-key (current-global-map) [remap find-file-other-window]
1642       'dired-x-find-file-other-window)))
1643
1644 ;; Now call it so binding is correct.  This could go in the :initialize
1645 ;; slot, but then dired-x-bind-find-file has to be defined before the
1646 ;; defcustom, and we get free variable warnings.
1647 (dired-x-bind-find-file)
1648
1649 (defun dired-x-find-file (filename)
1650   "Edit file FILENAME.
1651 Like `find-file', except that when called interactively with a
1652 prefix argument, it offers the filename near point as a default."
1653   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1654   (find-file filename))
1655
1656 (defun dired-x-find-file-other-window (filename)
1657   "Edit file FILENAME, in another window.
1658 Like `find-file-other-window', except that when called interactively with
1659 a prefix argument, when it offers the filename near point as a default."
1660   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1661   (find-file-other-window filename))
1662
1663 ;;; Internal functions.
1664
1665 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1666 (defun dired-filename-at-point ()
1667   "Return the filename closest to point, expanded.
1668 Point should be in or after a filename."
1669   (save-excursion
1670     ;; First see if just past a filename.
1671     (or (eobp)                             ; why?
1672         (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens
1673           (skip-chars-backward " \n\t\r({[]})")
1674           (or (bobp) (backward-char 1))))
1675     (let ((filename-chars "-.[:alnum:]_/:$+@")
1676           start prefix)
1677       (if (looking-at-p (format "[%s]" filename-chars))
1678           (progn
1679             (skip-chars-backward filename-chars)
1680             (setq start (point)
1681                   prefix
1682                   ;; This is something to do with ange-ftp filenames.
1683                   ;; It convert foo@bar to /foo@bar.
1684                   ;; But when does the former occur in dired buffers?
1685                   (and (string-match-p
1686                         "^\\w+@"
1687                         (buffer-substring start (line-end-position)))
1688                        "/"))
1689             (if (string-match-p "[/~]" (char-to-string (preceding-char)))
1690                 (setq start (1- start)))
1691             (skip-chars-forward filename-chars))
1692         (error "No file found around point!"))
1693       ;; Return string.
1694       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1695
1696 (defun dired-x-read-filename-at-point (prompt)
1697   "Return filename prompting with PROMPT with completion.
1698 If `current-prefix-arg' is non-nil, uses name at point as guess."
1699   (if current-prefix-arg
1700       (let ((guess (dired-filename-at-point)))
1701         (read-file-name prompt
1702                         (file-name-directory guess)
1703                         guess
1704                         nil (file-name-nondirectory guess)))
1705     (read-file-name prompt default-directory)))
1706
1707 (define-obsolete-function-alias 'read-filename-at-point
1708   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1709 \f
1710 ;;; BUG REPORTS
1711
1712 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1713
1714 \f
1715 ;; As Barry Warsaw would say: "This might be useful..."
1716 (provide 'dired-x)
1717
1718 ;; Local Variables:
1719 ;; byte-compile-dynamic: t
1720 ;; generated-autoload-file: "dired-loaddefs.el"
1721 ;; End:
1722
1723 ;;; dired-x.el ends here