| blob | 519f826f270a8e68073208d496ddcea98d0f1ce2 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 95, 96, 1999, 2000, 01, 02, 03, 2004
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 AC_ARG_ENABLE(maintainer-mode,
129 [ --enable-maintainer-mode enable make rules and dependencies not useful
130 (and sometimes confusing) to the casual installer],
131 USE_MAINTAINER_MODE=$enableval,
132 USE_MAINTAINER_MODE=no)
133 if test $USE_MAINTAINER_MODE = yes; then
134 MAINT=
135 else
136 MAINT=#
137 fi
138 AC_SUBST(MAINT)
140 #### Make srcdir absolute, if it isn't already. It's important to
141 #### avoid running the path through pwd unnecessarily, since pwd can
142 #### give you automounter prefixes, which can go away. We do all this
143 #### so Emacs can find its files when run uninstalled.
144 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
145 unset CDPATH
146 case "${srcdir}" in
147 /* ) ;;
148 . )
149 ## We may be able to use the $PWD environment variable to make this
150 ## absolute. But sometimes PWD is inaccurate.
151 ## Note: we used to use ${PWD} at the end instead of `pwd`,
152 ## but that tested only for a well-formed and valid PWD,
153 ## it did not object when PWD was well-formed and valid but just wrong.
154 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
155 then
156 srcdir="$PWD"
157 else
158 srcdir="`(cd ${srcdir}; pwd)`"
159 fi
160 ;;
161 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
162 esac
164 #### Check if the source directory already has a configured system in it.
165 if test `pwd` != `(cd ${srcdir} && pwd)` \
166 && test -f "${srcdir}/src/config.h" ; then
167 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
168 as a build directory right now; it has been configured in its own
169 right. To configure in another directory as well, you MUST
170 use GNU make. If you do not have GNU make, then you must
171 now do `make distclean' in ${srcdir},
172 and then run $0 again.]])
173 fi
175 #### Given the configuration name, set machfile and opsysfile to the
176 #### names of the m/*.h and s/*.h files we should use.
178 ### Canonicalize the configuration name.
180 AC_CANONICAL_HOST
181 canonical=$host
182 configuration=${host_alias-$host}
184 dnl This used to use changequote, but, apart from `changequote is evil'
185 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
186 dnl the great gob of text. Thus it's not processed for possible expansion.
187 dnl Just make sure the brackets remain balanced.
188 dnl
189 dnl Since Emacs can't find matching pairs of quotes, boundaries are
190 dnl indicated by comments.
191 dnl quotation begins
192 [
194 ### If you add support for a new configuration, add code to this
195 ### switch statement to recognize your configuration name and select
196 ### the appropriate operating system and machine description files.
198 ### You would hope that you could choose an m/*.h file pretty much
199 ### based on the machine portion of the configuration name, and an s-
200 ### file based on the operating system portion. However, it turns out
201 ### that each m/*.h file is pretty manufacturer-specific - for
202 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
203 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
204 ### machines. So we basically have to have a special case for each
205 ### configuration name.
206 ###
207 ### As far as handling version numbers on operating systems is
208 ### concerned, make sure things will fail in a fixable way. If
209 ### /etc/MACHINES doesn't say anything about version numbers, be
210 ### prepared to handle anything reasonably. If version numbers
211 ### matter, be sure /etc/MACHINES says something about it.
212 ###
213 ### Eric Raymond says we should accept strings like "sysvr4" to mean
214 ### "System V Release 4"; he writes, "The old convention encouraged
215 ### confusion between `system' and `release' levels'."
217 machine='' opsys='' unported=no
218 case "${canonical}" in
220 ## FreeBSD ports
221 *-*-freebsd* )
222 opsys=freebsd
223 case "${canonical}" in
224 alpha*-*-freebsd*) machine=alpha ;;
225 i[3456]86-*-freebsd*) machine=intel386 ;;
226 esac
227 ;;
229 ## NetBSD ports
230 *-*-netbsd* )
231 opsys=netbsd
232 if test -f /usr/lib/crti.o; then]
233 dnl The close and open brackets here are because this section is quoted --
234 dnl see the `changequote' comment above.
235 AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
236 [ fi
238 case "${canonical}" in
239 alpha*-*-netbsd*) machine=alpha ;;
240 i[3456]86-*-netbsd*) machine=intel386 ;;
241 m68k-*-netbsd*)
242 # This is somewhat bogus.
243 machine=hp9000s300 ;;
244 powerpc-apple-netbsd*) machine=macppc ;;
245 mips-*-netbsd*) machine=pmax ;;
246 mipsel-*-netbsd*) machine=pmax ;;
247 mipseb-*-netbsd*) machine=pmax ;;
248 ns32k-*-netbsd*) machine=ns32000 ;;
249 powerpc-*-netbsd*) machine=macppc ;;
250 sparc*-*-netbsd*) machine=sparc ;;
251 vax-*-netbsd*) machine=vax ;;
252 arm-*-netbsd*) machine=arm ;;
253 esac
254 ;;
256 ## OpenBSD ports
257 *-*-openbsd* )
258 opsys=openbsd
259 case "${canonical}" in
260 alpha*-*-openbsd*) machine=alpha ;;
261 i386-*-openbsd*) machine=intel386 ;;
262 m68k-*-openbsd*) machine=hp9000s300 ;;
263 mipsel-*-openbsd*) machine=pmax ;;
264 ns32k-*-openbsd*) machine=ns32000 ;;
265 sparc-*-openbsd*) machine=sparc ;;
266 vax-*-openbsd*) machine=vax ;;
267 esac
268 ;;
270 ## Acorn RISCiX:
271 arm-acorn-riscix1.1* )
272 machine=acorn opsys=riscix1-1
273 ;;
274 arm-acorn-riscix1.2* | arm-acorn-riscix )
275 ## This name is riscix12 instead of riscix1.2
276 ## to avoid a file name conflict on MSDOS.
277 machine=acorn opsys=riscix12
278 ;;
280 ## BSDI ports
281 *-*-bsdi* )
282 opsys=bsdi
283 case "${canonical}" in
284 i[345]86-*-bsdi*) machine=intel386 ;;
285 sparc-*-bsdi*) machine=sparc ;;
286 powerpc-*-bsdi*) machine=macppc ;;
287 esac
288 case "${canonical}" in
289 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
290 *-*-bsdi2.0* ) opsys=bsdos2 ;;
291 *-*-bsdi2* ) opsys=bsdos2-1 ;;
292 *-*-bsdi3* ) opsys=bsdos3 ;;
293 *-*-bsdi[45]* ) opsys=bsdos4 ;;
294 esac
295 ;;
297 ## Alliant machines
298 ## Strictly speaking, we need the version of the alliant operating
299 ## system to choose the right machine file, but currently the
300 ## configuration name doesn't tell us enough to choose the right
301 ## one; we need to give alliants their own operating system name to
302 ## do this right. When someone cares, they can help us.
303 fx80-alliant-* )
304 machine=alliant4 opsys=bsd4-2
305 ;;
306 i860-alliant-* )
307 machine=alliant-2800 opsys=bsd4-3
308 ;;
310 ## Alpha (DEC) machines.
311 alpha*-dec-osf* )
312 machine=alpha opsys=osf1
313 # This is needed to find X11R6.1 libraries for certain tests.
314 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
315 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
316 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
317 # due to non-traditional preprocessing with the current compiler
318 # defaults. OSF 4 can also have that compiler version, and there
319 # seems always to have been a usable /usr/bin/cpp.
320 NON_GNU_CPP=/usr/bin/cpp
321 case "${canonical}" in
322 alpha*-dec-osf[5-9]*)
323 opsys=osf5-0 ;;
324 esac
325 ;;
327 alpha*-*-linux-gnu* )
328 machine=alpha opsys=gnu-linux
329 ;;
331 arm*-*-linux-gnu* )
332 machine=arm opsys=gnu-linux
333 ;;
335 ppc-*-linux | \
336 powerpc-*-linux* )
337 machine=macppc opsys=gnu-linux
338 ;;
340 ## Altos 3068
341 m68*-altos-sysv* )
342 machine=altos opsys=usg5-2
343 ;;
345 ## Amdahl UTS
346 580-amdahl-sysv* )
347 machine=amdahl opsys=usg5-2-2
348 ;;
350 ## Apollo, Domain/OS
351 m68*-apollo-* )
352 machine=apollo opsys=bsd4-3
353 ;;
355 ## AT&T 3b2, 3b5, 3b15, 3b20
356 we32k-att-sysv* )
357 machine=att3b opsys=usg5-2-2
358 ;;
360 ## AT&T 3b1 - The Mighty Unix PC!
361 m68*-att-sysv* )
362 machine=7300 opsys=usg5-2-2
363 ;;
365 ## Bull dpx20
366 rs6000-bull-bosx* )
367 machine=ibmrs6000 opsys=aix3-2
368 ;;
370 ## Bull dpx2
371 m68*-bull-sysv3* )
372 machine=dpx2 opsys=usg5-3
373 ;;
375 ## Bull sps7
376 m68*-bull-sysv2* )
377 machine=sps7 opsys=usg5-2
378 ;;
380 ## CCI 5/32, 6/32 -- see "Tahoe".
382 ## Celerity
383 ## I don't know what configuration name to use for this; config.sub
384 ## doesn't seem to know anything about it. Hey, Celerity users, get
385 ## in touch with us!
386 celerity-celerity-bsd* )
387 machine=celerity opsys=bsd4-2
388 ;;
390 ## Clipper
391 ## What operating systems does this chip run that Emacs has been
392 ## tested on?
393 clipper-* )
394 machine=clipper
395 ## We'll use the catch-all code at the bottom to guess the
396 ## operating system.
397 ;;
399 ## Compaq Nonstop
400 mips-compaq-nonstopux* )
401 machine=nonstopux opsys=nonstopux
402 ;;
404 ## Convex
405 *-convex-bsd* | *-convex-convexos* )
406 machine=convex opsys=bsd4-3
407 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
408 NON_GNU_CPP="cc -E -P"
409 ;;
411 ## Cubix QBx/386
412 i[3456]86-cubix-sysv* )
413 machine=intel386 opsys=usg5-3
414 ;;
416 ## Cydra 5
417 cydra*-cydrome-sysv* )
418 machine=cydra5 opsys=usg5-3
419 ;;
421 ## Data General AViiON Machines
422 ## DG changed naming conventions with the release of 5.4.4.10, they
423 ## dropped the initial 5.4 but left the intervening R. Because of the
424 ## R this shouldn't conflict with older versions of the OS (which I
425 ## think were named like dgux4.*). In addition, DG new AViiONs series
426 ## uses either Motorola M88k or Intel Pentium CPUs.
427 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
428 machine=aviion opsys=dgux4
429 ;;
430 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
431 ## This name is dgux5-4-3 instead of dgux5-4r3
432 ## to avoid a file name conflict on MSDOS.
433 machine=aviion opsys=dgux5-4-3
434 ;;
435 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
436 machine=aviion opsys=dgux5-4r2
437 ;;
438 m88k-dg-dgux* )
439 machine=aviion opsys=dgux
440 ;;
442 ## Data General AViiON Intel (x86) Machines
443 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
444 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
445 i[345]86-dg-dguxR4* )
446 machine=aviion-intel opsys=dgux4
447 ;;
449 ## DECstations
450 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
451 machine=pmax opsys=bsd4-2
452 ;;
453 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
454 machine=pmax opsys=bsd4-3
455 ;;
456 mips-dec-ultrix* )
457 machine=pmax opsys=ultrix4-3
458 ;;
459 mips-dec-osf* )
460 machine=pmax opsys=osf1
461 ;;
462 mips-dec-mach_bsd4.3* )
463 machine=pmax opsys=mach-bsd4-3
464 ;;
466 ## Motorola Delta machines
467 m68k-motorola-sysv* | m68000-motorola-sysv* )
468 machine=delta opsys=usg5-3
469 if test -z "`type gnucc | grep 'not found'`"
470 then
471 if test -s /etc/167config
472 then CC="gnucc -m68040"
473 else CC="gnucc -m68881"
474 fi
475 else
476 if test -z "`type gcc | grep 'not found'`"
477 then CC=gcc
478 else CC=cc
479 fi
480 fi
481 ;;
482 m88k-motorola-sysv4* )
483 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
484 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
485 # I hope there are not other 4.0 versions for this machine
486 # which really need usg5-4 instead.
487 machine=delta88k opsys=usg5-4-2
488 ;;
489 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
490 machine=delta88k opsys=usg5-3
491 ;;
493 ## Dual machines
494 m68*-dual-sysv* )
495 machine=dual opsys=usg5-2
496 ;;
497 m68*-dual-uniplus* )
498 machine=dual opsys=unipl5-2
499 ;;
501 ## Elxsi 6400
502 elxsi-elxsi-sysv* )
503 machine=elxsi opsys=usg5-2
504 ;;
506 ## Encore machines
507 ns16k-encore-bsd* )
508 machine=ns16000 opsys=umax
509 ;;
511 ## The GEC 63 - apparently, this port isn't really finished yet.
512 # I'm sure we finished off the last of the machines, though. -- fx
514 ## Gould Power Node and NP1
515 pn-gould-bsd4.2* )
516 machine=gould opsys=bsd4-2
517 ;;
518 pn-gould-bsd4.3* )
519 machine=gould opsys=bsd4-3
520 ;;
521 np1-gould-bsd* )
522 machine=gould-np1 opsys=bsd4-3
523 ;;
525 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
526 ## as far as Emacs is concerned).
527 m88k-harris-cxux* )
528 # Build needs to be different on 7.0 and later releases
529 case "`uname -r`" in
530 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
531 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
532 esac
533 NON_GNU_CPP="/lib/cpp"
534 ;;
535 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
536 m68k-harris-cxux* )
537 machine=nh3000 opsys=cxux
538 ;;
539 ## Harris power pc NightHawk running Power UNIX (Series 6000)
540 powerpc-harris-powerunix )
541 machine=nh6000 opsys=powerunix
542 NON_GNU_CPP="cc -Xo -E -P"
543 ;;
544 ## SR2001/SR2201 running HI-UX/MPP
545 hppa1.1-hitachi-hiuxmpp* )
546 machine=sr2k opsys=hiuxmpp
547 ;;
548 hppa1.1-hitachi-hiuxwe2* )
549 machine=sr2k opsys=hiuxwe2
550 ;;
551 ## Honeywell XPS100
552 xps*-honeywell-sysv* )
553 machine=xps100 opsys=usg5-2
554 ;;
556 ## HP 9000 series 200 or 300
557 m68*-hp-bsd* )
558 machine=hp9000s300 opsys=bsd4-3
559 ;;
560 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
561 m68*-hp-hpux* )
562 case "`uname -r`" in
563 ## Someone's system reports A.B8.05 for this.
564 ## I wonder what other possibilities there are.
565 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
566 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
567 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
568 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
569 *) machine=hp9000s300 opsys=hpux ;;
570 esac
571 ;;
573 ## HP 9000 series 700 and 800, running HP/UX
574 hppa*-hp-hpux7* )
575 machine=hp800 opsys=hpux
576 ;;
577 hppa*-hp-hpux8* )
578 machine=hp800 opsys=hpux8
579 ;;
580 hppa*-hp-hpux9shr* )
581 machine=hp800 opsys=hpux9shr
582 ;;
583 hppa*-hp-hpux9* )
584 machine=hp800 opsys=hpux9
585 ;;
586 hppa*-hp-hpux10.2* )
587 machine=hp800 opsys=hpux10-20
588 ;;
589 hppa*-hp-hpux10* )
590 machine=hp800 opsys=hpux10
591 ;;
592 hppa*-hp-hpux1[1-9]* )
593 machine=hp800 opsys=hpux11
594 ;;
596 hppa*-*-linux-gnu* )
597 machine=hp800 opsys=gnu-linux
598 ;;
600 ## HP 9000 series 700 and 800, running HP/UX
601 hppa*-hp-hpux* )
602 ## Cross-compilation? Nah!
603 case "`uname -r`" in
604 ## Someone's system reports A.B8.05 for this.
605 ## I wonder what other possibilities there are.
606 *.B8.* ) machine=hp800 opsys=hpux8 ;;
607 *.08.* ) machine=hp800 opsys=hpux8 ;;
608 *.09.* ) machine=hp800 opsys=hpux9 ;;
609 *) machine=hp800 opsys=hpux10 ;;
610 esac
611 ;;
612 hppa*-*-nextstep* )
613 machine=hp800 opsys=nextstep
614 ;;
616 ## Orion machines
617 orion-orion-bsd* )
618 machine=orion opsys=bsd4-2
619 ;;
620 clipper-orion-bsd* )
621 machine=orion105 opsys=bsd4-2
622 ;;
624 ## IBM machines
625 i[3456]86-ibm-aix1.1* )
626 machine=ibmps2-aix opsys=usg5-2-2
627 ;;
628 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
629 machine=ibmps2-aix opsys=usg5-3
630 ;;
631 i370-ibm-aix*)
632 machine=ibm370aix opsys=usg5-3
633 ;;
634 s390-*-linux-gnu* )
635 machine=ibms390 opsys=gnu-linux
636 ;;
637 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
638 machine=ibmrs6000 opsys=aix3-1
639 ;;
640 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
641 machine=ibmrs6000 opsys=aix3-2-5
642 ;;
643 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
644 machine=ibmrs6000 opsys=aix4-1
645 ;;
646 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
647 machine=ibmrs6000 opsys=aix4-2
648 ;;
649 rs6000-ibm-aix5* | powerpc-ibm-aix5* )
650 machine=ibmrs6000 opsys=aix4-2
651 ;;
652 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
653 machine=ibmrs6000 opsys=aix4
654 ;;
655 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
656 machine=ibmrs6000 opsys=aix4-1
657 ;;
658 rs6000-ibm-aix* | powerpc-ibm-aix* )
659 machine=ibmrs6000 opsys=aix3-2
660 ;;
661 romp-ibm-bsd4.3* )
662 machine=ibmrt opsys=bsd4-3
663 ;;
664 romp-ibm-bsd4.2* )
665 machine=ibmrt opsys=bsd4-2
666 ;;
667 romp-ibm-aos4.3* )
668 machine=ibmrt opsys=bsd4-3
669 ;;
670 romp-ibm-aos4.2* )
671 machine=ibmrt opsys=bsd4-2
672 ;;
673 romp-ibm-aos* )
674 machine=ibmrt opsys=bsd4-3
675 ;;
676 romp-ibm-bsd* )
677 machine=ibmrt opsys=bsd4-3
678 ;;
679 romp-ibm-aix* )
680 machine=ibmrt-aix opsys=usg5-2-2
681 ;;
683 ## Integrated Solutions `Optimum V'
684 m68*-isi-bsd4.2* )
685 machine=isi-ov opsys=bsd4-2
686 ;;
687 m68*-isi-bsd4.3* )
688 machine=isi-ov opsys=bsd4-3
689 ;;
691 ## Intel 386 machines where we do care about the manufacturer
692 i[3456]86-intsys-sysv* )
693 machine=is386 opsys=usg5-2-2
694 ;;
696 ## Prime EXL
697 i[3456]86-prime-sysv* )
698 machine=i386 opsys=usg5-3
699 ;;
701 ## Sequent Symmetry running Dynix
702 i[3456]86-sequent-bsd* )
703 machine=symmetry opsys=bsd4-3
704 ;;
706 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
707 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
708 machine=sequent-ptx opsys=ptx4
709 NON_GNU_CPP=/lib/cpp
710 ;;
712 ## Sequent Symmetry running DYNIX/ptx
713 ## Use the old cpp rather than the newer ANSI one.
714 i[3456]86-sequent-ptx* )
715 machine=sequent-ptx opsys=ptx
716 NON_GNU_CPP="/lib/cpp"
717 ;;
719 ## ncr machine running svr4.3.
720 i[3456]86-ncr-sysv4.3 )
721 machine=ncr386 opsys=usg5-4-3
722 ;;
724 ## Unspecified sysv on an ncr machine defaults to svr4.2.
725 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
726 i[3456]86-ncr-sysv* )
727 machine=ncr386 opsys=usg5-4-2
728 ;;
730 ## Intel Paragon OSF/1
731 i860-intel-osf1* )
732 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
733 ;;
735 ## Intel 860
736 i860-*-sysv4* )
737 machine=i860 opsys=usg5-4
738 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
739 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
740 ;;
742 ## Macintosh PowerPC
743 powerpc*-*-linux-gnu* )
744 machine=macppc opsys=gnu-linux
745 ;;
747 ## Masscomp machines
748 m68*-masscomp-rtu* )
749 machine=masscomp opsys=rtu
750 ;;
752 ## Megatest machines
753 m68*-megatest-bsd* )
754 machine=mega68 opsys=bsd4-2
755 ;;
757 ## Workstations sold by MIPS
758 ## This is not necessarily all workstations using the MIPS processor -
759 ## Irises are produced by SGI, and DECstations by DEC.
761 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
762 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
763 ## it gives for choosing between the alternatives seems to be "Use
764 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
765 ## the BSD world." I'll assume that these are instructions for
766 ## handling two odd situations, and that every other situation
767 ## should use mips.h and usg5-2-2, they being listed first.
768 mips-mips-usg* )
769 machine=mips4
770 ## Fall through to the general code at the bottom to decide on the OS.
771 ;;
772 mips-mips-riscos4* )
773 machine=mips4 opsys=bsd4-3
774 NON_GNU_CC="cc -systype bsd43"
775 NON_GNU_CPP="cc -systype bsd43 -E"
776 ;;
777 mips-mips-riscos5* )
778 machine=mips4 opsys=riscos5
779 NON_GNU_CC="cc -systype bsd43"
780 NON_GNU_CPP="cc -systype bsd43 -E"
781 ;;
782 mips-mips-bsd* )
783 machine=mips opsys=bsd4-3
784 ;;
785 mips-mips-* )
786 machine=mips opsys=usg5-2-2
787 ;;
789 ## NeXT
790 m68*-next-* | m68k-*-nextstep* )
791 machine=m68k opsys=nextstep
792 ;;
794 ## The complete machine from National Semiconductor
795 ns32k-ns-genix* )
796 machine=ns32000 opsys=usg5-2
797 ;;
799 ## NCR machines
800 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
801 machine=tower32 opsys=usg5-2-2
802 ;;
803 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
804 machine=tower32v3 opsys=usg5-3
805 ;;
807 ## NEC EWS4800
808 mips-nec-sysv4*)
809 machine=ews4800 opsys=ux4800
810 ;;
812 ## Nixdorf Targon 31
813 m68*-nixdorf-sysv* )
814 machine=targon31 opsys=usg5-2-2
815 ;;
817 ## Nu (TI or LMI)
818 m68*-nu-sysv* )
819 machine=nu opsys=usg5-2
820 ;;
822 ## Plexus
823 m68*-plexus-sysv* )
824 machine=plexus opsys=usg5-2
825 ;;
827 ## Pyramid machines
828 ## I don't really have any idea what sort of processor the Pyramid has,
829 ## so I'm assuming it is its own architecture.
830 pyramid-pyramid-bsd* )
831 machine=pyramid opsys=bsd4-2
832 ;;
834 ## Sequent Balance
835 ns32k-sequent-bsd4.2* )
836 machine=sequent opsys=bsd4-2
837 ;;
838 ns32k-sequent-bsd4.3* )
839 machine=sequent opsys=bsd4-3
840 ;;
842 ## Siemens Nixdorf
843 mips-siemens-sysv* | mips-sni-sysv*)
844 machine=mips-siemens opsys=usg5-4
845 NON_GNU_CC=/usr/ccs/bin/cc
846 NON_GNU_CPP=/usr/ccs/lib/cpp
847 ;;
849 ## Silicon Graphics machines
850 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
851 m68*-sgi-iris3.5* )
852 machine=irist opsys=iris3-5
853 ;;
854 m68*-sgi-iris3.6* | m68*-sgi-iris*)
855 machine=irist opsys=iris3-6
856 ;;
857 ## Iris 4D
858 mips-sgi-irix3* )
859 machine=iris4d opsys=irix3-3
860 ;;
861 mips-sgi-irix4* )
862 machine=iris4d opsys=irix4-0
863 ;;
864 mips-sgi-irix6.5 )
865 machine=iris4d opsys=irix6-5
866 # Without defining _LANGUAGE_C, things get masked out in the headers
867 # so that, for instance, grepping for `free' in stdlib.h fails and
868 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
869 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
870 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
871 ;;
872 mips-sgi-irix6* )
873 machine=iris4d opsys=irix6-0
874 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
875 # but presumably it does no harm.
876 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
877 # -32 probably isn't necessary in later v.6s -- anyone know which?
878 NON_GCC_TEST_OPTIONS=-32
879 ;;
880 mips-sgi-irix5.[01]* )
881 machine=iris4d opsys=irix5-0
882 ;;
883 mips-sgi-irix5* | mips-sgi-irix* )
884 machine=iris4d opsys=irix5-2
885 ;;
887 ## SONY machines
888 m68*-sony-bsd4.2* )
889 machine=news opsys=bsd4-2
890 ;;
891 m68*-sony-bsd4.3* )
892 machine=news opsys=bsd4-3
893 ;;
894 m68*-sony-newsos3* | m68*-sony-news3*)
895 machine=news opsys=bsd4-3
896 ;;
897 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
898 machine=news-risc opsys=bsd4-3
899 ;;
900 mips-sony-newsos6* )
901 machine=news-r6 opsys=newsos6
902 ;;
903 mips-sony-news* )
904 machine=news-risc opsys=newsos5
905 ;;
907 ## Stride
908 m68*-stride-sysv* )
909 machine=stride opsys=usg5-2
910 ;;
912 ## Suns
913 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
914 machine=sparc opsys=gnu-linux
915 ;;
917 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
918 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
919 | rs6000-*-solaris2*)
920 case "${canonical}" in
921 m68*-sunos1* ) machine=sun1 ;;
922 m68*-sunos2* ) machine=sun2 ;;
923 m68* ) machine=sun3 ;;
924 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
925 i[3456]86-*-* ) machine=intel386 ;;
926 powerpcle* ) machine=powerpcle ;;
927 powerpc* | rs6000* ) machine=ibmrs6000 ;;
928 sparc* ) machine=sparc ;;
929 * ) unported=yes ;;
930 esac
931 case "${canonical}" in
932 ## The Sun386 didn't get past 4.0.
933 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
934 *-sunos4.0* ) opsys=sunos4-0 ;;
935 *-sunos4.1.[3-9]*noshare )
936 ## This name is sunos413 instead of sunos4-1-3
937 ## to avoid a file name conflict on MSDOS.
938 opsys=sunos413
939 NON_GNU_CPP=/usr/lib/cpp
940 NON_GCC_TEST_OPTIONS=-Bstatic
941 GCC_TEST_OPTIONS=-static
942 ;;
943 *-sunos4.1.[3-9]* | *-sunos4shr*)
944 opsys=sunos4shr
945 NON_GNU_CPP=/usr/lib/cpp
946 ;;
947 *-sunos4* | *-sunos )
948 opsys=sunos4-1
949 NON_GCC_TEST_OPTIONS=-Bstatic
950 GCC_TEST_OPTIONS=-static
951 ;;
952 *-sunos5.3* | *-solaris2.3* )
953 opsys=sol2-3
954 NON_GNU_CPP=/usr/ccs/lib/cpp
955 ;;
956 *-sunos5.4* | *-solaris2.4* )
957 opsys=sol2-4
958 NON_GNU_CPP=/usr/ccs/lib/cpp
959 RANLIB="ar -ts"
960 ;;
961 *-sunos5.5* | *-solaris2.5* )
962 opsys=sol2-5
963 NON_GNU_CPP=/usr/ccs/lib/cpp
964 RANLIB="ar -ts"
965 ;;
966 *-sunos5.6* | *-solaris2.6* )
967 opsys=sol2-6
968 NON_GNU_CPP=/usr/ccs/lib/cpp
969 RANLIB="ar -ts"
970 ;;
971 *-sunos5* | *-solaris* )
972 opsys=sol2-6
973 NON_GNU_CPP=/usr/ccs/lib/cpp
974 ;;
975 * ) opsys=bsd4-2 ;;
976 esac
977 ## Watch out for a compiler that we know will not work.
978 case "${canonical}" in
979 *-solaris* | *-sunos5* )
980 if [ "x$CC" = x/usr/ucb/cc ]; then
981 ## /usr/ucb/cc doesn't work;
982 ## we should find some other compiler that does work.
983 unset CC
984 fi
985 ;;
986 *) ;;
987 esac
988 ;;
989 sparc-*-nextstep* )
990 machine=sparc opsys=nextstep
991 ;;
993 ## Tadpole 68k
994 m68*-tadpole-sysv* )
995 machine=tad68k opsys=usg5-3
996 ;;
998 ## Tahoe machines
999 tahoe-tahoe-bsd4.2* )
1000 machine=tahoe opsys=bsd4-2
1001 ;;
1002 tahoe-tahoe-bsd4.3* )
1003 machine=tahoe opsys=bsd4-3
1004 ;;
1006 ## Tandem Integrity S2
1007 mips-tandem-sysv* )
1008 machine=tandem-s2 opsys=usg5-3
1009 ;;
1011 ## Tektronix XD88
1012 m88k-tektronix-sysv3* )
1013 machine=tekxd88 opsys=usg5-3
1014 ;;
1016 ## Tektronix 16000 box (6130?)
1017 ns16k-tektronix-bsd* )
1018 machine=ns16000 opsys=bsd4-2
1019 ;;
1020 ## Tektronix 4300
1021 ## src/m/tek4300.h hints that this is a m68k machine.
1022 m68*-tektronix-bsd* )
1023 machine=tek4300 opsys=bsd4-3
1024 ;;
1026 ## Titan P2 or P3
1027 ## We seem to have lost the machine-description file titan.h!
1028 titan-titan-sysv* )
1029 machine=titan opsys=usg5-3
1030 ;;
1032 ## Ustation E30 (SS5E)
1033 m68*-unisys-uniplus* )
1034 machine=ustation opsystem=unipl5-2
1035 ;;
1037 ## Vaxen.
1038 vax-dec-* )
1039 machine=vax
1040 case "${canonical}" in
1041 *-bsd4.1* ) opsys=bsd4-1 ;;
1042 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1043 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1044 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1045 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1046 *-vms* ) opsys=vms ;;
1047 * ) unported=yes
1048 esac
1049 ;;
1051 ## Whitechapel MG1
1052 ns16k-whitechapel-* )
1053 machine=mg1
1054 ## We don't know what sort of OS runs on these; we'll let the
1055 ## operating system guessing code below try.
1056 ;;
1058 ## Wicat
1059 m68*-wicat-sysv* )
1060 machine=wicat opsys=usg5-2
1061 ;;
1063 ## IA-64
1064 ia64*-*-linux* )
1065 machine=ia64 opsys=gnu-linux
1066 ;;
1068 ## Intel 386 machines where we don't care about the manufacturer
1069 i[3456]86-*-* )
1070 machine=intel386
1071 case "${canonical}" in
1072 *-cygwin ) opsys=cygwin ;;
1073 *-lynxos* ) opsys=lynxos ;;
1074 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1075 *-isc2.2* ) opsys=isc2-2 ;;
1076 *-isc4.0* ) opsys=isc4-0 ;;
1077 *-isc4.* ) opsys=isc4-1
1078 GCC_TEST_OPTIONS=-posix
1079 NON_GCC_TEST_OPTIONS=-Xp
1080 ;;
1081 *-isc* ) opsys=isc3-0 ;;
1082 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1083 *-esix* ) opsys=esix ;;
1084 *-xenix* ) opsys=xenix ;;
1085 *-linux-gnu* ) opsys=gnu-linux ;;
1086 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1087 *-sco3.2v5* ) opsys=sco5
1088 NON_GNU_CPP=/lib/cpp
1089 # Prevent -belf from being passed to $CPP.
1090 # /lib/cpp does not accept it.
1091 OVERRIDE_CPPFLAGS=" "
1092 ;;
1093 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1094 *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1095 *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1096 *-386bsd* ) opsys=386bsd ;;
1097 *-nextstep* ) opsys=nextstep ;;
1098 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1099 esac
1100 ;;
1102 ## m68k Linux-based GNU system
1103 m68k-*-linux-gnu* )
1104 machine=m68k opsys=gnu-linux
1105 ;;
1107 ## Mips Linux-based GNU system
1108 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1109 machine=mips opsys=gnu-linux
1110 ;;
1112 ## UXP/DS
1113 sparc-fujitsu-sysv4* )
1114 machine=sparc opsys=uxpds
1115 NON_GNU_CPP=/usr/ccs/lib/cpp
1116 RANLIB="ar -ts"
1117 ;;
1119 ## UXP/V
1120 f301-fujitsu-uxpv4.1)
1121 machine=f301 opsys=uxpv
1122 ;;
1124 ## Darwin / Mac OS X
1125 powerpc-apple-darwin* )
1126 machine=powermac opsys=darwin
1127 # Define CPP as follows to make autoconf work correctly.
1128 CPP="${CC-cc} -E -no-cpp-precomp"
1129 # Use fink packages if available.
1130 if test -d /sw/include && test -d /sw/lib; then
1131 GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
1132 CPP="${CPP} ${GCC_TEST_OPTIONS}"
1133 NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
1134 fi
1135 ;;
1137 ## AMD x86-64 Linux-based GNU system
1138 x86_64-*-linux-gnu* )
1139 machine=amdx86-64 opsys=gnu-linux
1140 ;;
1142 * )
1143 unported=yes
1144 ;;
1145 esac
1147 ### If the code above didn't choose an operating system, just choose
1148 ### an operating system based on the configuration name. You really
1149 ### only want to use this when you have no idea what the right
1150 ### operating system is; if you know what operating systems a machine
1151 ### runs, it's cleaner to make it explicit in the case statement
1152 ### above.
1153 if test x"${opsys}" = x; then
1154 case "${canonical}" in
1155 *-gnu* ) opsys=gnu ;;
1156 *-bsd4.[01] ) opsys=bsd4-1 ;;
1157 *-bsd4.2 ) opsys=bsd4-2 ;;
1158 *-bsd4.3 ) opsys=bsd4-3 ;;
1159 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1160 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1161 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1162 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1163 *-sysv4.2uw* ) opsys=unixware ;;
1164 *-sysv5uw* ) opsys=unixware ;;
1165 *-sysv5OpenUNIX* ) opsys=unixware ;;
1166 *-sysv4.1* | *-sysvr4.1* )
1167 NON_GNU_CPP=/usr/lib/cpp
1168 opsys=usg5-4 ;;
1169 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1170 if [ x$NON_GNU_CPP = x ]; then
1171 if [ -f /usr/ccs/lib/cpp ]; then
1172 NON_GNU_CPP=/usr/ccs/lib/cpp
1173 else
1174 NON_GNU_CPP=/lib/cpp
1175 fi
1176 fi
1177 opsys=usg5-4-2 ;;
1178 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1179 * )
1180 unported=yes
1181 ;;
1182 esac
1183 fi
1185 ]
1186 dnl quotation ends
1188 if test $unported = yes; then
1189 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1190 Check `etc/MACHINES' for recognized configuration names.])
1191 fi
1193 machfile="m/${machine}.h"
1194 opsysfile="s/${opsys}.h"
1197 #### Choose a compiler.
1198 test -n "$CC" && cc_specified=yes
1200 # Save the value of CFLAGS that the user specified.
1201 SPECIFIED_CFLAGS="$CFLAGS"
1203 case ${with_gcc} in
1204 "yes" ) CC="gcc" GCC=yes ;;
1205 "no" ) : ${CC=cc} ;;
1206 * )
1207 esac
1208 AC_PROG_CC
1210 # On Suns, sometimes $CPP names a directory.
1211 if test -n "$CPP" && test -d "$CPP"; then
1212 CPP=
1213 fi
1215 #### Some systems specify a CPP to use unless we are using GCC.
1216 #### Now that we know whether we are using GCC, we can decide whether
1217 #### to use that one.
1218 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1219 then
1220 CPP="$NON_GNU_CPP"
1221 fi
1223 #### Some systems specify a CC to use unless we are using GCC.
1224 #### Now that we know whether we are using GCC, we can decide whether
1225 #### to use that one.
1226 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1227 test x$cc_specified != xyes
1228 then
1229 CC="$NON_GNU_CC"
1230 fi
1232 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1233 then
1234 CC="$CC $GCC_TEST_OPTIONS"
1235 fi
1237 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1238 then
1239 CC="$CC $NON_GCC_TEST_OPTIONS"
1240 fi
1242 #### Some other nice autoconf tests.
1244 dnl checks for programs
1245 AC_PROG_LN_S
1246 AC_PROG_CPP
1247 AC_PROG_INSTALL
1248 if test "x$RANLIB" = x; then
1249 AC_PROG_RANLIB
1250 fi
1251 AC_PATH_PROG(INSTALL_INFO, install-info)
1252 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1253 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1255 dnl Add our options to ac_link now, after it is set up.
1257 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1258 then
1259 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1260 fi
1262 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1263 then
1264 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1265 fi
1267 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1268 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1269 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1270 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1271 dnl if not built to support GNU ld.
1273 late_LDFLAGS=$LDFLAGS
1274 if test "$GCC" = yes; then
1275 LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1276 else
1277 LDFLAGS="$LDFLAGS -znocombreloc"
1278 fi
1280 AC_MSG_CHECKING([For -znocombreloc])
1281 AC_LINK_IFELSE([main(){return 0;}],
1282 [AC_MSG_RESULT(yes)],
1283 LDFLAGS=$late_LDFLAGS
1284 [AC_MSG_RESULT(no)])
1286 dnl checks for Unix variants
1287 AC_AIX
1290 #### Extract some information from the operating system and machine files.
1292 AC_CHECKING([the machine- and system-dependent files to find out
1293 - which libraries the lib-src programs will want, and
1294 - whether the GNU malloc routines are usable])
1296 ### First figure out CFLAGS (which we use for running the compiler here)
1297 ### and REAL_CFLAGS (which we use for real compilation).
1298 ### The two are the same except on a few systems, where they are made
1299 ### different to work around various lossages. For example,
1300 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1301 ### as implying static linking.
1303 ### If the CFLAGS env var is specified, we use that value
1304 ### instead of the default.
1306 ### It's not important that this name contain the PID; you can't run
1307 ### two configures in the same directory and have anything work
1308 ### anyway.
1309 tempcname="conftest.c"
1311 echo '
1312 #include "'${srcdir}'/src/'${opsysfile}'"
1313 #include "'${srcdir}'/src/'${machfile}'"
1314 #ifndef LIBS_MACHINE
1315 #define LIBS_MACHINE
1316 #endif
1317 #ifndef LIBS_SYSTEM
1318 #define LIBS_SYSTEM
1319 #endif
1320 #ifndef C_SWITCH_SYSTEM
1321 #define C_SWITCH_SYSTEM
1322 #endif
1323 #ifndef C_SWITCH_MACHINE
1324 #define C_SWITCH_MACHINE
1325 #endif
1326 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1327 configure___ c_switch_system=C_SWITCH_SYSTEM
1328 configure___ c_switch_machine=C_SWITCH_MACHINE
1330 #ifndef LIB_X11_LIB
1331 #define LIB_X11_LIB -lX11
1332 #endif
1334 #ifndef LIBX11_MACHINE
1335 #define LIBX11_MACHINE
1336 #endif
1338 #ifndef LIBX11_SYSTEM
1339 #define LIBX11_SYSTEM
1340 #endif
1341 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1343 #ifdef UNEXEC
1344 configure___ unexec=UNEXEC
1345 #else
1346 configure___ unexec=unexec.o
1347 #endif
1349 #ifdef SYSTEM_MALLOC
1350 configure___ system_malloc=yes
1351 #else
1352 configure___ system_malloc=no
1353 #endif
1355 #ifdef USE_MMAP_FOR_BUFFERS
1356 configure___ use_mmap_for_buffers=yes
1357 #else
1358 configure___ use_mmap_for_buffers=no
1359 #endif
1361 #ifndef C_DEBUG_SWITCH
1362 #define C_DEBUG_SWITCH -g
1363 #endif
1365 #ifndef C_OPTIMIZE_SWITCH
1366 #ifdef __GNUC__
1367 #define C_OPTIMIZE_SWITCH -O2
1368 #else
1369 #define C_OPTIMIZE_SWITCH -O
1370 #endif
1371 #endif
1373 #ifndef LD_SWITCH_MACHINE
1374 #define LD_SWITCH_MACHINE
1375 #endif
1377 #ifndef LD_SWITCH_SYSTEM
1378 #define LD_SWITCH_SYSTEM
1379 #endif
1381 #ifndef LD_SWITCH_X_SITE_AUX
1382 #define LD_SWITCH_X_SITE_AUX
1383 #endif
1385 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1386 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1388 #ifdef THIS_IS_CONFIGURE
1390 /* Get the CFLAGS for tests in configure. */
1391 #ifdef __GNUC__
1392 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1393 #else
1394 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1395 #endif
1397 #else /* not THIS_IS_CONFIGURE */
1399 /* Get the CFLAGS for real compilation. */
1400 #ifdef __GNUC__
1401 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1402 #else
1403 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1404 #endif
1406 #endif /* not THIS_IS_CONFIGURE */
1407 ' > ${tempcname}
1409 # The value of CPP is a quoted variable reference, so we need to do this
1410 # to get its actual value...
1411 CPP=`eval "echo $CPP"`
1412 [eval `${CPP} -Isrc ${tempcname} \
1413 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1414 if test "x$SPECIFIED_CFLAGS" = x; then
1415 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1416 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1417 else
1418 REAL_CFLAGS="$CFLAGS"
1419 fi]
1420 rm ${tempcname}
1422 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1424 ### Make sure subsequent tests use flags consistent with the build flags.
1426 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1427 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1428 else
1429 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1430 fi
1432 dnl For AC_FUNC_GETLOADAVG, at least:
1433 AC_CONFIG_LIBOBJ_DIR(src)
1435 AC_GNU_SOURCE
1437 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1438 AC_SYS_LARGEFILE
1440 if test "${with_sound}" != "no"; then
1441 # Sound support for GNU/Linux and the free BSDs.
1442 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1443 # Emulation library used on NetBSD.
1444 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1445 AC_SUBST(LIBSOUND)
1446 fi
1448 dnl checks for header files
1449 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1450 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1451 termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1452 sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h)
1453 dnl On Solaris 8 there's a compilation warning for term.h because
1454 dnl it doesn't define `bool'.
1455 AC_CHECK_HEADERS(term.h, , , -)
1456 AC_HEADER_STDC
1457 AC_HEADER_TIME
1458 AC_CHECK_DECLS([sys_siglist])
1459 if test $ac_cv_have_decl_sys_siglist != yes; then
1460 # For Tru64, at least:
1461 AC_CHECK_DECLS([__sys_siglist])
1462 if test $ac_cv_have_decl___sys_siglist = yes; then
1463 AC_DEFINE(sys_siglist, __sys_siglist,
1464 [Define to any substitute for sys_siglist.])
1465 fi
1466 fi
1467 AC_HEADER_SYS_WAIT
1469 dnl Some systems have utime.h but don't declare the struct anyplace.
1470 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1471 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1472 #include <sys/time.h>
1473 #include <time.h>
1474 #else
1475 #ifdef HAVE_SYS_TIME_H
1476 #include <sys/time.h>
1477 #else
1478 #include <time.h>
1479 #endif
1480 #endif
1481 #ifdef HAVE_UTIME_H
1482 #include <utime.h>
1483 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1484 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1485 if test $emacs_cv_struct_utimbuf = yes; then
1486 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1487 fi
1489 dnl checks for typedefs
1490 AC_TYPE_SIGNAL
1492 dnl Check for speed_t typedef.
1493 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1494 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1495 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1496 if test $emacs_cv_speed_t = yes; then
1497 AC_DEFINE(HAVE_SPEED_T, 1,
1498 [Define to 1 if `speed_t' is declared by <termios.h>.])
1499 fi
1501 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1502 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1503 #include <sys/time.h>
1504 #include <time.h>
1505 #else
1506 #ifdef HAVE_SYS_TIME_H
1507 #include <sys/time.h>
1508 #else
1509 #include <time.h>
1510 #endif
1511 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1512 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1513 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1514 if test $emacs_cv_struct_timeval = yes; then
1515 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1516 fi
1518 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1519 AC_TRY_COMPILE([#include <math.h>],
1520 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1521 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1522 HAVE_EXCEPTION=$emacs_cv_struct_exception
1523 if test $emacs_cv_struct_exception != yes; then
1524 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1525 fi
1527 AC_CHECK_HEADERS(sys/socket.h)
1528 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1529 #if HAVE_SYS_SOCKET_H
1530 #include <sys/socket.h>
1531 #endif])
1533 dnl checks for structure members
1534 AC_STRUCT_TM
1535 AC_STRUCT_TIMEZONE
1536 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1537 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1538 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1539 [#include <time.h>])
1540 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1541 struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1542 struct ifreq.ifr_addr], , ,
1543 [AC_INCLUDES_DEFAULT
1544 #if HAVE_SYS_SOCKET_H
1545 #include <sys/socket.h>
1546 #endif
1547 #if HAVE_NET_IF_H
1548 #include <net/if.h>
1549 #endif])
1551 dnl checks for compiler characteristics
1553 dnl Testing __STDC__ to determine prototype support isn't good enough.
1554 dnl DEC C, for instance, doesn't define it with default options, and
1555 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1556 dnl and void *.
1557 AC_C_PROTOTYPES
1558 AC_C_VOLATILE
1559 AC_C_CONST
1560 dnl This isn't useful because we can't turn on use of `inline' unless
1561 dnl the compiler groks `extern inline'.
1562 dnl AC_C_INLINE
1563 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1564 [AC_TRY_COMPILE(, [void * foo;],
1565 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1566 if test $emacs_cv_void_star = yes; then
1567 AC_DEFINE(POINTER_TYPE, void)
1568 else
1569 AC_DEFINE(POINTER_TYPE, char)
1570 fi
1571 AH_TEMPLATE(POINTER_TYPE,
1572 [Define as `void' if your compiler accepts `void *'; otherwise
1573 define as `char'.])dnl
1575 dnl Test if heap start address is randomized (exec-shield does this).
1576 dnl The test program requires unistd.h and stdlib.h. They are present
1577 dnl on the systems that currently have exec-shield.
1578 AC_MSG_CHECKING(whether heap start address is randomized)
1579 if test x"$ac_cv_header_unistd_h" != x && test x"$ac_cv_header_stdlib_h" != x
1580 then
1581 AC_TRY_RUN([#include <stdio.h>
1582 #include <unistd.h>
1583 #include <stdlib.h>
1584 int main (int argc, char *argv[])
1585 {
1586 unsigned long old_sbrk = 0;
1587 unsigned long this_sbrk = (unsigned long) sbrk(0);
1588 int nr = 1;
1589 if (argc != 1) {
1590 old_sbrk = strtoul (argv[1], 0, 0);
1591 nr = atoi (argv[2])+1;
1592 }
1593 if (argc == 1 || (old_sbrk == this_sbrk && nr < 3))
1594 {
1595 char buf1[32], buf2[32];
1596 sprintf (buf1, "%lu", this_sbrk);
1597 sprintf (buf2, "%d", nr);
1598 execl (argv[0], argv[0], buf1, buf2, 0);
1599 exit (-1);
1600 }
1601 exit (this_sbrk == old_sbrk);
1602 }], emacs_cv_randomheap=yes, emacs_cv_randomheap=no,
1603 emacs_cv_randomheap='assuming no')
1604 else
1605 emacs_cv_randomheap='assuming no'
1606 fi
1607 AC_MSG_RESULT($emacs_cv_randomheap)
1609 if test "$emacs_cv_randomheap" = yes; then
1610 AC_PATH_PROG(SETARCH, setarch, no)
1611 AC_SUBST(SETARCH)
1612 if test "$SETARCH" != no && test "$machine" = "intel386"; then
1613 AC_DEFINE(HAVE_RANDOM_HEAPSTART, 1,
1614 [Define to 1 if this OS randomizes the start address of the heap.])
1615 else
1616 dnl We do the warning at the end of the configure run so it is seen.
1617 emacs_cv_randomheap=warn
1618 fi
1619 fi
1622 dnl This could be used for targets which can have both byte sexes.
1623 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1624 dnl AC_C_BIGENDIAN
1626 dnl check for Make feature
1627 AC_PROG_MAKE_SET
1629 dnl checks for operating system services
1630 AC_SYS_LONG_FILE_NAMES
1632 #### Choose a window system.
1634 AC_PATH_X
1635 if test "$no_x" = yes; then
1636 window_system=none
1637 else
1638 window_system=x11
1639 fi
1641 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1642 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1643 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1644 x_default_search_path=""
1645 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1646 x_search_path="\
1647 ${x_library}/X11/%L/%T/%N%C%S:\
1648 ${x_library}/X11/%l/%T/%N%C%S:\
1649 ${x_library}/X11/%T/%N%C%S:\
1650 ${x_library}/X11/%L/%T/%N%S:\
1651 ${x_library}/X11/%l/%T/%N%S:\
1652 ${x_library}/X11/%T/%N%S"
1653 if test x"${x_default_search_path}" = x; then
1654 x_default_search_path=${x_search_path}
1655 else
1656 x_default_search_path="${x_search_path}:${x_default_search_path}"
1657 fi
1658 done
1659 fi
1660 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1661 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1662 fi
1664 if test x"${x_includes}" = x; then
1665 bitmapdir=/usr/include/X11/bitmaps
1666 else
1667 # accumulate include directories that have X11 bitmap subdirectories
1668 bmd_acc="dummyval"
1669 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1670 if test -d "${bmd}/X11/bitmaps"; then
1671 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1672 fi
1673 if test -d "${bmd}/bitmaps"; then
1674 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1675 fi
1676 done
1677 if test ${bmd_acc} != "dummyval"; then
1678 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1679 fi
1680 fi
1682 case "${window_system}" in
1683 x11 )
1684 HAVE_X_WINDOWS=yes
1685 HAVE_X11=yes
1686 case "${with_x_toolkit}" in
1687 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1688 motif ) USE_X_TOOLKIT=MOTIF ;;
1689 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1690 gtk ) with_gtk=yes
1691 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1692 dnl USE_X_TOOLKIT is set.
1693 USE_X_TOOLKIT=none ;;
1694 no ) USE_X_TOOLKIT=none ;;
1695 dnl If user did not say whether to use a toolkit,
1696 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1697 * ) USE_X_TOOLKIT=maybe ;;
1698 esac
1699 ;;
1700 none )
1701 HAVE_X_WINDOWS=no
1702 HAVE_X11=no
1703 USE_X_TOOLKIT=none
1704 ;;
1705 esac
1707 ### If we're using X11, we should use the X menu package.
1708 HAVE_MENUS=no
1709 case ${HAVE_X11} in
1710 yes ) HAVE_MENUS=yes ;;
1711 esac
1713 if test "${opsys}" = "hpux9"; then
1714 case "${x_libraries}" in
1715 *X11R4* )
1716 opsysfile="s/hpux9-x11r4.h"
1717 ;;
1718 esac
1719 fi
1721 if test "${opsys}" = "hpux9shr"; then
1722 case "${x_libraries}" in
1723 *X11R4* )
1724 opsysfile="s/hpux9shxr4.h"
1725 ;;
1726 esac
1727 fi
1729 ### Compute the unexec source name from the object name.
1730 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1732 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1733 # Assume not, until told otherwise.
1734 GNU_MALLOC=yes
1735 doug_lea_malloc=yes
1736 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1737 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1738 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1739 emacs_cv_var___after_morecore_hook,
1740 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1741 emacs_cv_var___after_morecore_hook=yes,
1742 emacs_cv_var___after_morecore_hook=no)])
1743 if test $emacs_cv_var___after_morecore_hook = no; then
1744 doug_lea_malloc=no
1745 fi
1746 if test "${system_malloc}" = "yes"; then
1747 GNU_MALLOC=no
1748 GNU_MALLOC_reason="
1749 (The GNU allocators don't work with this system configuration.)"
1750 fi
1751 if test "$doug_lea_malloc" = "yes" ; then
1752 if test "$GNU_MALLOC" = yes ; then
1753 GNU_MALLOC_reason="
1754 (Using Doug Lea's new malloc from the GNU C Library.)"
1755 fi
1756 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1757 [Define to 1 if you are using the GNU C Library.])
1758 fi
1760 if test x"${REL_ALLOC}" = x; then
1761 REL_ALLOC=${GNU_MALLOC}
1762 fi
1764 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1765 dnl the system configuration file (s/*.h) to turn the use of mmap
1766 dnl in the relocating allocator on.
1768 AC_FUNC_MMAP
1769 if test $use_mmap_for_buffers = yes; then
1770 REL_ALLOC=no
1771 fi
1773 LIBS="$libsrc_libs $LIBS"
1775 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1776 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1777 AC_CHECK_LIB(dnet, dnet_ntoa)
1778 dnl This causes -lresolv to get used in subsequent tests,
1779 dnl which causes failures on some systems such as HPUX 9.
1780 dnl AC_CHECK_LIB(resolv, gethostbyname)
1782 dnl FIXME replace main with a function we actually want from this library.
1783 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1785 AC_CHECK_LIB(pthreads, cma_open)
1787 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1788 if test -d /usr/X386/include; then
1789 HAVE_XFREE386=yes
1790 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1791 else
1792 HAVE_XFREE386=no
1793 fi
1794 AC_MSG_RESULT($HAVE_XFREE386)
1796 dnl Check for need for bigtoc support on IBM AIX
1798 case ${host_os} in
1799 aix*)
1800 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1801 case $GCC in
1802 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1803 *) gdb_cv_bigtoc=-bbigtoc ;;
1804 esac
1806 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1807 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1808 ])
1809 ;;
1810 esac
1812 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1813 # used for the tests that follow. We set them back to REAL_CFLAGS and
1814 # REAL_CPPFLAGS later on.
1816 REAL_CPPFLAGS="$CPPFLAGS"
1818 if test "${HAVE_X11}" = "yes"; then
1819 DEFS="$C_SWITCH_X_SITE $DEFS"
1820 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1821 LIBS="$LIBX $LIBS"
1822 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1823 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1825 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1826 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1827 # but it's more convenient here to set LD_RUN_PATH
1828 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1829 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1830 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1831 export LD_RUN_PATH
1832 fi
1834 if test "${opsys}" = "gnu-linux"; then
1835 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1836 AC_TRY_LINK([],
1837 [XOpenDisplay ("foo");],
1838 [xlinux_first_failure=no],
1839 [xlinux_first_failure=yes])
1840 if test "${xlinux_first_failure}" = "yes"; then
1841 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1842 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1843 OLD_CPPFLAGS="$CPPFLAGS"
1844 OLD_LIBS="$LIBS"
1845 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1846 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1847 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1848 LIBS="$LIBS -b i486-linuxaout"
1849 AC_TRY_LINK([],
1850 [XOpenDisplay ("foo");],
1851 [xlinux_second_failure=no],
1852 [xlinux_second_failure=yes])
1853 if test "${xlinux_second_failure}" = "yes"; then
1854 # If we get the same failure with -b, there is no use adding -b.
1855 # So take it out. This plays safe.
1856 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1857 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1858 CPPFLAGS="$OLD_CPPFLAGS"
1859 LIBS="$OLD_LIBS"
1860 AC_MSG_RESULT(no)
1861 else
1862 AC_MSG_RESULT(yes)
1863 fi
1864 else
1865 AC_MSG_RESULT(no)
1866 fi
1867 fi
1869 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1870 # header files included from there.
1871 AC_MSG_CHECKING(for Xkb)
1872 AC_TRY_LINK([#include <X11/Xlib.h>
1873 #include <X11/XKBlib.h>],
1874 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1875 emacs_xkb=yes, emacs_xkb=no)
1876 AC_MSG_RESULT($emacs_xkb)
1877 if test $emacs_xkb = yes; then
1878 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1879 fi
1881 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1882 XScreenNumberOfScreen XSetWMProtocols)
1883 fi
1885 if test "${window_system}" = "x11"; then
1886 AC_MSG_CHECKING(X11 version 6)
1887 AC_CACHE_VAL(emacs_cv_x11_version_6,
1888 [AC_TRY_LINK([#include <X11/Xlib.h>],
1889 [#if XlibSpecificationRelease < 6
1890 fail;
1891 #endif
1892 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1893 if test $emacs_cv_x11_version_6 = yes; then
1894 AC_MSG_RESULT(6 or newer)
1895 AC_DEFINE(HAVE_X11R6, 1,
1896 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1897 else
1898 AC_MSG_RESULT(before 6)
1899 fi
1900 fi
1902 if test "${window_system}" = "x11"; then
1903 AC_MSG_CHECKING(X11 version 5)
1904 AC_CACHE_VAL(emacs_cv_x11_version_5,
1905 [AC_TRY_LINK([#include <X11/Xlib.h>],
1906 [#if XlibSpecificationRelease < 5
1907 fail;
1908 #endif
1909 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1910 if test $emacs_cv_x11_version_5 = yes; then
1911 AC_MSG_RESULT(5 or newer)
1912 HAVE_X11R5=yes
1913 AC_DEFINE(HAVE_X11R5, 1,
1914 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1915 else
1916 HAVE_X11R5=no
1917 AC_MSG_RESULT(before 5)
1918 fi
1919 fi
1921 dnl This function defintion taken from Gnome 2.0
1922 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1923 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1924 dnl also defines GSTUFF_PKG_ERRORS on error
1925 AC_DEFUN([PKG_CHECK_MODULES], [
1926 succeeded=no
1928 if test -z "$PKG_CONFIG"; then
1929 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1930 fi
1932 if test "$PKG_CONFIG" = "no" ; then
1933 echo "*** The pkg-config script could not be found. Make sure it is"
1934 echo "*** in your path, or give the full path to pkg-config with"
1935 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1936 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1937 else
1938 PKG_CONFIG_MIN_VERSION=0.9.0
1939 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1940 AC_MSG_CHECKING(for $2)
1942 if $PKG_CONFIG --exists "$2" ; then
1943 AC_MSG_RESULT(yes)
1944 succeeded=yes
1946 AC_MSG_CHECKING($1_CFLAGS)
1947 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1948 AC_MSG_RESULT($$1_CFLAGS)
1950 AC_MSG_CHECKING($1_LIBS)
1951 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1952 AC_MSG_RESULT($$1_LIBS)
1953 else
1954 $1_CFLAGS=""
1955 $1_LIBS=""
1956 ## If we have a custom action on failure, don't print errors, but
1957 ## do set a variable so people can do so.
1958 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1959 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1960 fi
1962 AC_SUBST($1_CFLAGS)
1963 AC_SUBST($1_LIBS)
1964 else
1965 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1966 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1967 fi
1968 fi
1970 if test $succeeded = yes; then
1971 ifelse([$3], , :, [$3])
1972 else
1973 ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1974 fi
1975 ])
1977 HAVE_GTK=no
1978 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1979 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1980 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1981 fi
1982 GLIB_REQUIRED=2.0.1
1983 GTK_REQUIRED=2.0.1
1984 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1986 dnl Check if --with-pkg-config-prog has been given.
1987 if test "X${with_pkg_config_prog}" != X; then
1988 PKG_CONFIG="${with_pkg_config_prog}"
1989 fi
1990 dnl Checks for libraries.
1991 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1992 AC_SUBST(GTK_CFLAGS)
1993 AC_SUBST(GTK_LIBS)
1994 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1995 CFLAGS="$CFLAGS $GTK_CFLAGS"
1996 LIBS="$GTK_LIBS $LIBS"
1997 HAVE_GTK=yes
1998 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1999 USE_X_TOOLKIT=none
2001 dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2002 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
2003 with_toolkit_scroll_bars=yes
2005 dnl Check if we can use multiple displays with this GTK version.
2006 dnl If gdk_display_open exists, assume all others are there also.
2007 HAVE_GTK_MULTIDISPLAY=no
2008 AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
2009 if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
2010 AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
2011 [Define to 1 if GTK can handle more than one display.])
2012 fi
2013 fi
2015 dnl Do not put whitespace before the #include statements below.
2016 dnl Older compilers (eg sunos4 cc) choke on it.
2017 if test x"${USE_X_TOOLKIT}" = xmaybe; then
2018 if test x"${HAVE_X11R5}" = xyes; then
2019 AC_MSG_CHECKING(X11 version 5 with Xaw)
2020 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
2021 [AC_TRY_LINK([
2022 #include <X11/Intrinsic.h>
2023 #include <X11/Xaw/Simple.h>],
2024 [],
2025 emacs_cv_x11_version_5_with_xaw=yes,
2026 emacs_cv_x11_version_5_with_xaw=no)])
2027 if test $emacs_cv_x11_version_5_with_xaw = yes; then
2028 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
2029 USE_X_TOOLKIT=LUCID
2030 else
2031 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
2032 USE_X_TOOLKIT=none
2033 fi
2034 else
2035 USE_X_TOOLKIT=none
2036 fi
2037 fi
2039 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2041 if test "${USE_X_TOOLKIT}" != "none"; then
2042 AC_MSG_CHECKING(X11 toolkit version)
2043 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2044 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2045 [#if XtSpecificationRelease < 6
2046 fail;
2047 #endif
2048 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2049 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2050 if test $emacs_cv_x11_toolkit_version_6 = yes; then
2051 AC_MSG_RESULT(6 or newer)
2052 AC_DEFINE(HAVE_X11XTR6, 1,
2053 [Define to 1 if you have the X11R6 or newer version of Xt.])
2054 else
2055 AC_MSG_RESULT(before 6)
2056 fi
2058 dnl If using toolkit, check whether libXmu.a exists.
2059 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2060 OLDLIBS="$LIBS"
2061 if test x$HAVE_X11XTR6 = xyes; then
2062 LIBS="-lXt -lSM -lICE $LIBS"
2063 else
2064 LIBS="-lXt $LIBS"
2065 fi
2066 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2067 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2068 fi
2070 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2071 if test "${HAVE_X11}" = "yes"; then
2072 if test "${USE_X_TOOLKIT}" != "none"; then
2073 AC_CHECK_LIB(Xext, XShapeQueryExtension)
2074 fi
2075 fi
2077 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2078 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2079 # We put this in CFLAGS temporarily to precede other -I options
2080 # that might be in CFLAGS temporarily.
2081 # We put this in CPPFLAGS where it precedes the other -I options.
2082 OLD_CPPFLAGS=$CPPFLAGS
2083 OLD_CFLAGS=$CFLAGS
2084 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2085 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2086 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2087 [int x = 5;],
2088 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2089 if test $emacs_cv_lesstif = yes; then
2090 # Make sure this -I option remains in CPPFLAGS after it is set
2091 # back to REAL_CPPFLAGS.
2092 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2093 # have those other -I options anyway. Ultimately, having this
2094 # directory ultimately in CPPFLAGS will be enough.
2095 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2096 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2097 else
2098 CFLAGS=$OLD_CFLAGS
2099 CPPFLAGS=$OLD_CPPFLAGS
2100 fi
2101 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2102 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2103 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2104 int x = 5;
2105 #else
2106 Motif version prior to 2.1.
2107 #endif],
2108 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2109 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2110 if test $emacs_cv_motif_version_2_1 = yes; then
2111 HAVE_LIBXP=no
2112 AC_DEFINE(HAVE_MOTIF_2_1, 1,
2113 [Define to 1 if you have Motif 2.1 or newer.])
2114 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2115 if test ${HAVE_LIBXP} = yes; then
2116 AC_DEFINE(HAVE_LIBXP, 1,
2117 [Define to 1 if you have the Xp library (-lXp).])
2118 fi
2119 fi
2120 fi
2122 ### Is -lXaw3d available?
2123 HAVE_XAW3D=no
2124 if test "${HAVE_X11}" = "yes"; then
2125 if test "${USE_X_TOOLKIT}" != "none"; then
2126 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2127 dnl errors from the test without the `-'.
2128 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2129 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2130 if test "${HAVE_XAW3D}" = "yes"; then
2131 AC_DEFINE(HAVE_XAW3D, 1,
2132 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2133 fi
2134 fi
2135 fi
2137 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2138 dnl using Motif or Xaw3d is available, and unless
2139 dnl --with-toolkit-scroll-bars=no was specified.
2141 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2142 [Define to 1 if we should use toolkit scroll bars.])dnl
2143 USE_TOOLKIT_SCROLL_BARS=no
2144 if test "${with_toolkit_scroll_bars}" != "no"; then
2145 if test "${USE_X_TOOLKIT}" != "none"; then
2146 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2147 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2148 HAVE_XAW3D=no
2149 USE_TOOLKIT_SCROLL_BARS=yes
2150 elif test "${HAVE_XAW3D}" = "yes"; then
2151 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2152 USE_TOOLKIT_SCROLL_BARS=yes
2153 fi
2154 elif test "${HAVE_GTK}" = "yes"; then
2155 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2156 USE_TOOLKIT_SCROLL_BARS=yes
2157 fi
2158 fi
2160 dnl See if XIM is available.
2161 AC_TRY_COMPILE([
2162 #include <X11/Xlib.h>
2163 #include <X11/Xresource.h>],
2164 [XIMProc callback;],
2165 HAVE_XIM=yes
2166 AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available]),
2167 HAVE_XIM=no)
2169 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2171 if test "${with_xim}" != "no"; then
2172 AC_DEFINE(USE_XIM, 1,
2173 [Define to 1 if we should use XIM, if it is available.])
2174 fi
2177 if test "${HAVE_XIM}" != "no"; then
2178 late_CFLAGS=$CFLAGS
2179 if test "$GCC" = yes; then
2180 CFLAGS="$CFLAGS --pedantic-errors"
2181 fi
2182 AC_TRY_COMPILE([
2183 #include <X11/Xlib.h>
2184 #include <X11/Xresource.h>],
2185 [Display *display;
2186 XrmDatabase db;
2187 char *res_name;
2188 char *res_class;
2189 XIMProc callback;
2190 XPointer *client_data;
2191 #ifndef __GNUC__
2192 /* If we're not using GCC, it's probably not XFree86, and this is
2193 probably right, but we can't use something like --pedantic-errors. */
2194 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2195 char*, XIMProc, XPointer*);
2196 #endif
2197 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2198 client_data);],
2199 [emacs_cv_arg6_star=yes])
2200 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2201 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2202 either XPointer or XPointer*.])dnl
2203 if test "$emacs_cv_arg6_star" = yes; then
2204 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2205 else
2206 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2207 fi
2208 CFLAGS=$late_CFLAGS
2209 fi
2211 ### Use -lXpm if available, unless `--with-xpm=no'.
2212 HAVE_XPM=no
2213 if test "${HAVE_X11}" = "yes"; then
2214 if test "${with_xpm}" != "no"; then
2215 AC_CHECK_HEADER(X11/xpm.h,
2216 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2217 if test "${HAVE_XPM}" = "yes"; then
2218 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2219 AC_EGREP_CPP(no_return_alloc_pixels,
2220 [#include "X11/xpm.h"
2221 #ifndef XpmReturnAllocPixels
2222 no_return_alloc_pixels
2223 #endif
2224 ], HAVE_XPM=no, HAVE_XPM=yes)
2226 if test "${HAVE_XPM}" = "yes"; then
2227 AC_MSG_RESULT(yes)
2228 else
2229 AC_MSG_RESULT(no)
2230 fi
2231 fi
2232 fi
2234 if test "${HAVE_XPM}" = "yes"; then
2235 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2236 fi
2237 fi
2239 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2240 HAVE_JPEG=no
2241 if test "${HAVE_X11}" = "yes"; then
2242 if test "${with_jpeg}" != "no"; then
2243 dnl Checking for jpeglib.h can lose because of a redefinition of
2244 dnl HAVE_STDLIB_H.
2245 AC_CHECK_HEADER(jerror.h,
2246 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2247 fi
2249 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2250 if test "${HAVE_JPEG}" = "yes"; then
2251 AC_DEFINE(HAVE_JPEG)
2252 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2253 [#include <jpeglib.h>
2254 version=JPEG_LIB_VERSION
2255 ],
2256 AC_DEFINE(HAVE_JPEG),
2257 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2258 HAVE_JPEG=no])
2259 fi
2260 fi
2262 ### Use -lpng if available, unless `--with-png=no'.
2263 HAVE_PNG=no
2264 if test "${HAVE_X11}" = "yes"; then
2265 if test "${with_png}" != "no"; then
2266 # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2267 # in /usr/include/libpng.
2268 AC_CHECK_HEADERS(png.h libpng/png.h)
2269 if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2270 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2271 fi
2272 fi
2274 if test "${HAVE_PNG}" = "yes"; then
2275 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2276 fi
2277 fi
2279 ### Use -ltiff if available, unless `--with-tiff=no'.
2280 HAVE_TIFF=no
2281 if test "${HAVE_X11}" = "yes"; then
2282 if test "${with_tiff}" != "no"; then
2283 AC_CHECK_HEADER(tiffio.h,
2284 tifflibs="-lz -lm"
2285 # At least one tiff package requires the jpeg library.
2286 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2287 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2288 fi
2290 if test "${HAVE_TIFF}" = "yes"; then
2291 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2292 fi
2293 fi
2295 ### Use -lgif if available, unless `--with-gif=no'.
2296 HAVE_GIF=no
2297 if test "${HAVE_X11}" = "yes"; then
2298 if test "${with_gif}" != "no"; then
2299 AC_CHECK_HEADER(gif_lib.h,
2300 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2301 # Earlier versions can crash Emacs.
2302 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2303 fi
2305 if test "${HAVE_GIF}" = "yes"; then
2306 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2307 fi
2308 fi
2310 ### Use Mac OS X Carbon API to implement GUI.
2311 HAVE_CARBON=no
2312 if test "${with_carbon}" != "no"; then
2313 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2314 fi
2316 dnl Check for malloc/malloc.h on darwin
2317 AC_CHECK_HEADER(malloc/malloc.h, AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.]))
2319 if test "${HAVE_CARBON}" = "yes"; then
2320 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2321 window_system=mac
2322 ## Specify the install directory
2323 carbon_appdir=
2324 if test "${carbon_appdir_x}" != ""; then
2325 case ${carbon_appdir_x} in
2326 y | ye | yes) carbon_appdir=/Applications ;;
2327 * ) carbon_appdir=${carbon_appdir_x} ;;
2328 esac
2329 fi
2330 # We also have mouse menus.
2331 HAVE_MENUS=yes
2332 fi
2334 ### Use session management (-lSM -lICE) if available
2335 HAVE_X_SM=no
2336 if test "${HAVE_X11}" = "yes"; then
2337 AC_CHECK_HEADER(X11/SM/SMlib.h,
2338 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE))
2340 if test "${HAVE_X_SM}" = "yes"; then
2341 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2342 case "$LIBS" in
2343 *-lSM*) ;;
2344 *) LIBS="-lSM -lICE $LIBS" ;;
2345 esac
2346 fi
2347 fi
2349 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2350 AC_CACHE_CHECK(whether netdb declares h_errno,
2351 emacs_cv_netdb_declares_h_errno,
2352 [AC_TRY_LINK([#include <netdb.h>],
2353 [return h_errno;],
2354 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2355 if test $emacs_cv_netdb_declares_h_errno = yes; then
2356 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2357 fi
2359 AC_FUNC_ALLOCA
2361 # fmod, logb, and frexp are found in -lm on most systems.
2362 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2363 AC_CHECK_LIB(m, sqrt)
2365 # Check for mail-locking functions in a "mail" library. Probably this should
2366 # have the same check as for liblockfile below.
2367 AC_CHECK_LIB(mail, maillock)
2368 dnl Debian, at least:
2369 AC_CHECK_LIB(lockfile, maillock)
2370 # If we have the shared liblockfile, assume we must use it for mail
2371 # locking (e.g. Debian). If we couldn't link against liblockfile
2372 # (no liblockfile.a installed), ensure that we don't need to.
2373 if test "$ac_cv_lib_lockfile_maillock" = no; then
2374 dnl This works for files generally, not just executables.
2375 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2376 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2377 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2378 if test $ac_cv_prog_liblockfile = yes; then
2379 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2380 This probably means that movemail could lose mail.
2381 There may be a `development' package to install containing liblockfile.])
2382 else :
2383 fi
2384 fi
2385 AC_CHECK_FUNCS(touchlock)
2386 AC_CHECK_HEADERS(maillock.h)
2388 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2389 rename closedir mkdir rmdir sysinfo \
2390 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2391 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2392 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2393 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2394 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2395 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2396 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2398 AC_CHECK_HEADERS(sys/un.h)
2400 AC_FUNC_MKTIME
2401 if test "$ac_cv_func_working_mktime" = no; then
2402 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2403 fi
2405 AC_FUNC_GETLOADAVG
2407 AC_FUNC_FSEEKO
2409 AC_FUNC_GETPGRP
2411 AC_FUNC_STRFTIME
2413 # UNIX98 PTYs.
2414 AC_CHECK_FUNCS(grantpt)
2416 # PTY-related GNU extensions.
2417 AC_CHECK_FUNCS(getpt)
2419 # Check this now, so that we will NOT find the above functions in ncurses.
2420 # That is because we have not set up to link ncurses in lib-src.
2421 # It's better to believe a function is not available
2422 # than to expect to find it in ncurses.
2423 AC_CHECK_LIB(ncurses, tparm)
2425 # Do we need the Hesiod library to provide the support routines?
2426 if test "$with_hesiod" = yes ; then
2427 # Don't set $LIBS here -- see comments above.
2428 resolv=no
2429 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2430 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2431 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2432 if test "$resolv" = yes ; then
2433 RESOLVLIB=-lresolv
2434 AC_DEFINE(HAVE_LIBRESOLV, 1,
2435 [Define to 1 if you have the resolv library (-lresolv).])
2436 else
2437 RESOLVLIB=
2438 fi
2439 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2440 AC_DEFINE(HAVE_LIBHESIOD, 1,
2441 [Define to 1 if you have the hesiod library (-lhesiod).]),
2442 :, $RESOLVLIB)])
2443 fi
2445 # These tell us which Kerberos-related libraries to use.
2446 if test "${with_kerberos+set}" = set; then
2447 AC_CHECK_LIB(com_err, com_err)
2448 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2449 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2450 AC_CHECK_LIB(krb5, krb5_init_context)
2451 if test "${with_kerberos5+set}" != set; then
2452 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2453 AC_CHECK_LIB(des, des_cbc_encrypt))
2454 AC_CHECK_LIB(krb4, krb_get_cred,,
2455 AC_CHECK_LIB(krb, krb_get_cred))
2456 fi
2458 if test "${with_kerberos5+set}" = set; then
2459 AC_CHECK_HEADERS(krb5.h)
2460 else
2461 AC_CHECK_HEADERS(des.h,,
2462 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2463 [AC_CHECK_HEADERS(kerberos/des.h)])])
2464 AC_CHECK_HEADERS(krb.h,,
2465 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2466 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2467 fi
2468 AC_CHECK_HEADERS(com_err.h)
2469 fi
2471 # Solaris requires -lintl if you want strerror (which calls dgettext)
2472 # to return localized messages.
2473 AC_CHECK_LIB(intl, dgettext)
2475 AC_MSG_CHECKING(whether localtime caches TZ)
2476 AC_CACHE_VAL(emacs_cv_localtime_cache,
2477 [if test x$ac_cv_func_tzset = xyes; then
2478 AC_TRY_RUN([#include <time.h>
2479 extern char **environ;
2480 unset_TZ ()
2481 {
2482 char **from, **to;
2483 for (to = from = environ; (*to = *from); from++)
2484 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2485 to++;
2486 }
2487 char TZ_GMT0[] = "TZ=GMT0";
2488 char TZ_PST8[] = "TZ=PST8";
2489 main()
2490 {
2491 time_t now = time ((time_t *) 0);
2492 int hour_GMT0, hour_unset;
2493 if (putenv (TZ_GMT0) != 0)
2494 exit (1);
2495 hour_GMT0 = localtime (&now)->tm_hour;
2496 unset_TZ ();
2497 hour_unset = localtime (&now)->tm_hour;
2498 if (putenv (TZ_PST8) != 0)
2499 exit (1);
2500 if (localtime (&now)->tm_hour == hour_GMT0)
2501 exit (1);
2502 unset_TZ ();
2503 if (localtime (&now)->tm_hour != hour_unset)
2504 exit (1);
2505 exit (0);
2506 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2507 [# If we have tzset, assume the worst when cross-compiling.
2508 emacs_cv_localtime_cache=yes])
2509 else
2510 # If we lack tzset, report that localtime does not cache TZ,
2511 # since we can't invalidate the cache if we don't have tzset.
2512 emacs_cv_localtime_cache=no
2513 fi])dnl
2514 AC_MSG_RESULT($emacs_cv_localtime_cache)
2515 if test $emacs_cv_localtime_cache = yes; then
2516 AC_DEFINE(LOCALTIME_CACHE, 1,
2517 [Define to 1 if localtime caches TZ.])
2518 fi
2520 if test "x$HAVE_TIMEVAL" = xyes; then
2521 AC_CHECK_FUNCS(gettimeofday)
2522 if test $ac_cv_func_gettimeofday = yes; then
2523 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2524 emacs_cv_gettimeofday_two_arguments,
2525 [AC_TRY_COMPILE([
2526 #ifdef TIME_WITH_SYS_TIME
2527 #include <sys/time.h>
2528 #include <time.h>
2529 #else
2530 #ifdef HAVE_SYS_TIME_H
2531 #include <sys/time.h>
2532 #else
2533 #include <time.h>
2534 #endif
2535 #endif],
2536 [struct timeval time;
2537 gettimeofday (&time, 0);],
2538 emacs_cv_gettimeofday_two_arguments=yes,
2539 emacs_cv_gettimeofday_two_arguments=no)])
2540 if test $emacs_cv_gettimeofday_two_arguments = no; then
2541 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2542 [Define to 1 if gettimeofday accepts only one argument.])
2543 fi
2544 fi
2545 fi
2547 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2548 AC_STRUCT_TIMEZONE
2550 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2551 if test "$ac_cv_func_gettimeofday" = yes; then
2552 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2553 [AC_TRY_COMPILE([#include <sys/time.h>],
2554 [struct timezone tz;],
2555 dnl It may be that we can't call gettimeofday with a non-null pointer,
2556 dnl even though we have struct timezone (e.g. HPUX). In that case
2557 dnl we'll lie about struct timezone.
2558 [AC_TRY_RUN([
2559 #ifdef TIME_WITH_SYS_TIME
2560 #include <sys/time.h>
2561 #include <time.h>
2562 #else
2563 #ifdef HAVE_SYS_TIME_H
2564 #include <sys/time.h>
2565 #else
2566 #include <time.h>
2567 #endif
2568 #endif
2569 main () {
2570 struct timeval time;
2571 struct timezone dummy;
2572 exit (gettimeofday (&time, &dummy));
2573 }],
2574 emacs_cv_struct_timezone=yes,
2575 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2576 emacs_cv_struct_timezone=no)])
2577 fi
2579 ok_so_far=yes
2580 AC_CHECK_FUNC(socket, , ok_so_far=no)
2581 if test $ok_so_far = yes; then
2582 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2583 fi
2584 if test $ok_so_far = yes; then
2585 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2586 fi
2587 if test $ok_so_far = yes; then
2588 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2589 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2590 [Define to 1 if you have inet sockets.])
2591 fi
2593 AC_CHECK_HEADERS(sys/ioctl.h)
2595 if test -f /usr/lpp/X11/bin/smt.exp; then
2596 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2597 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2598 fi
2600 AC_MSG_CHECKING(whether system supports dynamic ptys)
2601 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2602 AC_MSG_RESULT(yes)
2603 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2604 else
2605 AC_MSG_RESULT(no)
2606 fi
2608 AC_FUNC_FORK
2610 dnl Adapted from Haible's version.
2611 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2612 [AC_TRY_LINK([#include <langinfo.h>],
2613 [char* cs = nl_langinfo(CODESET);],
2614 emacs_cv_langinfo_codeset=yes,
2615 emacs_cv_langinfo_codeset=no)
2616 ])
2617 if test $emacs_cv_langinfo_codeset = yes; then
2618 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2619 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2620 fi
2622 AC_CHECK_TYPES(size_t)
2624 AC_TYPE_MBSTATE_T
2626 dnl Restrict could probably be used effectively other than in regex.c.
2627 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2628 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2629 emacs_cv_c_restrict=yes,
2630 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2631 emacs_cv_c_restrict=__restrict,
2632 emacs_cv_c_restrict=no)])])
2633 case "$emacs_cv_c_restrict" in
2634 yes) emacs_restrict=restrict;;
2635 no) emacs_restrict="";;
2636 *) emacs_restrict="$emacs_cv_c_restrict";;
2637 esac
2638 if test "$emacs_restrict" != __restrict; then
2639 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2640 [Define to compiler's equivalent of C99 restrict keyword.
2641 Don't define if equivalent is `__restrict'.])
2642 fi
2644 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2645 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2646 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2647 if test "$emacs_cv_c_restrict_arr" = yes; then
2648 AC_DEFINE(__restrict_arr, __restrict,
2649 [Define to compiler's equivalent of C99 restrict keyword in array
2650 declarations. Define as empty for no equivalent.])
2651 fi
2653 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2654 dnl how the tty code is related to POSIX and/or other versions of termios.
2655 dnl The following looks like a useful start.
2656 dnl
2657 dnl AC_SYS_POSIX_TERMIOS
2658 dnl if test $ac_cv_sys_posix_termios = yes; then
2659 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2660 dnl and macros for terminal control.])
2661 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2662 dnl fi
2664 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2666 # Set up the CFLAGS for real compilation, so we can substitute it.
2667 CFLAGS="$REAL_CFLAGS"
2668 CPPFLAGS="$REAL_CPPFLAGS"
2670 #### Find out which version of Emacs this is.
2671 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2672 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2673 if test x"${version}" = x; then
2674 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2675 fi
2677 ### Specify what sort of things we'll be editing into Makefile and config.h.
2678 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2679 AC_SUBST(version)
2680 AC_SUBST(configuration)
2681 AC_SUBST(canonical)
2682 AC_SUBST(srcdir)
2683 AC_SUBST(prefix)
2684 AC_SUBST(exec_prefix)
2685 AC_SUBST(bindir)
2686 AC_SUBST(datadir)
2687 AC_SUBST(sharedstatedir)
2688 AC_SUBST(libexecdir)
2689 AC_SUBST(mandir)
2690 AC_SUBST(infodir)
2691 AC_SUBST(lispdir)
2692 AC_SUBST(locallisppath)
2693 AC_SUBST(lisppath)
2694 AC_SUBST(x_default_search_path)
2695 AC_SUBST(etcdir)
2696 AC_SUBST(archlibdir)
2697 AC_SUBST(docdir)
2698 AC_SUBST(bitmapdir)
2699 AC_SUBST(gamedir)
2700 AC_SUBST(gameuser)
2701 AC_SUBST(c_switch_system)
2702 AC_SUBST(c_switch_machine)
2703 AC_SUBST(LD_SWITCH_X_SITE)
2704 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2705 AC_SUBST(C_SWITCH_X_SITE)
2706 AC_SUBST(CFLAGS)
2707 AC_SUBST(X_TOOLKIT_TYPE)
2708 AC_SUBST(machfile)
2709 AC_SUBST(opsysfile)
2710 AC_SUBST(GETLOADAVG_LIBS)
2711 AC_SUBST(carbon_appdir)
2713 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2714 [Define to the canonical Emacs configuration name.])
2715 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2716 [Define to the options passed to configure.])
2717 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2718 [Define to the used machine dependent file.])
2719 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2720 [Define to the used os dependent file.])
2721 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2722 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2723 may need to deal with X Windows. For instance, if you've defined
2724 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2725 your loader can find on its own, you might want to add "-L/..." or
2726 something similar.])
2727 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2728 [Define LD_SWITCH_X_SITE_AUX with an -R option
2729 in case it's needed (for Solaris, for example).])
2730 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2731 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2732 may need to deal with X Windows. For instance, if you've defined
2733 HAVE_X_WINDOWS above and your X include files aren't in a place
2734 that your compiler can find on its own, you might want to add
2735 "-I/..." or something similar.])
2736 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2737 [Define to the unexec source file name.])
2739 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2740 AC_DEFINE(HAVE_X_WINDOWS, 1,
2741 [Define to 1 if you want to use the X window system.])
2742 fi
2743 if test "${USE_X_TOOLKIT}" != "none" ; then
2744 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2745 fi
2746 if test "${HAVE_X11}" = "yes" ; then
2747 AC_DEFINE(HAVE_X11, 1,
2748 [Define to 1 if you want to use version 11 of X windows.
2749 Otherwise, Emacs expects to use version 10.])
2750 fi
2751 if test "${HAVE_XFREE386}" = "yes" ; then
2752 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2753 fi
2754 if test "${HAVE_MENUS}" = "yes" ; then
2755 AC_DEFINE(HAVE_MENUS, 1,
2756 [Define to 1 if you have mouse menus.
2757 (This is automatic if you use X, but the option to specify it remains.)
2758 It is also defined with other window systems that support xmenu.c.])
2759 fi
2760 if test "${GNU_MALLOC}" = "yes" ; then
2761 AC_DEFINE(GNU_MALLOC, 1,
2762 [Define to 1 if you want to use the GNU memory allocator.])
2763 fi
2764 if test "${REL_ALLOC}" = "yes" ; then
2765 AC_DEFINE(REL_ALLOC, 1,
2766 [Define REL_ALLOC if you want to use the relocating allocator for
2767 buffer space.])
2768 fi
2770 AH_TOP([/* GNU Emacs site configuration template file.
2771 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2773 This file is part of GNU Emacs.
2775 GNU Emacs is free software; you can redistribute it and/or modify
2776 it under the terms of the GNU General Public License as published by
2777 the Free Software Foundation; either version 2, or (at your option)
2778 any later version.
2780 GNU Emacs is distributed in the hope that it will be useful,
2781 but WITHOUT ANY WARRANTY; without even the implied warranty of
2782 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2783 GNU General Public License for more details.
2785 You should have received a copy of the GNU General Public License
2786 along with GNU Emacs; see the file COPYING. If not, write to the
2787 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2788 Boston, MA 02111-1307, USA. */
2791 /* No code in Emacs #includes config.h twice, but some bits of code
2792 intended to work with other packages as well (like gmalloc.c)
2793 think they can include it as many times as they like. */
2794 #ifndef EMACS_CONFIG_H
2795 #define EMACS_CONFIG_H
2796 ])dnl
2798 AH_BOTTOM([
2799 /* If we're using any sort of window system, define some consequences. */
2800 #ifdef HAVE_X_WINDOWS
2801 #define HAVE_WINDOW_SYSTEM
2802 #define MULTI_KBOARD
2803 #define HAVE_MOUSE
2804 #endif
2806 /* If we're using the Carbon API on Mac OS X, define a few more
2807 variables as well. */
2808 #ifdef HAVE_CARBON
2809 #define HAVE_WINDOW_SYSTEM
2810 #define HAVE_MOUSE
2811 #endif
2813 /* Define USER_FULL_NAME to return a string
2814 that is the user's full name.
2815 It can assume that the variable `pw'
2816 points to the password file entry for this user.
2818 At some sites, the pw_gecos field contains
2819 the user's full name. If neither this nor any other
2820 field contains the right thing, use pw_name,
2821 giving the user's login name, since that is better than nothing. */
2822 #define USER_FULL_NAME pw->pw_gecos
2824 /* Define AMPERSAND_FULL_NAME if you use the convention
2825 that & in the full name stands for the login id. */
2826 /* Turned on June 1996 supposing nobody will mind it. */
2827 #define AMPERSAND_FULL_NAME
2829 /* We have blockinput.h. */
2830 #define DO_BLOCK_INPUT
2832 /* Define HAVE_SOUND if we have sound support. We know it works
2833 and compiles only on the specified platforms. For others,
2834 it probably doesn't make sense to try. */
2836 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2837 #ifdef HAVE_MACHINE_SOUNDCARD_H
2838 #define HAVE_SOUND 1
2839 #endif
2840 #ifdef HAVE_SYS_SOUNDCARD_H
2841 #define HAVE_SOUND 1
2842 #endif
2843 #ifdef HAVE_SOUNDCARD_H
2844 #define HAVE_SOUND 1
2845 #endif
2846 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2848 /* If using GNU, then support inline function declarations. */
2849 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2850 generally, because even if non-gcc compilers accept `inline', they
2851 may reject `extern inline'. */
2852 #ifdef __GNUC__
2853 #define INLINE __inline__
2854 #else
2855 #define INLINE
2856 #endif
2858 /* Include the os and machine dependent files. */
2859 #include config_opsysfile
2860 #include config_machfile
2862 /* Load in the conversion definitions if this system
2863 needs them and the source file being compiled has not
2864 said to inhibit this. There should be no need for you
2865 to alter these lines. */
2867 #ifdef SHORTNAMES
2868 #ifndef NO_SHORTNAMES
2869 #include "../shortnames/remap.h"
2870 #endif /* not NO_SHORTNAMES */
2871 #endif /* SHORTNAMES */
2873 /* If no remapping takes place, static variables cannot be dumped as
2874 pure, so don't worry about the `static' keyword. */
2875 #ifdef NO_REMAP
2876 #undef static
2877 #endif
2879 /* Define `subprocesses' should be defined if you want to
2880 have code for asynchronous subprocesses
2881 (as used in M-x compile and M-x shell).
2882 These do not work for some USG systems yet;
2883 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2885 #ifndef VMS
2886 #ifndef USG
2887 /* #define subprocesses */
2888 #endif
2889 #endif
2891 /* SIGTYPE is the macro we actually use. */
2892 #ifndef SIGTYPE
2893 #define SIGTYPE RETSIGTYPE
2894 #endif
2896 #ifdef emacs /* Don't do this for lib-src. */
2897 /* Tell regex.c to use a type compatible with Emacs. */
2898 #define RE_TRANSLATE_TYPE Lisp_Object
2899 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2900 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2901 #endif
2903 /* Avoid link-time collision with system mktime if we will use our own. */
2904 #if ! HAVE_MKTIME || BROKEN_MKTIME
2905 #define mktime emacs_mktime
2906 #endif
2908 #define my_strftime nstrftime /* for strftime.c */
2910 /* The rest of the code currently tests the CPP symbol BSTRING.
2911 Override any claims made by the system-description files.
2912 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2913 #undef BSTRING
2914 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2915 #define BSTRING
2916 #endif
2918 /* Some of the files of Emacs which are intended for use with other
2919 programs assume that if you have a config.h file, you must declare
2920 the type of getenv.
2922 This declaration shouldn't appear when alloca.s or Makefile.in
2923 includes config.h. */
2924 #ifndef NOT_C_CODE
2925 extern char *getenv ();
2926 #endif
2928 /* These default definitions are good for almost all machines.
2929 The exceptions override them in m/MACHINE.h. */
2931 #ifndef BITS_PER_CHAR
2932 #define BITS_PER_CHAR 8
2933 #endif
2935 #ifndef BITS_PER_SHORT
2936 #define BITS_PER_SHORT 16
2937 #endif
2939 /* Note that lisp.h uses this in a preprocessor conditional, so it
2940 would not work to use sizeof. That being so, we do all of them
2941 without sizeof, for uniformity's sake. */
2942 #ifndef BITS_PER_INT
2943 #define BITS_PER_INT 32
2944 #endif
2946 #ifndef BITS_PER_LONG
2947 #ifdef _LP64
2948 #define BITS_PER_LONG 64
2949 #else
2950 #define BITS_PER_LONG 32
2951 #endif
2952 #endif
2954 /* Define if the compiler supports function prototypes. It may do so
2955 but not define __STDC__ (e.g. DEC C by default) or may define it as
2956 zero. */
2957 #undef PROTOTYPES
2958 /* For mktime.c: */
2959 #ifndef __P
2960 # if defined PROTOTYPES
2961 # define __P(args) args
2962 # else
2963 # define __P(args) ()
2964 # endif /* GCC. */
2965 #endif /* __P */
2967 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2968 #ifndef NOT_C_CODE
2969 #ifdef HAVE_STRING_H
2970 #include "string.h"
2971 #endif
2972 #ifdef HAVE_STRINGS_H
2973 #include "strings.h" /* May be needed for bcopy & al. */
2974 #endif
2975 #ifdef HAVE_STDLIB_H
2976 #include <stdlib.h>
2977 #endif
2978 #ifndef __GNUC__
2979 # ifdef HAVE_ALLOCA_H
2980 # include <alloca.h>
2981 # else /* AIX files deal with #pragma. */
2982 # ifndef alloca /* predefined by HP cc +Olibcalls */
2983 char *alloca ();
2984 # endif
2985 # endif /* HAVE_ALLOCA_H */
2986 #endif /* __GNUC__ */
2987 #ifndef HAVE_SIZE_T
2988 typedef unsigned size_t;
2989 #endif
2990 #endif /* NOT_C_CODE */
2992 /* Define HAVE_X_I18N if we have usable i18n support. */
2994 #ifdef HAVE_X11R6
2995 #define HAVE_X_I18N
2996 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2997 #define HAVE_X_I18N
2998 #endif
3000 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
3002 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3003 #define HAVE_X11R6_XIM
3004 #endif
3006 /* Should we enable expensive run-time checking of data types? */
3007 #undef ENABLE_CHECKING
3009 #if defined __GNUC__ && (__GNUC__ > 2 \
3010 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3011 #define NO_RETURN __attribute__ ((__noreturn__))
3012 #else
3013 #define NO_RETURN /* nothing */
3014 #endif
3016 /* These won't be used automatically yet. We also need to know, at least,
3017 that the stack is continuous. */
3018 #ifdef __GNUC__
3019 # ifndef GC_SETJMP_WORKS
3020 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3021 see NON_SAVING_SETJMP in the target descriptions. */
3022 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3023 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3024 Fixme: Deal with ns32k, SVR3. */
3025 # define GC_SETJMP_WORKS 1
3026 # endif
3027 # ifndef GC_LISP_OBJECT_ALIGNMENT
3028 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3029 # endif
3030 #endif
3032 #ifndef HAVE_BCOPY
3033 #define bcopy(a,b,s) memcpy (b,a,s)
3034 #endif
3035 #ifndef HAVE_BZERO
3036 #define bzero(a,s) memset (a,0,s)
3037 #endif
3038 #ifndef HAVE_BCMP
3039 #define BCMP memcmp
3040 #endif
3042 #endif /* EMACS_CONFIG_H */
3044 /*
3045 Local Variables:
3046 mode: c
3047 End:
3048 */
3049 ])dnl
3051 #### Report on what we decided to do.
3052 #### Report GTK as a toolkit, even if it doesn't use Xt.
3053 #### It makes printing result more understandable as using GTK sets
3054 #### toolkit_scroll_bars to yes by default.
3055 if test "${HAVE_GTK}" = "yes"; then
3056 USE_X_TOOLKIT=GTK
3057 fi
3059 echo "
3060 Configured for \`${canonical}'.
3062 Where should the build process find the source code? ${srcdir}
3063 What operating system and machine description files should Emacs use?
3064 \`${opsysfile}' and \`${machfile}'
3065 What compiler should emacs be built with? ${CC} ${CFLAGS}
3066 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
3067 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
3068 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
3069 What window system should Emacs use? ${window_system}
3070 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
3072 if test -n "${x_includes}"; then
3073 echo " Where do we find X Windows header files? ${x_includes}"
3074 else
3075 echo " Where do we find X Windows header files? Standard dirs"
3076 fi
3077 if test -n "${x_libraries}"; then
3078 echo " Where do we find X Windows libraries? ${x_libraries}"
3079 else
3080 echo " Where do we find X Windows libraries? Standard dirs"
3081 fi
3083 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
3084 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
3085 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
3086 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
3087 echo " Does Emacs use -lungif? ${HAVE_GIF}"
3088 echo " Does Emacs use -lpng? ${HAVE_PNG}"
3089 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
3090 echo
3092 if test "$emacs_cv_randomheap" = warn; then
3093 AC_MSG_WARN([
3094 **********************************************************************
3096 Heap start address is randomized and no workaround is known.
3097 Emacs will probably dump core when temacs is run in the build phase.
3098 Maybe exec-shield is turned on. Read about exec-shield in `etc/PROBLEMS'
3099 for further information.
3101 **********************************************************************
3102 ])
3103 fi
3105 # Remove any trailing slashes in these variables.
3106 [test "${prefix}" != NONE &&
3107 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3108 test "${exec_prefix}" != NONE &&
3109 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3111 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
3112 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3113 ## from Makefile.c can correctly provide the arg `-traditional' to the
3114 ## C preprocessor.
3116 AC_EGREP_CPP(yes..yes,
3117 [yes..yes],
3118 CPP_NEED_TRADITIONAL=no,
3119 CPP_NEED_TRADITIONAL=yes)
3121 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3122 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3123 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3125 ### Make the necessary directories, if they don't exist.
3126 for dir in etc lisp ; do
3127 test -d ${dir} || mkdir ${dir}
3128 done
3130 # Build src/Makefile from ${srcdir}/src/Makefile.c
3131 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3132 # This must be done after src/config.h is built, since we rely on that file.
3134 # Now get this: Some word that is part of the ${srcdir} directory name
3135 # or the ${configuration} value might, just might, happen to be an
3136 # identifier like `sun4' or `i386' or something, and be predefined by
3137 # the C preprocessor to some helpful value like 1, or maybe the empty
3138 # string. Needless to say consequent macro substitutions are less
3139 # than conducive to the makefile finding the correct directory.
3140 [undefs="`echo $top_srcdir $configuration $canonical |
3141 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
3142 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3143 `"]
3145 echo creating src/epaths.h
3146 ${MAKE-make} epaths-force
3148 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3149 # `..' to `. .' unless invoked with -traditional
3151 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3152 CPPFLAGS="$CPPFLAGS -traditional"
3153 fi
3155 echo creating lib-src/Makefile
3156 ( cd lib-src
3157 rm -f junk.c junk1.c junk2.c
3158 sed -e '/start of cpp stuff/q' \
3159 < Makefile.c > junk1.c
3160 sed -e '1,/start of cpp stuff/d'\
3161 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3162 < Makefile.c > junk.c
3163 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3164 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3165 cat junk1.c junk2.c > Makefile.new
3166 rm -f junk.c junk1.c junk2.c
3167 chmod 444 Makefile.new
3168 mv -f Makefile.new Makefile
3169 )
3171 echo creating src/Makefile
3172 ( cd src
3173 rm -f junk.c junk1.c junk2.c
3174 sed -e '/start of cpp stuff/q' \
3175 < Makefile.c > junk1.c
3176 sed -e '1,/start of cpp stuff/d'\
3177 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3178 < Makefile.c > junk.c
3179 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3180 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3181 cat junk1.c junk2.c > Makefile.new
3182 rm -f junk.c junk1.c junk2.c
3183 chmod 444 Makefile.new
3184 mv -f Makefile.new Makefile
3185 )
3187 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3188 echo creating src/.gdbinit
3189 echo source $srcdir/src/.gdbinit > src/.gdbinit
3190 fi
3192 # This is how we know whether to re-run configure in certain cases.
3193 touch src/config.stamp
3195 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3197 m4_if(dnl Do not change this comment
3198 arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3199 )dnl