lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Howie Kaye
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the sorting facilities documented in the Emacs
  28 ;; user's manual.
  29
  30 ;;; Code:
  31
  32 (defgroup sort nil
  33   "Commands to sort text in an Emacs buffer."
  34   :group 'data)
  35
  36 (defcustom sort-fold-case nil
  37   "*Non-nil if the buffer sort functions should ignore case."
  38   :group 'sort
  39   :type 'boolean)
  40 ;;;###autoload(put 'sort-fold-case 'safe-local-variable 'booleanp)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun
  44                           &optional startkeyfun endkeyfun predicate)
  45   "General text sorting routine to divide buffer into records and sort them.
  46
  47 We divide the accessible portion of the buffer into disjoint pieces
  48 called sort records.  A portion of each sort record (perhaps all of
  49 it) is designated as the sort key.  The records are rearranged in the
  50 buffer in order by their sort keys.  The records may or may not be
  51 contiguous.
  52
  53 Usually the records are rearranged in order of ascending sort key.
  54 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  55 The variable `sort-fold-case' determines whether alphabetic case affects
  56 the sort order.
  57
  58 The next four arguments are functions to be called to move point
  59 across a sort record.  They will be called many times from within sort-subr.
  60
  61 NEXTRECFUN is called with point at the end of the previous record.
  62 It moves point to the start of the next record.
  63 It should move point to the end of the buffer if there are no more records.
  64 The first record is assumed to start at the position of point when sort-subr
  65 is called.
  66
  67 ENDRECFUN is called with point within the record.
  68 It should move point to the end of the record.
  69
  70 STARTKEYFUN moves from the start of the record to the start of the key.
  71 It may return either a non-nil value to be used as the key, or
  72 else the key is the substring between the values of point after
  73 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  74 starts at the beginning of the record.
  75
  76 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  77 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  78 same as ENDRECFUN.
  79
  80 PREDICATE is the function to use to compare keys.  If keys are numbers,
  81 it defaults to `<', otherwise it defaults to `string<'."
  82   ;; Heuristically try to avoid messages if sorting a small amt of text.
  83   (let ((messages (> (- (point-max) (point-min)) 50000)))
  84     (save-excursion
  85       (if messages (message "Finding sort keys..."))
  86       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  87                                            startkeyfun endkeyfun))
  88              (old (reverse sort-lists))
  89              (case-fold-search sort-fold-case))
  90         (if (null sort-lists)
  91             ()
  92           (or reverse (setq sort-lists (nreverse sort-lists)))
  93           (if messages (message "Sorting records..."))
  94           (setq sort-lists
  95                 (sort sort-lists
  96                       (cond (predicate
  97                              `(lambda (a b) (,predicate (car a) (car b))))
  98                             ((numberp (car (car sort-lists)))
  99                              'car-less-than-car)
 100                             ((consp (car (car sort-lists)))
 101                              (lambda (a b)
 102                                (> 0 (compare-buffer-substrings
 103                                      nil (car (car a)) (cdr (car a))
 104                                      nil (car (car b)) (cdr (car b))))))
 105                             (t
 106                              (lambda (a b) (string< (car a) (car b)))))))
 107           (if reverse (setq sort-lists (nreverse sort-lists)))
 108           (if messages (message "Reordering buffer..."))
 109           (sort-reorder-buffer sort-lists old)))
 110       (if messages (message "Reordering buffer... Done"))))
 111   nil)
 112
 113 ;; Parse buffer into records using the arguments as Lisp expressions;
 114 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 115 ;; where KEY is the sort key (a number or string),
 116 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 117
 118 ;; The records appear in the list lastmost first!
 119
 120 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 121   (let ((sort-lists ())
 122         (start-rec nil)
 123         done key)
 124     ;; Loop over sort records.
 125     ;(goto-char (point-min)) -- it is the caller's responsibility to
 126     ;arrange this if necessary
 127     (while (not (eobp))
 128       (setq start-rec (point))          ;save record start
 129       (setq done nil)
 130       ;; Get key value, or move to start of key.
 131       (setq key (catch 'key
 132                   (or (and startkeyfun (funcall startkeyfun))
 133                       ;; If key was not returned as value,
 134                       ;; move to end of key and get key from the buffer.
 135                       (let ((start (point)))
 136                         (funcall (or endkeyfun
 137                                      (prog1 endrecfun (setq done t))))
 138                         (cons start (point))))))
 139       ;; Move to end of this record (start of next one, or end of buffer).
 140       (cond ((prog1 done (setq done nil)))
 141             (endrecfun (funcall endrecfun))
 142             (nextrecfun (funcall nextrecfun) (setq done t)))
 143       (if key (push
 144                ;; consing optimization in case in which key is same as record.
 145                (if (and (consp key)
 146                         (equal (car key) start-rec)
 147                         (equal (cdr key) (point)))
 148                    (cons key key)
 149                  (cons key (cons start-rec (point))))
 150                sort-lists))
 151       (and (not done) nextrecfun (funcall nextrecfun)))
 152     sort-lists))
 153
 154 (defun sort-reorder-buffer (sort-lists old)
 155   (let ((last (point-min))
 156         (min (point-min)) (max (point-max))
 157         (old-buffer (current-buffer))
 158         (mb enable-multibyte-characters)
 159         temp-buffer)
 160     (with-temp-buffer
 161       (set-buffer-multibyte mb)
 162       ;; Record the temporary buffer.
 163       (setq temp-buffer (current-buffer))
 164
 165       ;; Copy the sorted text into the temporary buffer.
 166       (while sort-lists
 167         (goto-char (point-max))
 168         (insert-buffer-substring old-buffer
 169                                  last
 170                                  (nth 1 (car old)))
 171         (goto-char (point-max))
 172         (insert-buffer-substring old-buffer
 173                                  (nth 1 (car sort-lists))
 174                                  (cdr (cdr (car sort-lists))))
 175         (setq last (cdr (cdr (car old)))
 176               sort-lists (cdr sort-lists)
 177               old (cdr old)))
 178       (goto-char (point-max))
 179       (insert-buffer-substring old-buffer last max)
 180
 181       ;; Copy the reordered text from the temporary buffer
 182       ;; to the buffer we sorted (OLD-BUFFER).
 183       (set-buffer old-buffer)
 184       (let ((inhibit-quit t))
 185         ;; Make sure insertions done for reordering
 186         ;; saves any markers at the end of the sorted region,
 187         ;; by leaving the last character of the region.
 188         (delete-region min (1- max))
 189         ;; Now replace the one remaining old character with the sorted text.
 190         (goto-char (point-min))
 191         (insert-buffer-substring temp-buffer)
 192         (delete-region max (1+ max))))))
 193
 194 ;;;###autoload
 195 (defun sort-lines (reverse beg end)
 196   "Sort lines in region alphabetically; argument means descending order.
 197 Called from a program, there are three arguments:
 198 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 199 The variable `sort-fold-case' determines whether alphabetic case affects
 200 the sort order."
 201   (interactive "P\nr")
 202   (save-excursion
 203     (save-restriction
 204       (narrow-to-region beg end)
 205       (goto-char (point-min))
 206       (let ;; To make `end-of-line' and etc. to ignore fields.
 207           ((inhibit-field-text-motion t))
 208         (sort-subr reverse 'forward-line 'end-of-line)))))
 209
 210 ;;;###autoload
 211 (defun sort-paragraphs (reverse beg end)
 212   "Sort paragraphs in region alphabetically; argument means descending order.
 213 Called from a program, there are three arguments:
 214 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 215 The variable `sort-fold-case' determines whether alphabetic case affects
 216 the sort order."
 217   (interactive "P\nr")
 218   (save-excursion
 219     (save-restriction
 220       (narrow-to-region beg end)
 221       (goto-char (point-min))
 222       (sort-subr reverse
 223                  (function
 224                   (lambda ()
 225                     (while (and (not (eobp)) (looking-at paragraph-separate))
 226                       (forward-line 1))))
 227                  'forward-paragraph))))
 228
 229 ;;;###autoload
 230 (defun sort-pages (reverse beg end)
 231   "Sort pages in region alphabetically; argument means descending order.
 232 Called from a program, there are three arguments:
 233 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 234 The variable `sort-fold-case' determines whether alphabetic case affects
 235 the sort order."
 236   (interactive "P\nr")
 237   (save-excursion
 238     (save-restriction
 239       (narrow-to-region beg end)
 240       (goto-char (point-min))
 241       (sort-subr reverse
 242                  (function (lambda () (skip-chars-forward "\n")))
 243                  'forward-page))))
 244 \f
 245 (defvar sort-fields-syntax-table nil)
 246 (if sort-fields-syntax-table nil
 247   (let ((table (make-syntax-table))
 248         (i 0))
 249     (while (< i 256)
 250       (modify-syntax-entry i "w" table)
 251       (setq i (1+ i)))
 252     (modify-syntax-entry ?\s " " table)
 253     (modify-syntax-entry ?\t " " table)
 254     (modify-syntax-entry ?\n " " table)
 255     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 256     (setq sort-fields-syntax-table table)))
 257
 258 (defcustom sort-numeric-base 10
 259   "*The default base used by `sort-numeric-fields'."
 260   :group 'sort
 261   :type 'integer)
 262 ;;;###autoload(put 'sort-numeric-base 'safe-local-variable 'integerp)
 263
 264 ;;;###autoload
 265 (defun sort-numeric-fields (field beg end)
 266   "Sort lines in region numerically by the ARGth field of each line.
 267 Fields are separated by whitespace and numbered from 1 up.
 268 Specified field must contain a number in each line of the region,
 269 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 270 Otherwise, the number is interpreted according to sort-numeric-base.
 271 With a negative arg, sorts by the ARGth field counted from the right.
 272 Called from a program, there are three arguments:
 273 FIELD, BEG and END.  BEG and END specify region to sort."
 274   (interactive "p\nr")
 275   (let ;; To make `end-of-line' and etc. to ignore fields.
 276       ((inhibit-field-text-motion t))
 277     (sort-fields-1 field beg end
 278                    (lambda ()
 279                      (sort-skip-fields field)
 280                      (let* ((case-fold-search t)
 281                             (base
 282                              (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 283                                  (cond ((match-beginning 1)
 284                                         (goto-char (match-end 1))
 285                                         16)
 286                                        ((match-beginning 2)
 287                                         (goto-char (match-end 2))
 288                                         8)
 289                                        (t nil)))))
 290                        (string-to-number (buffer-substring (point)
 291                                                            (save-excursion
 292                                                              (forward-sexp 1)
 293                                                              (point)))
 294                                          (or base sort-numeric-base))))
 295                    nil)))
 296
 297 ;;;;;###autoload
 298 ;;(defun sort-float-fields (field beg end)
 299 ;;  "Sort lines in region numerically by the ARGth field of each line.
 300 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 301 ;;must contain a floating point number in each line of the region.  With a
 302 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 303 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 304 ;;region to sort."
 305 ;;  (interactive "p\nr")
 306 ;;  (sort-fields-1 field beg end
 307 ;;               (function (lambda ()
 308 ;;                           (sort-skip-fields field)
 309 ;;                           (string-to-number
 310 ;;                            (buffer-substring
 311 ;;                             (point)
 312 ;;                             (save-excursion
 313 ;;                               (re-search-forward
 314 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 315 ;;                               (point))))))
 316 ;;               nil))
 317
 318 ;;;###autoload
 319 (defun sort-fields (field beg end)
 320   "Sort lines in region lexicographically by the ARGth field of each line.
 321 Fields are separated by whitespace and numbered from 1 up.
 322 With a negative arg, sorts by the ARGth field counted from the right.
 323 Called from a program, there are three arguments:
 324 FIELD, BEG and END.  BEG and END specify region to sort.
 325 The variable `sort-fold-case' determines whether alphabetic case affects
 326 the sort order."
 327   (interactive "p\nr")
 328   (let ;; To make `end-of-line' and etc. to ignore fields.
 329       ((inhibit-field-text-motion t))
 330     (sort-fields-1 field beg end
 331                    (function (lambda ()
 332                                (sort-skip-fields field)
 333                                nil))
 334                    (function (lambda () (skip-chars-forward "^ \t\n"))))))
 335
 336 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 337   (let ((tbl (syntax-table)))
 338     (if (zerop field) (setq field 1))
 339     (unwind-protect
 340         (save-excursion
 341           (save-restriction
 342             (narrow-to-region beg end)
 343             (goto-char (point-min))
 344             (set-syntax-table sort-fields-syntax-table)
 345             (sort-subr nil
 346                        'forward-line 'end-of-line
 347                        startkeyfun endkeyfun)))
 348       (set-syntax-table tbl))))
 349
 350 ;; Position at the beginning of field N on the current line,
 351 ;; assuming point is initially at the beginning of the line.
 352 (defun sort-skip-fields (n)
 353   (if (> n 0)
 354       ;; Skip across N - 1 fields.
 355       (let ((i (1- n)))
 356         (while (> i 0)
 357           (skip-chars-forward " \t")
 358           (skip-chars-forward "^ \t\n")
 359           (setq i (1- i)))
 360         (skip-chars-forward " \t")
 361         (if (eolp)
 362             (error "Line has too few fields: %s"
 363                    (buffer-substring
 364                     (save-excursion (beginning-of-line) (point))
 365                     (save-excursion (end-of-line) (point))))))
 366     (end-of-line)
 367     ;; Skip back across - N - 1 fields.
 368     (let ((i (1- (- n))))
 369       (while (> i 0)
 370         (skip-chars-backward " \t")
 371         (skip-chars-backward "^ \t\n")
 372         (setq i (1- i)))
 373       (skip-chars-backward " \t"))
 374     (if (bolp)
 375         (error "Line has too few fields: %s"
 376                (buffer-substring
 377                 (save-excursion (beginning-of-line) (point))
 378                 (save-excursion (end-of-line) (point)))))
 379     ;; Position at the front of the field
 380     ;; even if moving backwards.
 381     (skip-chars-backward "^ \t\n")))
 382 \f
 383 (defvar sort-regexp-fields-regexp)
 384 (defvar sort-regexp-record-end)
 385
 386 ;; Move to the beginning of the next match for record-regexp,
 387 ;; and set sort-regexp-record-end to the end of that match.
 388 ;; If the next match is empty and does not advance point,
 389 ;; skip one character and try again.
 390 (defun sort-regexp-fields-next-record ()
 391   (let ((oldpos (point)))
 392     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 393          (setq sort-regexp-record-end (match-end 0))
 394          (if (= sort-regexp-record-end oldpos)
 395              (progn
 396                (forward-char 1)
 397                (re-search-forward sort-regexp-fields-regexp nil 'move)
 398                (setq sort-regexp-record-end (match-end 0)))
 399            t)
 400          (goto-char (match-beginning 0)))))
 401
 402 ;;;###autoload
 403 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 404   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 405 RECORD-REGEXP specifies the textual units which should be sorted.
 406   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 407 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 408   is to be used for sorting.
 409   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 410   RECORD-REGEXP is used.
 411   If it is \"\\\\&\" then the whole record is used.
 412   Otherwise, it is a regular-expression for which to search within the record.
 413 If a match for KEY is not found within a record then that record is ignored.
 414
 415 With a negative prefix arg sorts in reverse order.
 416
 417 The variable `sort-fold-case' determines whether alphabetic case affects
 418 the sort order.
 419
 420 For example: to sort lines in the region by the first word on each line
 421  starting with the letter \"f\",
 422  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 423   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 424   ;; other sort-.*fields functions but then again this was before, since it
 425   ;; didn't use the magnitude of the arg to specify anything.
 426   (interactive "P\nsRegexp specifying records to sort:
 427 sRegexp specifying key within record: \nr")
 428   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 429          (setq key-regexp 0))
 430         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 431          (setq key-regexp (- (aref key-regexp 1) ?0))))
 432   (save-excursion
 433     (save-restriction
 434       (narrow-to-region beg end)
 435       (goto-char (point-min))
 436       (let (sort-regexp-record-end
 437             (sort-regexp-fields-regexp record-regexp))
 438         (re-search-forward sort-regexp-fields-regexp nil t)
 439         (setq sort-regexp-record-end (point))
 440         (goto-char (match-beginning 0))
 441         (sort-subr reverse
 442                    'sort-regexp-fields-next-record
 443                    (function (lambda ()
 444                                (goto-char sort-regexp-record-end)))
 445                    (function (lambda ()
 446                                (let ((n 0))
 447                                  (cond ((numberp key-regexp)
 448                                         (setq n key-regexp))
 449                                        ((re-search-forward
 450                                           key-regexp sort-regexp-record-end t)
 451                                         (setq n 0))
 452                                        (t (throw 'key nil)))
 453                                  (condition-case ()
 454                                      (cons (match-beginning n)
 455                                            (match-end n))
 456                                    ;; if there was no such register
 457                                    (error (throw 'key nil)))))))))))
 458
 459 \f
 460 (defvar sort-columns-subprocess t)
 461
 462 ;;;###autoload
 463 (defun sort-columns (reverse &optional beg end)
 464   "Sort lines in region alphabetically by a certain range of columns.
 465 For the purpose of this command, the region BEG...END includes
 466 the entire line that point is in and the entire line the mark is in.
 467 The column positions of point and mark bound the range of columns to sort on.
 468 A prefix argument means sort into REVERSE order.
 469 The variable `sort-fold-case' determines whether alphabetic case affects
 470 the sort order.
 471
 472 Note that `sort-columns' rejects text that contains tabs,
 473 because tabs could be split across the specified columns
 474 and it doesn't know how to handle that.  Also, when possible,
 475 it uses the `sort' utility program, which doesn't understand tabs.
 476 Use \\[untabify] to convert tabs to spaces before sorting."
 477   (interactive "P\nr")
 478   (save-excursion
 479     (let ;; To make `end-of-line' and etc. to ignore fields.
 480         ((inhibit-field-text-motion t)
 481          beg1 end1 col-beg1 col-end1 col-start col-end)
 482       (goto-char (min beg end))
 483       (setq col-beg1 (current-column))
 484       (beginning-of-line)
 485       (setq beg1 (point))
 486       (goto-char (max beg end))
 487       (setq col-end1 (current-column))
 488       (forward-line)
 489       (setq end1 (point))
 490       (setq col-start (min col-beg1 col-end1))
 491       (setq col-end (max col-beg1 col-end1))
 492       (if (search-backward "\t" beg1 t)
 493           (error "sort-columns does not work with tabs -- use M-x untabify"))
 494       (if (not (or (memq system-type '(windows-nt))
 495                    (let ((pos beg1) plist fontified)
 496                      (catch 'found
 497                        (while (< pos end1)
 498                          (setq plist (text-properties-at pos))
 499                          (setq fontified (plist-get plist 'fontified))
 500                          (while (consp plist)
 501                            (unless (or (eq (car plist) 'fontified)
 502                                        (and (eq (car plist) 'face)
 503                                             fontified))
 504                              (throw 'found t))
 505                            (setq plist (cddr plist)))
 506                          (setq pos (next-property-change pos nil end1)))))))
 507           ;; Use the sort utility if we can; it is 4 times as fast.
 508           ;; Do not use it if there are any non-font-lock properties
 509           ;; in the region, since the sort utility would lose the
 510           ;; properties.  Tabs are used as field separator; on NetBSD,
 511           ;; sort complains if "\n" is used as field separator.
 512           (let ((sort-args (list (if reverse "-rt\t" "-t\t")
 513                                  (format "-k1.%d,1.%d"
 514                                          (1+ col-start)
 515                                          (1+ col-end)))))
 516             (when sort-fold-case
 517               (push "-f" sort-args))
 518             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 519         ;; On ms-windows, use Emacs's own facilities.
 520         (save-excursion
 521           (save-restriction
 522             (narrow-to-region beg1 end1)
 523             (goto-char beg1)
 524             (sort-subr reverse 'forward-line 'end-of-line
 525                        #'(lambda () (move-to-column col-start) nil)
 526                        #'(lambda () (move-to-column col-end) nil))))))))
 527
 528 ;;;###autoload
 529 (defun reverse-region (beg end)
 530   "Reverse the order of lines in a region.
 531 From a program takes two point or marker arguments, BEG and END."
 532   (interactive "r")
 533   (if (> beg end)
 534       (let (mid) (setq mid end end beg beg mid)))
 535   (save-excursion
 536     ;; put beg at the start of a line and end and the end of one --
 537     ;; the largest possible region which fits this criteria
 538     (goto-char beg)
 539     (or (bolp) (forward-line 1))
 540     (setq beg (point))
 541     (goto-char end)
 542     ;; the test for bolp is for those times when end is on an empty line;
 543     ;; it is probably not the case that the line should be included in the
 544     ;; reversal; it isn't difficult to add it afterward.
 545     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 546     (setq end (point-marker))
 547     ;; the real work.  this thing cranks through memory on large regions.
 548     (let (ll (do t))
 549       (while do
 550         (goto-char beg)
 551         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 552                        ll))
 553         (setq do (/= (point) end))
 554         (delete-region beg (if do (1+ (point)) (point))))
 555       (while (cdr ll)
 556         (insert (car ll) "\n")
 557         (setq ll (cdr ll)))
 558       (insert (car ll)))))
 559
 560 (provide 'sort)
 561
 562 ;; arch-tag: fbac12be-2a7b-4c8a-9665-264d61f70bd9
 563 ;;; sort.el ends here