lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- Netscape Cookie support
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'timezone)
  30 (require 'url-util)
  31 (require 'url-parse)
  32 (eval-when-compile (require 'cl))
  33
  34 ;; See http://home.netscape.com/newsref/std/cookie_spec.html for the
  35 ;; 'open standard' defining this crap.
  36 ;;
  37 ;; A cookie is stored internally as a vector of 7 slots
  38 ;; [ cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  39
  40 (defsubst url-cookie-name    (cookie) (aref cookie 1))
  41 (defsubst url-cookie-value   (cookie) (aref cookie 2))
  42 (defsubst url-cookie-expires (cookie) (aref cookie 3))
  43 (defsubst url-cookie-localpart    (cookie) (aref cookie 4))
  44 (defsubst url-cookie-domain  (cookie) (aref cookie 5))
  45 (defsubst url-cookie-secure  (cookie) (aref cookie 6))
  46
  47 (defsubst url-cookie-set-name    (cookie val) (aset cookie 1 val))
  48 (defsubst url-cookie-set-value   (cookie val) (aset cookie 2 val))
  49 (defsubst url-cookie-set-expires (cookie val) (aset cookie 3 val))
  50 (defsubst url-cookie-set-localpart (cookie val) (aset cookie 4 val))
  51 (defsubst url-cookie-set-domain  (cookie val) (aset cookie 5 val))
  52 (defsubst url-cookie-set-secure  (cookie val) (aset cookie 6 val))
  53 (defsubst url-cookie-retrieve-arg (key args) (nth 1 (memq key args)))
  54
  55 (defsubst url-cookie-create (&rest args)
  56   "Create a cookie vector object from keyword-value pairs ARGS.
  57 The keywords allowed are
  58   :name NAME
  59   :value VALUE
  60   :expires TIME
  61   :localpart LOCALPAR
  62   :domain DOMAIN
  63   :secure ???
  64 Could someone fill in more information?"
  65   (let ((retval (make-vector 7 nil)))
  66     (aset retval 0 'cookie)
  67     (url-cookie-set-name retval (url-cookie-retrieve-arg :name args))
  68     (url-cookie-set-value retval (url-cookie-retrieve-arg :value args))
  69     (url-cookie-set-expires retval (url-cookie-retrieve-arg :expires args))
  70     (url-cookie-set-localpart retval (url-cookie-retrieve-arg :localpart args))
  71     (url-cookie-set-domain retval (url-cookie-retrieve-arg :domain args))
  72     (url-cookie-set-secure retval (url-cookie-retrieve-arg :secure args))
  73     retval))
  74
  75 (defun url-cookie-p (obj)
  76   "Return non-nil if OBJ is a cookie vector object.
  77 These objects represent cookies in the URL package.
  78 A cookie vector object is a vector of 7 slots:
  79  [cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE]."
  80   (and (vectorp obj) (= (length obj) 7) (eq (aref obj 0) 'cookie)))
  81
  82 (defgroup url-cookie nil
  83   "URL cookies."
  84   :prefix "url-"
  85   :prefix "url-cookie-"
  86   :group 'url)
  87
  88 (defvar url-cookie-storage nil         "Where cookies are stored.")
  89 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  90 (defcustom url-cookie-file nil
  91   "*File where cookies are stored on disk."
  92   :type '(choice (const :tag "Default" :value nil) file)
  93   :group 'url-file
  94   :group 'url-cookie)
  95
  96 (defcustom url-cookie-confirmation nil
  97   "*If non-nil, confirmation by the user is required to accept HTTP cookies."
  98   :type 'boolean
  99   :group 'url-cookie)
 100
 101 (defcustom url-cookie-multiple-line nil
 102   "*If nil, HTTP requests put all cookies for the server on one line.
 103 Some web servers, such as http://www.hotmail.com/, only accept cookies
 104 when they are on one line.  This is broken behavior, but just try
 105 telling Microsoft that."
 106   :type 'boolean
 107   :group 'url-cookie)
 108
 109 (defvar url-cookies-changed-since-last-save nil
 110   "Whether the cookies list has changed since the last save operation.")
 111
 112 (defun url-cookie-parse-file (&optional fname)
 113   (setq fname (or fname url-cookie-file))
 114   (condition-case ()
 115       (load fname nil t)
 116     (error
 117      ;; It's completely normal for the cookies file not to exist yet.
 118      ;; (message "Could not load cookie file %s" fname)
 119      )))
 120
 121 (defun url-cookie-clean-up (&optional secure)
 122   (let* (
 123          (var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
 124          (val (symbol-value var))
 125          (cur nil)
 126          (new nil)
 127          (cookies nil)
 128          (cur-cookie nil)
 129          (new-cookies nil)
 130          )
 131     (while val
 132       (setq cur (car val)
 133             val (cdr val)
 134             new-cookies nil
 135             cookies (cdr cur))
 136       (while cookies
 137         (setq cur-cookie (car cookies)
 138               cookies (cdr cookies))
 139         (if (or (not (url-cookie-p cur-cookie))
 140                 (url-cookie-expired-p cur-cookie)
 141                 (null (url-cookie-expires cur-cookie)))
 142             nil
 143           (setq new-cookies (cons cur-cookie new-cookies))))
 144       (if (not new-cookies)
 145           nil
 146         (setcdr cur new-cookies)
 147         (setq new (cons cur new))))
 148     (set var new)))
 149
 150 (defun url-cookie-write-file (&optional fname)
 151   (setq fname (or fname url-cookie-file))
 152   (unless (file-directory-p (file-name-directory fname))
 153     (ignore-errors (make-directory (file-name-directory fname))))
 154   (cond
 155    ((not url-cookies-changed-since-last-save) nil)
 156    ((not (file-writable-p fname))
 157     (message "Cookies file %s (see variable `url-cookie-file') is unwritable." fname))
 158    (t
 159     (url-cookie-clean-up)
 160     (url-cookie-clean-up t)
 161     (with-current-buffer (get-buffer-create " *cookies*")
 162       (erase-buffer)
 163       (fundamental-mode)
 164       (insert ";; Emacs-W3 HTTP cookies file\n"
 165               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 166               "(setq url-cookie-storage\n '")
 167       (pp url-cookie-storage (current-buffer))
 168       (insert ")\n(setq url-cookie-secure-storage\n '")
 169       (pp url-cookie-secure-storage (current-buffer))
 170       (insert ")\n")
 171       (write-file fname)
 172       (kill-buffer (current-buffer))))))
 173
 174 (defun url-cookie-store (name value &optional expires domain localpart secure)
 175   "Store a netscape-style cookie."
 176   (let* ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 177          (tmp storage)
 178          (cur nil)
 179          (found-domain nil))
 180
 181     ;; First, look for a matching domain
 182     (setq found-domain (assoc domain storage))
 183
 184     (if found-domain
 185         ;; Need to either stick the new cookie in existing domain storage
 186         ;; or possibly replace an existing cookie if the names match.
 187         (progn
 188           (setq storage (cdr found-domain)
 189                 tmp nil)
 190           (while storage
 191             (setq cur (car storage)
 192                   storage (cdr storage))
 193             (if (and (equal localpart (url-cookie-localpart cur))
 194                      (equal name (url-cookie-name cur)))
 195                 (progn
 196                   (url-cookie-set-expires cur expires)
 197                   (url-cookie-set-value cur value)
 198                   (setq tmp t))))
 199           (if (not tmp)
 200               ;; New cookie
 201               (setcdr found-domain (cons
 202                                     (url-cookie-create :name name
 203                                                        :value value
 204                                                        :expires expires
 205                                                        :domain domain
 206                                                        :localpart localpart
 207                                                        :secure secure)
 208                                     (cdr found-domain)))))
 209       ;; Need to add a new top-level domain
 210       (setq tmp (url-cookie-create :name name
 211                                    :value value
 212                                    :expires expires
 213                                    :domain domain
 214                                    :localpart localpart
 215                                    :secure secure))
 216       (cond
 217        (storage
 218         (setcdr storage (cons (list domain tmp) (cdr storage))))
 219        (secure
 220         (setq url-cookie-secure-storage (list (list domain tmp))))
 221        (t
 222         (setq url-cookie-storage (list (list domain tmp))))))))
 223
 224 (defun url-cookie-expired-p (cookie)
 225   (let* (
 226          (exp (url-cookie-expires cookie))
 227          (cur-date (and exp (timezone-parse-date (current-time-string))))
 228          (exp-date (and exp (timezone-parse-date exp)))
 229          (cur-greg (and cur-date (timezone-absolute-from-gregorian
 230                                   (string-to-number (aref cur-date 1))
 231                                   (string-to-number (aref cur-date 2))
 232                                   (string-to-number (aref cur-date 0)))))
 233          (exp-greg (and exp (timezone-absolute-from-gregorian
 234                              (string-to-number (aref exp-date 1))
 235                              (string-to-number (aref exp-date 2))
 236                              (string-to-number (aref exp-date 0)))))
 237          (diff-in-days (and exp (- cur-greg exp-greg)))
 238          )
 239     (cond
 240      ((not exp) nil)                    ; No expiry == expires at browser quit
 241      ((< diff-in-days 0) nil)           ; Expires sometime after today
 242      ((> diff-in-days 0) t)             ; Expired before today
 243      (t                                 ; Expires sometime today, check times
 244       (let* ((cur-time (timezone-parse-time (aref cur-date 3)))
 245              (exp-time (timezone-parse-time (aref exp-date 3)))
 246              (cur-norm (+ (* 360 (string-to-number (aref cur-time 2)))
 247                           (*  60 (string-to-number (aref cur-time 1)))
 248                           (*   1 (string-to-number (aref cur-time 0)))))
 249              (exp-norm (+ (* 360 (string-to-number (aref exp-time 2)))
 250                           (*  60 (string-to-number (aref exp-time 1)))
 251                           (*   1 (string-to-number (aref exp-time 0))))))
 252         (> (- cur-norm exp-norm) 1))))))
 253
 254 (defun url-cookie-retrieve (host localpart &optional secure)
 255   "Retrieve all the netscape-style cookies for a specified HOST and LOCALPART."
 256   (let ((storage (if secure
 257                      (append url-cookie-secure-storage url-cookie-storage)
 258                    url-cookie-storage))
 259         (case-fold-search t)
 260         (cookies nil)
 261         (cur nil)
 262         (retval nil)
 263         (localpart-regexp nil))
 264     (while storage
 265       (setq cur (car storage)
 266             storage (cdr storage)
 267             cookies (cdr cur))
 268       (if (and (car cur)
 269                (string-match (concat "^.*" (regexp-quote (car cur)) "$") host))
 270           ;; The domains match - a possible hit!
 271           (while cookies
 272             (setq cur (car cookies)
 273                   cookies (cdr cookies)
 274                   localpart-regexp (concat "^" (regexp-quote
 275                                                 (url-cookie-localpart cur))))
 276             (if (and (string-match localpart-regexp localpart)
 277                      (not (url-cookie-expired-p cur)))
 278                 (setq retval (cons cur retval))))))
 279     retval))
 280
 281 (defun url-cookie-generate-header-lines (host localpart secure)
 282   (let* ((cookies (url-cookie-retrieve host localpart secure))
 283          (retval nil)
 284          (cur nil)
 285          (chunk nil))
 286     ;; Have to sort this for sending most specific cookies first
 287     (setq cookies (and cookies
 288                        (sort cookies
 289                              (function
 290                               (lambda (x y)
 291                                 (> (length (url-cookie-localpart x))
 292                                    (length (url-cookie-localpart y))))))))
 293     (while cookies
 294       (setq cur (car cookies)
 295             cookies (cdr cookies)
 296             chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 297             retval (if (and url-cookie-multiple-line
 298                             (< 80 (+ (length retval) (length chunk) 4)))
 299                        (concat retval "\r\nCookie: " chunk)
 300                      (if retval
 301                          (concat retval "; " chunk)
 302                        (concat "Cookie: " chunk)))))
 303     (if retval
 304         (concat retval "\r\n")
 305       "")))
 306
 307 (defvar url-cookie-two-dot-domains
 308   (concat "\\.\\("
 309    (mapconcat 'identity (list "com" "edu" "net" "org" "gov" "mil" "int")
 310               "\\|")
 311    "\\)$")
 312   "A regexp of top level domains that only require two matching
 313 '.'s in the domain name in order to set a cookie.")
 314
 315 (defcustom url-cookie-trusted-urls nil
 316   "*A list of regular expressions matching URLs to always accept cookies from."
 317   :type '(repeat regexp)
 318   :group 'url-cookie)
 319
 320 (defcustom url-cookie-untrusted-urls nil
 321   "*A list of regular expressions matching URLs to never accept cookies from."
 322   :type '(repeat regexp)
 323   :group 'url-cookie)
 324
 325 (defun url-cookie-host-can-set-p (host domain)
 326   (let ((numdots 0)
 327         (tmp domain)
 328         (last nil)
 329         (case-fold-search t)
 330         (mindots 3))
 331     (while (setq last (string-match "\\." domain last))
 332       (setq numdots (1+ numdots)
 333             last (1+ last)))
 334     (if (string-match url-cookie-two-dot-domains domain)
 335         (setq mindots 2))
 336     (cond
 337      ((string= host domain)             ; Apparently netscape lets you do this
 338       t)
 339      ((>= numdots mindots)              ; We have enough dots in domain name
 340       ;; Need to check and make sure the host is actually _in_ the
 341       ;; domain it wants to set a cookie for though.
 342       (string-match (concat (regexp-quote domain) "$") host))
 343      (t
 344       nil))))
 345
 346 (defun url-cookie-handle-set-cookie (str)
 347   (setq url-cookies-changed-since-last-save t)
 348   (let* ((args (url-parse-args str t))
 349          (case-fold-search t)
 350          (secure (and (assoc-string "secure" args t) t))
 351          (domain (or (cdr-safe (assoc-string "domain" args t))
 352                      (url-host url-current-object)))
 353          (current-url (url-view-url t))
 354          (trusted url-cookie-trusted-urls)
 355          (untrusted url-cookie-untrusted-urls)
 356          (expires (cdr-safe (assoc-string "expires" args t)))
 357          (localpart (or (cdr-safe (assoc-string "path" args t))
 358                         (file-name-directory
 359                          (url-filename url-current-object))))
 360          (rest nil))
 361     (while args
 362       (if (not (member (downcase (car (car args)))
 363                        '("secure" "domain" "expires" "path")))
 364           (setq rest (cons (car args) rest)))
 365       (setq args (cdr args)))
 366
 367     ;; Sometimes we get dates that the timezone package cannot handle very
 368     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 369     ;; to speed things up.
 370     (if (and expires
 371              (string-match
 372               (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 373                       "\\(..:..:..\\) +\\[*\\([^\]]+\\)\\]*$")
 374               expires))
 375         (setq expires (concat (match-string 1 expires) " "
 376                               (match-string 2 expires) " "
 377                               (match-string 3 expires) " "
 378                               (match-string 4 expires) " ["
 379                               (match-string 5 expires) "]")))
 380
 381     ;; This one is for older Emacs/XEmacs variants that don't
 382     ;; understand this format without tenths of a second in it.
 383     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 384     ;;       - vs -
 385     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 386     (if (and expires
 387              (string-match
 388               "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 389               expires))
 390         (setq expires (concat (match-string 1 expires) "-"      ; day
 391                               (match-string 2 expires) "-"      ; month
 392                               (match-string 3 expires) " "      ; year
 393                               (match-string 4 expires) ".00 " ; hour:minutes:seconds
 394                               (match-string 6 expires)))) ":" ; timezone
 395
 396     (while (consp trusted)
 397       (if (string-match (car trusted) current-url)
 398           (setq trusted (- (match-end 0) (match-beginning 0)))
 399         (pop trusted)))
 400     (while (consp untrusted)
 401       (if (string-match (car untrusted) current-url)
 402           (setq untrusted (- (match-end 0) (match-beginning 0)))
 403         (pop untrusted)))
 404     (if (and trusted untrusted)
 405         ;; Choose the more specific match
 406         (if (> trusted untrusted)
 407             (setq untrusted nil)
 408           (setq trusted nil)))
 409     (cond
 410      (untrusted
 411       ;; The site was explicity marked as untrusted by the user
 412       nil)
 413      ((or (eq url-privacy-level 'paranoid)
 414           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 415       ;; user never wants cookies
 416       nil)
 417      ((and url-cookie-confirmation
 418            (not trusted)
 419            (save-window-excursion
 420              (with-output-to-temp-buffer "*Cookie Warning*"
 421                (mapcar
 422                 (function
 423                  (lambda (x)
 424                    (princ (format "%s - %s" (car x) (cdr x))))) rest))
 425              (prog1
 426                  (not (funcall url-confirmation-func
 427                                (format "Allow %s to set these cookies? "
 428                                        (url-host url-current-object))))
 429                (if (get-buffer "*Cookie Warning*")
 430                    (kill-buffer "*Cookie Warning*")))))
 431       ;; user wants to be asked, and declined.
 432       nil)
 433      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 434       ;; Cookie is accepted by the user, and passes our security checks
 435       (let ((cur nil))
 436         (while rest
 437           (setq cur (pop rest))
 438           (url-cookie-store (car cur) (cdr cur)
 439                             expires domain localpart secure))))
 440      (t
 441       (message "%s tried to set a cookie for domain %s - rejected."
 442                (url-host url-current-object) domain)))))
 443
 444 (defvar url-cookie-timer nil)
 445
 446 (defcustom url-cookie-save-interval 3600
 447   "*The number of seconds between automatic saves of cookies.
 448 Default is 1 hour.  Note that if you change this variable outside of
 449 the `customize' interface after `url-do-setup' has been run, you need
 450 to run the `url-cookie-setup-save-timer' function manually."
 451   :set #'(lambda (var val)
 452            (set-default var val)
 453            (if (bound-and-true-p url-setup-done)
 454                (url-cookie-setup-save-timer)))
 455   :type 'integer
 456   :group 'url)
 457
 458 (defun url-cookie-setup-save-timer ()
 459   "Reset the cookie saver timer."
 460   (interactive)
 461   (ignore-errors (cancel-timer url-cookie-timer))
 462   (setq url-cookie-timer nil)
 463   (if url-cookie-save-interval
 464       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 465                                           url-cookie-save-interval
 466                                           #'url-cookie-write-file))))
 467
 468 (provide 'url-cookie)
 469
 470 ;; arch-tag: 2568751b-6452-4398-aa2d-303edadb54d7
 471 ;;; url-cookie.el ends here