lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   7 ;;   2008, 2009, 2010 Free Software Foundation, Inc.
   8 ;; Based partially on earlier release by Lucid.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defcustom selection-coding-system nil
  30   "Coding system for communicating with other X clients.
  31
  32 When sending text via selection and clipboard, if the target
  33 data-type matches with the type of this coding system, it is used
  34 for encoding the text.  Otherwise (including the case that this
  35 variable is nil), a proper coding system is used as below:
  36
  37 data-type       coding system
  38 ---------       -------------
  39 UTF8_STRING     utf-8
  40 COMPOUND_TEXT   compound-text-with-extensions
  41 STRING          iso-latin-1
  42 C_STRING        no-conversion
  43
  44 When receiving text, if this coding system is non-nil, it is used
  45 for decoding regardless of the data-type.  If this is nil, a
  46 proper coding system is used according to the data-type as above.
  47
  48 See also the documentation of the variable `x-select-request-type' how
  49 to control which data-type to request for receiving text.
  50
  51 The default value is nil."
  52   :type 'coding-system
  53   :group 'mule
  54   ;; Default was compound-text-with-extensions in 22.x (pre-unicode).
  55   :version "23.1"
  56   :set (lambda (symbol value)
  57          (set-selection-coding-system value)
  58          (set symbol value)))
  59
  60 (defvar next-selection-coding-system nil
  61   "Coding system for the next communication with other X clients.
  62 Usually, `selection-coding-system' is used for communicating with
  63 other X clients.  But, if this variable is set, it is used for
  64 the next communication only.  After the communication, this
  65 variable is set to nil.")
  66
  67 (declare-function x-get-selection-internal "xselect.c"
  68                   (selection-symbol target-type &optional time-stamp))
  69
  70 ;; This is for temporary compatibility with pre-release Emacs 19.
  71 (defalias 'x-selection 'x-get-selection)
  72 (defun x-get-selection (&optional type data-type)
  73   "Return the value of an X Windows selection.
  74 The argument TYPE (default `PRIMARY') says which selection,
  75 and the argument DATA-TYPE (default `STRING') says
  76 how to convert the data.
  77
  78 TYPE may be any symbol \(but nil stands for `PRIMARY').  However,
  79 only a few symbols are commonly used.  They conventionally have
  80 all upper-case names.  The most often used ones, in addition to
  81 `PRIMARY', are `SECONDARY' and `CLIPBOARD'.
  82
  83 DATA-TYPE is usually `STRING', but can also be one of the symbols
  84 in `selection-converter-alist', which see."
  85   (let ((data (x-get-selection-internal (or type 'PRIMARY)
  86                                         (or data-type 'STRING)))
  87         coding)
  88     (when (and (stringp data)
  89                (setq data-type (get-text-property 0 'foreign-selection data)))
  90       (setq coding (or next-selection-coding-system
  91                        selection-coding-system
  92                        (cond ((eq data-type 'UTF8_STRING)
  93                               'utf-8)
  94                              ((eq data-type 'COMPOUND_TEXT)
  95                               'compound-text-with-extensions)
  96                              ((eq data-type 'C_STRING)
  97                               nil)
  98                              ((eq data-type 'STRING)
  99                               'iso-8859-1)
 100                              (t
 101                               (error "Unknow selection data type: %S" type))))
 102             data (if coding (decode-coding-string data coding)
 103                    (string-to-multibyte data)))
 104       (setq next-selection-coding-system nil)
 105       (put-text-property 0 (length data) 'foreign-selection data-type data))
 106     data))
 107
 108 (defun x-get-clipboard ()
 109   "Return text pasted to the clipboard."
 110   (x-get-selection-internal 'CLIPBOARD 'STRING))
 111
 112 (declare-function x-own-selection-internal "xselect.c"
 113                   (selection-name selection-value))
 114 (declare-function x-disown-selection-internal "xselect.c"
 115                   (selection &optional time))
 116
 117 (defun x-set-selection (type data)
 118   "Make an X selection of type TYPE and value DATA.
 119 The argument TYPE (nil means `PRIMARY') says which selection, and
 120 DATA specifies the contents.  TYPE must be a symbol.  \(It can also
 121 be a string, which stands for the symbol with that name, but this
 122 is considered obsolete.)  DATA may be a string, a symbol, an
 123 integer (or a cons of two integers or list of two integers).
 124
 125 The selection may also be a cons of two markers pointing to the same buffer,
 126 or an overlay.  In these cases, the selection is considered to be the text
 127 between the markers *at whatever time the selection is examined*.
 128 Thus, editing done in the buffer after you specify the selection
 129 can alter the effective value of the selection.
 130
 131 The data may also be a vector of valid non-vector selection values.
 132
 133 The return value is DATA.
 134
 135 Interactively, this command sets the primary selection.  Without
 136 prefix argument, it reads the selection in the minibuffer.  With
 137 prefix argument, it uses the text of the region as the selection value.
 138
 139 Note that on MS-Windows, primary and secondary selections set by Emacs
 140 are not available to other programs."
 141   (interactive (if (not current-prefix-arg)
 142                    (list 'PRIMARY (read-string "Set text for pasting: "))
 143                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
 144   (if (stringp type) (setq type (intern type)))
 145   (or (x-valid-simple-selection-p data)
 146       (and (vectorp data)
 147            (let ((valid t)
 148                  (i (1- (length data))))
 149              (while (>= i 0)
 150                (or (x-valid-simple-selection-p (aref data i))
 151                    (setq valid nil))
 152                (setq i (1- i)))
 153              valid))
 154       (signal 'error (list "invalid selection" data)))
 155   (or type (setq type 'PRIMARY))
 156   (if data
 157       (x-own-selection-internal type data)
 158     (x-disown-selection-internal type))
 159   data)
 160
 161 (defun x-valid-simple-selection-p (data)
 162   (or (bufferp data)
 163       (and (consp data)
 164            (markerp (car data))
 165            (markerp (cdr data))
 166            (marker-buffer (car data))
 167            (buffer-name (marker-buffer (car data)))
 168            (eq (marker-buffer (car data))
 169                (marker-buffer (cdr data))))
 170       (stringp data)
 171       (and (overlayp data)
 172            (overlay-buffer data)
 173            (buffer-name (overlay-buffer data)))
 174       (symbolp data)
 175       (integerp data)))
 176 \f
 177 ;;; Cut Buffer support
 178
 179 (declare-function x-get-cut-buffer-internal "xselect.c")
 180
 181 (defun x-get-cut-buffer (&optional which-one)
 182   "Return the value of one of the 8 X server cut-buffers.
 183 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 184 Cut buffers are considered obsolete; you should use selections instead."
 185   (x-get-cut-buffer-internal
 186    (if which-one
 187        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 188               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 189              which-one)
 190      'CUT_BUFFER0)))
 191
 192 (declare-function x-rotate-cut-buffers-internal "xselect.c")
 193 (declare-function x-store-cut-buffer-internal "xselect.c")
 194
 195 (defun x-set-cut-buffer (string &optional push)
 196   "Store STRING into the X server's primary cut buffer.
 197 If PUSH is non-nil, also rotate the cut buffers:
 198 this means the previous value of the primary cut buffer moves to the second
 199 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 200 Cut buffers are considered obsolete; you should use selections instead."
 201   (or (stringp string) (signal 'wrong-type-argument (list 'stringp string)))
 202   (if push
 203       (x-rotate-cut-buffers-internal 1))
 204   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 205
 206 \f
 207 ;; Functions to convert the selection into various other selection types.
 208 ;; Every selection type that Emacs handles is implemented this way, except
 209 ;; for TIMESTAMP, which is a special case.
 210
 211 (defun xselect--selection-bounds (value)
 212   "Return bounds of X selection value VALUE.
 213 The return value is a list (BEG END BUF) if VALUE is a cons of
 214 two markers or an overlay.  Otherwise, it is nil."
 215   (cond ((bufferp value)
 216          (with-current-buffer value
 217            (when (mark t)
 218              (list (mark t) (point) value))))
 219         ((and (consp value)
 220               (markerp (car value))
 221               (markerp (cdr value)))
 222          (when (and (marker-buffer (car value))
 223                     (buffer-name (marker-buffer (car value)))
 224                     (eq (marker-buffer (car value))
 225                         (marker-buffer (cdr value))))
 226            (list (marker-position (car value))
 227                  (marker-position (cdr value))
 228                  (marker-buffer (car value)))))
 229         ((overlayp value)
 230          (when (overlay-buffer value)
 231            (list (overlay-start value)
 232                  (overlay-end value)
 233                  (overlay-buffer value))))))
 234
 235 (defun xselect--int-to-cons (n)
 236   (cons (ash n -16) (logand n 65535)))
 237
 238 (defun xselect-convert-to-string (selection type value)
 239   (let (str coding)
 240     ;; Get the actual string from VALUE.
 241     (cond ((stringp value)
 242            (setq str value))
 243           ((setq value (xselect--selection-bounds value))
 244            (with-current-buffer (nth 2 value)
 245              (setq str (buffer-substring (nth 0 value)
 246                                          (nth 1 value))))))
 247     (when str
 248       ;; If TYPE is nil, this is a local request, thus return STR as
 249       ;; is.  Otherwise, encode STR.
 250       (if (not type)
 251           str
 252         (setq coding (or next-selection-coding-system selection-coding-system))
 253         (if coding
 254             (setq coding (coding-system-base coding)))
 255         (let ((inhibit-read-only t))
 256           ;; Suppress producing escape sequences for compositions.
 257           (remove-text-properties 0 (length str) '(composition nil) str)
 258           (if (eq type 'TEXT)
 259               ;; TEXT is a polymorphic target.  We must select the
 260               ;; actual type from `UTF8_STRING', `COMPOUND_TEXT',
 261               ;; `STRING', and `C_STRING'.
 262               (if (not (multibyte-string-p str))
 263                   (setq type 'C_STRING)
 264                 (let (non-latin-1 non-unicode eight-bit)
 265                   (mapc #'(lambda (x)
 266                             (if (>= x #x100)
 267                                 (if (< x #x110000)
 268                                     (setq non-latin-1 t)
 269                                   (if (< x #x3FFF80)
 270                                       (setq non-unicode t)
 271                                     (setq eight-bit t)))))
 272                         str)
 273                   (setq type (if non-unicode 'COMPOUND_TEXT
 274                                (if non-latin-1 'UTF8_STRING
 275                                  (if eight-bit 'C_STRING 'STRING)))))))
 276           (cond
 277            ((eq type 'UTF8_STRING)
 278             (if (or (not coding)
 279                     (not (eq (coding-system-type coding) 'utf-8)))
 280                 (setq coding 'utf-8))
 281             (setq str (encode-coding-string str coding)))
 282
 283            ((eq type 'STRING)
 284             (if (or (not coding)
 285                     (not (eq (coding-system-type coding) 'charset)))
 286                 (setq coding 'iso-8859-1))
 287             (setq str (encode-coding-string str coding)))
 288
 289            ((eq type 'COMPOUND_TEXT)
 290             (if (or (not coding)
 291                     (not (eq (coding-system-type coding) 'iso-2022)))
 292                 (setq coding 'compound-text-with-extensions))
 293             (setq str (encode-coding-string str coding)))
 294
 295            ((eq type 'C_STRING)
 296             (setq str (string-make-unibyte str)))
 297
 298            (t
 299             (error "Unknown selection type: %S" type)))))
 300
 301       (setq next-selection-coding-system nil)
 302       (cons type str))))
 303
 304 (defun xselect-convert-to-length (selection type value)
 305   (let ((len (cond ((stringp value)
 306                     (length value))
 307                    ((setq value (xselect--selection-bounds value))
 308                     (abs (- (nth 0 value) (nth 1 value)))))))
 309     (if len
 310         (xselect--int-to-cons len))))
 311
 312 (defun xselect-convert-to-targets (selection type value)
 313   ;; return a vector of atoms, but remove duplicates first.
 314   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 315          (rest all))
 316     (while rest
 317       (cond ((memq (car rest) (cdr rest))
 318              (setcdr rest (delq (car rest) (cdr rest))))
 319             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 320              (setcdr rest (cdr (cdr rest))))
 321             (t
 322              (setq rest (cdr rest)))))
 323     (apply 'vector all)))
 324
 325 (defun xselect-convert-to-delete (selection type value)
 326   (x-disown-selection-internal selection)
 327   ;; A return value of nil means that we do not know how to do this conversion,
 328   ;; and replies with an "error".  A return value of NULL means that we have
 329   ;; done the conversion (and any side-effects) but have no value to return.
 330   'NULL)
 331
 332 (defun xselect-convert-to-filename (selection type value)
 333   (when (setq value (xselect--selection-bounds value))
 334     (buffer-file-name (nth 2 value))))
 335
 336 (defun xselect-convert-to-charpos (selection type value)
 337   (when (setq value (xselect--selection-bounds value))
 338     (let ((beg (1- (nth 0 value))) ; zero-based
 339           (end (1- (nth 1 value))))
 340       (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 341                           (xselect--int-to-cons (max beg end)))))))
 342
 343 (defun xselect-convert-to-lineno (selection type value)
 344   (when (setq value (xselect--selection-bounds value))
 345     (with-current-buffer (nth 2 value)
 346       (let ((beg (line-number-at-pos (nth 0 value)))
 347             (end (line-number-at-pos (nth 1 value))))
 348         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 349                             (xselect--int-to-cons (max beg end))))))))
 350
 351 (defun xselect-convert-to-colno (selection type value)
 352   (when (setq value (xselect--selection-bounds value))
 353     (with-current-buffer (nth 2 value)
 354       (let ((beg (progn (goto-char (nth 0 value)) (current-column)))
 355             (end (progn (goto-char (nth 1 value)) (current-column))))
 356         (cons 'SPAN (vector (xselect--int-to-cons (min beg end))
 357                             (xselect--int-to-cons (max beg end))))))))
 358
 359 (defun xselect-convert-to-os (selection type size)
 360   (symbol-name system-type))
 361
 362 (defun xselect-convert-to-host (selection type size)
 363   (system-name))
 364
 365 (defun xselect-convert-to-user (selection type size)
 366   (user-full-name))
 367
 368 (defun xselect-convert-to-class (selection type size)
 369   "Convert selection to class.
 370 This function returns the string \"Emacs\"."
 371   "Emacs")
 372
 373 ;; We do not try to determine the name Emacs was invoked with,
 374 ;; because it is not clean for a program's behavior to depend on that.
 375 (defun xselect-convert-to-name (selection type size)
 376   "Convert selection to name.
 377 This function returns the string \"emacs\"."
 378   "emacs")
 379
 380 (defun xselect-convert-to-integer (selection type value)
 381   (and (integerp value)
 382        (xselect--int-to-cons value)))
 383
 384 (defun xselect-convert-to-atom (selection type value)
 385   (and (symbolp value) value))
 386
 387 (defun xselect-convert-to-identity (selection type value) ; used internally
 388   (vector value))
 389
 390 (setq selection-converter-alist
 391       '((TEXT . xselect-convert-to-string)
 392         (COMPOUND_TEXT . xselect-convert-to-string)
 393         (STRING . xselect-convert-to-string)
 394         (UTF8_STRING . xselect-convert-to-string)
 395         (TARGETS . xselect-convert-to-targets)
 396         (LENGTH . xselect-convert-to-length)
 397         (DELETE . xselect-convert-to-delete)
 398         (FILE_NAME . xselect-convert-to-filename)
 399         (CHARACTER_POSITION . xselect-convert-to-charpos)
 400         (LINE_NUMBER . xselect-convert-to-lineno)
 401         (COLUMN_NUMBER . xselect-convert-to-colno)
 402         (OWNER_OS . xselect-convert-to-os)
 403         (HOST_NAME . xselect-convert-to-host)
 404         (USER . xselect-convert-to-user)
 405         (CLASS . xselect-convert-to-class)
 406         (NAME . xselect-convert-to-name)
 407         (ATOM . xselect-convert-to-atom)
 408         (INTEGER . xselect-convert-to-integer)
 409         (_EMACS_INTERNAL . xselect-convert-to-identity)))
 410
 411 (provide 'select)
 412
 413 ;; arch-tag: bb634f97-8a3b-4b0a-b940-f6e09982328c
 414 ;;; select.el ends here