lisp/pcmpl-linux.el

   1 ;;; pcmpl-linux.el --- functions for dealing with GNU/Linux completions
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Package: pcomplete
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; These functions are for use with GNU/Linux.  Since they depend on a
  26 ;; certain knowledge of the layout of such systems, they probably
  27 ;; won't work very well on other operating systems.
  28
  29 ;;; Code:
  30
  31 (provide 'pcmpl-linux)
  32
  33 (require 'pcomplete)
  34
  35 (defgroup pcmpl-linux nil
  36   "Functions for dealing with GNU/Linux completions."
  37   :group 'pcomplete)
  38
  39 ;; Functions:
  40
  41 ;;;###autoload
  42 (defun pcomplete/kill ()
  43   "Completion for GNU/Linux `kill', using /proc filesystem."
  44   (if (pcomplete-match "^-\\(.*\\)" 0)
  45       (pcomplete-here
  46        (pcomplete-uniqify-list
  47         (split-string
  48          (pcomplete-process-result "kill" "-l")))
  49        (pcomplete-match-string 1 0)))
  50   (while (pcomplete-here
  51           (if (file-directory-p "/proc")
  52               (directory-files "/proc" nil "\\`[0-9]+\\'"))
  53           nil 'identity)))
  54
  55 ;;;###autoload
  56 (defun pcomplete/umount ()
  57   "Completion for GNU/Linux `umount'."
  58   (pcomplete-opt "hVafrnvt(pcmpl-linux-fs-types)")
  59   (while (pcomplete-here (pcmpl-linux-mounted-directories)
  60                          nil 'identity)))
  61
  62 ;;;###autoload
  63 (defun pcomplete/mount ()
  64   "Completion for GNU/Linux `mount'."
  65   (pcomplete-opt "hVanfFrsvwt(pcmpl-linux-fs-types)o?L?U?")
  66   (while (pcomplete-here (pcomplete-entries) nil 'identity)))
  67
  68 (defun pcmpl-linux-fs-types ()
  69   "Return a list of available fs modules on GNU/Linux systems."
  70   (let ((kernel-ver (pcomplete-process-result "uname" "-r")))
  71     (directory-files
  72      (concat "/lib/modules/" kernel-ver "/kernel/fs/"))))
  73
  74 (defun pcmpl-linux-mounted-directories ()
  75   "Return a list of mounted directory names."
  76   (let (points)
  77     (when (file-readable-p "/etc/mtab")
  78       (with-temp-buffer
  79         (insert-file-contents-literally "/etc/mtab")
  80         (while (not (eobp))
  81           (let* ((line (buffer-substring (point) (line-end-position)))
  82                  (args (split-string line " ")))
  83             (setq points (cons (nth 1 args) points)))
  84           (forward-line)))
  85       (pcomplete-uniqify-list points))))
  86
  87 (defun pcmpl-linux-mountable-directories ()
  88   "Return a list of mountable directory names."
  89   (let (points)
  90     (when (file-readable-p "/etc/fstab")
  91       (with-temp-buffer
  92         (insert-file-contents-literally "/etc/fstab")
  93         (while (not (eobp))
  94           (let* ((line (buffer-substring (point) (line-end-position)))
  95                  (args (split-string line "\\s-+")))
  96             (setq points (cons (nth 1 args) points)))
  97           (forward-line)))
  98       (pcomplete-pare-list
  99        (pcomplete-uniqify-list points)
 100        (cons "swap" (pcmpl-linux-mounted-directories))))))
 101
 102 ;; arch-tag: bb0961a6-a623-463d-92c6-497c317293b1
 103 ;;; pcmpl-linux.el ends here