lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set global variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       )))
  51 ;; (add-hook 'dired-mode-hook
  52 ;;           (function (lambda ()
  53 ;;                       ;; Set buffer-local variables here.  For example:
  54 ;;                       ;; (dired-omit-mode 1)
  55 ;;                       )))
  56 ;;
  57 ;; At load time dired-x.el will install itself, redefine some functions, and
  58 ;; bind some dired keys.  *Please* see the info pages for more details.
  59
  60 ;; *Please* see the info pages for more details.
  61
  62 ;; User defined variables:
  63 ;;
  64 ;;      dired-bind-vm
  65 ;;      dired-vm-read-only-folders
  66 ;;      dired-bind-jump
  67 ;;      dired-bind-info
  68 ;;      dired-bind-man
  69 ;;      dired-x-hands-off-my-keys
  70 ;;      dired-find-subdir
  71 ;;      dired-enable-local-variables
  72 ;;      dired-local-variables-file
  73 ;;      dired-guess-shell-gnutar
  74 ;;      dired-guess-shell-gzip-quiet
  75 ;;      dired-guess-shell-znew-switches
  76 ;;      dired-guess-shell-alist-user
  77 ;;      dired-clean-up-buffers-too
  78 ;;      dired-omit-mode
  79 ;;      dired-omit-files
  80 ;;      dired-omit-extensions
  81 ;;      dired-omit-size-limit
  82 ;;
  83 ;; To find out more about these variables, load this file, put your cursor at
  84 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  85 ;; the info pages for more details.
  86
  87 ;; When loaded this code redefines the following functions of GNU Emacs
  88 ;;
  89 ;;   Function                         Found in this file of GNU Emacs
  90 ;;   --------                         -------------------------------
  91 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  92 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  93 ;;   dired-initial-position           ../lisp/dired.el
  94 ;;
  95 ;;   dired-add-entry                  ../lisp/dired-aux.el
  96 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  97
  98 \f
  99 ;;; Code:
 100
 101 ;; LOAD.
 102
 103 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 104 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 105 ;; (instead of autoloading to dired as is suggested in the info-pages).
 106
 107 (require 'dired)
 108
 109 ;; We will redefine some functions and also need some macros so we need to
 110 ;; load dired stuff of GNU Emacs.
 111
 112 (require 'dired-aux)
 113
 114 (defvar vm-folder-directory)
 115 (eval-when-compile (require 'man))
 116
 117 ;;; User-defined variables.
 118
 119 (defgroup dired-x nil
 120   "Extended directory editing (dired-x)."
 121   :group 'dired)
 122
 123 (defgroup dired-keys nil
 124   "Dired keys customizations."
 125   :prefix "dired-"
 126   :group 'dired-x)
 127
 128 (defcustom dired-bind-vm nil
 129   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 130 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 131 `dired-advertised-find-file', will run rmail."
 132   :type 'boolean
 133   :group 'dired-keys)
 134
 135 (defcustom dired-bind-jump t
 136   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 137   :type 'boolean
 138   :group 'dired-keys)
 139
 140 (defcustom dired-bind-man t
 141   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 142   :type 'boolean
 143   :group 'dired-keys)
 144
 145 (defcustom dired-bind-info t
 146   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 147   :type 'boolean
 148   :group 'dired-keys)
 149
 150 (defcustom dired-vm-read-only-folders nil
 151   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 152 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 153 files not writable by you are visited read-only.
 154
 155 Read-only folders only work in VM 5, not in VM 4."
 156   :type '(choice (const :tag "off" nil)
 157                  (const :tag "on" t)
 158                  (other :tag "non-writable only" if-file-read-only))
 159   :group 'dired-x)
 160
 161 (define-minor-mode dired-omit-mode
 162   "Toggle Dired-Omit mode.
 163 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 164 otherwise.  Enabling and disabling is buffer-local.
 165 If enabled, \"uninteresting\" files are not listed.
 166 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 167 plus those ending with extensions in `dired-omit-extensions'."
 168   :group 'dired-x
 169   (if dired-omit-mode
 170       ;; This will mention how many lines were omitted:
 171       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 172     (revert-buffer)))
 173
 174 ;; For backward compatibility
 175 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 176 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 177
 178 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 179   "*Filenames matching this regexp will not be displayed.
 180 This only has effect when `dired-omit-mode' is t.  See interactive function
 181 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 182 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 183 files and lock files."
 184   :type 'regexp
 185   :group 'dired-x)
 186
 187 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 188   "*If non-nil, Dired always finds a directory in a buffer of its own.
 189 If nil, Dired finds the directory as a subdirectory in some other buffer
 190 if it is present as one.
 191
 192 If there are several dired buffers for a directory, the most recently
 193 used is chosen.
 194
 195 Dired avoids switching to the current buffer, so that if you have
 196 a normal and a wildcard buffer for the same directory, \\[dired] will
 197 toggle between those two."
 198   :type 'boolean
 199   :group 'dired-x)
 200
 201 (defcustom dired-omit-size-limit 30000
 202   "*Maximum size for the \"omitting\" feature.
 203 If nil, there is no maximum size."
 204   :type '(choice (const :tag "no maximum" nil) integer)
 205   :group 'dired-x)
 206
 207 (defcustom dired-enable-local-variables t
 208   "*Control use of local-variables lists in Dired.
 209 The value can be t, nil or something else.
 210 A value of t means local-variables lists are obeyed;
 211 nil means they are ignored; anything else means query.
 212
 213 This temporarily overrides the value of `enable-local-variables' when listing
 214 a directory.  See also `dired-local-variables-file'."
 215   :type 'boolean
 216   :group 'dired-x)
 217
 218 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 219                                               (eq system-type 'gnu/linux))
 220                                       "tar")
 221   "*If non-nil, name of GNU tar executable.
 222 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 223 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 224 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 225   :type '(choice (const :tag "Not GNU tar" nil)
 226                  (string :tag "Command name"))
 227   :group 'dired-x)
 228
 229 (defcustom dired-guess-shell-gzip-quiet t
 230   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 231   :type 'boolean
 232   :group 'dired-x)
 233
 234 (defcustom dired-guess-shell-znew-switches nil
 235   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 236   :type '(choice (const :tag "None" nil)
 237                  (string :tag "Switches"))
 238   :group 'dired-x)
 239
 240 (defcustom dired-clean-up-buffers-too t
 241   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 242   :type 'boolean
 243   :group 'dired-x)
 244
 245 ;;; KEY BINDINGS.
 246
 247 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 248 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 249 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 250 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 251 (define-key dired-mode-map "*." 'dired-mark-extension)
 252 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 253 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 254 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 255 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 256 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 257 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 258 (define-key dired-mode-map "V" 'dired-do-run-mail)
 259
 260 (if dired-bind-man
 261     (define-key dired-mode-map "N" 'dired-man))
 262
 263 (if dired-bind-info
 264     (define-key dired-mode-map "I" 'dired-info))
 265
 266 ;;; MENU BINDINGS
 267
 268 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 269   (let ((menu (lookup-key menu-bar [operate])))
 270     (define-key-after
 271       menu
 272       [find-files]
 273       '(menu-item
 274         "Find files"
 275         dired-do-find-marked-files
 276         :help "Find current or marked files")
 277       'delete)
 278     (define-key-after
 279       menu
 280       [relsymlink]
 281       '(menu-item
 282         "Relative symlink to..."
 283         dired-do-relsymlink
 284         :visible (fboundp 'make-symbolic-link)
 285         :help "Make relative symbolic links for current or marked files")
 286       'symlink))
 287   (let ((menu (lookup-key menu-bar [mark])))
 288     (define-key-after
 289       menu
 290       [flag-extension]
 291       '(menu-item
 292         "Flag extension..."
 293         dired-flag-extension
 294         :help "Flag files with a certain extension for deletion")
 295       'garbage-files)
 296     (define-key-after
 297       menu
 298       [mark-extension]
 299       '(menu-item
 300         "Mark extension..."
 301         dired-mark-extension
 302         :help "Mark files with a certain extension")
 303       'symlinks)
 304     (define-key-after
 305       menu
 306       [mark-omitted]
 307       '(menu-item
 308         "Mark omitted"
 309         dired-mark-omitted
 310         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 311       'mark-extension))
 312   (let ((menu (lookup-key menu-bar [regexp])))
 313     (define-key-after
 314       menu
 315       [relsymlink-regexp]
 316       '(menu-item
 317         "Relative symlink..."
 318         dired-do-relsymlink-regexp
 319         :visible (fboundp 'make-symbolic-link)
 320         :help "Make relative symbolic links for files matching regexp")
 321       'symlink))
 322   (let ((menu (lookup-key menu-bar [immediate])))
 323     (define-key-after
 324       menu
 325       [omit-mode]
 326       '(menu-item
 327         "Omit mode" dired-omit-mode
 328         :button (:toggle . dired-omit-mode)
 329         :help "Enable or disable omitting \"uninteresting\" files")
 330       'dashes)))
 331
 332 ;;; GLOBAL BINDING.
 333 (if dired-bind-jump
 334     (progn
 335       (define-key global-map "\C-x\C-j" 'dired-jump)
 336       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 337
 338 \f
 339 ;;; Install into appropriate hooks.
 340
 341 (add-hook 'dired-mode-hook 'dired-extra-startup)
 342 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 343
 344 (defun dired-extra-startup ()
 345   "Automatically put on `dired-mode-hook' to get extra Dired features:
 346 \\<dired-mode-map>
 347   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 348   \\[dired-info]\t-- run info on file
 349   \\[dired-man]\t-- run man on file
 350   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 351   \\[dired-omit-mode]\t-- toggle omitting of files
 352   \\[dired-mark-sexp]\t-- mark by Lisp expression
 353   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 354   \t   you can feed it to other commands using \\[yank]
 355
 356 For more features, see variables
 357
 358   `dired-bind-vm'
 359   `dired-bind-jump'
 360   `dired-bind-info'
 361   `dired-bind-man'
 362   `dired-vm-read-only-folders'
 363   `dired-omit-mode'
 364   `dired-omit-files'
 365   `dired-omit-extensions'
 366   `dired-omit-size-limit'
 367   `dired-find-subdir'
 368   `dired-enable-local-variables'
 369   `dired-local-variables-file'
 370   `dired-guess-shell-gnutar'
 371   `dired-guess-shell-gzip-quiet'
 372   `dired-guess-shell-znew-switches'
 373   `dired-guess-shell-alist-user'
 374   `dired-clean-up-buffers-too'
 375
 376 See also functions
 377
 378   `dired-flag-extension'
 379   `dired-virtual'
 380   `dired-jump'
 381   `dired-man'
 382   `dired-vm'
 383   `dired-rmail'
 384   `dired-info'
 385   `dired-do-find-marked-files'"
 386   (interactive)
 387
 388   ;; These must be done in each new dired buffer.
 389   (dired-hack-local-variables)
 390   (dired-omit-startup))
 391
 392 \f
 393 ;;; BUFFER CLEANING.
 394
 395 ;; REDEFINE.
 396 (defun dired-clean-up-after-deletion (fn)
 397   "Clean up after a deleted file or directory FN.
 398 Remove expanded subdir of deleted dir, if any."
 399   (save-excursion (and (cdr dired-subdir-alist)
 400                        (dired-goto-subdir fn)
 401                        (dired-kill-subdir)))
 402
 403   ;; Offer to kill buffer of deleted file FN.
 404   (if dired-clean-up-buffers-too
 405       (progn
 406         (let ((buf (get-file-buffer fn)))
 407           (and buf
 408                (funcall (function y-or-n-p)
 409                         (format "Kill buffer of %s, too? "
 410                                 (file-name-nondirectory fn)))
 411                (save-excursion ; you never know where kill-buffer leaves you
 412                  (kill-buffer buf))))
 413         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 414               (buf nil))
 415           (and buf-list
 416                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 417                                  (dired-plural-s (length buf-list))
 418                                  (file-name-nondirectory fn)))
 419                (while buf-list
 420                  (save-excursion (kill-buffer (car buf-list)))
 421                  (setq buf-list (cdr buf-list)))))))
 422   ;; Anything else?
 423   )
 424
 425 \f
 426 ;;; EXTENSION MARKING FUNCTIONS.
 427
 428 ;;; Mark files with some extension.
 429 (defun dired-mark-extension (extension &optional marker-char)
 430   "Mark all files with a certain EXTENSION for use in later commands.
 431 A `.' is *not* automatically prepended to the string entered."
 432   ;; EXTENSION may also be a list of extensions instead of a single one.
 433   ;; Optional MARKER-CHAR is marker to use.
 434   (interactive "sMarking extension: \nP")
 435   (or (listp extension)
 436       (setq extension (list extension)))
 437   (dired-mark-files-regexp
 438    (concat ".";; don't match names with nothing but an extension
 439            "\\("
 440            (mapconcat 'regexp-quote extension "\\|")
 441            "\\)$")
 442    marker-char))
 443
 444 (defun dired-flag-extension (extension)
 445   "In dired, flag all files with a certain EXTENSION for deletion.
 446 A `.' is *not* automatically prepended to the string entered."
 447   (interactive "sFlagging extension: ")
 448   (dired-mark-extension extension dired-del-marker))
 449
 450 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 451
 452 (defvar dired-patch-unclean-extensions
 453   '(".rej" ".orig")
 454   "List of extensions of dispensable files created by the `patch' program.")
 455
 456 (defvar dired-tex-unclean-extensions
 457   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 458   "List of extensions of dispensable files created by TeX.")
 459
 460 (defvar dired-latex-unclean-extensions
 461   '(".idx" ".lof" ".lot" ".glo")
 462   "List of extensions of dispensable files created by LaTeX.")
 463
 464 (defvar dired-bibtex-unclean-extensions
 465   '(".blg" ".bbl")
 466   "List of extensions of dispensable files created by BibTeX.")
 467
 468 (defvar dired-texinfo-unclean-extensions
 469   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 470     ".tp" ".tps" ".vr" ".vrs")
 471   "List of extensions of dispensable files created by texinfo.")
 472
 473 (defun dired-clean-patch ()
 474   "Flag dispensable files created by patch for deletion.
 475 See variable `dired-patch-unclean-extensions'."
 476   (interactive)
 477   (dired-flag-extension dired-patch-unclean-extensions))
 478
 479 (defun dired-clean-tex ()
 480   "Flag dispensable files created by [La]TeX etc. for deletion.
 481 See variables `dired-tex-unclean-extensions',
 482 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 483 `dired-texinfo-unclean-extensions'."
 484   (interactive)
 485   (dired-flag-extension (append dired-texinfo-unclean-extensions
 486                                 dired-latex-unclean-extensions
 487                                 dired-bibtex-unclean-extensions
 488                                 dired-tex-unclean-extensions)))
 489
 490 (defun dired-very-clean-tex ()
 491   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 492 See variables `dired-texinfo-unclean-extensions',
 493 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 494 `dired-texinfo-unclean-extensions'."
 495   (interactive)
 496   (dired-flag-extension (append dired-texinfo-unclean-extensions
 497                                 dired-latex-unclean-extensions
 498                                 dired-bibtex-unclean-extensions
 499                                 dired-tex-unclean-extensions
 500                                 (list ".dvi"))))
 501 \f
 502 ;;; JUMP.
 503
 504 ;;;###autoload
 505 (defun dired-jump (&optional other-window)
 506   "Jump to dired buffer corresponding to current buffer.
 507 If in a file, dired the current directory and move to file's line.
 508 If in Dired already, pop up a level and goto old directory's line.
 509 In case the proper dired file line cannot be found, refresh the dired
 510 buffer and try again."
 511   (interactive "P")
 512   (let* ((file buffer-file-name)
 513          (dir (if file (file-name-directory file) default-directory)))
 514     (if (eq major-mode 'dired-mode)
 515         (progn
 516           (setq dir (dired-current-directory))
 517           (dired-up-directory other-window)
 518           (or (dired-goto-file dir)
 519               ;; refresh and try again
 520               (progn
 521                 (dired-insert-subdir (file-name-directory dir))
 522                 (dired-goto-file dir))))
 523       (if other-window
 524           (dired-other-window dir)
 525         (dired dir))
 526       (if file
 527           (or (dired-goto-file file)
 528               ;; refresh and try again
 529               (progn
 530                 (dired-insert-subdir (file-name-directory file))
 531                 (dired-goto-file file))
 532               ;; Toggle omitting, if it is on, and try again.
 533               (if dired-omit-mode
 534                   (progn
 535                     (dired-omit-mode)
 536                     (dired-goto-file file))))))))
 537
 538 (defun dired-jump-other-window ()
 539   "Like \\[dired-jump] (`dired-jump') but in other window."
 540   (interactive)
 541   (dired-jump t))
 542 \f
 543 ;;; OMITTING.
 544
 545 ;;; Enhanced omitting of lines from directory listings.
 546 ;;; Marked files are never omitted.
 547
 548 ;; should probably get rid of this and always use 'no-dir.
 549 ;; sk 28-Aug-1991 09:37
 550 (defvar dired-omit-localp 'no-dir
 551   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 552 If it is `no-dir', omitting is much faster, but you can only match
 553 against the non-directory part of the file name.  Set it to nil if you
 554 need to match the entire file name.")
 555
 556 ;; \017=^O for Omit - other packages can chose other control characters.
 557 (defvar dired-omit-marker-char ?\017
 558   "Temporary marker used by dired-omit.
 559 Should never be used as marker by the user or other packages.")
 560
 561 (defun dired-omit-startup ()
 562   (or (assq 'dired-omit-mode minor-mode-alist)
 563       (setq minor-mode-alist
 564             (append '((dired-omit-mode
 565                        (:eval (if (eq major-mode 'dired-mode)
 566                                   " Omit" ""))))
 567                     minor-mode-alist))))
 568
 569 (defun dired-mark-omitted ()
 570   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 571   (interactive)
 572   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 573   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 574
 575 (defvar dired-omit-extensions
 576   (append completion-ignored-extensions
 577           dired-latex-unclean-extensions
 578           dired-bibtex-unclean-extensions
 579           dired-texinfo-unclean-extensions)
 580   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 581 Defaults to elements of `completion-ignored-extensions',
 582 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 583 `dired-texinfo-unclean-extensions'.
 584
 585 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 586 variables `dired-omit-mode' and `dired-omit-files'.")
 587
 588 (defun dired-omit-expunge (&optional regexp)
 589   "Erases all unmarked files matching REGEXP.
 590 Does nothing if global variable `dired-omit-mode' is nil, or if called
 591   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 592 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 593   filenames ending in `dired-omit-extensions'.
 594 If REGEXP is the empty string, this function is a no-op.
 595
 596 This functions works by temporarily binding `dired-marker-char' to
 597 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 598   (interactive "sOmit files (regexp): ")
 599   (if (and dired-omit-mode
 600            (or (interactive-p)
 601                (not dired-omit-size-limit)
 602                (< (buffer-size) dired-omit-size-limit)
 603                (progn
 604                  (message "Not omitting: directory larger than %d characters."
 605                           dired-omit-size-limit)
 606                  (setq dired-omit-mode nil)
 607                  nil)))
 608       (let ((omit-re (or regexp (dired-omit-regexp)))
 609             (old-modified-p (buffer-modified-p))
 610             count)
 611         (or (string= omit-re "")
 612             (let ((dired-marker-char dired-omit-marker-char))
 613               (message "Omitting...")
 614               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 615                   (progn
 616                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 617                     (force-mode-line-update))
 618                 (message "(Nothing to omit)"))))
 619         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 620         ;; in mode-line of omitted buffers.
 621         (set-buffer-modified-p (and old-modified-p
 622                                     (save-excursion
 623                                       (goto-char (point-min))
 624                                       (re-search-forward dired-re-mark nil t))))
 625         count)))
 626
 627 (defun dired-omit-regexp ()
 628   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 629           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 630           (if dired-omit-extensions
 631               (concat ".";; a non-extension part should exist
 632                       "\\("
 633                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 634                       "\\)$")
 635             "")))
 636
 637 ;; Returns t if any work was done, nil otherwise.
 638 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 639   "Mark unmarked files matching REGEXP, displaying MSG.
 640 REGEXP is matched against the entire file name.
 641 Does not re-mark files which already have a mark.
 642 With prefix argument, unflag all those files.
 643 Optional fourth argument LOCALP is as in `dired-get-filename'."
 644   (interactive "P")
 645   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 646     (dired-mark-if
 647      (and
 648       ;; not already marked
 649       (looking-at " ")
 650       ;; uninteresting
 651       (let ((fn (dired-get-filename localp t)))
 652         (and fn (string-match regexp fn))))
 653      msg)))
 654
 655 ;;; REDEFINE.
 656 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 657   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 658   ;; files that are going to be omitted anyway.
 659   (if dired-omit-mode
 660       ;; perhaps return t without calling ls
 661       (let ((omit-re (dired-omit-regexp)))
 662         (if (or (string= omit-re "")
 663                 (not
 664                  (string-match omit-re
 665                                (cond
 666                                 ((eq 'no-dir dired-omit-localp)
 667                                  filename)
 668                                 ((eq t dired-omit-localp)
 669                                  (dired-make-relative filename))
 670                                 (t
 671                                  (dired-make-absolute
 672                                   filename
 673                                   (file-name-directory filename)))))))
 674             ;; if it didn't match, go ahead and add the entry
 675             (dired-omit-old-add-entry filename marker-char relative)
 676           ;; dired-add-entry returns t for success, perhaps we should
 677           ;; return file-exists-p
 678           t))
 679     ;; omitting is not turned on at all
 680     (dired-omit-old-add-entry filename marker-char relative)))
 681
 682 ;;; REDEFINE.
 683 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 684 ;;; Save old defun if not already done:
 685 (or (fboundp 'dired-omit-old-add-entry)
 686     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 687 ;; Redefine it.
 688 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 689
 690 \f
 691 ;;; VIRTUAL DIRED MODE.
 692
 693 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 694
 695 (defalias 'virtual-dired 'dired-virtual)
 696 (defun dired-virtual (dirname &optional switches)
 697   "Put this buffer into Virtual Dired mode.
 698
 699 In Virtual Dired mode, all commands that do not actually consult the
 700 filesystem will work.
 701
 702 This is useful if you want to peruse and move around in an ls -lR
 703 output file, for example one you got from an ftp server.  With
 704 ange-ftp, you can even dired a directory containing an ls-lR file,
 705 visit that file and turn on virtual dired mode.  But don't try to save
 706 this file, as dired-virtual indents the listing and thus changes the
 707 buffer.
 708
 709 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 710 resume it in a later session.
 711
 712 Type \\<dired-mode-map>\\[revert-buffer] \
 713 in the Virtual Dired buffer and answer `y' to convert
 714 the virtual to a real dired buffer again.  You don't have to do this, though:
 715 you can relist single subdirs using \\[dired-do-redisplay]."
 716
 717   ;; DIRNAME is the top level directory of the buffer.  It will become
 718   ;; its `default-directory'.  If nil, the old value of
 719   ;; default-directory is used.
 720
 721   ;; Optional SWITCHES are the ls switches to use.
 722
 723   ;; Shell wildcards will be used if there already is a `wildcard'
 724   ;; line in the buffer (thus it is a saved Dired buffer), but there
 725   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 726   ;; hand if you want them.
 727
 728   (interactive
 729    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 730   (goto-char (point-min))
 731   (or (looking-at "  ")
 732       ;; if not already indented, do it now:
 733       (indent-region (point-min) (point-max) 2))
 734   (or dirname (setq dirname default-directory))
 735   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 736   (setq default-directory dirname)      ; contains no wildcards
 737   (let ((wildcard (save-excursion
 738                     (goto-char (point-min))
 739                     (forward-line 1)
 740                     (and (looking-at "^  wildcard ")
 741                          (buffer-substring (match-end 0)
 742                                            (progn (end-of-line) (point)))))))
 743   (if wildcard
 744         (setq dirname (expand-file-name wildcard default-directory))))
 745   ;; If raw ls listing (not a saved old dired buffer), give it a
 746   ;; decent subdir headerline:
 747   (goto-char (point-min))
 748   (or (looking-at dired-subdir-regexp)
 749       (insert "  "
 750               (directory-file-name (file-name-directory default-directory))
 751               ":\n"))
 752   (dired-mode dirname (or switches dired-listing-switches))
 753   (setq mode-name "Virtual Dired"
 754         revert-buffer-function 'dired-virtual-revert)
 755   (set (make-local-variable 'dired-subdir-alist) nil)
 756   (dired-build-subdir-alist)
 757   (goto-char (point-min))
 758   (dired-initial-position dirname))
 759
 760 (defun dired-virtual-guess-dir ()
 761   "Guess and return appropriate working directory of this buffer.
 762 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 763 based upon buffer contents.  If nothing could be guessed, returns
 764 nil."
 765
 766   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 767         (subexpr 2))
 768     (goto-char (point-min))
 769     (cond ((looking-at regexp)
 770            ;; If a saved dired buffer, look to which dir and
 771            ;; perhaps wildcard it belongs:
 772            (let ((dir (buffer-substring (match-beginning subexpr)
 773                                         (match-end subexpr))))
 774              (file-name-as-directory dir)))
 775           ;; Else no match for headerline found.  It's a raw ls listing.
 776           ;; In raw ls listings the directory does not have a headerline
 777           ;; try parent of first subdir, if any
 778           ((re-search-forward regexp nil t)
 779            (file-name-directory
 780             (directory-file-name
 781              (file-name-as-directory
 782               (buffer-substring (match-beginning subexpr)
 783                                 (match-end subexpr))))))
 784           (t                            ; if all else fails
 785            nil))))
 786
 787
 788 (defun dired-virtual-revert (&optional arg noconfirm)
 789   (if (not
 790        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 791       (error "Cannot revert a Virtual Dired buffer")
 792     (setq mode-name "Dired"
 793           revert-buffer-function 'dired-revert)
 794     (revert-buffer)))
 795
 796 ;; A zero-arg version of dired-virtual.
 797 ;; You need my modified version of set-auto-mode for the
 798 ;; `buffer-contents-mode-alist'.
 799 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 800 (defun dired-virtual-mode ()
 801   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 802 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 803
 804     \"^  \\(/[^ /]+\\)/?+:$\"
 805
 806 to put saved dired buffers automatically into Virtual Dired mode.
 807
 808 Also useful for `auto-mode-alist' (which see) like this:
 809
 810   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 811                               auto-mode-alist)\)"
 812   (interactive)
 813   (dired-virtual (dired-virtual-guess-dir)))
 814
 815 \f
 816 ;;; SMART SHELL.
 817
 818 ;;; An Emacs buffer can have but one working directory, stored in the
 819 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 820 ;;; several subdirectories inserted, but still has but one working directory:
 821 ;;; that of the top level Dired directory in that buffer.  For some commands
 822 ;;; it is appropriate that they use the current Dired directory instead of
 823 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 824 ;;; mechanism is provided for special handling of the working directory in
 825 ;;; special major modes.
 826
 827 ;; It's easier to add to this alist than redefine function
 828 ;; default-directory while keeping the old information.
 829 (defconst default-directory-alist
 830   '((dired-mode . (if (fboundp 'dired-current-directory)
 831                       (dired-current-directory)
 832                     default-directory)))
 833   "Alist of major modes and their opinion on `default-directory'.
 834 This is given as a Lisp expression to evaluate.  A resulting value of
 835 nil is ignored in favor of `default-directory'.")
 836
 837 (defun dired-default-directory ()
 838   "Usage like variable `default-directory'.
 839 Knows about the special cases in variable `default-directory-alist'."
 840   (or (eval (cdr (assq major-mode default-directory-alist)))
 841       default-directory))
 842
 843 (defun dired-smart-shell-command (cmd &optional insert)
 844   "Like function `shell-command', but in the current Virtual Dired directory."
 845   (interactive (list (read-from-minibuffer "Shell command: "
 846                                            nil nil nil 'shell-command-history)
 847                      current-prefix-arg))
 848   (let ((default-directory (dired-default-directory)))
 849     (shell-command cmd insert)))
 850
 851 \f
 852 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 853
 854 ;;; Brief Description:
 855 ;;;
 856 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 857 ;;;
 858 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 859 ;;;
 860 ;;; * `dired-hack-local-variables' checks the value of
 861 ;;;   `dired-local-variables-file'
 862 ;;;
 863 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 864 ;;;   filename found in the directory of the Dired Buffer being created.
 865 ;;;
 866 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 867 ;;;   include it in the Dired Buffer at the bottom.
 868 ;;;
 869 ;;; * Set `enable-local-variables' temporarily to the user variable
 870 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 871 ;;;   Dired Buffer.
 872
 873 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 874   "Filename, as string, containing local dired buffer variables to be hacked.
 875 If this file found in current directory, then it will be inserted into dired
 876 buffer and `hack-local-variables' will be run.  See Info node
 877 `(emacs)File Variables' for more information on local variables.
 878 See also `dired-enable-local-variables'.")
 879
 880 (defun dired-hack-local-variables ()
 881   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 882   (if (and dired-local-variables-file
 883            (stringp dired-local-variables-file)
 884            (file-exists-p dired-local-variables-file))
 885       (let ((opoint (point-max))
 886             buffer-read-only
 887             ;; In case user has `enable-local-variables' set to nil we
 888             ;; override it locally with dired's variable.
 889             (enable-local-variables dired-enable-local-variables))
 890         ;; Insert 'em.
 891         (save-excursion
 892           (goto-char opoint)
 893           (insert "\^L\n")
 894           (insert-file-contents dired-local-variables-file))
 895         ;; Hack 'em.
 896         (let ((buffer-file-name dired-local-variables-file))
 897           (hack-local-variables))
 898         ;; Make sure that the modeline shows the proper information.
 899         (dired-sort-set-modeline)
 900         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 901         (delete-region opoint (point-max)))))
 902
 903 (defun dired-omit-here-always ()
 904   "Create `dired-local-variables-file' for omitting and reverts directory.
 905 Sets `dired-omit-mode' to t in a local variables file that is readable by
 906 dired."
 907   (interactive)
 908   (if (file-exists-p dired-local-variables-file)
 909       (message "File `./%s' already exists." dired-local-variables-file)
 910
 911     ;; Create `dired-local-variables-file'.
 912     (save-excursion
 913       (set-buffer (get-buffer-create " *dot-dired*"))
 914       (erase-buffer)
 915       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 916       (write-file dired-local-variables-file)
 917       (kill-buffer (current-buffer)))
 918
 919     ;; Run extra-hooks and revert directory.
 920     (dired-extra-startup)
 921     (dired-revert)))
 922
 923 \f
 924 ;;; GUESS SHELL COMMAND.
 925
 926 ;;; Brief Description:
 927 ;;;
 928 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 929 ;;;
 930 ;;; * Redefine `dired-do-shell-command' so it calls
 931 ;;;   `dired-guess-shell-command'.
 932 ;;;
 933 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 934 ;;;    marked files.
 935 ;;;
 936 ;;; * Parse `dired-guess-shell-alist-user' and
 937 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 938 ;;;   that matches the first file in the file list.
 939 ;;;
 940 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 941 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 942 ;;;   string.  COMMAND may be a list of commands.
 943 ;;;
 944 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 945 ;;;   with it.  The list of commands is temporarily put into the history list.
 946 ;;;   If a command is used successfully then it is stored permanently in
 947 ;;;   `dired-shell-command-history'.
 948
 949 ;;; Guess what shell command to apply to a file.
 950 (defvar dired-shell-command-history nil
 951   "History list for commands that read dired-shell commands.")
 952
 953 ;;; Default list of shell commands.
 954
 955 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 956 ;;; install GNU zip's version of zcat.
 957
 958 (defvar dired-guess-shell-alist-default
 959   (list
 960    (list "\\.tar$"
 961          '(if dired-guess-shell-gnutar
 962               (concat dired-guess-shell-gnutar " xvf")
 963             "tar xvf")
 964          ;; Extract files into a separate subdirectory
 965          '(if dired-guess-shell-gnutar
 966               (concat "mkdir " (file-name-sans-extension file)
 967                       "; " dired-guess-shell-gnutar " -C "
 968                       (file-name-sans-extension file) " -xvf")
 969             (concat "mkdir " (file-name-sans-extension file)
 970                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 971          ;; List archive contents.
 972          '(if dired-guess-shell-gnutar
 973               (concat dired-guess-shell-gnutar " tvf")
 974             "tar tvf"))
 975
 976    ;; REGEXPS for compressed archives must come before the .Z rule to
 977    ;; be recognized:
 978    (list "\\.tar\\.Z$"
 979          ;; Untar it.
 980          '(if dired-guess-shell-gnutar
 981               (concat dired-guess-shell-gnutar " zxvf")
 982             (concat "zcat * | tar xvf -"))
 983          ;; Optional conversion to gzip format.
 984          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 985                   " " dired-guess-shell-znew-switches))
 986
 987    ;; gzip'ed archives
 988    (list "\\.t\\(ar\\.\\)?gz$"
 989          '(if dired-guess-shell-gnutar
 990               (concat dired-guess-shell-gnutar " zxvf")
 991             (concat "gunzip -qc * | tar xvf -"))
 992          ;; Extract files into a separate subdirectory
 993          '(if dired-guess-shell-gnutar
 994               (concat "mkdir " (file-name-sans-extension file)
 995                       "; " dired-guess-shell-gnutar " -C "
 996                       (file-name-sans-extension file) " -zxvf")
 997             (concat "mkdir " (file-name-sans-extension file)
 998                     "; gunzip -qc * | tar -C "
 999                     (file-name-sans-extension file) " -xvf -"))
1000          ;; Optional decompression.
1001          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1002          ;; List archive contents.
1003          '(if dired-guess-shell-gnutar
1004               (concat dired-guess-shell-gnutar " ztvf")
1005             (concat "gunzip -qc * | tar tvf -")))
1006
1007    ;; bzip2'ed archives
1008    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1009          "bunzip2 -c * | tar xvf -"
1010          ;; Extract files into a separate subdirectory
1011          '(concat "mkdir " (file-name-sans-extension file)
1012                   "; bunzip2 -c * | tar -C "
1013                   (file-name-sans-extension file) " -xvf -")
1014          ;; Optional decompression.
1015          "bunzip2")
1016
1017    '("\\.shar\\.Z$" "zcat * | unshar")
1018    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1019
1020    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1021    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1022          ;; Optional decompression.
1023          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1024    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1025          ;; Optional conversion to gzip format.
1026          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1027                   " " dired-guess-shell-znew-switches))
1028
1029    '("\\.patch$" "cat * | patch")
1030    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1031          ;; Optional decompression.
1032          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1033    (list "\\.patch\\.Z$" "zcat * | patch"
1034          ;; Optional conversion to gzip format.
1035          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1036                   " " dired-guess-shell-znew-switches))
1037
1038    ;; The following four extensions are useful with dired-man ("N" key)
1039    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1040                                            (if (Man-support-local-filenames)
1041                                                "man -l"
1042                                              "cat * | tbl | nroff -man -h")))
1043    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1044                                                  (if (Man-support-local-filenames)
1045                                                      "man -l"
1046                                                    "gunzip -qc * | tbl | nroff -man -h"))
1047          ;; Optional decompression.
1048          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1049    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1050                                  (if (Man-support-local-filenames)
1051                                      "man -l"
1052                                    "zcat * | tbl | nroff -man -h"))
1053          ;; Optional conversion to gzip format.
1054          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1055                   " " dired-guess-shell-znew-switches))
1056    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1057
1058    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1059    '("\\.au$" "play")                   ; play Sun audiofiles
1060    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1061    '("\\.wav$" "play")
1062    '("\\.uu$" "uudecode")               ; for uudecoded files
1063    '("\\.hqx$" "mcvert")
1064    '("\\.sh$" "sh")                     ; execute shell scripts
1065    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1066    '("\\.gp$" "gnuplot")
1067    '("\\.p[bgpn]m$" "xloadimage")
1068    '("\\.gif$" "xloadimage")            ; view gif pictures
1069    '("\\.tif$" "xloadimage")
1070    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1071    '("\\.jpe?g$" "xloadimage")
1072    '("\\.fig$" "xfig")                  ; edit fig pictures
1073    '("\\.out$" "xgraph")                ; for plotting purposes.
1074    '("\\.tex$" "latex" "tex")
1075    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1076    '("\\.pdf$" "xpdf")
1077    '("\\.doc$" "antiword" "strings")
1078    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1079    '("\\.dia$" "dia")
1080    '("\\.mgp$" "mgp")
1081
1082    ;; Some other popular archivers.
1083    (list "\\.zip$" "unzip" "unzip -l"
1084          ;; Extract files into a separate subdirectory
1085          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1086                   " -d " (file-name-sans-extension file)))
1087    '("\\.zoo$" "zoo x//")
1088    '("\\.lzh$" "lharc x")
1089    '("\\.arc$" "arc x")
1090    '("\\.shar$" "unshar")
1091
1092    ;; Compression.
1093    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1094    (list "\\.dz$" "dictunzip")
1095    (list "\\.bz2$" "bunzip2")
1096    (list "\\.Z$" "uncompress"
1097          ;; Optional conversion to gzip format.
1098          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1099                   " " dired-guess-shell-znew-switches))
1100
1101    '("\\.sign?$" "gpg --verify"))
1102
1103   "Default alist used for shell command guessing.
1104 See `dired-guess-shell-alist-user'.")
1105
1106 (defcustom dired-guess-shell-alist-user nil
1107   "User-defined alist of rules for suggested commands.
1108 These rules take precedence over the predefined rules in the variable
1109 `dired-guess-shell-alist-default' (to which they are prepended).
1110
1111 Each element of this list looks like
1112
1113     \(REGEXP COMMAND...\)
1114
1115 where each COMMAND can either be a string or a Lisp expression that evaluates
1116 to a string.  If several COMMANDs are given, the first one will be the default
1117 and the rest will be added temporarily to the history and can be retrieved
1118 with \\[previous-history-element] (M-p) .
1119
1120 You can set this variable in your ~/.emacs.  For example, to add rules for
1121 `.foo' and `.bar' files, write
1122
1123  \(setq dired-guess-shell-alist-user
1124        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1125               ;; possibly more rules ...
1126               (list \"\\\\.bar\\\'\";; rule with condition test
1127                     '(if condition
1128                           \"BAR-COMMAND-1\"
1129                         \"BAR-COMMAND-2\")))\)"
1130   :group 'dired-x
1131   :type '(alist :key-type regexp :value-type (repeat sexp)))
1132
1133 (defcustom dired-guess-shell-case-fold-search t
1134   "If non-nil, `dired-guess-shell-alist-default' and
1135 `dired-guess-shell-alist-user' are matched case-insensitively."
1136   :group 'dired-x
1137   :type 'boolean)
1138
1139 (defun dired-guess-default (files)
1140   "Guess a shell commands for FILES.  Return command or list of commands.
1141 See `dired-guess-shell-alist-user'."
1142
1143   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1144          ;; Prepend the user's alist to the default alist.
1145          (alist (append dired-guess-shell-alist-user
1146                         dired-guess-shell-alist-default))
1147          (file (car files))
1148          (flist (cdr files))
1149          elt regexp cmds)
1150
1151     ;; Find the first match in the alist for first file in FILES.
1152     (while alist
1153       (setq elt (car alist)
1154             regexp (car elt)
1155             alist (cdr alist))
1156       (if (string-match regexp file)
1157           (setq cmds (cdr elt)
1158                 alist nil)))
1159
1160     ;; If more than one file, see if all of FILES match regular expression.
1161     (while (and flist
1162                 (string-match regexp (car flist)))
1163       (setq flist (cdr flist)))
1164
1165     ;; If flist is still non-nil, then do not guess since this means that not
1166     ;; all the files in FILES were matched by the regexp.
1167     (setq cmds (and (not flist) cmds))
1168
1169     ;; Return commands or nil if flist is still non-nil.
1170     ;; Evaluate the commands in order that any logical testing will be done.
1171     (cond ((not (cdr cmds))
1172            (eval (car cmds))) ; single command
1173           (t
1174            (mapcar (function eval) cmds)))))
1175
1176 (defun dired-guess-shell-command (prompt files)
1177   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1178
1179   (let ((default (dired-guess-default files))
1180         default-list old-history val (failed t))
1181
1182     (if (null default)
1183         ;; Nothing to guess
1184         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1185
1186       ;; Save current history list
1187       (setq old-history dired-shell-command-history)
1188
1189       (if (listp default)
1190
1191           ;; More than one guess
1192           (setq default-list default
1193                 default (car default)
1194                 prompt (concat
1195                         prompt
1196                         (format "{%d guesses} " (length default-list))))
1197
1198         ;; Just one guess
1199         (setq default-list (list default)))
1200
1201       ;; Push all guesses onto history so that they can be retrieved with M-p
1202       ;; and put the first guess in the prompt but not in the initial value.
1203       (setq dired-shell-command-history
1204             (append default-list dired-shell-command-history)
1205             prompt (concat prompt (format "[%s] " default)))
1206
1207       ;; The unwind-protect returns VAL, and we too.
1208       (unwind-protect
1209           ;; BODYFORM
1210           (progn
1211             (setq val (read-from-minibuffer prompt nil nil nil
1212                                             'dired-shell-command-history)
1213                   failed nil)
1214             ;; If we got a return, then use default.
1215             (if (equal val "")
1216                 (setq val default))
1217             val)
1218
1219         ;; UNWINDFORMS
1220         ;; Undo pushing onto the history list so that an aborted
1221         ;; command doesn't get the default in the next command.
1222         (setq dired-shell-command-history old-history)
1223         (if (not failed)
1224             (or (equal val (car-safe dired-shell-command-history))
1225                 (setq dired-shell-command-history
1226                       (cons val dired-shell-command-history))))))))
1227
1228
1229 ;;; REDEFINE.
1230 ;;; Redefine dired-aux.el's version:
1231 (defun dired-read-shell-command (prompt arg files)
1232   "Read a dired shell command prompting with PROMPT (using read-string).
1233 ARG is the prefix arg and may be used to indicate in the prompt which
1234   files are affected.
1235 This is an extra function so that you can redefine it."
1236   (dired-mark-pop-up
1237    nil 'shell files
1238    'dired-guess-shell-command
1239    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1240    files))                                       ; FILES
1241
1242 \f
1243 ;;; RELATIVE SYMBOLIC LINKS.
1244
1245 (defvar dired-keep-marker-relsymlink ?S
1246   "See variable `dired-keep-marker-move'.")
1247
1248 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1249   "Make a symbolic link (pointing to FILE1) in FILE2.
1250 The link is relative (if possible), for example
1251
1252     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1253
1254 results in
1255
1256     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1257   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1258   (let (name1 name2 len1 len2 (index 0) sub)
1259     (setq file1 (expand-file-name file1)
1260           file2 (expand-file-name file2)
1261           len1 (length file1)
1262           len2 (length file2))
1263     ;; Find common initial file name components:
1264     (let (next)
1265       (while (and (setq next (string-match "/" file1 index))
1266                   (setq next (1+ next))
1267                   (< next (min len1 len2))
1268                   ;; For the comparison, both substrings must end in
1269                   ;; `/', so NEXT is *one plus* the result of the
1270                   ;; string-match.
1271                   ;; E.g., consider the case of linking "/tmp/a/abc"
1272                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1273                   ;; of "/tmp/" as common initial component
1274                   (string-equal (substring file1 0 next)
1275                                 (substring file2 0 next)))
1276         (setq index next))
1277       (setq name2 file2
1278             sub (substring file1 0 index)
1279             name1 (substring file1 index)))
1280     (if (string-equal sub "/")
1281         ;; No common initial file name found
1282         (setq name1 file1)
1283       ;; Else they have a common parent directory
1284       (let ((tem (substring file2 index))
1285             (start 0)
1286             (count 0))
1287         ;; Count number of slashes we must compensate for ...
1288         (while (setq start (string-match "/" tem start))
1289           (setq count (1+ count)
1290                 start (1+ start)))
1291         ;; ... and prepend a "../" for each slash found:
1292         (while (> count 0)
1293           (setq count (1- count)
1294                 name1 (concat "../" name1)))))
1295     (make-symbolic-link
1296      (directory-file-name name1)        ; must not link to foo/
1297                                         ; (trailing slash!)
1298      name2 ok-if-already-exists)))
1299
1300 ;;;###autoload
1301 (defun dired-do-relsymlink (&optional arg)
1302    "Relative symlink all marked (or next ARG) files into a directory.
1303 Otherwise make a relative symbolic link to the current file.
1304 This creates relative symbolic links like
1305
1306     foo -> ../bar/foo
1307
1308 not absolute ones like
1309
1310     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1311
1312 For absolute symlinks, use \\[dired-do-symlink]."
1313   (interactive "P")
1314   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1315                            "RelSymLink" arg dired-keep-marker-relsymlink))
1316
1317 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1318   "RelSymlink all marked files containing REGEXP to NEWNAME.
1319 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1320 for more info."
1321   (interactive (dired-mark-read-regexp "RelSymLink"))
1322   (dired-do-create-files-regexp
1323    (function dired-make-relative-symlink)
1324    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1325
1326 \f
1327 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1328
1329 ;;; Brief Description:
1330 ;;;
1331 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1332 ;;;
1333 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1334 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1335 ;;;
1336 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1337 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1338 ;;;
1339 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1340 ;;;   list each time.
1341 ;;;
1342 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1343 ;;;   element of FILE-LIST.
1344 ;;;
1345 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1346 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1347 ;;;   cognizant of the window-configuration.
1348 ;;;
1349 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1350 ;;;   of FILE-LIST giving each a window of height `size'.
1351
1352 (defun dired-do-find-marked-files (&optional noselect)
1353   "Find all marked files displaying all of them simultaneously.
1354 With optional NOSELECT just find files but do not select them.
1355
1356 The current window is split across all files marked, as evenly as possible.
1357 Remaining lines go to bottom-most window.  The number of files that can be
1358 displayed this way is restricted by the height of the current window and
1359 `window-min-height'.
1360
1361 To keep dired buffer displayed, type \\[split-window-vertically] first.
1362 To display just marked files, type \\[delete-other-windows] first."
1363
1364   (interactive "P")
1365   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1366
1367 (defun dired-simultaneous-find-file (file-list noselect)
1368
1369   "Visit all files in FILE-LIST and display them simultaneously.
1370 The current window is split across all files in FILE-LIST, as evenly as
1371 possible.  Remaining lines go to the bottom-most window.  The number of
1372 files that can be displayed this way is restricted by the height of the
1373 current window and the variable `window-min-height'.  With non-nil
1374 NOSELECT the files are merely found but not selected."
1375
1376   ;; We don't make this function interactive because it is usually too clumsy
1377   ;; to specify FILE-LIST interactively unless via dired.
1378
1379   (let (size)
1380
1381     (if noselect
1382         ;; Do not select the buffer.
1383         (find-file-noselect (car file-list))
1384
1385       ;; We will have to select the buffer.  Calculate and check window size.
1386       (setq size (/ (window-height) (length file-list)))
1387       (or (<= window-min-height size)
1388           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1389       (find-file (car file-list)))
1390
1391     ;; Decrement.
1392     (setq file-list (cdr file-list))
1393
1394     (while file-list
1395
1396       (if noselect
1397           ;; Do not select the buffer.
1398           (find-file-noselect (car file-list))
1399
1400         ;; Vertically split off a window of desired size.  Upper window will
1401         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1402         (select-window (split-window nil size))
1403         (find-file (car file-list)))
1404
1405       ;; Decrement.
1406       (setq file-list (cdr file-list)))))
1407
1408 \f
1409 ;;; MISCELLANEOUS COMMANDS.
1410
1411 ;;; Run man on files.
1412
1413 (defun dired-man ()
1414   "Run man on this file.  Display old buffer if buffer name matches filename.
1415 Uses `man.el' of \\[manual-entry] fame."
1416   (interactive)
1417   (require 'man)
1418   (let* ((file (dired-get-filename))
1419          (manual-program (replace-regexp-in-string "\\*" "%s"
1420                           (dired-guess-shell-command
1421                            "Man command: " (list file)))))
1422     (Man-getpage-in-background file)))
1423
1424 ;;; Run Info on files.
1425
1426 (defun dired-info ()
1427   "Run info on this file."
1428   (interactive)
1429   (info (dired-get-filename)))
1430
1431 ;;; Run mail on mail folders.
1432
1433 ;; Avoid compiler warning.
1434 (eval-when-compile
1435   (when (not (fboundp 'vm-visit-folder))
1436     (defun vm-visit-folder (file &optional arg)
1437       nil)))
1438
1439 (defun dired-vm (&optional read-only)
1440   "Run VM on this file.
1441 With prefix arg, visit folder read-only (this requires at least VM 5).
1442 See also variable `dired-vm-read-only-folders'."
1443   (interactive "P")
1444   (let ((dir (dired-current-directory))
1445         (fil (dired-get-filename)))
1446     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1447     (cond (read-only (vm-visit-folder fil t))
1448           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1449           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1450           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1451     ;; so that pressing `v' inside VM does prompt within current directory:
1452     (set (make-local-variable 'vm-folder-directory) dir)))
1453
1454 (defun dired-rmail ()
1455   "Run RMAIL on this file."
1456   (interactive)
1457   (rmail (dired-get-filename)))
1458
1459 (defun dired-do-run-mail ()
1460   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1461   (interactive)
1462   (if dired-bind-vm
1463       ;; Read mail folder using vm.
1464       (dired-vm)
1465     ;; Read mail folder using rmail.
1466     (dired-rmail)))
1467
1468 \f
1469 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1470
1471 (or (fboundp 'dired-old-find-buffer-nocreate)
1472     (fset 'dired-old-find-buffer-nocreate
1473           (symbol-function 'dired-find-buffer-nocreate)))
1474
1475 ;;; REDEFINE.
1476 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1477 (defun dired-find-buffer-nocreate (dirname &optional mode)
1478   (if (and dired-find-subdir
1479            ;; don't try to find a wildcard as a subdirectory
1480            (string-equal dirname (file-name-directory dirname)))
1481       (let* ((cur-buf (current-buffer))
1482              (buffers (nreverse
1483                        (dired-buffers-for-dir (expand-file-name dirname))))
1484              (cur-buf-matches (and (memq cur-buf buffers)
1485                                    ;; wildcards must match, too:
1486                                    (equal dired-directory dirname))))
1487         ;; We don't want to switch to the same buffer---
1488         (setq buffers (delq cur-buf buffers));;need setq with delq
1489         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1490             ;; ---unless it's the only possibility:
1491             (and cur-buf-matches cur-buf)))
1492     (dired-old-find-buffer-nocreate dirname mode)))
1493
1494 ;; This should be a builtin
1495 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1496   "Return t if BUFFER1 is more recently used than BUFFER2."
1497   (if (equal buffer1 buffer2)
1498       nil
1499     (let ((more-recent nil)
1500           (list (buffer-list)))
1501       (while (and list
1502                   (not (setq more-recent (equal buffer1 (car list))))
1503                   (not (equal buffer2 (car list))))
1504         (setq list (cdr list)))
1505       more-recent)))
1506
1507 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1508 ;;; (defun dired-buffers-for-dir-exact (dir)
1509 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1510 ;;; ;; at top level, or as subdirectory.
1511 ;;; ;; Top level matches must match the wildcard part too, if any.
1512 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1513 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1514 ;;; ;; dired-buffers.
1515 ;;;   (let ((alist dired-buffers) result elt)
1516 ;;;     (while alist
1517 ;;;       (setq elt (car alist)
1518 ;;;             alist (cdr alist))
1519 ;;;       (let ((buf (cdr elt)))
1520 ;;;         (if (buffer-name buf)
1521 ;;;             ;; Top level must match exactly against dired-directory in
1522 ;;;             ;; case one of them is a wildcard.
1523 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1524 ;;;                                                dired-directory))
1525 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1526 ;;;                                                dired-subdir-alist)))
1527 ;;;                 (setq result (cons buf result)))
1528 ;;;           ;; else buffer is killed - clean up:
1529 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1530 ;;;     result))
1531
1532 ;;; REDEFINE.
1533 ;;; Redefines dired.el's version of `dired-initial-position'
1534 (defun dired-initial-position (dirname)
1535   "Where point should go in a new listing of DIRNAME.
1536 Point assumed at beginning of new subdir line.
1537 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1538   (end-of-line)
1539   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1540   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1541
1542 \f
1543 ;; Does anyone use this? - lrd 6/29/93.
1544 ;; Apparently people do use it. - lrd 12/22/97.
1545 (defun dired-mark-sexp (predicate &optional unflag-p)
1546   "Mark files for which PREDICATE returns non-nil.
1547 With a prefix arg, unflag those files instead.
1548
1549 PREDICATE is a lisp expression that can refer to the following symbols:
1550
1551     inode  [integer] the inode of the file (only for ls -i output)
1552     s      [integer] the size of the file for ls -s output
1553                      (usually in blocks or, with -k, in KByte)
1554     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1555     nlink  [integer] number of links to file
1556     uid    [string]  owner
1557     gid    [string]  group  (If the gid is not displayed by ls,
1558                      this will still be set (to the same as uid))
1559     size   [integer] file size in bytes
1560     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1561     name   [string]  the name of the file
1562     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1563
1564 For example, use
1565
1566         (equal 0 size)
1567
1568 to mark all zero length files."
1569   ;; Using sym="" instead of nil avoids the trap of
1570   ;; (string-match "foo" sym) into which a user would soon fall.
1571   ;; Give `equal' instead of `=' in the example, as this works on
1572   ;; integers and strings.
1573   (interactive "xMark if (lisp expr): \nP")
1574   (message "%s" predicate)
1575   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1576         inode s mode nlink uid gid size time name sym)
1577     (dired-mark-if
1578      (save-excursion
1579        (and
1580         ;; Sets vars
1581         ;;                inode s mode nlink uid gid size time name sym
1582
1583         ;; according to current file line.  Returns t for success, nil if
1584         ;; there is no file line.  Upon success, all variables are set, either
1585         ;; to nil or the appropriate value, so they need not be initialized.
1586         ;; Moves point within the current line.
1587         (if (dired-move-to-filename)
1588             (let (pos
1589                   (mode-len 10) ; length of mode string
1590                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1591                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1592               (beginning-of-line)
1593               (forward-char 2)
1594               (if (looking-at dired-re-inode-size)
1595                   (progn
1596                     (goto-char (match-end 0))
1597                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1598                                                                     (match-end 1)))
1599                           s (string-to-number (buffer-substring (match-beginning 2)
1600                                                                 (match-end 2)))))
1601                 (setq inode nil
1602                       s nil))
1603               (setq mode (buffer-substring (point) (+ mode-len (point))))
1604               (forward-char mode-len)
1605               (setq nlink (read (current-buffer)))
1606               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1607               (setq uid (buffer-substring (+ (point) 1)
1608                                           (progn (forward-word 1) (point))))
1609               (re-search-forward directory-listing-before-filename-regexp)
1610               (goto-char (match-beginning 1))
1611               (forward-char -1)
1612               (setq size (string-to-number (buffer-substring (save-excursion
1613                                                                (backward-word 1)
1614                                                                (setq pos (point)))
1615                                                              (point))))
1616               (goto-char pos)
1617               (backward-word 1)
1618               ;; if no gid is displayed, gid will be set to uid
1619               ;; but user will then not reference it anyway in PREDICATE.
1620               (setq gid (buffer-substring (save-excursion
1621                                             (forward-word 1) (point))
1622                                           (point))
1623                     time (buffer-substring (match-beginning 1)
1624                                            (1- (dired-move-to-filename)))
1625                     name (buffer-substring (point)
1626                                            (or
1627                                             (dired-move-to-end-of-filename t)
1628                                             (point)))
1629                     sym  (progn
1630                            (if (looking-at " -> ")
1631                                (buffer-substring
1632                                 (progn (forward-char 4) (point))
1633                                 (progn (end-of-line) (point)))
1634                              "")))
1635               t)
1636           nil)
1637                       (eval predicate)))
1638      (format "'%s file" predicate))))
1639
1640 \f
1641 ;;; FIND FILE AT POINT.
1642
1643 (defvar dired-x-hands-off-my-keys t
1644   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1645 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1646 If you change this variable after `dired-x.el' is loaded then do
1647 \\[dired-x-bind-find-file].")
1648
1649 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1650 ;;; `find-file{-other-window}' is bound?
1651 (defun dired-x-bind-find-file ()
1652   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1653 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1654 Binding direction based on `dired-x-hands-off-my-keys'.
1655 This function is part of `after-init-hook'."
1656   (interactive)
1657   (if (interactive-p)
1658       (setq dired-x-hands-off-my-keys
1659             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1660   (cond ((not dired-x-hands-off-my-keys)
1661          (substitute-key-definition 'find-file
1662                                     'dired-x-find-file
1663                                     (current-global-map))
1664          (substitute-key-definition 'find-file-other-window
1665                                     'dired-x-find-file-other-window
1666                                     (current-global-map)))
1667         (t
1668          (substitute-key-definition 'dired-x-find-file
1669                                     'find-file
1670                                     (current-global-map))
1671          (substitute-key-definition 'dired-x-find-file-other-window
1672                                     'find-file-other-window
1673                                     (current-global-map))))
1674   ;; Clear mini-buffer.
1675   (message nil))
1676
1677 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1678 ;;; user changes binding.
1679 (dired-x-bind-find-file)
1680 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1681
1682 (defun dired-x-find-file (filename)
1683   "Edit file FILENAME.
1684 May create a new window, or reuse an existing one.
1685 See the function `display-buffer'.
1686
1687 Identical to `find-file' except when called interactively, with a prefix arg
1688 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1689 Useful for editing file mentioned in buffer you are viewing,
1690 or to test if that file exists.  Use minibuffer after snatching filename."
1691   (interactive (list (read-filename-at-point "Find file: ")))
1692   (find-file (expand-file-name filename)))
1693
1694 (defun dired-x-find-file-other-window (filename)
1695   "Edit file FILENAME, in another window.
1696 May create a new window, or reuse an existing one.
1697 See the function `display-buffer'.
1698
1699 Identical to `find-file-other-window' except when called interactively, with a
1700 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1701 Useful for editing file mentioned in buffer you are viewing,
1702 or to test if that file exists.  Use minibuffer after snatching filename."
1703   (interactive (list (read-filename-at-point "Find file: ")))
1704   (find-file-other-window (expand-file-name filename)))
1705
1706 ;;; Internal functions.
1707
1708 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1709 (defun dired-filename-at-point ()
1710   "Get the filename closest to point, but do not change position.
1711 Has a preference for looking backward when not directly on a symbol.  Not
1712 perfect - point must be in middle of or end of filename."
1713
1714   (let ((filename-chars "-.[:alnum:]_/:$+@")
1715         start end filename prefix)
1716
1717     (save-excursion
1718       ;; First see if just past a filename.
1719       (if (not (eobp))
1720           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1721               (progn
1722                 (skip-chars-backward " \n\t\r({[]})")
1723                 (if (not (bobp))
1724                     (backward-char 1)))))
1725
1726       (if (string-match (concat "[" filename-chars "]")
1727                         (char-to-string (following-char)))
1728           (progn
1729             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1730                 (forward-char)
1731               (goto-char (point-min)))
1732             (setq start (point))
1733             (setq prefix
1734                   (and (string-match
1735                         "^\\w+@"
1736                         (buffer-substring start (line-beginning-position)))
1737                        "/"))
1738             (goto-char start)
1739             (if (string-match "[/~]" (char-to-string (preceding-char)))
1740                 (setq start (1- start)))
1741             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1742
1743         (error "No file found around point!"))
1744
1745       ;; Return string.
1746       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1747
1748 (defun read-filename-at-point (prompt)
1749   "Return filename prompting with PROMPT with completion.
1750 If `current-prefix-arg' is non-nil, uses name at point as guess."
1751   (if current-prefix-arg
1752       (let ((guess (dired-filename-at-point)))
1753         (read-file-name prompt
1754                         (file-name-directory guess)
1755                         guess
1756                         nil (file-name-nondirectory guess)))
1757     (read-file-name prompt default-directory)))
1758 \f
1759 ;;; BUG REPORTS
1760
1761 ;; Fixme: get rid of this later.
1762
1763 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1764 ;;; reporter.el which is bundled with GNU Emacs v19.
1765
1766 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1767   "Address(es) accepting submission of reports on dired-x.el.")
1768
1769 (defconst dired-x-variable-list
1770   (list
1771    'dired-bind-vm
1772    'dired-vm-read-only-folders
1773    'dired-bind-jump
1774    'dired-bind-info
1775    'dired-bind-man
1776    'dired-find-subdir
1777    'dired-enable-local-variables
1778    'dired-local-variables-file
1779    'dired-guess-shell-gnutar
1780    'dired-guess-shell-gzip-quiet
1781    'dired-guess-shell-znew-switches
1782    'dired-guess-shell-alist-user
1783    'dired-clean-up-buffers-too
1784    'dired-omit-mode
1785    'dired-omit-files
1786    'dired-omit-extensions
1787    )
1788   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1789
1790 (defun dired-x-submit-report ()
1791   "Submit via `reporter.el' a bug report on program.
1792 Send report on `dired-x-file' version `dired-x-version,' to
1793 `dired-x-maintainer' at address `dired-x-help-address' listing
1794 variables `dired-x-variable-list' in the message."
1795   (interactive)
1796
1797   (reporter-submit-bug-report
1798    dired-x-help-address                 ; address
1799    "dired-x"                            ; pkgname
1800    dired-x-variable-list                ; varlist
1801    nil nil                              ; pre-/post-hooks
1802    ""))
1803
1804 \f
1805 ;; As Barry Warsaw would say: "This might be useful..."
1806 (provide 'dired-x)
1807
1808 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1809 ;;; dired-x.el ends here