lisp/resume.el

   1 ;;; resume.el --- process command line args from within a suspended Emacs job
   2
   3 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Joe Wells <jbw@bucsf.bu.edu>
   6 ;; Adapted-By: ESR
   7 ;; Keywords: processes
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Theory: the first time you start Emacs, command line arguments are
  29 ;; handled normally.  Then, you suspend your emacs job.  When you want to edit
  30 ;; something else, you type "emacs filename" as usual, but instead of
  31 ;; starting a new emacs job, the old job is resumed instead, and the command
  32 ;; line arguments are placed in a file where the old emacs job looks for
  33 ;; them.
  34
  35 ;; Stephan Gildea suggested bug fix (gildea@bbn.com).
  36 ;; Ideas from Michael DeCorte and other people.
  37
  38 ;; For csh users, insert the following alias in your .cshrc file
  39 ;; (after removing the leading double semicolons, of course):
  40 ;;
  41 ;;# The following line could be just EMACS_CMD=emacs, but this depends on
  42 ;;# your site.
  43 ;;if (! $?EMACS_CMD) set EMACS_CMD=emacs
  44 ;;set JOBS_FILE=/tmp/jobs.$USER.$$
  45 ;;set ARGS_FILE=~/.emacs_args
  46 ;;set STOP_PATT='^\[[0-9]*\] *[ +-] Stopped ............ '
  47 ;;set SUNVIEW_CMD='emacstool -nw -f emacstool-init -f server-start'
  48 ;;set X_CMD=\'\''$EMACS_CMD -i -f server-start'
  49 ;;alias emacs \
  50 ;;' \\
  51 ;;   jobs >! "$JOBS_FILE" \\
  52 ;;   && grep "$STOP_PATT$EMACS_CMD" "$JOBS_FILE" >& /dev/null \\
  53 ;;   && echo `pwd` \!* >! "$ARGS_FILE" && ""fg %$EMACS_CMD \\
  54 ;;|| if (! -e ~/.emacs_server || -f ~/.emacs_server) set status=1 \\
  55 ;;   && emacsclient \!* \\
  56 ;;|| @ status=1 - $?DISPLAY && eval "$X_CMD -i \!* &" \\
  57 ;;|| @ status=1 - $?WINDOW_PARENT && eval "$SUNVIEW_CMD \!* &" \\
  58 ;;|| ""$EMACS_CMD -nw \!* \\
  59 ;;'
  60 ;;
  61 ;; The alias works as follows:
  62 ;; 1. If there is a suspended Emacs job that is a child of the
  63 ;; current shell, place its arguments in the ~/.emacs_args file and
  64 ;; resume it.
  65 ;; 2. Else if the ~/.emacs_server socket has been created, presume an
  66 ;; Emacs server is running and attempt to connect to it.  If no Emacs
  67 ;; server is listening on the socket, this will fail.
  68 ;; 3. Else if the DISPLAY environment variable is set, presume we are
  69 ;; running under X Windows and start a new GNU Emacs process in the
  70 ;; background as an X client.
  71 ;; 4. Else if the WINDOW_PARENT environment variable is set, presume we
  72 ;; are running under SunView and start an emacstool process in the
  73 ;; background.
  74 ;; 5. Else start a regular Emacs process.
  75 ;;
  76 ;; Notes:
  77 ;; The output of the "jobs" command is not piped directly into "grep"
  78 ;; because that would run the "jobs" command in a subshell.
  79 ;; Before resuming a suspended emacs, the current directory and all
  80 ;; command line arguments are placed in a file name ~/.emacs_args.
  81 ;; The "-nw" switch to Emacs means no windowing system.
  82
  83 ;; Insert this in your .emacs file:
  84 ;;(add-hook 'suspend-hook 'resume-suspend-hook)
  85
  86 ;; Finally, put the rest in a file named "resume.el" in a lisp library
  87 ;; directory.
  88
  89 ;;; Code:
  90
  91 (defvar resume-emacs-args-file (expand-file-name "~/.emacs_args")
  92   "*This file is where arguments are placed for a suspended emacs job.")
  93
  94 (defvar resume-emacs-args-buffer " *Command Line Args*"
  95   "Buffer that is used by resume-process-args.")
  96
  97 (defun resume-process-args ()
  98   "Handler for command line args given when Emacs is resumed."
  99   (let ((start-buffer (current-buffer))
 100         (args-buffer (get-buffer-create resume-emacs-args-buffer))
 101         length args
 102         (command-line-default-directory default-directory))
 103     (unwind-protect
 104         (progn
 105           (set-buffer args-buffer)
 106           (erase-buffer)
 107           ;; get the contents of resume-emacs-args-file
 108           (condition-case ()
 109               (let ((result (insert-file-contents resume-emacs-args-file)))
 110                 (setq length (car (cdr result))))
 111             ;; the file doesn't exist, ergo no arguments
 112             (file-error
 113               (erase-buffer)
 114               (setq length 0)))
 115           (if (<= length 0)
 116               (setq args nil)
 117             ;; get the arguments from the buffer
 118             (goto-char (point-min))
 119             (while (not (eobp))
 120               (skip-chars-forward " \t\n")
 121               (let ((begin (point)))
 122                 (skip-chars-forward "^ \t\n")
 123                 (setq args (cons (buffer-substring begin (point)) args)))
 124               (skip-chars-forward " \t\n"))
 125             ;; arguments are now in reverse order
 126             (setq args (nreverse args))
 127             ;; make sure they're not read again
 128             (erase-buffer))
 129           (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)
 130           ;; if nothing was in buffer, args will be null
 131           (or (null args)
 132               (setq command-line-default-directory
 133                     (file-name-as-directory (car args))
 134                     args (cdr args)))
 135           ;; actually process the arguments
 136           (command-line-1 args))
 137       ;; If the command line args don't result in a find-file, the
 138       ;; buffer will be left in args-buffer.  So we change back to the
 139       ;; original buffer.  The reason I don't just use
 140       ;; (let ((default-directory foo))
 141       ;;    (command-line-1 args))
 142       ;; in the context of the original buffer is because let does not
 143       ;; work properly with buffer-local variables.
 144       (if (eq (current-buffer) args-buffer)
 145           (set-buffer start-buffer)))))
 146
 147 ;;;###autoload
 148 (defun resume-suspend-hook ()
 149   "Clear out the file used for transmitting args when Emacs resumes."
 150   (save-excursion
 151     (set-buffer (get-buffer-create resume-emacs-args-buffer))
 152     (erase-buffer)
 153     (resume-write-buffer-to-file (current-buffer) resume-emacs-args-file)))
 154
 155 (defun resume-write-buffer-to-file (buffer file)
 156   "Writes the contents of BUFFER into FILE, if permissions allow."
 157   (if (not (file-writable-p file))
 158       (error "No permission to write file %s" file))
 159   (save-excursion
 160     (set-buffer buffer)
 161     (clear-visited-file-modtime)
 162     (save-restriction
 163       (widen)
 164       (write-region (point-min) (point-max) file nil 'quiet))
 165     (set-buffer-modified-p nil)))
 166
 167 (provide 'resume)
 168
 169 ;;; resume.el ends here