lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994, 1995, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Roland McGrath <roland@gnu.org>,
   7 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   8 ;; Maintainer: FSF
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'dired)
  33
  34 (defgroup find-dired nil
  35   "Run a `find' command and dired the output."
  36   :group 'dired
  37   :prefix "find-")
  38
  39 ;; find's -ls corresponds to these switches.
  40 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  41 ;;;###autoload
  42 (defcustom find-ls-option
  43   (if (eq system-type 'berkeley-unix) '("-ls" . "-gilsb")
  44     '("-exec ls -ld {} \\;" . "-ld"))
  45   "*Description of the option to `find' to produce an `ls -l'-type listing.
  46 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  47 gives the option (or options) to `find' that produce the desired output.
  48 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  49   :type '(cons (string :tag "Find Option")
  50                (string :tag "Ls Switches"))
  51   :group 'find-dired)
  52
  53 ;;;###autoload
  54 (defcustom find-ls-subdir-switches "-al"
  55   "`ls' switches for inserting subdirectories in `*Find*' buffers.
  56 This should contain the \"-l\" switch.
  57 Use the \"-F\" or \"-b\" switches if and only if you also use
  58 them for `find-ls-option'."
  59   :type 'string
  60   :group 'find-dired
  61   :version "22.1")
  62
  63 ;;;###autoload
  64 (defcustom find-grep-options
  65   (if (or (eq system-type 'berkeley-unix)
  66           (string-match "solaris2" system-configuration)
  67           (string-match "irix" system-configuration))
  68       "-s" "-q")
  69   "*Option to grep to be as silent as possible.
  70 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  71 On other systems, the closest you can come is to use `-l'."
  72   :type 'string
  73   :group 'find-dired)
  74
  75 ;;;###autoload
  76 (defcustom find-name-arg
  77   (if read-file-name-completion-ignore-case
  78       "-iname"
  79     "-name")
  80   "*Argument used to specify file name pattern.
  81 If `read-file-name-completion-ignore-case' is non-nil, -iname is used so that
  82 find also ignores case. Otherwise, -name is used."
  83   :type 'string
  84   :group 'find-dired
  85   :version "22.2")
  86
  87 (defvar find-args nil
  88   "Last arguments given to `find' by \\[find-dired].")
  89
  90 ;; History of find-args values entered in the minibuffer.
  91 (defvar find-args-history nil)
  92
  93 (defvar dired-sort-inhibit)
  94
  95 ;;;###autoload
  96 (defun find-dired (dir args)
  97   "Run `find' and go into Dired mode on a buffer of the output.
  98 The command run (after changing into DIR) is
  99
 100     find . \\( ARGS \\) -ls
 101
 102 except that the variable `find-ls-option' specifies what to use
 103 as the final argument."
 104   (interactive (list (read-file-name "Run find in directory: " nil "" t)
 105                      (read-string "Run find (with args): " find-args
 106                                   '(find-args-history . 1))))
 107   (let ((dired-buffers dired-buffers))
 108     ;; Expand DIR ("" means default-directory), and make sure it has a
 109     ;; trailing slash.
 110     (setq dir (file-name-as-directory (expand-file-name dir)))
 111     ;; Check that it's really a directory.
 112     (or (file-directory-p dir)
 113         (error "find-dired needs a directory: %s" dir))
 114     (switch-to-buffer (get-buffer-create "*Find*"))
 115
 116     ;; See if there's still a `find' running, and offer to kill
 117     ;; it first, if it is.
 118     (let ((find (get-buffer-process (current-buffer))))
 119       (when find
 120         (if (or (not (eq (process-status find) 'run))
 121                 (yes-or-no-p "A `find' process is running; kill it? "))
 122             (condition-case nil
 123                 (progn
 124                   (interrupt-process find)
 125                   (sit-for 1)
 126                   (delete-process find))
 127               (error nil))
 128           (error "Cannot have two processes in `%s' at once" (buffer-name)))))
 129
 130     (widen)
 131     (kill-all-local-variables)
 132     (setq buffer-read-only nil)
 133     (erase-buffer)
 134     (setq default-directory dir
 135           find-args args              ; save for next interactive call
 136           args (concat find-program " . "
 137                        (if (string= args "")
 138                            ""
 139                          (concat
 140                           (shell-quote-argument "(")
 141                           " " args " "
 142                           (shell-quote-argument ")")
 143                           " "))
 144                        (if (equal (car find-ls-option) "-exec ls -ld {} \\;")
 145                            (concat "-exec ls -ld "
 146                                    (shell-quote-argument "{}")
 147                                    " "
 148                                    (shell-quote-argument ";"))
 149                          (car find-ls-option))))
 150     ;; Start the find process.
 151     (shell-command (concat args "&") (current-buffer))
 152     ;; The next statement will bomb in classic dired (no optional arg allowed)
 153     (dired-mode dir (cdr find-ls-option))
 154     (let ((map (make-sparse-keymap)))
 155       (set-keymap-parent map (current-local-map))
 156       (define-key map "\C-c\C-k" 'kill-find)
 157       (use-local-map map))
 158     (make-local-variable 'dired-sort-inhibit)
 159     (setq dired-sort-inhibit t)
 160     (set (make-local-variable 'revert-buffer-function)
 161          `(lambda (ignore-auto noconfirm)
 162             (find-dired ,dir ,find-args)))
 163     ;; Set subdir-alist so that Tree Dired will work:
 164     (if (fboundp 'dired-simple-subdir-alist)
 165         ;; will work even with nested dired format (dired-nstd.el,v 1.15
 166         ;; and later)
 167         (dired-simple-subdir-alist)
 168       ;; else we have an ancient tree dired (or classic dired, where
 169       ;; this does no harm)
 170       (set (make-local-variable 'dired-subdir-alist)
 171            (list (cons default-directory (point-min-marker)))))
 172     (set (make-local-variable 'dired-subdir-switches) find-ls-subdir-switches)
 173     (setq buffer-read-only nil)
 174     ;; Subdir headlerline must come first because the first marker in
 175     ;; subdir-alist points there.
 176     (insert "  " dir ":\n")
 177     ;; Make second line a ``find'' line in analogy to the ``total'' or
 178     ;; ``wildcard'' line.
 179     (insert "  " args "\n")
 180     (setq buffer-read-only t)
 181     (let ((proc (get-buffer-process (current-buffer))))
 182       (set-process-filter proc (function find-dired-filter))
 183       (set-process-sentinel proc (function find-dired-sentinel))
 184       ;; Initialize the process marker; it is used by the filter.
 185       (move-marker (process-mark proc) 1 (current-buffer)))
 186     (setq mode-line-process '(":%s"))))
 187
 188 (defun kill-find ()
 189   "Kill the `find' process running in the current buffer."
 190   (interactive)
 191   (let ((find (get-buffer-process (current-buffer))))
 192     (and find (eq (process-status find) 'run)
 193          (eq (process-filter find) (function find-dired-filter))
 194          (condition-case nil
 195              (delete-process find)
 196            (error nil)))))
 197
 198 ;;;###autoload
 199 (defun find-name-dired (dir pattern)
 200   "Search DIR recursively for files matching the globbing pattern PATTERN,
 201 and run dired on those files.
 202 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 203 The command run (after changing into DIR) is
 204
 205     find . -name 'PATTERN' -ls"
 206   (interactive
 207    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 208   (find-dired dir (concat find-name-arg " " (shell-quote-argument pattern))))
 209
 210 ;; This functionality suggested by
 211 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 212 ;; Subject: find-dired, lookfor-dired
 213 ;; Date: 10 May 91 17:50:00 GMT
 214 ;; Organization: University of Waterloo
 215
 216 (defalias 'lookfor-dired 'find-grep-dired)
 217 ;;;###autoload
 218 (defun find-grep-dired (dir regexp)
 219   "Find files in DIR containing a regexp REGEXP and start Dired on output.
 220 The command run (after changing into DIR) is
 221
 222     find . -exec grep -s -e REGEXP {} \\\; -ls
 223
 224 Thus ARG can also contain additional grep options."
 225   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 226   ;; find -exec doesn't allow shell i/o redirections in the command,
 227   ;; or we could use `grep -l >/dev/null'
 228   ;; We use -type f, not ! -type d, to avoid getting screwed
 229   ;; by FIFOs and devices.  I'm not sure what's best to do
 230   ;; about symlinks, so as far as I know this is not wrong.
 231   (find-dired dir
 232               (concat "-type f -exec " grep-program " " find-grep-options " -e "
 233                       (shell-quote-argument regexp)
 234                       " "
 235                       (shell-quote-argument "{}")
 236                       " "
 237                       (shell-quote-argument ";"))))
 238
 239 (defun find-dired-filter (proc string)
 240   ;; Filter for \\[find-dired] processes.
 241   (let ((buf (process-buffer proc))
 242         (inhibit-read-only t))
 243     (if (buffer-name buf)
 244         (with-current-buffer buf
 245           (save-restriction
 246             (widen)
 247             (let ((buffer-read-only nil)
 248                   (beg (point-max))
 249                   (l-opt (and (consp find-ls-option)
 250                               (string-match "l" (cdr find-ls-option))))
 251                   (ls-regexp (concat "^ +[^ \t\r\n]+\\( +[^ \t\r\n]+\\) +"
 252                                      "[^ \t\r\n]+ +[^ \t\r\n]+\\( +[0-9]+\\)")))
 253               (goto-char beg)
 254               (insert string)
 255               (goto-char beg)
 256               (or (looking-at "^")
 257                   (forward-line 1))
 258               (while (looking-at "^")
 259                 (insert "  ")
 260                 (forward-line 1))
 261               ;; Convert ` ./FILE' to ` FILE'
 262               ;; This would lose if the current chunk of output
 263               ;; starts or ends within the ` ./', so back up a bit:
 264               (goto-char (- beg 3))     ; no error if < 0
 265               (while (search-forward " ./" nil t)
 266                 (delete-region (point) (- (point) 2)))
 267               ;; Pad the number of links and file size.  This is a
 268               ;; quick and dirty way of getting the columns to line up
 269               ;; most of the time, but it's not foolproof.
 270               (when l-opt
 271                 (goto-char beg)
 272                 (goto-char (line-beginning-position))
 273                 (while (re-search-forward ls-regexp nil t)
 274                   (replace-match (format "%4s" (match-string 1))
 275                                  nil nil nil 1)
 276                   (replace-match (format "%9s" (match-string 2))
 277                                  nil nil nil 2)
 278                   (forward-line 1)))
 279               ;; Find all the complete lines in the unprocessed
 280               ;; output and process it to add text properties.
 281               (goto-char (point-max))
 282               (if (search-backward "\n" (process-mark proc) t)
 283                   (progn
 284                     (dired-insert-set-properties (process-mark proc)
 285                                                  (1+ (point)))
 286                     (move-marker (process-mark proc) (1+ (point))))))))
 287       ;; The buffer has been killed.
 288       (delete-process proc))))
 289
 290 (defun find-dired-sentinel (proc state)
 291   ;; Sentinel for \\[find-dired] processes.
 292   (let ((buf (process-buffer proc))
 293         (inhibit-read-only t))
 294     (if (buffer-name buf)
 295         (save-excursion
 296           (set-buffer buf)
 297           (let ((buffer-read-only nil))
 298             (save-excursion
 299               (goto-char (point-max))
 300               (insert "\n  find " state)
 301               (forward-char -1)         ;Back up before \n at end of STATE.
 302               (insert " at " (substring (current-time-string) 0 19))
 303               (forward-char 1)
 304               (setq mode-line-process
 305                     (concat ":"
 306                             (symbol-name (process-status proc))))
 307               ;; Since the buffer and mode line will show that the
 308               ;; process is dead, we can delete it now.  Otherwise it
 309               ;; will stay around until M-x list-processes.
 310               (delete-process proc)
 311               (force-mode-line-update)))
 312           (message "find-dired %s finished." (current-buffer))))))
 313
 314 \f
 315 (provide 'find-dired)
 316
 317 ;;; arch-tag: 8edece95-af00-4221-bc74-a4bd2f75f9b0
 318 ;;; find-dired.el ends here