lisp/elide-head.el

   1 ;;; elide-head.el --- hide headers in files
   2
   3 ;; Copyright (C) 1999, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: outlines tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Functionality for eliding boilerplate text (normally copyright
  27 ;; notices) in file headers to avoid clutter when you know what it
  28 ;; says.
  29 ;;
  30 ;; `elide-head-headers-to-hide' controls what is elided by the command
  31 ;; `elide-head'.  A buffer-local invisible overlay manages the
  32 ;; elision.
  33
  34 ;; You might add `elide-head' to appropriate major mode hooks or to
  35 ;; `find-file-hook'.  Please do not do this in site init files.  If
  36 ;; you do, information may be hidden from users who don't know it
  37 ;; already.
  38
  39 ;; Note that `hs-minor-mode' will do a similar job by default, but
  40 ;; it's not selective about what leading commentary it hides.
  41
  42 ;; Inspired by jwz's hide-copyleft.el, for which we don't have an
  43 ;; assignment.
  44
  45 ;;; Code:
  46
  47 (defgroup elide-head nil
  48   "Eliding copyright headers and the like in source files."
  49   :version "21.1"
  50   :prefix "elide-head"
  51   :group 'tools)
  52
  53 (defcustom elide-head-headers-to-hide
  54   '(("is free software[:;] you can redistribute it" . ; GNU boilerplate
  55      "\\(Boston, MA 0211\\(1-1307\\|0-1301\\), USA\\|\
  56 If not, see <http://www\\.gnu\\.org/licenses/>\\)\\.")
  57     ("The Regents of the University of California\\.  All rights reserved\\." .
  58      "SUCH DAMAGE\\.")                                ; BSD
  59     ("Permission is hereby granted, free of charge" . ; X11
  60      "authorization from the X Consortium\\."))
  61   "Alist of regexps defining start end end of text to elide.
  62
  63 The cars of elements of the list are searched for in order.  Text is
  64 elided with an invisible overlay from the end of the line where the
  65 first match is found to the end of the match for the corresponding
  66 cdr."
  67   :group 'elide-head
  68   :type '(alist :key-type  (string :tag "Start regexp")
  69                 :value-type (string :tag "End regexp")))
  70
  71 (defvar elide-head-overlay nil)
  72 (make-variable-buffer-local 'elide-head-overlay)
  73
  74 ;;;###autoload
  75 (defun elide-head (&optional arg)
  76   "Hide header material in buffer according to `elide-head-headers-to-hide'.
  77
  78 The header is made invisible with an overlay.  With a prefix arg, show
  79 an elided material again.
  80
  81 This is suitable as an entry on `find-file-hook' or appropriate mode hooks."
  82   (interactive "P")
  83   (if arg
  84       (elide-head-show)
  85     (save-excursion
  86       (save-restriction
  87         (let ((rest elide-head-headers-to-hide)
  88               beg end)
  89           (widen)
  90           (goto-char (point-min))
  91           (while rest
  92             (save-excursion
  93               (when (re-search-forward (caar rest) nil t)
  94                 (setq beg (point))
  95                 (when (re-search-forward (cdar rest) nil t)
  96                   (setq end (point-marker)
  97                         rest nil))))
  98             (if rest (setq rest (cdr rest))))
  99           (if (not (and beg end))
 100               (if (called-interactively-p 'interactive)
 101                   (message "No header found"))
 102             (goto-char beg)
 103             (end-of-line)
 104             (if (overlayp elide-head-overlay)
 105                 (move-overlay elide-head-overlay (point-marker) end)
 106               (setq elide-head-overlay (make-overlay (point-marker) end)))
 107             (overlay-put elide-head-overlay 'invisible t)
 108             (overlay-put elide-head-overlay 'evaporate t)
 109             (overlay-put elide-head-overlay 'after-string "...")))))))
 110
 111 (defun elide-head-show ()
 112   "Show a header elided current buffer by \\[elide-head]."
 113   (interactive)
 114   (if (and (overlayp elide-head-overlay)
 115            (overlay-buffer elide-head-overlay))
 116       (delete-overlay elide-head-overlay)
 117     (if (called-interactively-p 'interactive)
 118         (message "No header hidden"))))
 119
 120 (provide 'elide-head)
 121
 122 ;; arch-tag: a00e6b5b-6aeb-45b1-b734-63e23df80928
 123 ;;; elide-head.el ends here