lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1993 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This code implements GNU Emac's on-line help system, the one invoked by
  27 ;;`M-x help-for-help'.
  28
  29 ;;; Code:
  30
  31 ;; Get the macro make-help-screen when this is compiled,
  32 ;; or run interpreted, but not when the compiled code is loaded.
  33 (eval-when-compile (require 'help-macro))
  34
  35 (defvar help-map (make-sparse-keymap)
  36   "Keymap for characters following the Help key.")
  37
  38 (define-key global-map (char-to-string help-char) 'help-command)
  39 (fset 'help-command help-map)
  40
  41 (define-key help-map (char-to-string help-char) 'help-for-help)
  42 (define-key help-map "?" 'help-for-help)
  43
  44 (define-key help-map "\C-c" 'describe-copying)
  45 (define-key help-map "\C-d" 'describe-distribution)
  46 (define-key help-map "\C-w" 'describe-no-warranty)
  47 (define-key help-map "\C-p" 'describe-project)
  48 (define-key help-map "a" 'command-apropos)
  49
  50 (define-key help-map "b" 'describe-bindings)
  51
  52 (define-key help-map "c" 'describe-key-briefly)
  53 (define-key help-map "k" 'describe-key)
  54
  55 (define-key help-map "d" 'describe-function)
  56 (define-key help-map "f" 'describe-function)
  57
  58 (define-key help-map "i" 'info)
  59 (define-key help-map "\C-f" 'Info-goto-emacs-command-node)
  60 (define-key help-map "\C-k" 'Info-goto-emacs-key-command-node)
  61
  62 (define-key help-map "l" 'view-lossage)
  63
  64 (define-key help-map "m" 'describe-mode)
  65
  66 (define-key help-map "\C-n" 'view-emacs-news)
  67 (define-key help-map "n" 'view-emacs-news)
  68
  69 (define-key help-map "p" 'finder-by-keyword)
  70 (autoload 'finder-by-keyword "finder")
  71
  72 (define-key help-map "s" 'describe-syntax)
  73
  74 (define-key help-map "t" 'help-with-tutorial)
  75
  76 (define-key help-map "w" 'where-is)
  77
  78 (define-key help-map "v" 'describe-variable)
  79
  80 (defun help-with-tutorial ()
  81   "Select the Emacs learn-by-doing tutorial."
  82   (interactive)
  83   (let ((file (expand-file-name "~/TUTORIAL")))
  84     (delete-other-windows)
  85     (if (get-file-buffer file)
  86         (switch-to-buffer (get-file-buffer file))
  87       (switch-to-buffer (create-file-buffer file))
  88       (setq buffer-file-name file)
  89       (setq default-directory (expand-file-name "~/"))
  90       (setq buffer-auto-save-file-name nil)
  91       (insert-file-contents (expand-file-name "TUTORIAL" data-directory))
  92       (goto-char (point-min))
  93       (search-forward "\n<<")
  94       (beginning-of-line)
  95       (delete-region (point) (progn (end-of-line) (point)))
  96       (let ((n (- (window-height (selected-window))
  97                   (count-lines (point-min) (point))
  98                   6)))
  99         (if (< n 12)
 100             (newline n)
 101           ;; Some people get confused by the large gap.
 102           (newline (/ n 2))
 103           (insert "[Middle of page left blank for didactic purposes.  "
 104                   "Text continues below]")
 105           (newline (- n (/ n 2)))))
 106       (goto-char (point-min))
 107       (set-buffer-modified-p nil))))
 108
 109 (defun describe-key-briefly (key)
 110   "Print the name of the function KEY invokes.  KEY is a string."
 111   (interactive "kDescribe key briefly: ")
 112   ;; If this key seq ends with a down event, discard the
 113   ;; following click or drag event.  Otherwise that would
 114   ;; erase the message.
 115   (let ((type (aref key (1- (length key)))))
 116     (if (listp type) (setq type (car type)))
 117     (and (symbolp type)
 118          (memq 'down (event-modifiers type))
 119          (read-event)))
 120   (let ((defn (key-binding key)))
 121     (if (or (null defn) (integerp defn))
 122         (message "%s is undefined" (key-description key))
 123       (message "%s runs the command %s"
 124                (key-description key)
 125                (if (symbolp defn) defn (prin1-to-string defn))))))
 126
 127 (defun print-help-return-message (&optional function)
 128   "Display or return message saying how to restore windows after help command.
 129 Computes a message and applies the optional argument FUNCTION to it.
 130 If FUNCTION is nil, applies `message' to it, thus printing it."
 131   (and (not (get-buffer-window standard-output))
 132        (funcall (or function 'message)
 133                 (concat
 134                  (substitute-command-keys
 135                   (if (one-window-p t)
 136                       (if pop-up-windows
 137                           "Type \\[delete-other-windows] to remove help window."
 138                         "Type \\[switch-to-buffer] RET to remove help window.")
 139                     "Type \\[switch-to-buffer-other-window] RET to restore the other window."))
 140                  (substitute-command-keys
 141                   "  \\[scroll-other-window] to scroll the help.")))))
 142
 143 (defun describe-key (key)
 144   "Display documentation of the function invoked by KEY.  KEY is a string."
 145   (interactive "kDescribe key: ")
 146   ;; If this key seq ends with a down event, discard the
 147   ;; following click or drag event.  Otherwise that would
 148   ;; erase the message.
 149   (let ((type (aref key (1- (length key)))))
 150     (if (listp type) (setq type (car type)))
 151     (and (symbolp type)
 152          (memq 'down (event-modifiers type))
 153          (read-event)))
 154   (let ((defn (key-binding key)))
 155     (if (or (null defn) (integerp defn))
 156         (message "%s is undefined" (key-description key))
 157       (with-output-to-temp-buffer "*Help*"
 158         (prin1 defn)
 159         (princ ":\n")
 160         (if (documentation defn)
 161             (princ (documentation defn))
 162           (princ "not documented"))
 163         (print-help-return-message)))))
 164
 165 (defun describe-mode (&optional minor)
 166   "Display documentation of current major mode.
 167 If optional MINOR is non-nil (or prefix argument is given if interactive),
 168 display documentation of active minor modes as well.
 169 For this to work correctly for a minor mode, the mode's indicator variable
 170 \(listed in `minor-mode-alist') must also be a function whose documentation
 171 describes the minor mode."
 172   (interactive)
 173   (with-output-to-temp-buffer "*Help*"
 174     (princ mode-name)
 175     (princ " Mode:\n")
 176     (princ (documentation major-mode))
 177     (let ((minor-modes minor-mode-alist)
 178           (locals (buffer-local-variables)))
 179       (while minor-modes
 180         (let* ((minor-mode (car (car minor-modes)))
 181                (indicator (car (cdr (car minor-modes))))
 182                (local-binding (assq minor-mode locals)))
 183           ;; Document a minor mode if it is listed in minor-mode-alist,
 184           ;; bound locally in this buffer, non-nil, and has a function
 185           ;; definition.
 186           (if (and local-binding
 187                    (cdr local-binding)
 188                    (fboundp minor-mode))
 189               (progn
 190                 (princ (format "\n\n\n%s minor mode (indicator%s):\n"
 191                                minor-mode indicator))
 192                 (princ (documentation minor-mode)))))
 193         (setq minor-modes (cdr minor-modes))))
 194     (print-help-return-message)))
 195
 196 ;; So keyboard macro definitions are documented correctly
 197 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 198
 199 (defun describe-distribution ()
 200   "Display info on how to obtain the latest version of GNU Emacs."
 201   (interactive)
 202   (find-file-read-only
 203    (expand-file-name "DISTRIB" data-directory)))
 204
 205 (defun describe-copying ()
 206   "Display info on how you may redistribute copies of GNU Emacs."
 207   (interactive)
 208   (find-file-read-only
 209    (expand-file-name "COPYING" data-directory))
 210   (goto-char (point-min)))
 211
 212 (defun describe-project ()
 213   "Display info on the GNU project."
 214   (interactive)
 215   (find-file-read-only
 216    (expand-file-name "GNU" data-directory))
 217   (goto-char (point-min)))
 218
 219 (defun describe-no-warranty ()
 220   "Display info on all the kinds of warranty Emacs does NOT have."
 221   (interactive)
 222   (describe-copying)
 223   (let (case-fold-search)
 224     (search-forward "NO WARRANTY")
 225     (recenter 0)))
 226
 227 (defun describe-prefix-bindings ()
 228   "Describe the bindings of the prefix used to reach this command.
 229 The prefix described consists of all but the last event
 230 of the key sequence that ran this command."
 231   (interactive)
 232   (let* ((key (this-command-keys))
 233          (prefix (make-vector (1- (length key)) nil))
 234          i)
 235     (setq i 0)
 236     (while (< i (length prefix))
 237       (aset prefix i (aref key i))
 238       (setq i (1+ i)))
 239     (describe-bindings prefix)))
 240 ;; Make C-h after a prefix, when not specifically bound,
 241 ;; run describe-prefix-bindings.
 242 (setq prefix-help-command 'describe-prefix-bindings)
 243
 244 (defun view-emacs-news ()
 245   "Display info on recent changes to Emacs."
 246   (interactive)
 247   (find-file-read-only (expand-file-name "NEWS" data-directory)))
 248
 249 (defun view-lossage ()
 250   "Display last 100 input keystrokes."
 251   (interactive)
 252   (with-output-to-temp-buffer "*Help*"
 253     (princ (key-description (recent-keys)))
 254     (save-excursion
 255       (set-buffer standard-output)
 256       (goto-char (point-min))
 257       (while (progn (move-to-column 50) (not (eobp)))
 258         (search-forward " " nil t)
 259         (insert "\n")))
 260     (print-help-return-message)))
 261
 262 (make-help-screen help-for-help
 263   "a b c f C-f i k C-k l m n p s t v w C-c C-d C-n C-w, or ? for more help:"
 264   "You have typed \\[help-command], the help character.  Type a Help option:
 265 \(Use \\<help-map>\\[scroll-up] or \\[scroll-down] to scroll through this text.)
 266
 267 a  command-apropos.  Give a substring, and see a list of commands
 268         (functions interactively callable) that contain
 269         that substring.  See also the  apropos  command.
 270 b  describe-bindings.  Display table of all key bindings.
 271 c  describe-key-briefly.  Type a command key sequence;
 272         it prints the function name that sequence runs.
 273 f  describe-function.  Type a function name and get documentation of it.
 274 C-f Info-goto-emacs-command-node.  Type a function name;
 275         it takes you to the Info node for that command.
 276 i  info. The  info  documentation reader.
 277 k  describe-key.  Type a command key sequence;
 278         it displays the full documentation.
 279 C-k Info-goto-emacs-key-command-node.  Type a command key sequence;
 280         it takes you to the Info node for the command bound to that key.
 281 l  view-lossage.  Shows last 100 characters you typed.
 282 m  describe-mode.  Print documentation of current major mode,
 283         which describes the commands peculiar to it.
 284 n  view-emacs-news.  Shows emacs news file.
 285 p  finder-by-keyword. Find packages matching a given topic keyword.
 286 s  describe-syntax.  Display contents of syntax table, plus explanations
 287 t  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 288 v  describe-variable.  Type name of a variable;
 289         it displays the variable's documentation and value.
 290 w  where-is.  Type command name; it prints which keystrokes
 291         invoke that command.
 292 C-c print Emacs copying permission (General Public License).
 293 C-d print Emacs ordering information.
 294 C-n print news of recent Emacs changes.
 295 C-p print information about the GNU project.
 296 C-w print information on absence of warranty for GNU Emacs."
 297   help-map)
 298
 299 ;; Return a function which is called by the list containing point.
 300 ;; If that gives no function, return a function whose name is around point.
 301 ;; If that doesn't give a function, return nil.
 302 (defun function-called-at-point ()
 303   (or (condition-case ()
 304           (save-excursion
 305             (save-restriction
 306               (narrow-to-region (max (point-min) (- (point) 1000)) (point-max))
 307               (backward-up-list 1)
 308               (forward-char 1)
 309               (let (obj)
 310                 (setq obj (read (current-buffer)))
 311                 (and (symbolp obj) (fboundp obj) obj))))
 312         (error nil))
 313       (condition-case ()
 314           (save-excursion
 315             (forward-sexp -1)
 316             (skip-chars-forward "'")
 317             (let ((obj (read (current-buffer))))
 318               (and (symbolp obj) (fboundp obj) obj)))
 319         (error nil))))
 320
 321 (defun describe-function (function)
 322   "Display the full documentation of FUNCTION (a symbol)."
 323   (interactive
 324    (let ((fn (function-called-at-point))
 325          (enable-recursive-minibuffers t)
 326          val)
 327      (setq val (completing-read (if fn
 328                                     (format "Describe function (default %s): " fn)
 329                                   "Describe function: ")
 330                                 obarray 'fboundp t))
 331      (list (if (equal val "")
 332                fn (intern val)))))
 333   (with-output-to-temp-buffer "*Help*"
 334     (prin1 function)
 335     (princ ": ")
 336     (let* ((def (symbol-function function))
 337            (beg (if (commandp def) "an interactive " "a ")))
 338       (princ (cond ((or (stringp def)
 339                         (vectorp def))
 340                     "a keyboard macro.")
 341                    ((subrp def)
 342                     (concat beg "built-in function."))
 343                    ((byte-code-function-p def)
 344                     (concat beg "compiled Lisp function."))
 345                    ((symbolp def)
 346                     (format "alias for `%s'." def))
 347                    ((eq (car-safe def) 'lambda)
 348                     (concat beg "Lisp function."))
 349                    ((eq (car-safe def) 'macro)
 350                     "a Lisp macro.")
 351                    ((eq (car-safe def) 'mocklisp)
 352                     "a mocklisp function.")
 353                    ((eq (car-safe def) 'autoload)
 354                     (format "%s autoloaded Lisp %s."
 355                             (if (commandp def) "an interactive" "an")
 356                             (if (nth 4 def) "macro" "function")
 357 ;;; Including the file name made this line too long.
 358 ;;;                         (nth 1 def)
 359                             ))
 360                    (t "")))
 361       (terpri)
 362       (let ((arglist (cond ((byte-code-function-p def)
 363                             (car (append def nil)))
 364                            ((eq (car-safe def) 'lambda)
 365                             (nth 1 def))
 366                            (t t))))
 367         (if (listp arglist)
 368             (progn
 369               (princ (cons function
 370                            (mapcar (lambda (arg)
 371                                      (if (memq arg '(&optional &rest))
 372                                          arg
 373                                        (intern (upcase (symbol-name arg)))))
 374                                    arglist)))
 375               (terpri))))
 376       (if (documentation function)
 377           (progn (terpri)
 378                  (princ (documentation function)))
 379         (princ "not documented"))
 380       )
 381     (print-help-return-message)
 382     ;; Return the text we displayed.
 383     (save-excursion (set-buffer standard-output) (buffer-string))))
 384
 385 (defun variable-at-point ()
 386   (condition-case ()
 387       (save-excursion
 388         (forward-sexp -1)
 389         (skip-chars-forward "'")
 390         (let ((obj (read (current-buffer))))
 391           (and (symbolp obj) (boundp obj) obj)))
 392     (error nil)))
 393
 394 (defun describe-variable (variable)
 395   "Display the full documentation of VARIABLE (a symbol).
 396 Returns the documentation as a string, also."
 397   (interactive
 398    (let ((v (variable-at-point))
 399          (enable-recursive-minibuffers t)
 400          val)
 401      (setq val (completing-read (if v
 402                                     (format "Describe variable (default %s): " v)
 403                                   "Describe variable: ")
 404                                 obarray 'boundp t))
 405      (list (if (equal val "")
 406                v (intern val)))))
 407   (with-output-to-temp-buffer "*Help*"
 408     (prin1 variable)
 409     (princ "'s value is ")
 410     (if (not (boundp variable))
 411         (princ "void.")
 412       (prin1 (symbol-value variable)))
 413     (terpri) (terpri)
 414     (princ "Documentation:")
 415     (terpri)
 416     (let ((doc (documentation-property variable 'variable-documentation)))
 417       (if doc
 418           (princ (substitute-command-keys doc))
 419         (princ "not documented as a variable.")))
 420     (print-help-return-message)
 421     ;; Return the text we displayed.
 422     (save-excursion (set-buffer standard-output) (buffer-string))))
 423
 424 (defun where-is (definition)
 425   "Print message listing key sequences that invoke specified command.
 426 Argument is a command definition, usually a symbol with a function definition."
 427   (interactive
 428    (let ((fn (function-called-at-point))
 429          (enable-recursive-minibuffers t)
 430          val)
 431      (setq val (completing-read (if fn
 432                                     (format "Where is command (default %s): " fn)
 433                                   "Where is command: ")
 434                                 obarray 'fboundp t))
 435      (list (if (equal val "")
 436                fn (intern val)))))
 437   (let* ((keys (where-is-internal definition overriding-local-map nil nil))
 438          (keys1 (mapconcat 'key-description keys ", ")))
 439     (if (> (length keys1) 0)
 440         (message "%s is on %s" definition keys1)
 441       (message "%s is not on any key" definition)))
 442   nil)
 443
 444 (defun command-apropos (string)
 445   "Like apropos but lists only symbols that are names of commands
 446 \(interactively callable functions).  Argument REGEXP is a regular expression
 447 that is matched against command symbol names.  Returns list of symbols and
 448 documentation found."
 449   (interactive "sCommand apropos (regexp): ")
 450   (let ((message
 451          (let ((standard-output (get-buffer-create "*Help*")))
 452            (print-help-return-message 'identity))))
 453     (if (apropos string t 'commandp)
 454         (and message (message message)))))
 455
 456 (defun locate-library (library &optional nosuffix)
 457   "Show the full path name of Emacs library LIBRARY.
 458 This command searches the directories in `load-path' like `M-x load-library'
 459 to find the file that `M-x load-library RET LIBRARY RET' would load.
 460 Optional second arg NOSUFFIX non-nil means don't add suffixes `.elc' or `.el'
 461 to the specified name LIBRARY (a la calling `load' instead of `load-library')."
 462   (interactive "sLocate library: ")
 463   (catch 'answer
 464     (mapcar
 465      '(lambda (dir)
 466         (mapcar
 467          '(lambda (suf)
 468             (let ((try (expand-file-name (concat library suf) dir)))
 469               (and (file-readable-p try)
 470                    (null (file-directory-p try))
 471                    (progn
 472                      (message "Library is file %s" try)
 473                      (throw 'answer try)))))
 474          (if nosuffix '("") '(".elc" ".el" ""))))
 475      load-path)
 476     (message "No library %s in search path" library)
 477     nil))
 478
 479 ;;; help.el ends here