lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil)
 138           process-file-side-effects)
 139       (when (consp prog)
 140         (setq args (cdr prog))
 141         (setq prog (car prog)))
 142       (apply 'process-file prog (file-relative-name file) t nil args)
 143       (buffer-substring (point-min) (+ (point-min) 40)))))
 144
 145 (defun vc-bzr-state-heuristic (file)
 146   "Like `vc-bzr-state' but hopefully without running Bzr."
 147   ;; `bzr status' was excrutiatingly slow with large histories and
 148   ;; pending merges, so try to avoid using it until they fix their
 149   ;; performance problems.
 150   ;; This function tries first to parse Bzr internal file
 151   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 152   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 153   ;; only parsed if it contains the string `#bazaar dirstate flat
 154   ;; format 3' in the first line.
 155   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 156   ;; running `vc-bzr-state'."
 157   (lexical-let ((root (vc-bzr-root file)))
 158     (when root    ; Short cut.
 159       ;; This looks at internal files.  May break if they change
 160       ;; their format.
 161       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 162         (condition-case nil
 163             (with-temp-buffer
 164               (insert-file-contents dirstate)
 165               (goto-char (point-min))
 166               (if (not (looking-at "#bazaar dirstate flat format 3"))
 167                   (vc-bzr-state file)   ; Some other unknown format?
 168                 (let* ((relfile (file-relative-name file root))
 169                        (reldir (file-name-directory relfile)))
 170                   (if (re-search-forward
 171                        (concat "^\0"
 172                                (if reldir (regexp-quote
 173                                            (directory-file-name reldir)))
 174                                "\0"
 175                                (regexp-quote (file-name-nondirectory relfile))
 176                                "\0"
 177                                "[^\0]*\0"     ;id?
 178                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 179                                "[^\0]*\0" ;sha1 (empty if conflicted)?
 180                                "\\([^\0]*\\)\0" ;size?
 181                                "[^\0]*\0"       ;"y/n", executable?
 182                                "[^\0]*\0"       ;?
 183                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 184                                "\\([^\0]*\\)\0" ;sha1 again?
 185                                "[^\0]*\0"       ;size again?
 186                                "[^\0]*\0" ;"y/n", executable again?
 187                                "[^\0]*\0" ;last revid?
 188                                ;; There are more fields when merges are pending.
 189                                )
 190                        nil t)
 191                       ;; Apparently the second sha1 is the one we want: when
 192                       ;; there's a conflict, the first sha1 is absent (and the
 193                       ;; first size seems to correspond to the file with
 194                       ;; conflict markers).
 195                       (cond
 196                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 197                        ((eq (char-after (match-beginning 3)) ?a) 'added)
 198                        ((and (eq (string-to-number (match-string 2))
 199                                  (nth 7 (file-attributes file)))
 200                              (equal (match-string 4)
 201                                     (vc-bzr-sha1 file)))
 202                         'up-to-date)
 203                        (t 'edited))
 204                     'unregistered))))
 205           ;; Either the dirstate file can't be read, or the sha1
 206           ;; executable is missing, or ...
 207           ;; In either case, recent versions of Bzr aren't that slow
 208           ;; any more.
 209           (error (vc-bzr-state file)))))))
 210
 211
 212 (defun vc-bzr-registered (file)
 213   "Return non-nil if FILE is registered with bzr."
 214   (let ((state (vc-bzr-state-heuristic file)))
 215     (not (memq state '(nil unregistered ignored)))))
 216
 217 (defconst vc-bzr-state-words
 218   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 219   "Regexp matching file status words as reported in `bzr' output.")
 220
 221 (defun vc-bzr-file-name-relative (filename)
 222   "Return file name FILENAME stripped of the initial Bzr repository path."
 223   (lexical-let*
 224       ((filename* (expand-file-name filename))
 225        (rootdir (vc-bzr-root filename*)))
 226     (when rootdir
 227          (file-relative-name filename* rootdir))))
 228
 229 (defun vc-bzr-status (file)
 230   "Return FILE status according to Bzr.
 231 Return value is a cons (STATUS . WARNING), where WARNING is a
 232 string or nil, and STATUS is one of the symbols: `added',
 233 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 234 which directly correspond to `bzr status' output, or 'unchanged
 235 for files whose copy in the working tree is identical to the one
 236 in the branch repository, or nil for files that are not
 237 registered with Bzr.
 238
 239 If any error occurred in running `bzr status', then return nil."
 240   (with-temp-buffer
 241     (let ((ret (condition-case nil
 242                    (vc-bzr-command "status" t 0 file)
 243                  (file-error nil)))     ; vc-bzr-program not found.
 244           (status 'unchanged))
 245           ;; the only secure status indication in `bzr status' output
 246           ;; is a couple of lines following the pattern::
 247           ;;   | <status>:
 248           ;;   |   <file name>
 249           ;; if the file is up-to-date, we get no status report from `bzr',
 250           ;; so if the regexp search for the above pattern fails, we consider
 251           ;; the file to be up-to-date.
 252           (goto-char (point-min))
 253           (when (re-search-forward
 254                  ;; bzr prints paths relative to the repository root.
 255                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 256                          (regexp-quote (vc-bzr-file-name-relative file))
 257                          ;; Bzr appends a '/' to directory names and
 258                          ;; '*' to executable files
 259                          (if (file-directory-p file) "/?" "\\*?")
 260                          "[ \t\n]*$")
 261                  nil t)
 262             (lexical-let ((statusword (match-string 1)))
 263               ;; Erase the status text that matched.
 264               (delete-region (match-beginning 0) (match-end 0))
 265               (setq status
 266                     (intern (replace-regexp-in-string " " "" statusword)))))
 267           (when status
 268             (goto-char (point-min))
 269             (skip-chars-forward " \n\t") ;Throw away spaces.
 270             (cons status
 271                   ;; "bzr" will output warnings and informational messages to
 272                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 273                   ;; `start-process' itself) limitations, we cannot catch stderr
 274                   ;; and stdout into different buffers.  So, if there's anything
 275                   ;; left in the buffer after removing the above status
 276                   ;; keywords, let us just presume that any other message from
 277                   ;; "bzr" is a user warning, and display it.
 278                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 279
 280 (defun vc-bzr-state (file)
 281   (lexical-let ((result (vc-bzr-status file)))
 282     (when (consp result)
 283       (when (cdr result)
 284         (message "Warnings in `bzr' output: %s" (cdr result)))
 285       (cdr (assq (car result)
 286                  '((added . added)
 287                    (kindchanged . edited)
 288                    (renamed . edited)
 289                    (modified . edited)
 290                    (removed . removed)
 291                    (ignored . ignored)
 292                    (unknown . unregistered)
 293                    (unchanged . up-to-date)))))))
 294
 295 (defun vc-bzr-resolve-when-done ()
 296   "Call \"bzr resolve\" if the conflict markers have been removed."
 297   (save-excursion
 298     (goto-char (point-min))
 299     (unless (re-search-forward "^<<<<<<< " nil t)
 300       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 301       ;; Remove the hook so that it is not called multiple times.
 302       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 303
 304 (defun vc-bzr-find-file-hook ()
 305   (when (and buffer-file-name
 306              ;; FIXME: We should check that "bzr status" says "conflict".
 307              (file-exists-p (concat buffer-file-name ".BASE"))
 308              (file-exists-p (concat buffer-file-name ".OTHER"))
 309              (file-exists-p (concat buffer-file-name ".THIS"))
 310              ;; If "bzr status" says there's a conflict but there are no
 311              ;; conflict markers, it's not clear what we should do.
 312              (save-excursion
 313                (goto-char (point-min))
 314                (re-search-forward "^<<<<<<< " nil t)))
 315     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 316     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 317     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 318     (smerge-start-session)
 319     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 320     (message "There are unresolved conflicts in this file")))
 321
 322 (defun vc-bzr-workfile-unchanged-p (file)
 323   (eq 'unchanged (car (vc-bzr-status file))))
 324
 325 (defun vc-bzr-working-revision (file)
 326   ;; Together with the code in vc-state-heuristic, this makes it possible
 327   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 328   (lexical-let*
 329       ((rootdir (vc-bzr-root file))
 330        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 331                                              rootdir))
 332        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 333        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 334     ;; This looks at internal files to avoid forking a bzr process.
 335     ;; May break if they change their format.
 336     (if (and (file-exists-p branch-format-file)
 337              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 338              ;; the branch-format-file does not contain the revision
 339              ;; information, we need to look up the branch-format-file
 340              ;; in the place where the lightweight checkout comes
 341              ;; from.  We only do that if it's a local file.
 342              (let ((location-fname (expand-file-name
 343                                     (concat vc-bzr-admin-dirname
 344                                             "/branch/location") rootdir)))
 345                ;; The existence of this file is how we distinguish
 346                ;; lightweight checkouts.
 347                (if (file-exists-p location-fname)
 348                    (with-temp-buffer
 349                      (insert-file-contents location-fname)
 350                      (when (re-search-forward "file://\(.+\)" nil t)
 351                        (setq branch-format-file (match-string 1))
 352                        (file-exists-p branch-format-file)))
 353                  t)))
 354         (with-temp-buffer
 355           (insert-file-contents branch-format-file)
 356           (goto-char (point-min))
 357           (cond
 358            ((or
 359              (looking-at "Bazaar-NG branch, format 0.0.4")
 360              (looking-at "Bazaar-NG branch format 5"))
 361             ;; count lines in .bzr/branch/revision-history
 362             (insert-file-contents revhistory-file)
 363             (number-to-string (count-lines (line-end-position) (point-max))))
 364            ((or
 365              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 366              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 367             ;; revno is the first number in .bzr/branch/last-revision
 368             (insert-file-contents lastrev-file)
 369             (when (re-search-forward "[0-9]+" nil t)
 370               (buffer-substring (match-beginning 0) (match-end 0))))))
 371       ;; fallback to calling "bzr revno"
 372       (lexical-let*
 373           ((result (vc-bzr-command-discarding-stderr
 374                     vc-bzr-program "revno" (file-relative-name file)))
 375            (exitcode (car result))
 376            (output (cdr result)))
 377         (cond
 378          ((eq exitcode 0) (substring output 0 -1))
 379          (t nil))))))
 380
 381 (defun vc-bzr-create-repo ()
 382   "Create a new Bzr repository."
 383   (vc-bzr-command "init" nil 0 nil))
 384
 385 (defun vc-bzr-init-revision (&optional file)
 386   "Always return nil, as Bzr cannot register explicit versions."
 387   nil)
 388
 389 (defun vc-bzr-previous-revision (file rev)
 390   (if (string-match "\\`[0-9]+\\'" rev)
 391       (number-to-string (1- (string-to-number rev)))
 392     (concat "before:" rev)))
 393
 394 (defun vc-bzr-next-revision (file rev)
 395   (if (string-match "\\`[0-9]+\\'" rev)
 396       (number-to-string (1+ (string-to-number rev)))
 397     (error "Don't know how to compute the next revision of %s" rev)))
 398
 399 (defun vc-bzr-register (files &optional rev comment)
 400   "Register FILE under bzr.
 401 Signal an error unless REV is nil.
 402 COMMENT is ignored."
 403   (if rev (error "Can't register explicit revision with bzr"))
 404   (vc-bzr-command "add" nil 0 files))
 405
 406 ;; Could run `bzr status' in the directory and see if it succeeds, but
 407 ;; that's relatively expensive.
 408 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 409   "Return non-nil if FILE is (potentially) controlled by bzr.
 410 The criterion is that there is a `.bzr' directory in the same
 411 or a superior directory.")
 412
 413 (defun vc-bzr-could-register (file)
 414   "Return non-nil if FILE could be registered under bzr."
 415   (and (vc-bzr-responsible-p file)      ; shortcut
 416        (condition-case ()
 417            (with-temp-buffer
 418              (vc-bzr-command "add" t 0 file "--dry-run")
 419              ;; The command succeeds with no output if file is
 420              ;; registered (in bzr 0.8).
 421              (goto-char (point-min))
 422              (looking-at "added "))
 423          (error))))
 424
 425 (defun vc-bzr-unregister (file)
 426   "Unregister FILE from bzr."
 427   (vc-bzr-command "remove" nil 0 file "--keep"))
 428
 429 (defun vc-bzr-checkin (files rev comment)
 430   "Check FILE in to bzr with log message COMMENT.
 431 REV non-nil gets an error."
 432   (if rev (error "Can't check in a specific revision with bzr"))
 433   (vc-bzr-command "commit" nil 0 files "-m" comment))
 434
 435 (defun vc-bzr-find-revision (file rev buffer)
 436   "Fetch revision REV of file FILE and put it into BUFFER."
 437     (with-current-buffer buffer
 438       (if (and rev (stringp rev) (not (string= rev "")))
 439           (vc-bzr-command "cat" t 0 file "-r" rev)
 440         (vc-bzr-command "cat" t 0 file))))
 441
 442 (defun vc-bzr-checkout (file &optional editable rev)
 443   (if rev (error "Operation not supported")
 444     ;; Else, there's nothing to do.
 445     nil))
 446
 447 (defun vc-bzr-revert (file &optional contents-done)
 448   (unless contents-done
 449     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 450
 451 (defvar log-view-message-re)
 452 (defvar log-view-file-re)
 453 (defvar log-view-font-lock-keywords)
 454 (defvar log-view-current-tag-function)
 455 (defvar log-view-per-file-logs)
 456 (defvar vc-short-log)
 457
 458 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 459   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 460   (require 'add-log)
 461   (set (make-local-variable 'log-view-per-file-logs) nil)
 462   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 463   (set (make-local-variable 'log-view-message-re)
 464        (if vc-short-log
 465            "^ *\\([0-9.]+\\) \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 466          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 467   (set (make-local-variable 'log-view-font-lock-keywords)
 468        ;; log-view-font-lock-keywords is careful to use the buffer-local
 469        ;; value of log-view-message-re only since Emacs-23.
 470        (if vc-short-log
 471          (append `((,log-view-message-re
 472                     (1 'log-view-message-face)
 473                     (2 'change-log-name)
 474                     (3 'change-log-date)
 475                     (4 'change-log-list nil lax))))
 476          (append `((,log-view-message-re . 'log-view-message-face))
 477                  ;; log-view-font-lock-keywords
 478                  '(("^ *committer: \
 479 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 480                     (1 'change-log-name)
 481                     (2 'change-log-email))
 482                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 483
 484 (defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
 485   "Get bzr change log for FILES into specified BUFFER."
 486   ;; `vc-do-command' creates the buffer, but we need it before running
 487   ;; the command.
 488   (vc-setup-buffer buffer)
 489   ;; If the buffer exists from a previous invocation it might be
 490   ;; read-only.
 491   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 492   ;; the log display may not what the user wants - but I see no other
 493   ;; way of getting the above regexps working.
 494   (with-current-buffer buffer
 495     (apply 'vc-bzr-command "log" buffer 'async files
 496            (append
 497             (when shortlog '("--short"))
 498             (when start-revision (list (format "-r..%s" start-revision)))
 499             (when limit (list "-l" (format "%s" limit)))
 500             (if (stringp vc-bzr-log-switches)
 501                 (list vc-bzr-log-switches)
 502               vc-bzr-log-switches)))))
 503
 504 (defun vc-bzr-show-log-entry (revision)
 505   "Find entry for patch name REVISION in bzr change log buffer."
 506   (goto-char (point-min))
 507   (when revision
 508     (let (case-fold-search
 509           found)
 510       (if (re-search-forward
 511            ;; "revno:" can appear either at the beginning of a line,
 512            ;; or indented.
 513            (concat "^[ ]*-+\n[ ]*revno: "
 514                    ;; The revision can contain ".", quote it so that it
 515                    ;; does not interfere with regexp matching.
 516                    (regexp-quote revision) "$") nil t)
 517           (progn
 518             (beginning-of-line 0)
 519             (setq found t))
 520         (goto-char (point-min)))
 521       found)))
 522
 523 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 524   "VC bzr backend for diff."
 525   ;; `bzr diff' exits with code 1 if diff is non-empty.
 526   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*") 'async files
 527          "--diff-options" (mapconcat 'identity
 528                                      (vc-switches 'bzr 'diff)
 529                                      " ")
 530          ;; This `when' is just an optimization because bzr-1.2 is *much*
 531          ;; faster when the revision argument is not given.
 532          (when (or rev1 rev2)
 533            (list "-r" (format "%s..%s"
 534                               (or rev1 "revno:-1")
 535                               (or rev2 ""))))))
 536
 537
 538 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 539 ;; straight integer revisions.
 540
 541 (defun vc-bzr-delete-file (file)
 542   "Delete FILE and delete it in the bzr repository."
 543   (condition-case ()
 544       (delete-file file)
 545     (file-error nil))
 546   (vc-bzr-command "remove" nil 0 file))
 547
 548 (defun vc-bzr-rename-file (old new)
 549   "Rename file from OLD to NEW using `bzr mv'."
 550   (vc-bzr-command "mv" nil 0 new old))
 551
 552 (defvar vc-bzr-annotation-table nil
 553   "Internal use.")
 554 (make-variable-buffer-local 'vc-bzr-annotation-table)
 555
 556 (defun vc-bzr-annotate-command (file buffer &optional revision)
 557   "Prepare BUFFER for `vc-annotate' on FILE.
 558 Each line is tagged with the revision number, which has a `help-echo'
 559 property containing author and date information."
 560   (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
 561          (if revision (list "-r" revision)))
 562   (lexical-let ((table (make-hash-table :test 'equal)))
 563     (set-process-filter
 564      (get-buffer-process buffer)
 565      (lambda (proc string)
 566        (when (process-buffer proc)
 567          (with-current-buffer (process-buffer proc)
 568            (setq string (concat (process-get proc :vc-left-over) string))
 569            (while (string-match "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
 570              (let* ((rev (match-string 1 string))
 571                     (author (match-string 2 string))
 572                     (date (match-string 3 string))
 573                     (key (substring string (match-beginning 0)
 574                                     (match-beginning 4)))
 575                     (line (match-string 4 string))
 576                     (tag (gethash key table))
 577                     (inhibit-read-only t))
 578                (setq string (substring string (match-end 0)))
 579                (unless tag
 580                  (setq tag
 581                        (propertize
 582                         (format "%s %-7.7s" rev author)
 583                         'help-echo (format "Revision: %d, author: %s, date: %s"
 584                                            (string-to-number rev)
 585                                            author date)
 586                         'mouse-face 'highlight))
 587                  (puthash key tag table))
 588                (goto-char (process-mark proc))
 589                (insert tag line)
 590                (move-marker (process-mark proc) (point))))
 591            (process-put proc :vc-left-over string)))))))
 592
 593 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 594
 595 (defun vc-bzr-annotate-time ()
 596   (when (re-search-forward "^ *[0-9.]+ +[^\n ]* +|" nil t)
 597     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 598       (string-match "[0-9]+\\'" prop)
 599       (let ((str (match-string-no-properties 0 prop)))
 600       (vc-annotate-convert-time
 601        (encode-time 0 0 0
 602                       (string-to-number (substring str 6 8))
 603                       (string-to-number (substring str 4 6))
 604                       (string-to-number (substring str 0 4))))))))
 605
 606 (defun vc-bzr-annotate-extract-revision-at-line ()
 607   "Return revision for current line of annoation buffer, or nil.
 608 Return nil if current line isn't annotated."
 609   (save-excursion
 610     (beginning-of-line)
 611     (if (looking-at "^ *\\([0-9.]+\\) +[^\n ]* +|")
 612         (match-string-no-properties 1))))
 613
 614 (defun vc-bzr-command-discarding-stderr (command &rest args)
 615   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 616 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 617 the (numerical) exit code of the process, and OUTPUT is a string
 618 containing whatever the process sent to its standard output
 619 stream.  Standard error output is discarded."
 620   (with-temp-buffer
 621     (cons
 622      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 623      (buffer-substring (point-min) (point-max)))))
 624
 625 (defstruct (vc-bzr-extra-fileinfo
 626             (:copier nil)
 627             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 628             (:conc-name vc-bzr-extra-fileinfo->))
 629   extra-name)         ;; original name for rename targets, new name for
 630
 631 (defun vc-bzr-dir-printer (info)
 632   "Pretty-printer for the vc-dir-fileinfo structure."
 633   (let ((extra (vc-dir-fileinfo->extra info)))
 634     (vc-default-dir-printer 'Bzr info)
 635     (when extra
 636       (insert (propertize
 637                (format "   (renamed from %s)"
 638                        (vc-bzr-extra-fileinfo->extra-name extra))
 639                'face 'font-lock-comment-face)))))
 640
 641 ;; FIXME: this needs testing, it's probably incomplete.
 642 (defun vc-bzr-after-dir-status (update-function relative-dir)
 643   (let ((status-str nil)
 644         (translation '(("+N " . added)
 645                        ("-D " . removed)
 646                        (" M " . edited) ;; file text modified
 647                        ("  *" . edited) ;; execute bit changed
 648                        (" M*" . edited) ;; text modified + execute bit changed
 649                        ;; FIXME: what about ignored files?
 650                        (" D " . missing)
 651                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 652                        ("C  " . conflict)
 653                        ("?  " . unregistered)
 654                        ("?  " . unregistered)
 655                        ;; No such state, but we need to distinguish this case.
 656                        ("R  " . renamed)
 657                        ;; For a non existent file FOO, the output is:
 658                        ;; bzr: ERROR: Path(s) do not exist: FOO
 659                        ("bzr" . not-found)
 660                        ;; If the tree is not up to date, bzr will print this warning:
 661                        ;; working tree is out of date, run 'bzr update'
 662                        ;; ignore it.
 663                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 664                        ("wor" . not-found)
 665                        ;; Ignore "P " and "P." for pending patches.
 666                        ))
 667         (translated nil)
 668         (result nil))
 669       (goto-char (point-min))
 670       (while (not (eobp))
 671         (setq status-str
 672               (buffer-substring-no-properties (point) (+ (point) 3)))
 673         (setq translated (cdr (assoc status-str translation)))
 674         (cond
 675          ((eq translated 'conflict)
 676           ;; For conflicts the file appears twice in the listing: once
 677           ;; with the M flag and once with the C flag, so take care
 678           ;; not to add it twice to `result'.  Ugly.
 679           (let* ((file
 680                   (buffer-substring-no-properties
 681                    ;;For files with conflicts the format is:
 682                    ;;C   Text conflict in FILENAME
 683                    ;; Bah.
 684                    (+ (point) 21) (line-end-position)))
 685                  (entry (assoc file result)))
 686             (when entry
 687               (setf (nth 1 entry) 'conflict))))
 688          ((eq translated 'renamed)
 689           (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 690           (let ((new-name (file-relative-name (match-string 2) relative-dir))
 691                 (old-name (file-relative-name (match-string 1) relative-dir)))
 692             (push (list new-name 'edited
 693                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 694          ;; do nothing for non existent files
 695          ((eq translated 'not-found))
 696          (t
 697           (push (list (file-relative-name
 698                        (buffer-substring-no-properties
 699                         (+ (point) 4)
 700                         (line-end-position)) relative-dir)
 701                       translated) result)))
 702         (forward-line))
 703       (funcall update-function result)))
 704
 705 (defun vc-bzr-dir-status (dir update-function)
 706   "Return a list of conses (file . state) for DIR."
 707   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 708   (vc-exec-after
 709    `(vc-bzr-after-dir-status (quote ,update-function)
 710                              ;; "bzr status" results are relative to
 711                              ;; the bzr root directory, NOT to the
 712                              ;; directory "bzr status" was invoked in.
 713                              ;; Ugh.
 714                              ;; We pass the relative directory here so
 715                              ;; that `vc-bzr-after-dir-status' can
 716                              ;; frob the results accordingly.
 717                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 718
 719 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 720   "Return a list of conses (file . state) for DIR."
 721   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 722   (vc-exec-after
 723    `(vc-bzr-after-dir-status (quote ,update-function)
 724                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 725
 726 (defvar vc-bzr-shelve-map
 727   (let ((map (make-sparse-keymap)))
 728     ;; Turn off vc-dir marking
 729     (define-key map [mouse-2] 'ignore)
 730
 731     (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
 732     (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
 733     ;; (define-key map "=" 'vc-bzr-shelve-show-at-point)
 734     ;; (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
 735     (define-key map "A" 'vc-bzr-shelve-apply-at-point)
 736     map))
 737
 738 (defvar vc-bzr-shelve-menu-map
 739   (let ((map (make-sparse-keymap "Bzr Shelve")))
 740     (define-key map [de]
 741       '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
 742                   :help "Delete the current shelf"))
 743     (define-key map [ap]
 744       '(menu-item "Apply shelf" vc-bzr-shelve-apply-at-point
 745                   :help "Apply the current shelf"))
 746     ;; (define-key map [sh]
 747     ;;   '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
 748     ;;            :help "Show the contents of the current shelve"))
 749     map))
 750
 751 (defvar vc-bzr-extra-menu-map
 752   (let ((map (make-sparse-keymap)))
 753     (define-key map [bzr-sh]
 754       '(menu-item "Shelve..." vc-bzr-shelve
 755                   :help "Shelve changes"))
 756     map))
 757
 758 (defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)
 759
 760 (defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)
 761
 762 (defun vc-bzr-dir-extra-headers (dir)
 763   (let*
 764       ((str (with-temp-buffer
 765               (vc-bzr-command "info" t 0 dir)
 766               (buffer-string)))
 767        (shelve (vc-bzr-shelve-list))
 768        (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
 769        (light-checkout
 770         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 771           (match-string 1 str)))
 772        (light-checkout-branch
 773         (when light-checkout
 774           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 775             (match-string 1 str)))))
 776     (concat
 777      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 778      (propertize
 779       (if (string-match "parent branch: \\(.+\\)$" str)
 780           (match-string 1 str)
 781         "None")
 782        'face 'font-lock-variable-name-face)
 783      "\n"
 784       (when light-checkout
 785         (concat
 786          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 787          (propertize light-checkout 'face 'font-lock-variable-name-face)
 788          "\n"))
 789       (when light-checkout-branch
 790         (concat
 791          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 792          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 793          "\n"))
 794      (if shelve
 795          (concat
 796           (propertize "Shelves            :\n" 'face 'font-lock-type-face
 797                       'help-echo shelve-help-echo)
 798           (mapconcat
 799            (lambda (x)
 800              (propertize x
 801                          'face 'font-lock-variable-name-face
 802                          'mouse-face 'highlight
 803                          'help-echo "mouse-3: Show shelve menu\nA: Apply shelf\nC-k: Delete shelf"
 804                          'keymap vc-bzr-shelve-map))
 805            shelve "\n"))
 806        (concat
 807         (propertize "Shelves            : " 'face 'font-lock-type-face
 808                     'help-echo shelve-help-echo)
 809         (propertize "No shelved changes"
 810                     'help-echo shelve-help-echo
 811                     'face 'font-lock-variable-name-face))))))
 812
 813 (defun vc-bzr-shelve (name)
 814   "Create a shelve."
 815   (interactive "sShelf name: ")
 816   (let ((root (vc-bzr-root default-directory)))
 817     (when root
 818       (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
 819       (vc-resynch-buffer root t t))))
 820
 821 ;; (defun vc-bzr-shelve-show (name)
 822 ;;   "Show the contents of shelve NAME."
 823 ;;   (interactive "sShelve name: ")
 824 ;;   (vc-setup-buffer "*vc-bzr-shelve*")
 825 ;;   ;; FIXME: how can you show the contents of a shelf?
 826 ;;   (vc-bzr-command "shelve" "*vc-bzr-shelve*" 'async nil name)
 827 ;;   (set-buffer "*vc-bzr-shelve*")
 828 ;;   (diff-mode)
 829 ;;   (setq buffer-read-only t)
 830 ;;   (pop-to-buffer (current-buffer)))
 831
 832 (defun vc-bzr-shelve-apply (name)
 833   "Apply shelve NAME."
 834   (interactive "sApply shelf: ")
 835   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" name)
 836   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 837
 838 (defun vc-bzr-shelve-list ()
 839   (with-temp-buffer
 840     (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
 841     (delete
 842      ""
 843      (split-string
 844       (buffer-substring (point-min) (point-max))
 845       "\n"))))
 846
 847 (defun vc-bzr-shelve-get-at-point (point)
 848   (save-excursion
 849     (goto-char point)
 850     (beginning-of-line)
 851     (if (looking-at "^ +\\([0-9]+\\):")
 852         (match-string 1)
 853       (error "Cannot find shelf at point"))))
 854
 855 (defun vc-bzr-shelve-delete-at-point ()
 856   (interactive)
 857   (let ((shelve (vc-bzr-shelve-get-at-point (point))))
 858     (when (y-or-n-p (format "Remove shelf %s ?" shelve))
 859       (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
 860       (vc-dir-refresh))))
 861
 862 ;; (defun vc-bzr-shelve-show-at-point ()
 863 ;;   (interactive)
 864 ;;   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))
 865
 866 (defun vc-bzr-shelve-apply-at-point ()
 867   (interactive)
 868   (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))
 869
 870 (defun vc-bzr-shelve-menu (e)
 871   (interactive "e")
 872   (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
 873
 874 ;;; Revision completion
 875
 876 (eval-and-compile
 877   (defconst vc-bzr-revision-keywords
 878     '("revno" "revid" "last" "before"
 879       "tag" "date" "ancestor" "branch" "submit")))
 880
 881 (defun vc-bzr-revision-completion-table (files)
 882   (lexical-let ((files files))
 883     ;; What about using `files'?!?  --Stef
 884     (lambda (string pred action)
 885       (cond
 886        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 887                       string)
 888         (completion-table-with-context (substring string 0 (match-end 0))
 889                                        'completion-file-name-table
 890                                        (substring string (match-end 0))
 891                                        ;; Dropping `pred' for no good reason.
 892                                        'file-directory-p
 893                                        action))
 894        ((string-match "\\`\\(before\\):" string)
 895         (completion-table-with-context (substring string 0 (match-end 0))
 896                                        (vc-bzr-revision-completion-table files)
 897                                        (substring string (match-end 0))
 898                                        pred
 899                                        action))
 900        ((string-match "\\`\\(tag\\):" string)
 901         (let ((prefix (substring string 0 (match-end 0)))
 902               (tag (substring string (match-end 0)))
 903               (table nil)
 904               process-file-side-effects)
 905           (with-temp-buffer
 906             ;; "bzr-1.2 tags" is much faster with --show-ids.
 907             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
 908             ;; The output is ambiguous, unless we assume that revids do not
 909             ;; contain spaces.
 910             (goto-char (point-min))
 911             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 912               (push (match-string-no-properties 1) table)))
 913           (completion-table-with-context prefix table tag pred action)))
 914
 915        ((string-match "\\`\\([a-z]+\\):" string)
 916         ;; no actual completion for the remaining keywords.
 917         (completion-table-with-context (substring string 0 (match-end 0))
 918                                        (if (member (match-string 1 string)
 919                                                    vc-bzr-revision-keywords)
 920                                            ;; If it's a valid keyword,
 921                                            ;; use a non-empty table to
 922                                            ;; indicate it.
 923                                            '("") nil)
 924                                        (substring string (match-end 0))
 925                                        pred
 926                                        action))
 927        (t
 928         ;; Could use completion-table-with-terminator, except that it
 929         ;; currently doesn't work right w.r.t pcm and doesn't give
 930         ;; the *Completions* output we want.
 931         (complete-with-action action (eval-when-compile
 932                                        (mapcar (lambda (s) (concat s ":"))
 933                                                vc-bzr-revision-keywords))
 934                               string pred))))))
 935
 936 (eval-after-load "vc"
 937   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 938
 939 (provide 'vc-bzr)
 940 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 941 ;;; vc-bzr.el ends here