lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985, 1986, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file is autoloaded to handle certain conditions
  27 ;; detected by the file-locking code within Emacs.
  28 ;; The two entry points are `ask-user-about-lock' and
  29 ;; `ask-user-about-supersession-threat'.
  30
  31 ;;; Code:
  32
  33 (put 'file-locked 'error-conditions '(file-locked file-error error))
  34 (put 'file-locked 'error-message "File is locked")
  35
  36 ;;;###autoload
  37 (defun ask-user-about-lock (file opponent)
  38   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  39 This function has a choice of three things to do:
  40   do (signal 'file-locked (list FILE OPPONENT))
  41     to refrain from editing the file
  42   return t (grab the lock on the file)
  43   return nil (edit the file even though it is locked).
  44 You can redefine this function to choose among those three alternatives
  45 in any way you like."
  46   (discard-input)
  47   (save-window-excursion
  48     (let (answer short-opponent short-file)
  49       (setq short-file
  50             (if (> (length file) 22)
  51                 (concat "..." (substring file (- (length file) 22)))
  52               file))
  53       (setq short-opponent
  54             (if (> (length opponent) 25)
  55                 (save-match-data
  56                   (string-match " (pid [0-9]+)" opponent)
  57                   (concat (substring opponent 0 13) "..."
  58                           (match-string 0 opponent)))
  59               opponent))
  60       (while (null answer)
  61         (message "%s locked by %s: (s, q, p, ?)? "
  62                  short-file short-opponent)
  63         (let ((tem (let ((inhibit-quit t)
  64                          (cursor-in-echo-area t))
  65                      (prog1 (downcase (read-char))
  66                             (setq quit-flag nil)))))
  67           (if (= tem help-char)
  68               (ask-user-about-lock-help)
  69             (setq answer (assoc tem '((?s . t)
  70                                       (?q . yield)
  71                                       (?\C-g . yield)
  72                                       (?p . nil)
  73                                       (?? . help))))
  74             (cond ((null answer)
  75                    (beep)
  76                    (message "Please type q, s, or p; or ? for help")
  77                    (sit-for 3))
  78                   ((eq (cdr answer) 'help)
  79                    (ask-user-about-lock-help)
  80                    (setq answer nil))
  81                   ((eq (cdr answer) 'yield)
  82                    (signal 'file-locked (list file opponent)))))))
  83       (cdr answer))))
  84
  85 (defun ask-user-about-lock-help ()
  86   (with-output-to-temp-buffer "*Help*"
  87     (princ "It has been detected that you want to modify a file that someone else has
  88 already started modifying in Emacs.
  89
  90 You can <s>teal the file; the other user becomes the
  91   intruder if (s)he ever unmodifies the file and then changes it again.
  92 You can <p>roceed; you edit at your own (and the other user's) risk.
  93 You can <q>uit; don't modify this file.")
  94     (with-current-buffer standard-output
  95       (help-mode))))
  96
  97 (put
  98  'file-supersession 'error-conditions '(file-supersession file-error error))
  99
 100 ;;;###autoload
 101 (defun ask-user-about-supersession-threat (fn)
 102   "Ask a user who is about to modify an obsolete buffer what to do.
 103 This function has two choices: it can return, in which case the modification
 104 of the buffer will proceed, or it can (signal 'file-supersession (file)),
 105 in which case the proposed buffer modification will not be made.
 106
 107 You can rewrite this to use any criterion you like to choose which one to do.
 108 The buffer in question is current when this function is called."
 109   (discard-input)
 110   (save-window-excursion
 111     (let (answer)
 112       (while (null answer)
 113         (message "%s changed on disk; really edit the buffer? (y, n, r or C-h) "
 114                  (file-name-nondirectory fn))
 115         (let ((tem (downcase (let ((cursor-in-echo-area t))
 116                                (read-char-exclusive)))))
 117           (setq answer
 118                 (if (= tem help-char)
 119                     'help
 120                   (cdr (assoc tem '((?n . yield)
 121                                     (?\C-g . yield)
 122                                     (?y . proceed)
 123                                     (?r . revert)
 124                                     (?? . help))))))
 125           (cond ((null answer)
 126                  (beep)
 127                  (message "Please type y, n or r; or ? for help")
 128                  (sit-for 3))
 129                 ((eq answer 'help)
 130                  (ask-user-about-supersession-help)
 131                  (setq answer nil))
 132                 ((eq answer 'revert)
 133                  (revert-buffer nil (not (buffer-modified-p)))
 134                                         ; ask confirmation if buffer modified
 135                  (signal 'file-supersession
 136                          (list "File reverted" fn)))
 137                 ((eq answer 'yield)
 138                  (signal 'file-supersession
 139                          (list "File changed on disk" fn))))))
 140       (message
 141         "File on disk now will become a backup file if you save these changes.")
 142       (setq buffer-backed-up nil))))
 143
 144 (defun ask-user-about-supersession-help ()
 145   (with-output-to-temp-buffer "*Help*"
 146     (princ "You want to modify a buffer whose disk file has changed
 147 since you last read it in or saved it with this buffer.
 148
 149 If you say `y' to go ahead and modify this buffer,
 150 you risk ruining the work of whoever rewrote the file.
 151 If you say `r' to revert, the contents of the buffer are refreshed
 152 from the file on disk.
 153 If you say `n', the change you started to make will be aborted.
 154
 155 Usually, you should type `n' and then `M-x revert-buffer',
 156 to get the latest version of the file, then make the change again.")
 157     (with-current-buffer standard-output
 158       (help-mode))))
 159
 160 ;; arch-tag: a61c5b60-e1c8-44fd-894a-c617f4dfc639
 161 ;;; userlock.el ends here