lisp/cus-dep.el

   1 ;;; cus-dep.el --- find customization dependencies
   2 ;;
   3 ;; Copyright (C) 1997 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (require 'widget)
  31 (require 'cus-face)
  32
  33 (defvar generated-custom-dependencies-file "cus-load.el"
  34   "File \\[cusom-make-dependencies] puts custom dependencies into.")
  35
  36 (defun custom-make-dependencies ()
  37   "Batch function to extract custom dependencies from .el files.
  38 Usage: emacs -batch -l ./cus-dep.el -f custom-make-dependencies DIRS"
  39   (let ((enable-local-eval nil))
  40     (set-buffer (get-buffer-create " cus-dep temp"))
  41     (dolist (subdir command-line-args-left)
  42       (message "Directory %s" subdir)
  43       (let ((files (directory-files subdir nil "\\`[^=].*\\.el\\'"))
  44             (default-directory (expand-file-name subdir))
  45             (preloaded (concat "\\`"
  46                                (regexp-opt (mapcar
  47                                             (lambda (f)
  48                                               (file-name-sans-extension
  49                                                (file-name-nondirectory f)))
  50                                             preloaded-file-list) t)
  51                                "\\.el\\'")))
  52         (dolist (file files)
  53           (when (and (file-exists-p file)
  54                      ;; Ignore files that are preloaded.
  55                      (not (string-match preloaded file)))
  56             (erase-buffer)
  57             (insert-file-contents file)
  58             (goto-char (point-min))
  59             (string-match "\\`\\(.*\\)\\.el\\'" file)
  60             (let ((name (file-name-nondirectory (match-string 1 file)))
  61                   (load-file-name file))
  62               (if (save-excursion
  63                     (re-search-forward
  64                      (concat "(provide[ \t\n]+\\('\\|(quote[ \t\n]\\)[ \t\n]*"
  65                              (regexp-quote name) "[ \t\n)]")
  66                      nil t))
  67                   (setq name (intern name)))
  68               (condition-case nil
  69                   (while (re-search-forward
  70                           "^(def\\(custom\\|face\\|group\\)" nil t)
  71                     (beginning-of-line)
  72                     (let ((expr (read (current-buffer))))
  73                       (condition-case nil
  74                           (let ((custom-dont-initialize t))
  75                             (eval expr)
  76                             (put (nth 1 expr) 'custom-where name))
  77                         (error nil))))
  78                 (error nil))))))))
  79   (message "Generating %s..." generated-custom-dependencies-file)
  80   (set-buffer (find-file-noselect generated-custom-dependencies-file))
  81   (erase-buffer)
  82   (insert "\
  83 ;;; " (file-name-nondirectory generated-custom-dependencies-file)
  84       " --- automatically extracted custom dependencies
  85 ;;
  86 ;;; Code:
  87
  88 ")
  89   (mapatoms (lambda (symbol)
  90               (let ((members (get symbol 'custom-group))
  91                     item where found)
  92                 (when members
  93                   ;; So x and no-x builds won't differ.
  94                   (setq members
  95                         (sort (copy-sequence members)
  96                               (lambda (x y) (string< (car x) (car y)))))
  97                   (while members
  98                     (setq item (car (car members))
  99                           members (cdr members)
 100                           where (get item 'custom-where))
 101                     (unless (or (null where)
 102                                 (member where found))
 103                       (if found
 104                           (insert " ")
 105                         (insert "(put '" (symbol-name symbol)
 106                                 " 'custom-loads '("))
 107                       (prin1 where (current-buffer))
 108                       (push where found)))
 109                   (when found
 110                     (insert "))\n"))))))
 111   (insert "\
 112 ;;; These are for handling :version.  We need to have a minimum of
 113 ;;; information so `customize-changed-options' could do its job.
 114
 115 ;;; For groups we set `custom-version', `group-documentation' and
 116 ;;; `custom-tag' (which are shown in the customize buffer), so we
 117 ;;; don't have to load the file containing the group.
 118
 119 ;;; `custom-versions-load-alist' is an alist that has as car a version
 120 ;;; number and as elts the files that have variables or faces that
 121 ;;; contain that version. These files should be loaded before showing
 122 ;;; the customization buffer that `customize-changed-options'
 123 ;;; generates.
 124
 125 ;;; This macro is used so we don't modify the information about
 126 ;;; variables and groups if it's already set. (We don't know when
 127 ;;; " (file-name-nondirectory generated-custom-dependencies-file)
 128       " is going to be loaded and at that time some of the
 129 ;;; files might be loaded and some others might not).
 130 \(defmacro custom-put-if-not (symbol propname value)
 131   `(unless (get ,symbol ,propname)
 132      (put ,symbol ,propname ,value)))
 133
 134 ")
 135   (let ((version-alist nil))
 136     (mapatoms (lambda (symbol)
 137                 (let ((version (get symbol 'custom-version))
 138                       where)
 139                   (when version
 140                     (setq where (get symbol 'custom-where))
 141                     (when where
 142                       (if (or (custom-variable-p symbol)
 143                               (custom-facep symbol))
 144                           ;; This means it's a variable or a face.
 145                           (progn
 146                             (if (assoc version version-alist)
 147                                 (unless
 148                                     (member where
 149                                             (cdr (assoc version version-alist)))
 150                                   (push where (cdr (assoc version version-alist))))
 151                               (push (cons version (list where)) version-alist)))
 152                         ;; This is a group
 153                         (insert "(custom-put-if-not '" (symbol-name symbol)
 154                                 " 'custom-version ")
 155                         (prin1 version (current-buffer))
 156                         (insert ")\n")
 157                         (insert "(custom-put-if-not '" (symbol-name symbol))
 158                         (insert " 'group-documentation ")
 159                         (prin1 (get symbol 'group-documentation) (current-buffer))
 160                         (insert ")\n")
 161                         (when (get symbol 'custom-tag)
 162                           (insert "(custom-put-if-not '" (symbol-name symbol))
 163                           (insert " 'custom-tag ")
 164                           (prin1 (get symbol 'custom-tag) (current-buffer))
 165                           (insert ")\n"))
 166                         ))))))
 167
 168     (insert "\n(defvar custom-versions-load-alist "
 169             (if version-alist "'" ""))
 170     (prin1 version-alist (current-buffer))
 171     (insert "\n \"For internal use by custom.\")\n"))
 172
 173   (insert "\
 174
 175 \(provide '" (file-name-sans-extension
 176               (file-name-nondirectory generated-custom-dependencies-file)) ")
 177
 178 ;;; Local Variables:
 179 ;;; version-control: never
 180 ;;; no-byte-compile: t
 181 ;;; no-update-autoloads: t
 182 ;;; End:
 183 ;;; " (file-name-nondirectory generated-custom-dependencies-file) " ends here\n")
 184   (let ((kept-new-versions 10000000))
 185     (save-buffer))
 186   (message "Generating %s...done" generated-custom-dependencies-file)
 187   (kill-emacs))
 188
 189 \f
 190
 191 ;;; arch-tag: b7b6421a-bf7a-44fd-a382-6f44976bdf68
 192 ;;; cus-dep.el ends here