lisp/ruler-mode.el

   1 ;;; ruler-mode.el --- display a ruler in the header line
   2
   3 ;; Copyright (C) 2001-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: David Ponce <david@dponce.com>
   6 ;; Maintainer: David Ponce <david@dponce.com>
   7 ;; Created: 24 Mar 2001
   8 ;; Version: 1.6
   9 ;; Keywords: convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This library provides a minor mode to display a ruler in the header
  29 ;; line.  It works from Emacs 21 onwards.
  30 ;;
  31 ;; You can use the mouse to change the `fill-column' `comment-column',
  32 ;; `goal-column', `window-margins' and `tab-stop-list' settings:
  33 ;;
  34 ;; [header-line (shift down-mouse-1)] set left margin end to the ruler
  35 ;; graduation where the mouse pointer is on.
  36 ;;
  37 ;; [header-line (shift down-mouse-3)] set right margin beginning to
  38 ;; the ruler graduation where the mouse pointer is on.
  39 ;;
  40 ;; [header-line down-mouse-2] Drag the `fill-column', `comment-column'
  41 ;; or `goal-column' to a ruler graduation.
  42 ;;
  43 ;; [header-line (control down-mouse-1)] add a tab stop to the ruler
  44 ;; graduation where the mouse pointer is on.
  45 ;;
  46 ;; [header-line (control down-mouse-3)] remove the tab stop at the
  47 ;; ruler graduation where the mouse pointer is on.
  48 ;;
  49 ;; [header-line (control down-mouse-2)] or M-x
  50 ;; `ruler-mode-toggle-show-tab-stops' toggle showing and visually
  51 ;; editing `tab-stop-list' setting.  The `ruler-mode-show-tab-stops'
  52 ;; option controls if the ruler shows tab stops by default.
  53 ;;
  54 ;; In the ruler the character `ruler-mode-current-column-char' shows
  55 ;; the `current-column' location, `ruler-mode-fill-column-char' shows
  56 ;; the `fill-column' location, `ruler-mode-comment-column-char' shows
  57 ;; the `comment-column' location, `ruler-mode-goal-column-char' shows
  58 ;; the `goal-column' and `ruler-mode-tab-stop-char' shows tab stop
  59 ;; locations.  Graduations in `window-margins' and `window-fringes'
  60 ;; areas are shown with a different foreground color.
  61 ;;
  62 ;; It is also possible to customize the following characters:
  63 ;;
  64 ;; - `ruler-mode-basic-graduation-char' character used for basic
  65 ;;   graduations ('.' by default).
  66 ;; - `ruler-mode-inter-graduation-char' character used for
  67 ;;   intermediate graduations ('!' by default).
  68 ;;
  69 ;; The following faces are customizable:
  70 ;;
  71 ;; - `ruler-mode-default' the ruler default face.
  72 ;; - `ruler-mode-fill-column' the face used to highlight the
  73 ;;   `fill-column' character.
  74 ;; - `ruler-mode-comment-column' the face used to highlight the
  75 ;;   `comment-column' character.
  76 ;; - `ruler-mode-goal-column' the face used to highlight the
  77 ;;   `goal-column' character.
  78 ;; - `ruler-mode-current-column' the face used to highlight the
  79 ;;   `current-column' character.
  80 ;; - `ruler-mode-tab-stop' the face used to highlight tab stop
  81 ;;   characters.
  82 ;; - `ruler-mode-margins' the face used to highlight graduations
  83 ;;   in the `window-margins' areas.
  84 ;; - `ruler-mode-fringes' the face used to highlight graduations
  85 ;;   in the `window-fringes' areas.
  86 ;; - `ruler-mode-column-number' the face used to highlight the
  87 ;;   numbered graduations.
  88 ;;
  89 ;; `ruler-mode-default' inherits from the built-in `default' face.
  90 ;; All `ruler-mode' faces inherit from `ruler-mode-default'.
  91 ;;
  92 ;; WARNING: To keep ruler graduations aligned on text columns it is
  93 ;; important to use the same font family and size for ruler and text
  94 ;; areas.
  95 ;;
  96 ;; You can override the ruler format by defining an appropriate
  97 ;; function as the buffer-local value of `ruler-mode-ruler-function'.
  98
  99 ;; Installation
 100 ;;
 101 ;; To automatically display the ruler in specific major modes use:
 102 ;;
 103 ;;    (add-hook '<major-mode>-hook 'ruler-mode)
 104 ;;
 105
 106 ;;; History:
 107 ;;
 108 \f
 109 ;;; Code:
 110 (eval-when-compile
 111   (require 'wid-edit))
 112 (require 'scroll-bar)
 113 (require 'fringe)
 114
 115 (defgroup ruler-mode nil
 116   "Display a ruler in the header line."
 117   :version "22.1"
 118   :group 'convenience)
 119
 120 (defcustom ruler-mode-show-tab-stops nil
 121   "If non-nil the ruler shows tab stop positions.
 122 Also allowing to visually change `tab-stop-list' setting using
 123 <C-down-mouse-1> and <C-down-mouse-3> on the ruler to respectively add
 124 or remove a tab stop.  \\[ruler-mode-toggle-show-tab-stops] or
 125 <C-down-mouse-2> on the ruler toggles showing/editing of tab stops."
 126   :group 'ruler-mode
 127   :type 'boolean)
 128
 129 ;; IMPORTANT: This function must be defined before the following
 130 ;; defcustoms because it is used in their :validate clause.
 131 (defun ruler-mode-character-validate (widget)
 132   "Ensure WIDGET value is a valid character value."
 133   (save-excursion
 134     (let ((value (widget-value widget)))
 135       (unless (characterp value)
 136         (widget-put widget :error
 137                     (format "Invalid character value: %S" value))
 138         widget))))
 139
 140 (defcustom ruler-mode-fill-column-char (if (char-displayable-p ?¶)
 141                                            ?\¶
 142                                          ?\|)
 143   "Character used at the `fill-column' location."
 144   :group 'ruler-mode
 145   :type '(choice
 146           (character :tag "Character")
 147           (integer :tag "Integer char value"
 148                    :validate ruler-mode-character-validate)))
 149
 150 (defcustom ruler-mode-comment-column-char ?\#
 151   "Character used at the `comment-column' location."
 152   :group 'ruler-mode
 153   :type '(choice
 154           (character :tag "Character")
 155           (integer :tag "Integer char value"
 156                    :validate ruler-mode-character-validate)))
 157
 158 (defcustom ruler-mode-goal-column-char ?G
 159   "Character used at the `goal-column' location."
 160   :group 'ruler-mode
 161   :type '(choice
 162           (character :tag "Character")
 163           (integer :tag "Integer char value"
 164                    :validate ruler-mode-character-validate)))
 165
 166 (defcustom ruler-mode-current-column-char (if (char-displayable-p ?¦)
 167                                               ?\¦
 168                                             ?\@)
 169   "Character used at the `current-column' location."
 170   :group 'ruler-mode
 171   :type '(choice
 172           (character :tag "Character")
 173           (integer :tag "Integer char value"
 174                    :validate ruler-mode-character-validate)))
 175
 176 (defcustom ruler-mode-tab-stop-char ?\T
 177   "Character used at `tab-stop-list' locations."
 178   :group 'ruler-mode
 179   :type '(choice
 180           (character :tag "Character")
 181           (integer :tag "Integer char value"
 182                    :validate ruler-mode-character-validate)))
 183
 184 (defcustom ruler-mode-basic-graduation-char ?\.
 185   "Character used for basic graduations."
 186   :group 'ruler-mode
 187   :type '(choice
 188           (character :tag "Character")
 189           (integer :tag "Integer char value"
 190                    :validate ruler-mode-character-validate)))
 191
 192 (defcustom ruler-mode-inter-graduation-char ?\!
 193   "Character used for intermediate graduations."
 194   :group 'ruler-mode
 195   :type '(choice
 196           (character :tag "Character")
 197           (integer :tag "Integer char value"
 198                    :validate ruler-mode-character-validate)))
 199
 200 (defcustom ruler-mode-set-goal-column-ding-flag t
 201   "Non-nil means do `ding' when `goal-column' is set."
 202   :group 'ruler-mode
 203   :type 'boolean)
 204 \f
 205 (defface ruler-mode-default
 206   '((((type tty))
 207      (:inherit default
 208                :background "grey64"
 209                :foreground "grey50"
 210                ))
 211     (t
 212      (:inherit default
 213                :background "grey76"
 214                :foreground "grey64"
 215                :box (:color "grey76"
 216                             :line-width 1
 217                             :style released-button)
 218                )))
 219   "Default face used by the ruler."
 220   :group 'ruler-mode)
 221
 222 (defface ruler-mode-pad
 223   '((((type tty))
 224      (:inherit ruler-mode-default
 225                :background "grey50"
 226                ))
 227     (t
 228      (:inherit ruler-mode-default
 229                :background "grey64"
 230                )))
 231   "Face used to pad inactive ruler areas."
 232   :group 'ruler-mode)
 233
 234 (defface ruler-mode-margins
 235   '((t
 236      (:inherit ruler-mode-default
 237                :foreground "white"
 238                )))
 239   "Face used to highlight margin areas."
 240   :group 'ruler-mode)
 241
 242 (defface ruler-mode-fringes
 243   '((t
 244      (:inherit ruler-mode-default
 245                :foreground "green"
 246                )))
 247   "Face used to highlight fringes areas."
 248   :group 'ruler-mode)
 249
 250 (defface ruler-mode-column-number
 251   '((t
 252      (:inherit ruler-mode-default
 253                :foreground "black"
 254                )))
 255   "Face used to highlight number graduations."
 256   :group 'ruler-mode)
 257
 258 (defface ruler-mode-fill-column
 259   '((t
 260      (:inherit ruler-mode-default
 261                :foreground "red"
 262                )))
 263   "Face used to highlight the fill column character."
 264   :group 'ruler-mode)
 265
 266 (defface ruler-mode-comment-column
 267   '((t
 268      (:inherit ruler-mode-default
 269                :foreground "red"
 270                )))
 271   "Face used to highlight the comment column character."
 272   :group 'ruler-mode)
 273
 274 (defface ruler-mode-goal-column
 275   '((t
 276      (:inherit ruler-mode-default
 277                :foreground "red"
 278                )))
 279   "Face used to highlight the goal column character."
 280   :group 'ruler-mode)
 281
 282 (defface ruler-mode-tab-stop
 283   '((t
 284      (:inherit ruler-mode-default
 285                :foreground "steelblue"
 286                )))
 287   "Face used to highlight tab stop characters."
 288   :group 'ruler-mode)
 289
 290 (defface ruler-mode-current-column
 291   '((t
 292      (:inherit ruler-mode-default
 293                :weight bold
 294                :foreground "yellow"
 295                )))
 296   "Face used to highlight the `current-column' character."
 297   :group 'ruler-mode)
 298 \f
 299
 300 (defsubst ruler-mode-full-window-width ()
 301   "Return the full width of the selected window."
 302   (let ((edges (window-edges)))
 303     (- (nth 2 edges) (nth 0 edges))))
 304
 305 (defsubst ruler-mode-window-col (n)
 306   "Return a column number relative to the selected window.
 307 N is a column number relative to selected frame."
 308   (- n
 309      (or (car (window-margins)) 0)
 310      (fringe-columns 'left)
 311      (scroll-bar-columns 'left)))
 312 \f
 313 (defun ruler-mode-mouse-set-left-margin (start-event)
 314   "Set left margin end to the graduation where the mouse pointer is on.
 315 START-EVENT is the mouse click event."
 316   (interactive "e")
 317   (let* ((start (event-start start-event))
 318          (end   (event-end   start-event))
 319          col w lm rm)
 320     (when (eq start end) ;; mouse click
 321       (save-selected-window
 322         (select-window (posn-window start))
 323         (setq col (- (car (posn-col-row start))
 324                      (scroll-bar-columns 'left))
 325               w   (- (ruler-mode-full-window-width)
 326                      (scroll-bar-columns 'left)
 327                      (scroll-bar-columns 'right)))
 328         (when (and (>= col 0) (< col w))
 329           (setq lm (window-margins)
 330                 rm (or (cdr lm) 0)
 331                 lm (or (car lm) 0))
 332           (message "Left margin set to %d (was %d)" col lm)
 333           (set-window-margins nil col rm))))))
 334
 335 (defun ruler-mode-mouse-set-right-margin (start-event)
 336   "Set right margin beginning to the graduation where the mouse pointer is on.
 337 START-EVENT is the mouse click event."
 338   (interactive "e")
 339   (let* ((start (event-start start-event))
 340          (end   (event-end   start-event))
 341          col w lm rm)
 342     (when (eq start end) ;; mouse click
 343       (save-selected-window
 344         (select-window (posn-window start))
 345         (setq col (- (car (posn-col-row start))
 346                      (scroll-bar-columns 'left))
 347               w   (- (ruler-mode-full-window-width)
 348                      (scroll-bar-columns 'left)
 349                      (scroll-bar-columns 'right)))
 350         (when (and (>= col 0) (< col w))
 351           (setq lm  (window-margins)
 352                 rm  (or (cdr lm) 0)
 353                 lm  (or (car lm) 0)
 354                 col (- w col 1))
 355           (message "Right margin set to %d (was %d)" col rm)
 356           (set-window-margins nil lm col))))))
 357
 358 (defvar ruler-mode-dragged-symbol nil
 359   "Column symbol dragged in the ruler.
 360 That is `fill-column', `comment-column', `goal-column', or nil when
 361 nothing is dragged.")
 362
 363 (defun ruler-mode-text-scaled-width (width)
 364   "Compute scaled text width according to current font scaling.
 365 Convert a width of char units into a text-scaled char width units,
 366 Ex. `window-hscroll'."
 367   (/ (* width (frame-char-width)) (default-font-width)))
 368
 369 (defun ruler-mode-text-scaled-window-hscroll ()
 370   "Text scaled `window-hscroll'."
 371   (ruler-mode-text-scaled-width (window-hscroll)))
 372
 373 (defun ruler-mode-text-scaled-window-width ()
 374   "Text scaled `window-width'."
 375   (ruler-mode-text-scaled-width (window-width)))
 376
 377 (defun ruler-mode-mouse-grab-any-column (start-event)
 378   "Drag a column symbol on the ruler.
 379 Start dragging on mouse down event START-EVENT, and update the column
 380 symbol value with the current value of the ruler graduation while
 381 dragging.  See also the variable `ruler-mode-dragged-symbol'."
 382   (interactive "e")
 383   (setq ruler-mode-dragged-symbol nil)
 384   (let* ((start (event-start start-event))
 385          col newc oldc)
 386     (save-selected-window
 387       (select-window (posn-window start))
 388       (setq col  (ruler-mode-window-col (car (posn-col-row start)))
 389             newc (+ col (ruler-mode-text-scaled-window-hscroll)))
 390       (and
 391        (>= col 0) (< col (ruler-mode-text-scaled-window-width))
 392        (cond
 393
 394         ;; Handle the fill column.
 395         ((eq newc fill-column)
 396          (setq oldc fill-column
 397                ruler-mode-dragged-symbol 'fill-column)
 398          t) ;; Start dragging
 399
 400         ;; Handle the comment column.
 401         ((eq newc comment-column)
 402          (setq oldc comment-column
 403                ruler-mode-dragged-symbol 'comment-column)
 404          t) ;; Start dragging
 405
 406         ;; Handle the goal column.
 407         ;; A. On mouse down on the goal column character on the ruler,
 408         ;;    update the `goal-column' value while dragging.
 409         ;; B. If `goal-column' is nil, set the goal column where the
 410         ;;    mouse is clicked.
 411         ;; C. On mouse click on the goal column character on the
 412         ;;    ruler, unset the goal column.
 413         ((eq newc goal-column)          ; A. Drag the goal column.
 414          (setq oldc goal-column
 415                ruler-mode-dragged-symbol 'goal-column)
 416          t) ;; Start dragging
 417
 418         ((null goal-column)             ; B. Set the goal column.
 419          (setq oldc goal-column
 420                goal-column newc)
 421          ;; mouse-2 coming AFTER drag-mouse-2 invokes `ding'.  This
 422          ;; `ding' flushes the next messages about setting goal
 423          ;; column.  So here I force fetch the event(mouse-2) and
 424          ;; throw away.
 425          (read-event)
 426          ;; Ding BEFORE `message' is OK.
 427          (when ruler-mode-set-goal-column-ding-flag
 428            (ding))
 429          (message "Goal column set to %d (click on %s again to unset it)"
 430                   newc
 431                   (propertize (char-to-string ruler-mode-goal-column-char)
 432                               'face 'ruler-mode-goal-column))
 433          nil) ;; Don't start dragging.
 434         )
 435        (if (eq 'click (ruler-mode-mouse-drag-any-column-iteration
 436                        (posn-window start)))
 437            (when (eq 'goal-column ruler-mode-dragged-symbol)
 438              ;; C. Unset the goal column.
 439              (set-goal-column t))
 440          ;; At end of dragging, report the updated column symbol.
 441          (message "%s is set to %d (was %d)"
 442                   ruler-mode-dragged-symbol
 443                   (symbol-value ruler-mode-dragged-symbol)
 444                   oldc))))))
 445
 446 (defun ruler-mode-mouse-drag-any-column-iteration (window)
 447   "Update the ruler while dragging the mouse.
 448 WINDOW is the window where occurred the last down-mouse event.
 449 Return the symbol `drag' if the mouse has been dragged, or `click' if
 450 the mouse has been clicked."
 451   (let ((drags 0)
 452         event)
 453     (track-mouse
 454       ;; Signal the display engine to freeze the mouse pointer shape.
 455       (setq track-mouse 'dragging)
 456       (while (mouse-movement-p (setq event (read-event)))
 457         (setq drags (1+ drags))
 458         (when (eq window (posn-window (event-end event)))
 459           (ruler-mode-mouse-drag-any-column event)
 460           (force-mode-line-update))))
 461     (if (and (zerop drags) (eq 'click (car (event-modifiers event))))
 462         'click
 463       'drag)))
 464
 465 (defun ruler-mode-mouse-drag-any-column (start-event)
 466   "Update the value of the symbol dragged on the ruler.
 467 Called on each mouse motion event START-EVENT."
 468   (let* ((start (event-start start-event))
 469          (end   (event-end   start-event))
 470          col newc)
 471     (save-selected-window
 472       (select-window (posn-window start))
 473       (setq col  (ruler-mode-window-col (car (posn-col-row end)))
 474             newc (+ col (ruler-mode-text-scaled-window-hscroll)))
 475       (when (and (>= col 0) (< col (ruler-mode-text-scaled-window-width)))
 476         (set ruler-mode-dragged-symbol newc)))))
 477 \f
 478 (defun ruler-mode-mouse-add-tab-stop (start-event)
 479   "Add a tab stop to the graduation where the mouse pointer is on.
 480 START-EVENT is the mouse click event."
 481   (interactive "e")
 482   (when ruler-mode-show-tab-stops
 483     (let* ((start (event-start start-event))
 484            (end   (event-end   start-event))
 485            col ts)
 486       (when (eq start end) ;; mouse click
 487         (save-selected-window
 488           (select-window (posn-window start))
 489           (setq col (ruler-mode-window-col (car (posn-col-row start)))
 490                 ts  (+ col (ruler-mode-text-scaled-window-hscroll)))
 491           (and (>= col 0) (< col (ruler-mode-text-scaled-window-width))
 492                (not (member ts tab-stop-list))
 493                (progn
 494                  (message "Tab stop set to %d" ts)
 495                  (when (null tab-stop-list)
 496                    (setq tab-stop-list (indent-accumulate-tab-stops (1- ts))))
 497                  (setq tab-stop-list (sort (cons ts tab-stop-list) #'<)))))))))
 498
 499 (defun ruler-mode-mouse-del-tab-stop (start-event)
 500   "Delete tab stop at the graduation where the mouse pointer is on.
 501 START-EVENT is the mouse click event."
 502   (interactive "e")
 503   (when ruler-mode-show-tab-stops
 504     (let* ((start (event-start start-event))
 505            (end   (event-end   start-event))
 506            col ts)
 507       (when (eq start end) ;; mouse click
 508         (save-selected-window
 509           (select-window (posn-window start))
 510           (setq col (ruler-mode-window-col (car (posn-col-row start)))
 511                 ts  (+ col (ruler-mode-text-scaled-window-hscroll)))
 512           (and (>= col 0) (< col (ruler-mode-text-scaled-window-width))
 513                (member ts tab-stop-list)
 514                (progn
 515                  (message "Tab stop at %d deleted" ts)
 516                  (setq tab-stop-list (delete ts tab-stop-list)))))))))
 517
 518 (defun ruler-mode-toggle-show-tab-stops ()
 519   "Toggle showing of tab stops on the ruler."
 520   (interactive)
 521   (setq ruler-mode-show-tab-stops (not ruler-mode-show-tab-stops))
 522   (force-mode-line-update))
 523 \f
 524 (defvar ruler-mode-map
 525   (let ((km (make-sparse-keymap)))
 526     (define-key km [header-line down-mouse-1]
 527       #'ignore)
 528     (define-key km [header-line down-mouse-3]
 529       #'ignore)
 530     (define-key km [header-line down-mouse-2]
 531       #'ruler-mode-mouse-grab-any-column)
 532     (define-key km [header-line (shift down-mouse-1)]
 533       #'ruler-mode-mouse-set-left-margin)
 534     (define-key km [header-line (shift down-mouse-3)]
 535       #'ruler-mode-mouse-set-right-margin)
 536     (define-key km [header-line (control down-mouse-1)]
 537       #'ruler-mode-mouse-add-tab-stop)
 538     (define-key km [header-line (control down-mouse-3)]
 539       #'ruler-mode-mouse-del-tab-stop)
 540     (define-key km [header-line (control down-mouse-2)]
 541       #'ruler-mode-toggle-show-tab-stops)
 542     (define-key km [header-line (shift mouse-1)]
 543       'ignore)
 544     (define-key km [header-line (shift mouse-3)]
 545       'ignore)
 546     (define-key km [header-line (control mouse-1)]
 547       'ignore)
 548     (define-key km [header-line (control mouse-3)]
 549       'ignore)
 550     (define-key km [header-line (control mouse-2)]
 551       'ignore)
 552     km)
 553   "Keymap for ruler minor mode.")
 554
 555 (defvar ruler-mode-header-line-format-old nil
 556   "Hold previous value of `header-line-format'.")
 557
 558 (defvar ruler-mode-ruler-function 'ruler-mode-ruler
 559   "Function to call to return ruler header line format.
 560 This variable is expected to be made buffer-local by modes.")
 561
 562 (defconst ruler-mode-header-line-format
 563   '(:eval (funcall ruler-mode-ruler-function))
 564   "`header-line-format' used in ruler mode.
 565 Call `ruler-mode-ruler-function' to compute the ruler value.")
 566
 567 ;;;###autoload
 568 (defvar ruler-mode nil
 569   "Non-nil if Ruler mode is enabled.
 570 Use the command `ruler-mode' to change this variable.")
 571 (make-variable-buffer-local 'ruler-mode)
 572
 573 (defun ruler--save-header-line-format ()
 574   "Install the header line format for Ruler mode.
 575 Unless Ruler mode is already enabled, save the old header line
 576 format first."
 577   (when (and (not ruler-mode)
 578              (local-variable-p 'header-line-format)
 579              (not (local-variable-p 'ruler-mode-header-line-format-old)))
 580     (set (make-local-variable 'ruler-mode-header-line-format-old)
 581          header-line-format))
 582   (setq header-line-format ruler-mode-header-line-format))
 583
 584 ;;;###autoload
 585 (define-minor-mode ruler-mode
 586   "Toggle display of ruler in header line (Ruler mode).
 587 With a prefix argument ARG, enable Ruler mode if ARG is positive,
 588 and disable it otherwise.  If called from Lisp, enable the mode
 589 if ARG is omitted or nil."
 590   nil nil
 591   ruler-mode-map
 592   :group 'ruler-mode
 593   :variable (ruler-mode
 594              . (lambda (enable)
 595                  (when enable
 596                    (ruler--save-header-line-format))
 597                  (setq ruler-mode enable)))
 598   (if ruler-mode
 599       (add-hook 'post-command-hook 'force-mode-line-update nil t)
 600     ;; When `ruler-mode' is off restore previous header line format if
 601     ;; the current one is the ruler header line format.
 602     (when (eq header-line-format ruler-mode-header-line-format)
 603       (kill-local-variable 'header-line-format)
 604       (when (local-variable-p 'ruler-mode-header-line-format-old)
 605         (setq header-line-format ruler-mode-header-line-format-old)
 606         (kill-local-variable 'ruler-mode-header-line-format-old)))
 607     (remove-hook 'post-command-hook 'force-mode-line-update t)))
 608 \f
 609 ;; Add ruler-mode to the minor mode menu in the mode line
 610 (define-key mode-line-mode-menu [ruler-mode]
 611   `(menu-item "Ruler" ruler-mode
 612               :button (:toggle . ruler-mode)))
 613
 614 (defconst ruler-mode-ruler-help-echo
 615   "\
 616 S-mouse-1/3: set L/R margin, \
 617 mouse-2: set goal column, \
 618 C-mouse-2: show tabs"
 619   "Help string shown when mouse is over the ruler.
 620 `ruler-mode-show-tab-stops' is nil.")
 621
 622 (defconst ruler-mode-ruler-help-echo-when-goal-column
 623   "\
 624 S-mouse-1/3: set L/R margin, \
 625 C-mouse-2: show tabs"
 626   "Help string shown when mouse is over the ruler.
 627 `goal-column' is set and `ruler-mode-show-tab-stops' is nil.")
 628
 629 (defconst ruler-mode-ruler-help-echo-when-tab-stops
 630   "\
 631 C-mouse1/3: set/unset tab, \
 632 C-mouse-2: hide tabs"
 633   "Help string shown when mouse is over the ruler.
 634 `ruler-mode-show-tab-stops' is non-nil.")
 635
 636 (defconst ruler-mode-fill-column-help-echo
 637   "drag-mouse-2: set fill column"
 638   "Help string shown when mouse is on the fill column character.")
 639
 640 (defconst ruler-mode-comment-column-help-echo
 641   "drag-mouse-2: set comment column"
 642   "Help string shown when mouse is on the comment column character.")
 643
 644 (defconst ruler-mode-goal-column-help-echo
 645   "\
 646 drag-mouse-2: set goal column, \
 647 mouse-2: unset goal column"
 648   "Help string shown when mouse is on the goal column character.")
 649
 650 (defconst ruler-mode-margin-help-echo
 651   "%s margin %S"
 652   "Help string shown when mouse is over a margin area.")
 653
 654 (defconst ruler-mode-fringe-help-echo
 655   "%s fringe %S"
 656   "Help string shown when mouse is over a fringe area.")
 657
 658 (defsubst ruler-mode-space (width &rest props)
 659   "Return a single space string of WIDTH times the normal character width.
 660 Optional argument PROPS specifies other text properties to apply."
 661   (apply 'propertize " " 'display (list 'space :width width) props))
 662 \f
 663 (defun ruler-mode-ruler ()
 664   "Compute and return a header line ruler."
 665   (let* ((w (ruler-mode-text-scaled-window-width))
 666          (m (window-margins))
 667          (f (window-fringes))
 668          (i 0)
 669          (j (ruler-mode-text-scaled-window-hscroll))
 670          ;; Setup the scrollbar, fringes, and margins areas.
 671          (lf (ruler-mode-space
 672               'left-fringe
 673               'face 'ruler-mode-fringes
 674               'help-echo (format ruler-mode-fringe-help-echo
 675                                  "Left" (or (car f) 0))))
 676          (rf (ruler-mode-space
 677               'right-fringe
 678               'face 'ruler-mode-fringes
 679               'help-echo (format ruler-mode-fringe-help-echo
 680                                  "Right" (or (cadr f) 0))))
 681          (lm (ruler-mode-space
 682               'left-margin
 683               'face 'ruler-mode-margins
 684               'help-echo (format ruler-mode-margin-help-echo
 685                                  "Left" (or (car m) 0))))
 686          (rm (ruler-mode-space
 687               'right-margin
 688               'face 'ruler-mode-margins
 689               'help-echo (format ruler-mode-margin-help-echo
 690                                  "Right" (or (cdr m) 0))))
 691          (sb (ruler-mode-space
 692               'scroll-bar
 693               'face 'ruler-mode-pad))
 694          ;; Remember the scrollbar vertical type.
 695          (sbvt (car (window-current-scroll-bars)))
 696          ;; Create an "clean" ruler.
 697          (ruler
 698           (propertize
 699            (string-to-multibyte
 700             (make-string w ruler-mode-basic-graduation-char))
 701            'face 'ruler-mode-default
 702            'local-map ruler-mode-map
 703            'help-echo (cond
 704                        (ruler-mode-show-tab-stops
 705                         ruler-mode-ruler-help-echo-when-tab-stops)
 706                        (goal-column
 707                         ruler-mode-ruler-help-echo-when-goal-column)
 708                        (ruler-mode-ruler-help-echo))))
 709          k c)
 710     ;; Setup the active area.
 711     (while (< i w)
 712       ;; Graduations.
 713       (cond
 714        ;; Show a number graduation.
 715        ((= (mod j 10) 0)
 716         (setq c (number-to-string (/ j 10))
 717               m (length c)
 718               k i)
 719         (put-text-property
 720          i (1+ i) 'face 'ruler-mode-column-number
 721          ruler)
 722         (while (and (> m 0) (>= k 0))
 723           (aset ruler k (aref c (setq m (1- m))))
 724           (setq k (1- k))))
 725        ;; Show an intermediate graduation.
 726        ((= (mod j 5) 0)
 727         (aset ruler i ruler-mode-inter-graduation-char)))
 728       ;; Special columns.
 729       (cond
 730        ;; Show the `current-column' marker.
 731        ((= j (current-column))
 732         (aset ruler i ruler-mode-current-column-char)
 733         (put-text-property
 734          i (1+ i) 'face 'ruler-mode-current-column
 735          ruler))
 736        ;; Show the `goal-column' marker.
 737        ((and goal-column (= j goal-column))
 738         (aset ruler i ruler-mode-goal-column-char)
 739         (put-text-property
 740          i (1+ i) 'face 'ruler-mode-goal-column
 741          ruler)
 742         (put-text-property
 743          i (1+ i) 'mouse-face 'mode-line-highlight
 744          ruler)
 745         (put-text-property
 746          i (1+ i) 'help-echo ruler-mode-goal-column-help-echo
 747          ruler))
 748        ;; Show the `comment-column' marker.
 749        ((= j comment-column)
 750         (aset ruler i ruler-mode-comment-column-char)
 751         (put-text-property
 752          i (1+ i) 'face 'ruler-mode-comment-column
 753          ruler)
 754         (put-text-property
 755          i (1+ i) 'mouse-face 'mode-line-highlight
 756          ruler)
 757         (put-text-property
 758          i (1+ i) 'help-echo ruler-mode-comment-column-help-echo
 759          ruler))
 760        ;; Show the `fill-column' marker.
 761        ((= j fill-column)
 762         (aset ruler i ruler-mode-fill-column-char)
 763         (put-text-property
 764          i (1+ i) 'face 'ruler-mode-fill-column
 765          ruler)
 766         (put-text-property
 767          i (1+ i) 'mouse-face 'mode-line-highlight
 768          ruler)
 769         (put-text-property
 770          i (1+ i) 'help-echo ruler-mode-fill-column-help-echo
 771          ruler))
 772        ;; Show the `tab-stop-list' markers.
 773        ((and ruler-mode-show-tab-stops (= j (indent-next-tab-stop (1- j))))
 774         (aset ruler i ruler-mode-tab-stop-char)
 775         (put-text-property
 776          i (1+ i) 'face 'ruler-mode-tab-stop
 777          ruler)))
 778       (setq i (1+ i)
 779             j (1+ j)))
 780     ;; Return the ruler propertized string.  Using list here,
 781     ;; instead of concat visually separate the different areas.
 782     (if (nth 2 (window-fringes))
 783         ;; fringes outside margins.
 784         (list "" (and (eq 'left sbvt) sb) lf lm
 785               ruler rm rf (and (eq 'right sbvt) sb))
 786       ;; fringes inside margins.
 787       (list "" (and (eq 'left sbvt) sb) lm lf
 788             ruler rf rm (and (eq 'right sbvt) sb)))))
 789
 790 (provide 'ruler-mode)
 791
 792 ;;; ruler-mode.el ends here