lisp/ls-lisp.el

   1 ;;; ls-lisp.el --- emulate insert-directory completely in Emacs Lisp
   2
   3 ;; Copyright (C) 1992, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;; Modified by: Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix, dired
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; OVERVIEW ==========================================================
  30
  31 ;; This file redefines the function `insert-directory' to implement it
  32 ;; directly from Emacs lisp, without running ls in a subprocess.  It
  33 ;; is useful if you cannot afford to fork Emacs on a real memory UNIX,
  34 ;; under VMS or other non-UNIX platforms if you don't have the ls
  35 ;; program, or if you want a different format from what ls offers.
  36
  37 ;; This function can use regexps instead of shell wildcards.  If you
  38 ;; enter regexps remember to double each $ sign.  For example, to
  39 ;; include files *.el, enter `.*\.el$$', resulting in the regexp
  40 ;; `.*\.el$'.
  41
  42 ;; RESTRICTIONS ======================================================
  43
  44 ;; * A few obscure ls switches are still ignored: see the docstring of
  45 ;; `insert-directory'.
  46
  47 ;; * Generally only numeric uid/gid.
  48
  49 ;; TO DO =============================================================
  50
  51 ;; Complete handling of F switch (if/when possible).
  52
  53 ;; FJW: May be able to sort much faster by consing the sort key onto
  54 ;; the front of each list element, sorting and then stripping the key
  55 ;; off again!
  56
  57 ;;; History:
  58
  59 ;; Written originally by Sebastian Kremer <sk@thp.uni-koeln.de>
  60 ;; Revised by Andrew Innes and Geoff Volker (and maybe others).
  61
  62 ;; Modified by Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>, mainly
  63 ;; to support many more ls options, "platform emulation", hooks for
  64 ;; external symbolic link support and more robust sorting.
  65
  66 ;;; Code:
  67
  68 ;;;###autoload
  69 (defgroup ls-lisp nil
  70   "Emulate the ls program completely in Emacs Lisp."
  71   :version "21.1"
  72   :group 'dired)
  73
  74 (defcustom ls-lisp-emulation
  75   (cond ((eq system-type 'macos) 'MacOS)
  76         ;; ((eq system-type 'windows-nt) 'MS-Windows)
  77         ((memq system-type
  78                '(hpux dgux usg-unix-v unisoft-unix rtu irix berkeley-unix))
  79          'UNIX))                        ; very similar to GNU
  80   ;; Anything else defaults to nil, meaning GNU.
  81   "*Platform to emulate: GNU (default), MacOS, MS-Windows, UNIX.
  82 Corresponding value is one of the atoms: nil, MacOS, MS-Windows, UNIX.
  83 Sets default values for: `ls-lisp-ignore-case', `ls-lisp-dirs-first',
  84 `ls-lisp-verbosity'.  Need not match actual platform.  Changing this
  85 option will have no effect until you restart Emacs."
  86   :type '(choice (const :tag "GNU" nil)
  87                  (const MacOS)
  88                  (const MS-Windows)
  89                  (const UNIX))
  90   :group 'ls-lisp)
  91
  92 (defcustom ls-lisp-ignore-case
  93   ;; Name change for consistency with other option names.
  94   (or (memq ls-lisp-emulation '(MS-Windows MacOS))
  95       (and (boundp 'ls-lisp-dired-ignore-case) ls-lisp-dired-ignore-case))
  96   "*Non-nil causes ls-lisp alphabetic sorting to ignore case."
  97   :type 'boolean
  98   :group 'ls-lisp)
  99
 100 (defcustom ls-lisp-dirs-first (eq ls-lisp-emulation 'MS-Windows)
 101   "*Non-nil causes ls-lisp to sort directories first in any ordering.
 102 \(Or last if it is reversed.)  Follows Microsoft Windows Explorer."
 103   ;; Functionality suggested by Chris McMahan <cmcmahan@one.net>
 104   :type 'boolean
 105   :group 'ls-lisp)
 106
 107 (defcustom ls-lisp-verbosity
 108   (cond ((eq ls-lisp-emulation 'MacOS) nil)
 109         ((eq ls-lisp-emulation 'MS-Windows)
 110          (if (and (fboundp 'w32-using-nt) (w32-using-nt))
 111              '(links)))                 ; distinguish NT/2K from 9x
 112         ((eq ls-lisp-emulation 'UNIX) '(links uid)) ; UNIX ls
 113         (t '(links uid gid)))           ; GNU ls
 114   "*A list of optional file attributes that ls-lisp should display.
 115 It should contain none or more of the symbols: links, uid, gid.
 116 nil (or an empty list) means display none of them.
 117
 118 Concepts come from UNIX: `links' means count of names associated with
 119 the file\; `uid' means user (owner) identifier\; `gid' means group
 120 identifier.
 121
 122 If emulation is MacOS then default is nil\;
 123 if emulation is MS-Windows then default is `(links)' if platform is
 124 Windows NT/2K, nil otherwise\;
 125 if emulation is UNIX then default is `(links uid)'\;
 126 if emulation is GNU then default is `(links uid gid)'."
 127   ;; Functionality suggested by Howard Melman <howard@silverstream.com>
 128   :type '(set (const :tag "Show Link Count" links)
 129               (const :tag "Show User" uid)
 130               (const :tag "Show Group" gid))
 131   :group 'ls-lisp)
 132
 133 (defcustom ls-lisp-use-insert-directory-program nil
 134   "*Non-nil causes ls-lisp to revert back to using `insert-directory-program'.
 135 This is useful on platforms where ls-lisp is dumped into Emacs, such as
 136 Microsoft Windows, but you would still like to use a program to list
 137 the contents of a directory."
 138   :type 'boolean
 139   :group 'ls-lisp)
 140
 141 (defcustom ls-lisp-support-shell-wildcards t
 142   "*Non-nil means ls-lisp treats file patterns as shell wildcards.
 143 Otherwise they are treated as Emacs regexps (for backward compatibility)."
 144   :type 'boolean
 145   :group 'ls-lisp)
 146
 147 ;; Remember the original insert-directory function
 148 (or (featurep 'ls-lisp)  ; FJW: unless this file is being reloaded!
 149     (fset 'original-insert-directory (symbol-function 'insert-directory)))
 150
 151 ;; This stub is to allow ls-lisp to parse symbolic links via another
 152 ;; library such as w32-symlinks.el from
 153 ;; http://centaur.qmw.ac.uk/Emacs/:
 154 (defun ls-lisp-parse-symlink (file-name)
 155   "This stub may be redefined to parse FILE-NAME as a symlink.
 156 It should return nil or the link target as a string."
 157   nil)
 158
 159 \f
 160 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 161
 162 (defun insert-directory (file switches &optional wildcard full-directory-p)
 163   "Insert directory listing for FILE, formatted according to SWITCHES.
 164 Leaves point after the inserted text.
 165 SWITCHES may be a string of options, or a list of strings.
 166 Optional third arg WILDCARD means treat FILE as shell wildcard.
 167 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 168 switches do not contain `d', so that a full listing is expected.
 169
 170 This version of the function comes from `ls-lisp.el'.
 171 If the value of `ls-lisp-use-insert-directory-program' is non-nil then
 172 it works exactly like the version from `files.el' and runs a directory
 173 listing program whose name is in the variable
 174 `insert-directory-program'; if also WILDCARD is non-nil then it runs
 175 the shell specified by `shell-file-name'.  If the value of
 176 `ls-lisp-use-insert-directory-program' is nil then it runs a Lisp
 177 emulation.
 178
 179 The Lisp emulation does not run any external programs or shells.  It
 180 supports ordinary shell wildcards if `ls-lisp-support-shell-wildcards'
 181 is non-nil; otherwise, it interprets wildcards as regular expressions
 182 to match file names.  It does not support all `ls' switches -- those
 183 that work are: A a c i r S s t u U X g G B C R and F partly."
 184   (if ls-lisp-use-insert-directory-program
 185       (original-insert-directory file switches wildcard full-directory-p)
 186     ;; We need the directory in order to find the right handler.
 187     (let ((handler (find-file-name-handler (expand-file-name file)
 188                                            'insert-directory)))
 189       (if handler
 190           (funcall handler 'insert-directory file switches
 191                    wildcard full-directory-p)
 192         ;; Convert SWITCHES to a list of characters.
 193         (setq switches (delete ?- (append switches nil)))
 194         (if wildcard
 195             (setq wildcard
 196                   (if ls-lisp-support-shell-wildcards
 197                       (wildcard-to-regexp (file-name-nondirectory file))
 198                     (file-name-nondirectory file))
 199                   file (file-name-directory file))
 200           (if (memq ?B switches) (setq wildcard "[^~]\\'")))
 201         (ls-lisp-insert-directory
 202          file switches (ls-lisp-time-index switches)
 203          wildcard full-directory-p)
 204         ;; Try to insert the amount of free space.
 205         (save-excursion
 206           (goto-char (point-min))
 207           ;; First find the line to put it on.
 208           (when (re-search-forward "^total" nil t)
 209             (let ((available (get-free-disk-space ".")))
 210               (when available
 211                 ;; Replace "total" with "total used", to avoid confusion.
 212                 (replace-match "total used in directory")
 213                 (end-of-line)
 214                 (insert " available " available)))))))))
 215
 216 (defun ls-lisp-insert-directory
 217   (file switches time-index wildcard full-directory-p)
 218   "Insert directory listing for FILE, formatted according to SWITCHES.
 219 Leaves point after the inserted text.  This is an internal function
 220 optionally called by the `ls-lisp.el' version of `insert-directory'.
 221 It is called recursively if the -R switch is used.
 222 SWITCHES is a *list* of characters.  TIME-INDEX is the time index into
 223 file-attributes according to SWITCHES.  WILDCARD is nil or an *Emacs
 224 regexp*.  FULL-DIRECTORY-P means file is a directory and SWITCHES does
 225 not contain `d', so that a full listing is expected."
 226   ;; Sometimes we get ".../foo*/" as FILE.  While the shell and
 227   ;; `ls' don't mind, we certainly do, because it makes us think
 228   ;; there is no wildcard, only a directory name.
 229   (if (and ls-lisp-support-shell-wildcards
 230            (string-match "[[?*]" file))
 231       (progn
 232         (or (not (eq (aref file (1- (length file))) ?/))
 233             (setq file (substring file 0 (1- (length file)))))
 234         (setq wildcard t)))
 235   (if (or wildcard full-directory-p)
 236       (let* ((dir (file-name-as-directory file))
 237              (default-directory dir)    ; so that file-attributes works
 238              (file-alist
 239               (directory-files-and-attributes dir nil wildcard t))
 240              (now (current-time))
 241              (sum 0)
 242              ;; do all bindings here for speed
 243              total-line files elt short file-size fil attr)
 244         (cond ((memq ?A switches)
 245                (setq file-alist
 246                      (ls-lisp-delete-matching "^\\.\\.?$" file-alist)))
 247               ((not (memq ?a switches))
 248                ;; if neither -A  nor -a, flush . files
 249                (setq file-alist
 250                      (ls-lisp-delete-matching "^\\." file-alist))))
 251         (setq file-alist
 252               (ls-lisp-handle-switches file-alist switches))
 253         (if (memq ?C switches)          ; column (-C) format
 254             (ls-lisp-column-format file-alist)
 255           (setq total-line (cons (point) (car-safe file-alist)))
 256           (setq files file-alist)
 257           (while files                  ; long (-l) format
 258             (setq elt (car files)
 259                   files (cdr files)
 260                   short (car elt)
 261                   attr (cdr elt)
 262                   file-size (nth 7 attr))
 263             (and attr
 264                  (setq sum (+ file-size
 265                               ;; Even if neither SUM nor file's size
 266                               ;; overflow, their sum could.
 267                               (if (or (< sum (- 134217727 file-size))
 268                                       (floatp sum)
 269                                       (floatp file-size))
 270                                   sum
 271                                 (float sum))))
 272                  (insert (ls-lisp-format short attr file-size
 273                                          switches time-index now))))
 274           ;; Insert total size of all files:
 275           (save-excursion
 276             (goto-char (car total-line))
 277             (or (cdr total-line)
 278                 ;; Shell says ``No match'' if no files match
 279                 ;; the wildcard; let's say something similar.
 280                 (insert "(No match)\n"))
 281             (insert (format "total %.0f\n" (fceiling (/ sum 1024.0))))))
 282         (if (memq ?R switches)
 283             ;; List the contents of all directories recursively.
 284             ;; cadr of each element of `file-alist' is t for
 285             ;; directory, string (name linked to) for symbolic
 286             ;; link, or nil.
 287             (while file-alist
 288               (setq elt (car file-alist)
 289                     file-alist (cdr file-alist))
 290               (when (and (eq (cadr elt) t) ; directory
 291                          (not (string-match "\\`\\.\\.?\\'" (car elt))))
 292                 (setq elt (expand-file-name (car elt) dir))
 293                 (insert "\n" elt ":\n")
 294                 (ls-lisp-insert-directory
 295                  elt switches time-index wildcard full-directory-p)))))
 296     ;; If not full-directory-p, FILE *must not* end in /, as
 297     ;; file-attributes will not recognize a symlink to a directory,
 298     ;; so must make it a relative filename as ls does:
 299     (if (eq (aref file (1- (length file))) ?/)
 300         (setq file (substring file 0 -1)))
 301     (let ((fattr (file-attributes file)))
 302       (if fattr
 303           (insert (ls-lisp-format file fattr (nth 7 fattr)
 304                                   switches time-index (current-time)))
 305         (message "%s: doesn't exist or is inaccessible" file)
 306         (ding) (sit-for 2)))))          ; to show user the message!
 307
 308 (defun ls-lisp-column-format (file-alist)
 309   "Insert the file names (only) in FILE-ALIST into the current buffer.
 310 Format in columns, sorted vertically, following GNU ls -C.
 311 Responds to the window width as ls should but may not!"
 312   (let (files fmt ncols collen (nfiles 0) (colwid 0))
 313     ;; Count number of files as `nfiles', build list of filenames as
 314     ;; `files', and find maximum filename length as `colwid':
 315     (let (file len)
 316       (while file-alist
 317         (setq nfiles (1+ nfiles)
 318               file (caar file-alist)
 319               files (cons file files)
 320               file-alist (cdr file-alist)
 321               len (length file))
 322         (if (> len colwid) (setq colwid len))))
 323     (setq files (nreverse files)
 324           colwid (+ 2 colwid)           ; 2 character column gap
 325           fmt (format "%%-%ds" colwid)  ; print format
 326           ncols (/ (window-width) colwid) ; no of columns
 327           collen (/ nfiles ncols))      ; floor of column length
 328     (if (> nfiles (* collen ncols)) (setq collen (1+ collen)))
 329     ;; Output the file names in columns, sorted vertically:
 330     (let ((i 0) j)
 331       (while (< i collen)
 332         (setq j i)
 333         (while (< j nfiles)
 334           (insert (format fmt (nth j files)))
 335           (setq j (+ j collen)))
 336         ;; FJW: This is completely unnecessary, but I don't like
 337         ;; trailing white space...
 338         (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 339         (insert ?\n)
 340         (setq i (1+ i))))))
 341
 342 (defun ls-lisp-delete-matching (regexp list)
 343   "Delete all elements matching REGEXP from LIST, return new list."
 344   ;; Should perhaps use setcdr for efficiency.
 345   (let (result)
 346     (while list
 347       (or (string-match regexp (caar list))
 348           (setq result (cons (car list) result)))
 349       (setq list (cdr list)))
 350     result))
 351
 352 (defsubst ls-lisp-string-lessp (s1 s2)
 353   "Return t if string S1 is less than string S2 in lexicographic order.
 354 Case is significant if `ls-lisp-ignore-case' is nil.
 355 Unibyte strings are converted to multibyte for comparison."
 356   (let ((u (compare-strings s1 0 nil s2 0 nil ls-lisp-ignore-case)))
 357     (and (numberp u) (< u 0))))
 358
 359 (defun ls-lisp-handle-switches (file-alist switches)
 360   "Return new FILE-ALIST sorted according to SWITCHES.
 361 SWITCHES is a list of characters.  Default sorting is alphabetic."
 362   ;; FILE-ALIST's elements are (FILE . FILE-ATTRIBUTES).
 363   (or (memq ?U switches)                ; unsorted
 364       ;; Catch and ignore unexpected sorting errors
 365       (condition-case err
 366           (setq file-alist
 367                 (let (index)
 368                   ;; Copy file-alist in case of error
 369                   (sort (copy-sequence file-alist) ; modifies its argument!
 370                         (cond ((memq ?S switches)
 371                                (lambda (x y) ; sorted on size
 372                                  ;; 7th file attribute is file size
 373                                  ;; Make largest file come first
 374                                  (< (nth 7 (cdr y))
 375                                     (nth 7 (cdr x)))))
 376                               ((setq index (ls-lisp-time-index switches))
 377                                (lambda (x y) ; sorted on time
 378                                  (ls-lisp-time-lessp (nth index (cdr y))
 379                                                      (nth index (cdr x)))))
 380                               ((memq ?X switches)
 381                                (lambda (x y) ; sorted on extension
 382                                  (ls-lisp-string-lessp
 383                                   (ls-lisp-extension (car x))
 384                                   (ls-lisp-extension (car y)))))
 385                               (t
 386                                (lambda (x y) ; sorted alphabetically
 387                                  (ls-lisp-string-lessp (car x) (car y))))))))
 388         (error (message "Unsorted (ls-lisp sorting error) - %s"
 389                         (error-message-string err))
 390                (ding) (sit-for 2))))    ; to show user the message!
 391   (if (memq ?F switches)                ; classify switch
 392       (setq file-alist (mapcar 'ls-lisp-classify file-alist)))
 393   (if ls-lisp-dirs-first
 394   ;; Re-sort directories first, without otherwise changing the
 395   ;; ordering, and reverse whole list.  cadr of each element of
 396   ;; `file-alist' is t for directory, string (name linked to) for
 397   ;; symbolic link, or nil.
 398       (let (el dirs files)
 399         (while file-alist
 400           (if (eq (cadr (setq el (car file-alist))) t) ; directory
 401               (setq dirs (cons el dirs))
 402             (setq files (cons el files)))
 403           (setq file-alist (cdr file-alist)))
 404         (setq file-alist
 405               (if (memq ?U switches)    ; unsorted order is reversed
 406                   (nconc dirs files)
 407                 (nconc files dirs)
 408                 ))))
 409   ;; Finally reverse file alist if necessary.
 410   ;; (eq below MUST compare `(not (memq ...))' to force comparison of
 411   ;; `t' or `nil', rather than list tails!)
 412   (if (eq (eq (not (memq ?U switches))  ; unsorted order is reversed
 413               (not (memq ?r switches))) ; reversed sort order requested
 414           ls-lisp-dirs-first)           ; already reversed
 415       (nreverse file-alist)
 416     file-alist))
 417
 418 (defun ls-lisp-classify (filedata)
 419   "Append a character to each file name indicating the file type.
 420 Also, for regular files that are executable, append `*'.
 421 The file type indicators are `/' for directories, `@' for symbolic
 422 links, `|' for FIFOs, `=' for sockets, and nothing for regular files.
 423 \[But FIFOs and sockets are not recognised.]
 424 FILEDATA has the form (filename . `file-attributes').  Its `cadr' is t
 425 for directory, string (name linked to) for symbolic link, or nil."
 426   (let ((dir (cadr filedata)) (file-name (car filedata)))
 427     (cond ((or dir
 428                ;; Parsing .lnk files here is perhaps overkill!
 429                (setq dir (ls-lisp-parse-symlink file-name)))
 430            (cons
 431             (concat file-name (if (eq dir t) "/" "@"))
 432             (cdr filedata)))
 433           ((string-match "x" (nth 9 filedata))
 434            (cons
 435             (concat file-name "*")
 436             (cdr filedata)))
 437           (t filedata))))
 438
 439 (defun ls-lisp-extension (filename)
 440   "Return extension of FILENAME (ignoring any version extension)
 441 FOLLOWED by null and full filename, SOLELY for full alpha sort."
 442   ;; Force extension sort order: `no ext' then `null ext' then `ext'
 443   ;; to agree with GNU ls.
 444   (concat
 445    (let* ((i (length filename)) end)
 446      (if (= (aref filename (1- i)) ?.) ; null extension
 447          "\0"
 448        (while (and (>= (setq i (1- i)) 0)
 449                    (/= (aref filename i) ?.)))
 450        (if (< i 0) "\0\0"               ; no extension
 451          (if (/= (aref filename (1+ i)) ?~)
 452              (substring filename (1+ i))
 453            ;; version extension found -- ignore it
 454            (setq end i)
 455            (while (and (>= (setq i (1- i)) 0)
 456                        (/= (aref filename i) ?.)))
 457            (if (< i 0) "\0\0"   ; no extension
 458              (substring filename (1+ i) end))))
 459        )) "\0" filename))
 460
 461 ;; From Roland McGrath.  Can use this to sort on time.
 462 (defun ls-lisp-time-lessp (time0 time1)
 463   "Return t if time TIME0 is earlier than time TIME1."
 464   (let ((hi0 (car time0)) (hi1 (car time1)))
 465     (or (< hi0 hi1)
 466         (and (= hi0 hi1)
 467              (< (cadr time0) (cadr time1))))))
 468
 469 (defun ls-lisp-format (file-name file-attr file-size switches time-index now)
 470   "Format one line of long ls output for file FILE-NAME.
 471 FILE-ATTR and FILE-SIZE give the file's attributes and size.
 472 SWITCHES, TIME-INDEX and NOW give the full switch list and time data."
 473   (let ((file-type (nth 0 file-attr))
 474         ;; t for directory, string (name linked to)
 475         ;; for symbolic link, or nil.
 476         (drwxrwxrwx (nth 8 file-attr))) ; attribute string ("drwxrwxrwx")
 477     (and (null file-type)
 478          ;; Maybe no kernel support for symlinks, so...
 479          (setq file-type (ls-lisp-parse-symlink file-name))
 480          (aset drwxrwxrwx 0 ?l)) ; symbolic link - update attribute string
 481     (concat (if (memq ?i switches)      ; inode number
 482                 (format " %6d" (nth 10 file-attr)))
 483             ;; nil is treated like "" in concat
 484             (if (memq ?s switches)      ; size in K
 485                 (format " %4.0f" (fceiling (/ file-size 1024.0))))
 486             drwxrwxrwx                  ; attribute string
 487             (if (memq 'links ls-lisp-verbosity)
 488                 (format " %3d" (nth 1 file-attr))) ; link count
 489             ;; Numeric uid/gid are more confusing than helpful;
 490             ;; Emacs should be able to make strings of them.
 491             ;; They tend to be bogus on non-UNIX platforms anyway so
 492             ;; optionally hide them.
 493             (if (memq 'uid ls-lisp-verbosity)
 494                 ;; (user-login-name uid) works on Windows NT but not
 495                 ;; on 9x and maybe not on some other platforms, so...
 496                 (let ((uid (nth 2 file-attr)))
 497                   (if (= uid (user-uid))
 498                       (format " %-8s" (user-login-name))
 499                     (format " %-8d" uid))))
 500             (if (not (memq ?G switches)) ; GNU ls -- shows group by default
 501                 (if (or (memq ?g switches) ; UNIX ls -- no group by default
 502                         (memq 'gid ls-lisp-verbosity))
 503                     (if (memq system-type '(macos windows-nt ms-dos))
 504                         ;; No useful concept of group...
 505                         " root"
 506                       (let* ((gid (nth 3 file-attr))
 507                              (group (user-login-name gid)))
 508                         (if group
 509                             (format " %-8s" group)
 510                           (format " %-8d" gid))))))
 511             (format (if (floatp file-size) " %8.0f" " %8d") file-size)
 512             " "
 513             (ls-lisp-format-time file-attr time-index now)
 514             " "
 515             file-name
 516             (if (stringp file-type)     ; is a symbolic link
 517                 (concat " -> " file-type))
 518             "\n"
 519             )))
 520
 521 (defun ls-lisp-time-index (switches)
 522   "Return time index into file-attributes according to ls SWITCHES list.
 523 Return nil if no time switch found."
 524   ;; FJW: Default of nil is IMPORTANT and used in `ls-lisp-handle-switches'!
 525   (cond ((memq ?c switches) 6)          ; last mode change
 526         ((memq ?t switches) 5)          ; last modtime
 527         ((memq ?u switches) 4)))        ; last access
 528
 529 (defun ls-lisp-time-to-seconds (time)
 530   "Convert TIME to a floating point number."
 531   (+ (* (car time) 65536.0)
 532      (cadr time)
 533      (/ (or (nth 2 time) 0) 1000000.0)))
 534
 535 (defun ls-lisp-format-time (file-attr time-index now)
 536   "Format time for file with attributes FILE-ATTR according to TIME-INDEX.
 537 Use the same method as ls to decide whether to show time-of-day or year,
 538 depending on distance between file date and NOW.
 539 All ls time options, namely c, t and u, are handled."
 540   (let* ((time (nth (or time-index 5) file-attr)) ; default is last modtime
 541          (diff (- (ls-lisp-time-to-seconds time)
 542                   (ls-lisp-time-to-seconds now)))
 543          ;; Consider a time to be recent if it is within the past six
 544          ;; months.  A Gregorian year has 365.2425 * 24 * 60 * 60 ==
 545          ;; 31556952 seconds on the average, and half of that is 15778476.
 546          ;; Write the constant explicitly to avoid roundoff error.
 547          (past-cutoff -15778476)) ; half a Gregorian year
 548     (condition-case nil
 549         ;; Use traditional time format in the C or POSIX locale,
 550         ;; ISO-style time format otherwise, so columns line up.
 551         (let ((locale system-time-locale))
 552           (if (not locale)
 553               (let ((vars '("LC_ALL" "LC_TIME" "LANG")))
 554                 (while (and vars (not (setq locale (getenv (car vars)))))
 555                   (setq vars (cdr vars)))))
 556           (if (member locale '("C" "POSIX"))
 557               (setq locale nil))
 558           (format-time-string
 559            (if (and (<= past-cutoff diff) (<= diff 0))
 560                (if locale "%m-%d %H:%M" "%b %e %H:%M")
 561              (if locale "%Y-%m-%d " "%b %e  %Y"))
 562            time))
 563       (error "Unk  0  0000"))))
 564
 565 (provide 'ls-lisp)
 566
 567 ;;; ls-lisp.el ends here